mirror of
https://github.com/VOREStation/VOREStation.git
synced 2026-05-17 20:30:46 +01:00
Will
0c8488b0ae
* testing makes me feel good * invalid lists * get rid of those boards * show expected mats * oop * error * wip techweb porting * more techweb entries * ported too * disable those for now * okay nevermind i guess * already exists * assemblies * moar * welding helmet * many entries * lol tg * fix test * again * fixagain * more moved * update techweb test * catch that too * screeee * more fixes * missing announcement * orphaned sleevecard * some more fixing * test * more * oops * glasses * illegal icons * non starting * it's starting * messed up * cleanup * more generic stuff * morrrreee * the plastic set * oops * correct value * barbed wires * more cleaning * many more * gone * cleanup * no longer * do not allow duped designs * it's own node * proper order no dupes * last of the broken nodes * fix bad path * cleanup * more test more limits * gone * almost done * these are gone * syringe gun * bioregenerator design * all moved * organized and webbed * more fixes * oops * cleaning up * organization * clean up * organize * organized * didn't save * wrong mat * adds many missing ammo types * svd doesn't exist * 10mm pistol added * magazines not casings * these are pistols * this is used by like, one weapon * m1 is ancient * this is hunting * extremely botched untested lathe * disk junk * rough foundations * slowly converting * slowly building this * local materials * almost * big reorganization * more cleanup * more cleaning * lathe stuff * small fixes * oops * many fixes * mat fix * more fixes * actually isolate the hacked designs * protolathe hacking * imprinter hacking * missing ammos * sheet printing for autolathe * fixs * again * fixed test * test test * fix * fix * WHY * fix it... * here we go * material print * on turf * body disk * consistant name * Many weapons to hacked lathe * missing node * wrong section * fixes * this list should be unified * ammo boxes * don't do single shells anymore * wat * specifics * snowflake * not needed * already available * pickaxe too * tweak * removed unneeded node * missing surgery items * Apply suggestion from @Cameron-The-Raven * Adds RMS * typo * illegal needs hacked * disabled material weapons * circuit testing * STRING TEST * test * fixing some things * huh? * hidden circuits * some flakey boards * grammar * fixes * more hidden * wrong board * security cams * alert consoles * spaceheater is simple enough to not have one * pcus * cargo vendors * tcomms stuff * solar tracker circuit * artifact stuff * SM stuff * illegal machines * med machines * no longer needed * more stuff * these are not standard * moreeee * doppler and more * organized * finishing * oop * use the define * inheret * dopper fixes * space heater * doing some organization * explain the var * some tweaks * wrong one * fixed test * material test too * simple roto gens * use the define * emergency power node * tgui fixes for icons * not needed * color blended material designs * icons for large research * oops * unshit that * use stack here * center math * . * . * . * . * . * unifi * fix these * NO COPYPASTA * ILLEEGGALLL * mandate descriptions * agony * actually lets do this * use macros * description * desc * desc * desc * desc * desc * desc * gps desc * telecomms component desc --------- Co-authored-by: Cameron Lennox <killer65311@gmail.com> Co-authored-by: Kashargul <144968721+Kashargul@users.noreply.github.com>
87 lines
2.3 KiB
Plaintext
87 lines
2.3 KiB
Plaintext
/obj/machinery/rnd
|
|
name = "R&D Device"
|
|
icon = 'icons/obj/machines/research_vr.dmi'
|
|
density = TRUE
|
|
anchored = TRUE
|
|
use_power = USE_POWER_IDLE
|
|
|
|
///Are we currently printing a machine
|
|
var/busy = FALSE
|
|
///Is this machne hacked via wires
|
|
var/hacked = FALSE
|
|
///Is this machine disabled via wires
|
|
var/disabled = FALSE
|
|
///Ref to global science techweb.
|
|
var/datum/techweb/stored_research
|
|
///The item loaded inside the machine, used by experimentors and destructive analyzers only.
|
|
var/datum/weakref/loaded_item
|
|
/// Wires for hacking, not every rnd machine has this set
|
|
var/datum/wires/protolathe/wires = null
|
|
|
|
/obj/machinery/rnd/Initialize(mapload)
|
|
. = ..()
|
|
if(!stored_research)
|
|
CONNECT_TO_RND_SERVER_ROUNDSTART(stored_research, src)
|
|
if(stored_research)
|
|
on_connected_techweb()
|
|
|
|
/obj/machinery/rnd/Destroy()
|
|
if(stored_research)
|
|
log_research("[src] disconnected from techweb [stored_research] (destroyed).")
|
|
stored_research = null
|
|
QDEL_NULL(wires)
|
|
return ..()
|
|
|
|
/obj/machinery/rnd/tgui_status(mob/user)
|
|
if(disabled)
|
|
return STATUS_CLOSE
|
|
return ..()
|
|
|
|
///Called when attempting to connect the machine to a techweb, forgetting the old.
|
|
/obj/machinery/rnd/proc/connect_techweb(datum/techweb/new_techweb)
|
|
if(stored_research)
|
|
log_research("[src] disconnected from techweb [stored_research] when connected to [new_techweb].")
|
|
stored_research = new_techweb
|
|
if(!isnull(stored_research))
|
|
on_connected_techweb()
|
|
|
|
///Called post-connection to a new techweb.
|
|
/obj/machinery/rnd/proc/on_connected_techweb()
|
|
SHOULD_CALL_PARENT(FALSE)
|
|
|
|
///Reset the state of this machine
|
|
/obj/machinery/rnd/proc/reset_busy()
|
|
busy = FALSE
|
|
|
|
/obj/machinery/rnd/attack_hand(mob/user)
|
|
. = ..()
|
|
if(.)
|
|
return
|
|
if(wires && panel_open)
|
|
return wires.Interact(user)
|
|
if(disabled)
|
|
return
|
|
tgui_interact(user)
|
|
|
|
/obj/machinery/rnd/attackby(obj/item/W, mob/user, attack_modifier, click_parameters)
|
|
add_fingerprint(user)
|
|
|
|
if(default_deconstruction_screwdriver(user, W))
|
|
if(wires && panel_open)
|
|
wires.Interact(user)
|
|
return
|
|
if(default_deconstruction_crowbar(user, W))
|
|
return
|
|
if(default_part_replacement(user, W))
|
|
return
|
|
if(default_unfasten_wrench(user, W, 2 SECONDS))
|
|
return
|
|
return ..()
|
|
|
|
/obj/machinery/rnd/dismantle()
|
|
var/obj/item/our_item = loaded_item?.resolve()
|
|
if(our_item)
|
|
our_item.forceMove(drop_location())
|
|
loaded_item = null
|
|
. = ..()
|