mirror of
https://github.com/yogstation13/Yogstation.git
synced 2025-02-26 09:04:50 +00:00
2333d64f09
* Cherry picks the unicode part 2 PR from TG * Things * drop 512 support * TAN --> tan * Manually does the things that was in renamed files * CLAMP --> clamp * ismovableatom -> ismovable * bugfixes, tg is bad * Ports sanitize_name * Bumps checks * Fixes new linter errors (#48126) About The Pull Request This fixes the errors raised by the new feature I'm adding to the linter: SpaceManiac/SpacemanDMM#119 * Update SpacemanDMM suite to 1.2 (#48785) * Update SpacemanDMM suite to 1.2 * Fix new lint errors * Removes unreachable code (#48143) About The Pull Request As detected by SpaceManiac/SpacemanDMM#123 * casually fixes 50 bugs * stoopid evil dreamchecker * stoopid evil dreamchecker * stoopid evil dreamchecker * almost the same thing * Makes all UIs UTF-8 * Fixes bugs * Fixes runtimes, some related to 513, some not * Fixes agent ids Co-authored-by: MrPerson <spamtaffic@gmail.com> Co-authored-by: alexkar598 <> Co-authored-by: spookydonut <github@spooksoftware.com>
82 lines
2.8 KiB
Plaintext
82 lines
2.8 KiB
Plaintext
#define STARTUP_STAGE 1
|
|
#define MAIN_STAGE 2
|
|
#define WIND_DOWN_STAGE 3
|
|
#define END_STAGE 4
|
|
|
|
//Used for all kinds of weather, ex. lavaland ash storms.
|
|
SUBSYSTEM_DEF(weather)
|
|
name = "Weather"
|
|
flags = SS_BACKGROUND
|
|
wait = 10
|
|
runlevels = RUNLEVEL_GAME
|
|
var/list/processing = list()
|
|
var/list/eligible_zlevels = list()
|
|
var/list/next_hit_by_zlevel = list() //Used by barometers to know when the next storm is coming
|
|
|
|
/datum/controller/subsystem/weather/fire()
|
|
// process active weather
|
|
for(var/V in processing)
|
|
var/datum/weather/W = V
|
|
if(W.aesthetic || W.stage != MAIN_STAGE)
|
|
continue
|
|
for(var/i in GLOB.mob_living_list)
|
|
var/mob/living/L = i
|
|
if(W.can_weather_act(L))
|
|
W.weather_act(L)
|
|
|
|
// start random weather on relevant levels
|
|
for(var/z in eligible_zlevels)
|
|
var/possible_weather = eligible_zlevels[z]
|
|
var/datum/weather/W = pickweight(possible_weather)
|
|
run_weather(W, list(text2num(z)))
|
|
eligible_zlevels -= z
|
|
var/randTime = rand(3000, 6000)
|
|
addtimer(CALLBACK(src, .proc/make_eligible, z, possible_weather), randTime + initial(W.weather_duration_upper), TIMER_UNIQUE) //Around 5-10 minutes between weathers
|
|
next_hit_by_zlevel["[z]"] = world.time + randTime + initial(W.telegraph_duration)
|
|
|
|
/datum/controller/subsystem/weather/Initialize(start_timeofday)
|
|
for(var/V in subtypesof(/datum/weather))
|
|
var/datum/weather/W = V
|
|
var/probability = initial(W.probability)
|
|
var/target_trait = initial(W.target_trait)
|
|
|
|
// any weather with a probability set may occur at random
|
|
if (probability)
|
|
for(var/z in SSmapping.levels_by_trait(target_trait))
|
|
LAZYINITLIST(eligible_zlevels["[z]"])
|
|
eligible_zlevels["[z]"][W] = probability
|
|
return ..()
|
|
|
|
/datum/controller/subsystem/weather/proc/run_weather(datum/weather/weather_datum_type, z_levels)
|
|
if (istext(weather_datum_type))
|
|
for (var/V in subtypesof(/datum/weather))
|
|
var/datum/weather/W = V
|
|
if (initial(W.name) == weather_datum_type)
|
|
weather_datum_type = V
|
|
break
|
|
if (!ispath(weather_datum_type, /datum/weather))
|
|
CRASH("run_weather called with invalid weather_datum_type: [weather_datum_type || "null"]")
|
|
|
|
if (isnull(z_levels))
|
|
z_levels = SSmapping.levels_by_trait(initial(weather_datum_type.target_trait))
|
|
else if (isnum(z_levels))
|
|
z_levels = list(z_levels)
|
|
else if (!islist(z_levels))
|
|
CRASH("run_weather called with invalid z_levels: [z_levels || "null"]")
|
|
|
|
var/datum/weather/W = new weather_datum_type(z_levels)
|
|
W.telegraph()
|
|
|
|
/datum/controller/subsystem/weather/proc/make_eligible(z, possible_weather)
|
|
eligible_zlevels[z] = possible_weather
|
|
next_hit_by_zlevel["[z]"] = null
|
|
|
|
/datum/controller/subsystem/weather/proc/get_weather(z, area/active_area)
|
|
var/datum/weather/A
|
|
for(var/V in processing)
|
|
var/datum/weather/W = V
|
|
if((z in W.impacted_z_levels) && W.area_type == active_area.type)
|
|
A = W
|
|
break
|
|
return A
|