mirror of
https://github.com/yogstation13/Yogstation.git
synced 2025-02-26 09:04:50 +00:00
3baeaeb0c4
* Steals tg's span macros * Fix alphabet * Updated some more spans * Misses a conflict * Fix compile errors * Converts more spans * oops
90 lines
2.7 KiB
Plaintext
90 lines
2.7 KiB
Plaintext
//CONTAINS: Evidence bags
|
|
|
|
/obj/item/evidencebag
|
|
name = "evidence bag"
|
|
desc = "An empty evidence bag."
|
|
icon = 'icons/obj/storage.dmi'
|
|
icon_state = "evidenceobj"
|
|
item_state = ""
|
|
w_class = WEIGHT_CLASS_TINY
|
|
|
|
/obj/item/evidencebag/afterattack(obj/item/I, mob/user,proximity)
|
|
. = ..()
|
|
if(!proximity || loc == I)
|
|
return
|
|
evidencebagEquip(I, user)
|
|
|
|
/obj/item/evidencebag/attackby(obj/item/I, mob/user, params)
|
|
if(evidencebagEquip(I, user))
|
|
return 1
|
|
|
|
/obj/item/evidencebag/handle_atom_del(atom/A)
|
|
cut_overlays()
|
|
w_class = initial(w_class)
|
|
icon_state = initial(icon_state)
|
|
desc = initial(desc)
|
|
|
|
/obj/item/evidencebag/proc/evidencebagEquip(obj/item/I, mob/user)
|
|
if(!istype(I) || I.anchored == 1)
|
|
return
|
|
|
|
if(istype(I, /obj/item/evidencebag))
|
|
to_chat(user, span_notice("You find putting an evidence bag in another evidence bag to be slightly absurd."))
|
|
return 1 //now this is podracing
|
|
|
|
if(I.w_class > WEIGHT_CLASS_NORMAL)
|
|
to_chat(user, span_notice("[I] won't fit in [src]."))
|
|
return
|
|
|
|
if(contents.len)
|
|
to_chat(user, span_notice("[src] already has something inside it."))
|
|
return
|
|
|
|
if(!isturf(I.loc)) //If it isn't on the floor. Do some checks to see if it's in our hands or a box. Otherwise give up.
|
|
if(SEND_SIGNAL(I.loc, COMSIG_CONTAINS_STORAGE)) //in a container.
|
|
SEND_SIGNAL(I.loc, COMSIG_TRY_STORAGE_TAKE, I, src)
|
|
if(!user.dropItemToGround(I))
|
|
return
|
|
|
|
user.visible_message("[user] puts [I] into [src].", span_notice("You put [I] inside [src]."),\
|
|
span_italics("You hear a rustle as someone puts something into a plastic bag."))
|
|
|
|
icon_state = "evidence"
|
|
|
|
var/mutable_appearance/in_evidence = new(I)
|
|
in_evidence.plane = FLOAT_PLANE
|
|
in_evidence.layer = FLOAT_LAYER
|
|
in_evidence.pixel_x = 0
|
|
in_evidence.pixel_y = 0
|
|
add_overlay(in_evidence)
|
|
add_overlay("evidence") //should look nicer for transparent stuff. not really that important, but hey.
|
|
|
|
desc = "An evidence bag containing [I]. [I.desc]"
|
|
I.forceMove(src)
|
|
w_class = I.w_class
|
|
return 1
|
|
|
|
/obj/item/evidencebag/attack_self(mob/user)
|
|
if(contents.len)
|
|
var/obj/item/I = contents[1]
|
|
user.visible_message("[user] takes [I] out of [src].", span_notice("You take [I] out of [src]."),\
|
|
span_italics("You hear someone rustle around in a plastic bag, and remove something."))
|
|
cut_overlays() //remove the overlays
|
|
user.put_in_hands(I)
|
|
w_class = WEIGHT_CLASS_TINY
|
|
icon_state = "evidenceobj"
|
|
desc = "An empty evidence bag."
|
|
|
|
else
|
|
to_chat(user, "[src] is empty.")
|
|
icon_state = "evidenceobj"
|
|
return
|
|
|
|
/obj/item/storage/box/evidence
|
|
name = "evidence bag box"
|
|
desc = "A box claiming to contain evidence bags."
|
|
|
|
/obj/item/storage/box/evidence/PopulateContents()
|
|
for(var/i in 1 to 6)
|
|
new /obj/item/evidencebag(src)
|