mirror of
https://github.com/yogstation13/Yogstation.git
synced 2025-02-26 09:04:50 +00:00
9e1ef0ffe2
* Add the system for managed global variables * Travis ban old globals * So you CAN inline proccall, that's neat * Fix that * master.dm * Remove the hack procs * Move InitGlobals to the proper spot * configuration.dm * Fix the missing pre-slash * clockcult.dm * This is probably for the best * Doy * Fix shit * Rest of the DEFINES tree * Fix * Use global. for access * Update find_references_in_globals Always hated that proc Whoever made it must've bee a r e a l idiot... * __HELPERS tree * Move global initialization to master. Fix the declaration * database.dm * Dat newline * I said DECLARATIVE order! * Here's something you can chew on @Iamgoofball * game_modes.dm * Fix this * genetics.dm * flavor_misc.dm * More stuff * Do it mso's way. Keep the controllers as global * Make master actually see it * Fix * Finish _globalvars/lists * Finish the rest of the _globalvars tree * This is weird * Migrate the controllers * SLOTH -> GLOB * Lighting globals * round_start_time -> ticker * PAI card list -> pai SS * record_id_num -> static * Diseases list -> SSdisease * More disease globals to the SS * More disease stuff * Emote list * Better and better * Bluh * So much stuff * Ahh * Wires * dview * station_areas * Teleportlocs * blood_splatter_icons * Stuff and such * More stuff * RAD IO * More stuff and such * Blob shit * Changeling stuff * Add "Balance" to changelogs * Balance for changelog compiler + Auto Tagging * Update the PR template * hivemind_bank * Bip * sacrificed * Good shit * Better define * More cult shit * Devil shit * Gang shit * > borers Fix shit * Rename the define * Nuke * Objectives * Sandbox * Multiverse sword * Announce systems * Stuff and such * TC con * Airlock * doppllllerrrrrr * holopads * Shut up byond you inconsistent fuck * Sneaky fuck * Burp * Bip * Fixnshit * Port without regard * askdlfjs; * asdfjasoidojfi * Protected globals and more * SO MANY * ajsimkvahsaoisd * akfdsiaopwimfeoiwafaw * gsdfigjosidjfgiosdg * AHHHHHHHHHHHHHHHHHHHHHHH!!!!! * facerolll * ASDFASDFASDF * Removes the unused parts of dmm_suite * WIP * Fix quote * asdfjauwfnkjs * afwlunhskjfda * asfjlaiwuefhaf * SO CLOSE * wwwweeeeeewwwww * agdgmoewranwg * HOLY MOTHER OF FUCK AND THATS JUST HALF THE JOB?!? * Fix syntax errors * 100 errors * Another 100 * So many... * Ugh * More shit * kilme * Stuuuuuufffff * ajrgmrlshio;djfa;sdkl * jkbhkhjbmjvjmh * soi soi soi * butt * TODAY WE LEARNED THAT GLOBAL AND STATIC ARE THE EXACT SAME FUCKING THING * lllllllllllllllllllllllllllllllllllllllllll * afsdijfiawhnflnjhnwsdfs * yugykihlugk,kj * time to go * STUFFF!!! * AAAAAAAAAAAAAAAAAHHHHHHHHHHHHHHHHHHHHHHHHHHH!!!!!!!!!!!!!!!!!!!!!!! * ngoaijdjlfkamsdlkf * Break time * aufjsdklfalsjfi * CONTROL KAY AND PRAY * IT COMPILEELEELELAKLJFKLDAFJLKFDJLADKJHFLJKAJGAHIEJALDFJ!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!! * Goteem * Fix testing mode * This does not belong in this PR * Convert it to a controller * Eh, fuck this option * Revert controllerization Ill do it some other time * Fix * Working controllerization * FOR THE LOVE OF CHRIST PROTECT THE LOGS * Protect admins and deadmins * Use the inbuilt proc
103 lines
3.3 KiB
Plaintext
103 lines
3.3 KiB
Plaintext
|
|
|
|
//Few global vars to track the blob
|
|
GLOBAL_LIST_EMPTY(blobs) //complete list of all blobs made.
|
|
GLOBAL_LIST_EMPTY(blob_cores)
|
|
GLOBAL_LIST_EMPTY(overminds)
|
|
GLOBAL_LIST_EMPTY(blob_nodes)
|
|
GLOBAL_LIST_EMPTY(blobs_legit) //used for win-score calculations, contains only blobs counted for win condition
|
|
|
|
#define BLOB_NO_PLACE_TIME 1800 //time, in deciseconds, blobs are prevented from bursting in the gamemode
|
|
|
|
/datum/game_mode/blob
|
|
name = "blob"
|
|
config_tag = "blob"
|
|
antag_flag = ROLE_BLOB
|
|
|
|
required_players = 25
|
|
required_enemies = 1
|
|
recommended_enemies = 1
|
|
|
|
round_ends_with_antag_death = 1
|
|
|
|
announce_span = "green"
|
|
announce_text = "Dangerous gelatinous organisms are spreading throughout the station!\n\
|
|
<span class='green'>Blobs</span>: Consume the station and spread as far as you can.\n\
|
|
<span class='notice'>Crew</span>: Fight back the blobs and minimize station damage."
|
|
|
|
var/message_sent = FALSE
|
|
|
|
var/cores_to_spawn = 1
|
|
var/players_per_core = 25
|
|
var/blob_point_rate = 3
|
|
var/blob_base_starting_points = 80
|
|
|
|
var/blobwincount = 250
|
|
|
|
var/messagedelay_low = 2400 //in deciseconds
|
|
var/messagedelay_high = 3600 //blob report will be sent after a random value between these (minimum 4 minutes, maximum 6 minutes)
|
|
|
|
var/list/blob_overminds = list()
|
|
|
|
/datum/game_mode/blob/pre_setup()
|
|
cores_to_spawn = max(round(num_players()/players_per_core, 1), 1)
|
|
|
|
var/win_multiplier = 1 + (0.1 * cores_to_spawn)
|
|
blobwincount = initial(blobwincount) * cores_to_spawn * win_multiplier
|
|
|
|
for(var/j = 0, j < cores_to_spawn, j++)
|
|
if (!antag_candidates.len)
|
|
break
|
|
var/datum/mind/blob = pick(antag_candidates)
|
|
blob_overminds += blob
|
|
blob.assigned_role = "Blob"
|
|
blob.special_role = "Blob"
|
|
log_game("[blob.key] (ckey) has been selected as a Blob")
|
|
antag_candidates -= blob
|
|
|
|
if(!blob_overminds.len)
|
|
return 0
|
|
|
|
return 1
|
|
|
|
/datum/game_mode/blob/proc/get_blob_candidates()
|
|
var/list/candidates = list()
|
|
for(var/mob/living/carbon/human/player in GLOB.player_list)
|
|
if(!player.stat && player.mind && !player.mind.special_role && !jobban_isbanned(player, "Syndicate") && (ROLE_BLOB in player.client.prefs.be_special))
|
|
if(age_check(player.client))
|
|
candidates += player
|
|
return candidates
|
|
|
|
/datum/game_mode/blob/proc/show_message(message)
|
|
for(var/datum/mind/blob in blob_overminds)
|
|
to_chat(blob.current, message)
|
|
|
|
/datum/game_mode/blob/post_setup()
|
|
set waitfor = FALSE
|
|
|
|
for(var/datum/mind/blob in blob_overminds)
|
|
var/mob/camera/blob/B = blob.current.become_overmind(TRUE, round(blob_base_starting_points/blob_overminds.len))
|
|
B.mind.name = B.name
|
|
var/turf/T = pick(GLOB.blobstart)
|
|
B.loc = T
|
|
B.base_point_rate = blob_point_rate
|
|
|
|
SSshuttle.registerHostileEnvironment(src)
|
|
|
|
// Disable the blob event for this round.
|
|
var/datum/round_event_control/blob/B = locate() in SSevents.control
|
|
if(B)
|
|
B.max_occurrences = 0 // disable the event
|
|
|
|
. = ..()
|
|
|
|
var/message_delay = rand(messagedelay_low, messagedelay_high) //between 4 and 6 minutes with 2400 low and 3600 high.
|
|
|
|
sleep(message_delay)
|
|
|
|
send_intercept(1)
|
|
message_sent = TRUE
|
|
|
|
sleep(24000) //40 minutes, plus burst_delay*3(minimum of 6 minutes, maximum of 8)
|
|
if(!replacementmode)
|
|
send_intercept(2) //if the blob has been alive this long, it's time to bomb it |