mirror of
https://github.com/VOREStation/VOREStation.git
synced 2026-08-20 18:47:53 +01:00
311c0117c1
* Automatic changelog compile [ci skip] * replace all bay instances for realname and nickname with tg * add comments where uncertain of sanitisation needed * Fix issue from git conflict.. * Fix issue causing setup menu not opening * Attempt to clean up how name datums are handled * Remove redundant check * Fix number issues with character names --------- Co-authored-by: vorestation-ci[bot] <199609141+vorestation-ci[bot]@users.noreply.github.com>
66 lines
2.7 KiB
Plaintext
66 lines
2.7 KiB
Plaintext
//Pretty small file, mostly just for storage.
|
|
/datum/preferences
|
|
var/obj/item/nif/nif_path
|
|
var/nif_durability
|
|
var/list/nif_savedata
|
|
|
|
// Definition of the stuff for NIFs
|
|
// Magic bullshit, they're stored separately from everything else
|
|
/datum/category_item/player_setup_item/general/nif
|
|
name = "NIF Data"
|
|
sort_order = 8
|
|
|
|
/proc/nif_savefile_path(ckey)
|
|
if(!ckey)
|
|
return
|
|
return "data/player_saves/[copytext(ckey,1,2)]/[ckey]/nif.json"
|
|
|
|
/datum/category_item/player_setup_item/general/nif/load_character()
|
|
var/datum/json_savefile/savefile = new /datum/json_savefile(nif_savefile_path(pref.client_ckey))
|
|
var/list/save_data_file = savefile.get_entry("character[pref.default_slot]", list())
|
|
|
|
pref.nif_path = save_data_file["nif_path"]
|
|
pref.nif_durability = save_data_file["nif_durability"]
|
|
pref.nif_savedata = check_list_copy(save_data_file["nif_savedata"])
|
|
|
|
/datum/category_item/player_setup_item/general/nif/save_character()
|
|
var/datum/json_savefile/savefile = new /datum/json_savefile(nif_savefile_path(pref.client_ckey))
|
|
var/list/save_data_file = savefile.get_entry("character[pref.default_slot]", list())
|
|
|
|
save_data_file["nif_path"] = pref.nif_path
|
|
save_data_file["nif_durability"] = pref.nif_durability
|
|
save_data_file["nif_savedata"] = check_list_copy(pref.nif_savedata)
|
|
|
|
savefile.set_entry("character[pref.default_slot]", save_data_file)
|
|
savefile.save()
|
|
|
|
/datum/category_item/player_setup_item/general/nif/sanitize_character()
|
|
var/char_name = pref.read_preference(/datum/preference/name/real_name) || "-name not yet loaded-"
|
|
if(pref.nif_path && !ispath(pref.nif_path)) //We have at least a text string that should be a path.
|
|
pref.nif_path = text2path(pref.nif_path) //Try to convert it to a hard path.
|
|
if(!pref.nif_path) //If we couldn't, kill it.
|
|
pref.nif_path = null //Kill!
|
|
WARNING("Loaded a NIF but it was an invalid path, [char_name]")
|
|
|
|
if (ispath(pref.nif_path, /obj/item/nif/protean) && pref.species != SPECIES_PROTEAN) //no free nifs
|
|
pref.nif_path = null
|
|
|
|
if(ispath(pref.nif_path) && isnull(pref.nif_durability)) //How'd you lose this?
|
|
pref.nif_durability = initial(pref.nif_path.durability) //Well, have a new one, my bad.
|
|
WARNING("Loaded a NIF but with no durability, [char_name]")
|
|
|
|
if(!islist(pref.nif_savedata))
|
|
pref.nif_savedata = list()
|
|
|
|
/datum/category_item/player_setup_item/general/nif/copy_to_mob(var/mob/living/carbon/human/character)
|
|
//If you had a NIF...
|
|
if(istype(character) && ispath(pref.nif_path) && pref.nif_durability && !ismannequin(character))
|
|
new pref.nif_path(character, pref.nif_durability, pref.nif_savedata)
|
|
|
|
/datum/category_item/player_setup_item/general/nif/tgui_data(mob/user, datum/tgui/ui, datum/tgui_state/state)
|
|
var/list/data = ..()
|
|
|
|
data["nif"] = ispath(pref.nif_path)
|
|
|
|
return data
|