mirror of
https://github.com/VOREStation/VOREStation.git
synced 2026-03-22 11:43:12 +00:00
f4bf017921
* Unit Test rework & Master/Ticker update * Fixes and working unit testing * Fixes * Test fixes and FA update * Fixed runtimes * Radio subsystem * move that glob wherever later * ident * CIBUILDING compile option * Fixed runtimes * Some changes to the workflow * CI Split * More split * Pathing * Linters and Annotators * ci dir fix * Missing undef fixed * Enable grep checks * More test conversions * More split * Correct file * Removes unneeded inputs * oop * More dependency changes * More conversions * Conversion fixes * Fixes * Some assert fixes * Corrects start gate * Converted some README.dms to README.mds * Removes duplicate proc * Removes unused defines * Example configs * fix dll access viol by double calling * Post-rebase fixes * Cleans up names global list * Undef restart counter * More code/game/ cleanup * Statpanel update * Skybox * add * Fix ticker * Roundend fix * Persistence dependency update * Reordering * Reordering * Reordering * Initstage fix * . * . * Reorder * Reorder * Circle * Mobs * Air * Test fix * CI Script Fix * Configs * More ticker stuff * This is now in 'reboot world' * Restart world announcements * no glob in PreInit * to define * Update * Removed old include * Make this file normal again * moved * test * shared unit testing objects * Updates batched_spritesheets and universal_icon * . * job data debug * rm that * init order * show us * . * i wonder * . * . * urg * do we not have a job ID? * . * rm sleep for now * updated rust-g linux binaries * binaries update 2 * binaries update 3 * testing something * change that * test something * . * . * . * locavar * test * move that * . * debug * don't run this test * strack trace it * cleaner * . * . * cras again * also comment this out * return to official rust g * Update robot_icons.dm * monitor the generation * . --------- Co-authored-by: Kashargul <144968721+Kashargul@users.noreply.github.com>
55 lines
2.2 KiB
Plaintext
55 lines
2.2 KiB
Plaintext
PROCESSING_SUBSYSTEM_DEF(instruments)
|
|
name = "Instruments"
|
|
wait = 0.5
|
|
flags = SS_KEEP_TIMING
|
|
priority = FIRE_PRIORITY_INSTRUMENTS
|
|
/// List of all instrument data, associative id = datum
|
|
var/static/list/datum/instrument/instrument_data = list()
|
|
/// List of all song datums.
|
|
var/static/list/datum/song/songs = list()
|
|
/// Max lines in songs
|
|
var/static/musician_maxlines = 600
|
|
/// Max characters per line in songs
|
|
var/static/musician_maxlinechars = 300
|
|
/// Deciseconds between hearchecks. Too high and instruments seem to lag when people are moving around in terms of who can hear it. Too low and the server lags from this.
|
|
var/static/musician_hearcheck_mindelay = 5
|
|
/// Maximum instrument channels total instruments are allowed to use. This is so you don't have instruments deadlocking all sound channels.
|
|
var/static/max_instrument_channels = MAX_INSTRUMENT_CHANNELS
|
|
/// Current number of channels allocated for instruments
|
|
var/static/current_instrument_channels = 0
|
|
/// Single cached list for synthesizer instrument ids, so you don't have to have a new list with every synthesizer.
|
|
var/static/list/synthesizer_instrument_ids
|
|
|
|
/datum/controller/subsystem/processing/instruments/Initialize()
|
|
initialize_instrument_data()
|
|
synthesizer_instrument_ids = get_allowed_instrument_ids()
|
|
return SS_INIT_SUCCESS
|
|
|
|
/datum/controller/subsystem/processing/instruments/proc/on_song_new(datum/song/S)
|
|
songs += S
|
|
|
|
/datum/controller/subsystem/processing/instruments/proc/on_song_del(datum/song/S)
|
|
songs -= S
|
|
|
|
/datum/controller/subsystem/processing/instruments/proc/initialize_instrument_data()
|
|
for(var/datum/instrument/I as anything in subtypesof(/datum/instrument))
|
|
if(initial(I.instrument_type) == I)
|
|
continue
|
|
I = new I
|
|
I.Initialize()
|
|
if(!I.id)
|
|
qdel(I)
|
|
continue
|
|
instrument_data[I.id] = I
|
|
CHECK_TICK
|
|
|
|
/datum/controller/subsystem/processing/instruments/proc/get_instrument(id_or_path)
|
|
return instrument_data["[id_or_path]"]
|
|
|
|
/datum/controller/subsystem/processing/instruments/proc/reserve_instrument_channel(datum/instrument/I)
|
|
if(current_instrument_channels > max_instrument_channels)
|
|
return
|
|
. = SSsounds.reserve_sound_channel(I)
|
|
if(!isnull(.))
|
|
current_instrument_channels++
|