mirror of
https://github.com/VOREStation/VOREStation.git
synced 2026-05-17 20:30:46 +01:00
Cameron Lennox
d5849910e5
* Begin clickcode attack_self fix Begins the work to make everything call back to parent for attack_self so that signals are sacred. * Makes MORE things call the attack_self() parent Yes, I could make special_handling a var on obj/item HOWEVER i want it to be specific so it can be tracked down later and ONLY the objects that use it can be refactored instead of sitting there literally forever and it just becoming 'a thing'. * Finishes making the rest of attack_self call parent. As mentioned, things such as 'specialty_goggles' 'special_handling' and the such are only there to help with attack_self until the attack_self is recoded for those items. * begone foul demon * some more cleanup * These * GOD this was annoying * yeh * Fix this * fLARES * Thesee too * toys! * Even more! * More fixes * Even more * rest of em * these too * Update syndie.dm * hardref clear * Update code/game/gamemodes/nuclear/pinpointer.dm * Update code/game/objects/effects/mines.dm * Update code/game/objects/items/blueprints_vr.dm * Update code/game/objects/items/blueprints_vr.dm * Update code/game/objects/items/contraband_vr.dm * Update code/game/objects/items/crayons.dm * Update code/game/objects/items/crayons.dm * Update code/game/objects/items/gunbox.dm * Update code/game/objects/items/gunbox.dm * Update code/game/objects/items/gunbox_vr.dm * Update code/game/objects/items/gunbox_vr.dm * Update code/game/objects/items/weapons/gift_wrappaper.dm * Update code/game/objects/items/crayons.dm * Update code/game/objects/items/crayons.dm * Update code/game/objects/items/gunbox.dm * these too * Update maintpanel_stack.dm * angry warning * Fixes packaged snacks. Fixes improper var default. * Special handling for these * proper poly types * Fixes magclaws Makes the 'features' it had just part of base magboots that can be adjusted via varswap. * Fixes jackets Fixes https://github.com/VOREStation/VOREStation/issues/18941 * Small bugfix Makes p_Theyre properly capitialize Makes examine show proper wording * Update gift_wrappaper.dm
50 lines
1.8 KiB
Plaintext
50 lines
1.8 KiB
Plaintext
// Bluespace crystals, used in telescience and when crushed it will blink you to a random turf.
|
|
|
|
/obj/item/bluespace_crystal
|
|
name = "bluespace crystal"
|
|
desc = "A glowing bluespace crystal, not much is known about how they work. It looks very delicate."
|
|
icon = 'icons/obj/telescience.dmi'
|
|
icon_state = "bluespace_crystal"
|
|
w_class = ITEMSIZE_TINY
|
|
origin_tech = list(TECH_BLUESPACE = 6, TECH_MATERIAL = 3)
|
|
var/blink_range = 8 // The teleport range when crushed/thrown at someone.
|
|
|
|
/obj/item/bluespace_crystal/Initialize(mapload)
|
|
. = ..()
|
|
pixel_x = rand(-5, 5)
|
|
pixel_y = rand(-5, 5)
|
|
|
|
/obj/item/bluespace_crystal/attack_self(mob/user)
|
|
. = ..(user)
|
|
if(.)
|
|
return TRUE
|
|
user.visible_message(span_warning("[user] crushes [src]!"), span_danger("You crush [src]!"))
|
|
var/datum/effect/effect/system/spark_spread/s = new /datum/effect/effect/system/spark_spread()
|
|
s.set_up(5, 1, get_turf(src))
|
|
s.start()
|
|
blink_mob(user)
|
|
user.unEquip(src)
|
|
qdel(src)
|
|
|
|
/obj/item/bluespace_crystal/proc/blink_mob(mob/living/L)
|
|
do_teleport(L, get_turf(L), blink_range, asoundin = 'sound/effects/phasein.ogg')
|
|
|
|
/obj/item/bluespace_crystal/throw_impact(atom/hit_atom)
|
|
if(!..()) // not caught in mid-air
|
|
visible_message(span_notice("[src] fizzles and disappears upon impact!"))
|
|
var/turf/T = get_turf(hit_atom)
|
|
var/datum/effect/effect/system/spark_spread/s = new /datum/effect/effect/system/spark_spread()
|
|
s.set_up(5, 1, T)
|
|
s.start()
|
|
if(isliving(hit_atom))
|
|
blink_mob(hit_atom)
|
|
qdel(src)
|
|
|
|
// Artifical bluespace crystal, doesn't give you much research.
|
|
|
|
/obj/item/bluespace_crystal/artificial
|
|
name = "artificial bluespace crystal"
|
|
desc = "An artificially made bluespace crystal, it looks delicate."
|
|
origin_tech = list(TECH_BLUESPACE = 3, TECH_PHORON = 4)
|
|
blink_range = 4 // Not as good as the organic stuff!
|