mirror of
https://github.com/yogstation13/Yogstation.git
synced 2025-02-26 09:04:50 +00:00
bb3d4a564f
* Yoinks all the shit man * Hopefully shuts CI the fuck up * Bins this stupid shit * Fixes * Windows too, I GUESS * fixes airlock alpha filter breaking on 514 (#4441) * fix This manually sets the alpha 0 and alpha 255 correctly as this feature of the alpha filter does not seem to work correctly on 514. * small comment change * Update airlock.dm Co-authored-by: MNarath <47279840+MNarath1@users.noreply.github.com>
120 lines
5.0 KiB
Plaintext
120 lines
5.0 KiB
Plaintext
//traits with no real impact that can be taken freely
|
|
//MAKE SURE THESE DO NOT MAJORLY IMPACT GAMEPLAY. those should be positive or negative traits.
|
|
|
|
/datum/quirk/vegetarian
|
|
name = "Vegetarian"
|
|
desc = "You find the idea of eating meat morally and physically repulsive."
|
|
value = 0
|
|
gain_text = "<span class='notice'>You feel repulsion at the idea of eating meat.</span>"
|
|
lose_text = "<span class='notice'>You feel like eating meat isn't that bad.</span>"
|
|
medical_record_text = "Patient reports a vegetarian diet."
|
|
|
|
/datum/quirk/vegetarian/add()
|
|
var/mob/living/carbon/human/H = quirk_holder
|
|
var/datum/species/species = H.dna.species
|
|
species.liked_food &= ~MEAT
|
|
species.disliked_food |= MEAT
|
|
|
|
/datum/quirk/vegetarian/remove()
|
|
var/mob/living/carbon/human/H = quirk_holder
|
|
if(H)
|
|
var/datum/species/species = H.dna.species
|
|
if(initial(species.liked_food) & MEAT)
|
|
species.liked_food |= MEAT
|
|
if(!(initial(species.disliked_food) & MEAT))
|
|
species.disliked_food &= ~MEAT
|
|
|
|
/datum/quirk/pineapple_liker
|
|
name = "Ananas Affinity"
|
|
desc = "You find yourself greatly enjoying fruits of the ananas genus. You can't seem to ever get enough of their sweet goodness!"
|
|
value = 0
|
|
gain_text = "<span class='notice'>You feel an intense craving for pineapple.</span>"
|
|
lose_text = "<span class='notice'>Your feelings towards pineapples seem to return to a lukewarm state.</span>"
|
|
medical_record_text = "Patient demonstrates a pathological love of pineapple."
|
|
|
|
/datum/quirk/pineapple_liker/add()
|
|
var/mob/living/carbon/human/H = quirk_holder
|
|
var/datum/species/species = H.dna.species
|
|
species.liked_food |= PINEAPPLE
|
|
|
|
/datum/quirk/pineapple_liker/remove()
|
|
var/mob/living/carbon/human/H = quirk_holder
|
|
if(H)
|
|
var/datum/species/species = H.dna.species
|
|
species.liked_food &= ~PINEAPPLE
|
|
|
|
/datum/quirk/pineapple_hater
|
|
name = "Ananas Aversion"
|
|
desc = "You find yourself greatly detesting fruits of the ananas genus. Serious, how the hell can anyone say these things are good? And what kind of madman would even dare putting it on a pizza!?"
|
|
value = 0
|
|
gain_text = "<span class='notice'>You find yourself pondering what kind of idiot actually enjoys pineapples...</span>"
|
|
lose_text = "<span class='notice'>Your feelings towards pineapples seem to return to a lukewarm state.</span>"
|
|
medical_record_text = "Patient is correct to think that pineapple is disgusting."
|
|
|
|
/datum/quirk/pineapple_hater/add()
|
|
var/mob/living/carbon/human/H = quirk_holder
|
|
var/datum/species/species = H.dna.species
|
|
species.disliked_food |= PINEAPPLE
|
|
|
|
/datum/quirk/pineapple_hater/remove()
|
|
var/mob/living/carbon/human/H = quirk_holder
|
|
if(H)
|
|
var/datum/species/species = H.dna.species
|
|
species.disliked_food &= ~PINEAPPLE
|
|
|
|
/datum/quirk/deviant_tastes
|
|
name = "Deviant Tastes"
|
|
desc = "You dislike food that most people enjoy, and find delicious what they don't."
|
|
value = 0
|
|
gain_text = "<span class='notice'>You start craving something that tastes strange.</span>"
|
|
lose_text = "<span class='notice'>You feel like eating normal food again.</span>"
|
|
medical_record_text = "Patient demonstrates irregular nutrition preferences."
|
|
|
|
/datum/quirk/deviant_tastes/add()
|
|
var/mob/living/carbon/human/H = quirk_holder
|
|
var/datum/species/species = H.dna.species
|
|
var/liked = species.liked_food
|
|
species.liked_food = species.disliked_food
|
|
species.disliked_food = liked
|
|
|
|
/datum/quirk/deviant_tastes/remove()
|
|
var/mob/living/carbon/human/H = quirk_holder
|
|
if(H)
|
|
var/datum/species/species = H.dna.species
|
|
species.liked_food = initial(species.liked_food)
|
|
species.disliked_food = initial(species.disliked_food)
|
|
|
|
/datum/quirk/monochromatic
|
|
name = "Monochromacy"
|
|
desc = "You suffer from full colorblindness, and perceive nearly the entire world in blacks and whites."
|
|
value = 0
|
|
medical_record_text = "Patient is afflicted with almost complete color blindness."
|
|
|
|
/datum/quirk/monochromatic/add()
|
|
quirk_holder.add_client_colour(/datum/client_colour/monochrome)
|
|
|
|
/datum/quirk/monochromatic/post_add()
|
|
if(quirk_holder.mind.assigned_role == "Detective")
|
|
to_chat(quirk_holder, "<span class='boldannounce'>Mmm. Nothing's ever clear on this station. It's all shades of gray...</span>")
|
|
quirk_holder.playsound_local(quirk_holder, 'sound/ambience/ambidet1.ogg', 50, FALSE)
|
|
|
|
/datum/quirk/monochromatic/remove()
|
|
if(quirk_holder)
|
|
quirk_holder.remove_client_colour(/datum/client_colour/monochrome)
|
|
|
|
/datum/quirk/random_accent
|
|
name = "Randomized Accent"
|
|
desc = "You have developed a random accent."
|
|
value = 0
|
|
mob_trait = TRAIT_RANDOM_ACCENT
|
|
gain_text = "<span class='danger'>You have developed an accent.</span>"
|
|
lose_text = "<span class='notice'>You have better control of how you pronounce your words.</span>"
|
|
medical_record_text = "Patient is difficult to understand."
|
|
|
|
/datum/quirk/random_accent/post_add()
|
|
var/mob/living/carbon/human/H = quirk_holder
|
|
if(!H.mind.accent_name)
|
|
H.mind.RegisterSignal(H, COMSIG_MOB_SAY, /datum/mind/.proc/handle_speech)
|
|
H.mind.accent_name = pick(assoc_list_strip_value(GLOB.accents_name2file))// Right now this pick just picks a straight random one from all implemented.
|
|
|