mirror of
https://github.com/yogstation13/Yogstation.git
synced 2025-02-26 09:04:50 +00:00
a28de54405
Spiritual successor and extension to #17798, an almost entire rebuild of the SQL ban system backend and interface. Bantypes are removed per #8584 and #6174. All bans are now 'role bans', server bans are when a ban's role is server. Admin bans are a column, meaning it's possible to ban admins from jobs. Bans now have only an expiry datetime, duration is calculated from this when queried. unbanned column is removed as it's superfluous, checking unban status is now done through checking unban_datetime. unban_round_id column added. Each ip and computerid columns rearranged so ip is always first, like in other tables. Bans now permit a null ckey, ip and computerid. Ban checking is split into two procs now is_banned_from() does a check if a ckey is banned from one or more roles and returns true or false. This effectively replaces jobban_isbanned() used in simple if() statements. If connected a client's ban cache is checked rather than querying the DB. This makes it possible for a client connected to two or more servers to ignore any bans made on one server until their ban cache is rebuilt on the others. Could be avoided with cross-server calls to update ban caches or just the removal of the ban cache but as is I've done neither since I think it's enough of an edge case to not be worth it. The second proc is is_banned_from_with_details(), this queries the DB for a role ban on a player's ckey, ip or CID and returns the details. This replaces direct queries in IsBanned.dm and the preferences menu. The legacy ban system is removed. The interfaces for banning, unbanning and editing bans have been remade to require less clicking and easier simultaneous operations. The banning and jobban panel are combined. They also store player connection details when opened so a client disconnecting no longer stops a ban being placed. New banning panel: Key, IP and CID can all be toggled to allow excluding them from a ban. Checking Use IP and CID from last connection lets you enter only a ckey and have the DB fill these fields in for you, if possible. Temporary bans have a drop-menu which lets you select between seconds, minutes, hours, days, weeks, months and years so you don't need to calculate how many minutes a long ban would be. The ban is still converted into minutes on the DB however. Checking any of the head roles will check both of the boxes for you. The red role box indicates there is already a ban on that role for this ckey. You can apply additional role bans to stack them. New unbanning panel: Unbanning panel is now separate from the banning panel but otherwise functionally the same. Ban editing panel: Actually just a modified banning panel, all the features from it work the same here. You can now edit almost all parameters of a ban instead of just the reason. You can't edit severity as it's not really part of the ban. The panels have been tested but I've not been able to get my local server to be accessible so ban functionality isn't properly confirmed. Plenty of testing will be required as I'd rather not break bans. cl admin: Ban interface rework. The banning and unbanning panels have received a new design which is easier to use and allows multiple role bans to be made at once. prefix: Ban search and unbanning moved to unbanning panel, which is now a separate panel to the old banning panel. /cl
101 lines
4.2 KiB
Plaintext
101 lines
4.2 KiB
Plaintext
/datum/game_mode
|
|
var/traitor_name = "traitor"
|
|
var/list/datum/mind/traitors = list()
|
|
|
|
var/datum/mind/exchange_red
|
|
var/datum/mind/exchange_blue
|
|
|
|
/datum/game_mode/traitor
|
|
name = "traitor"
|
|
config_tag = "traitor"
|
|
report_type = "traitor"
|
|
antag_flag = ROLE_TRAITOR
|
|
false_report_weight = 20 //Reports of traitors are pretty common.
|
|
restricted_jobs = list("Cyborg")//They are part of the AI if he is traitor so are they, they use to get double chances
|
|
protected_jobs = list("Security Officer", "Warden", "Detective", "Head of Security", "Captain", "Head of Personnel") //YOGS - added the hop
|
|
required_players = 0
|
|
required_enemies = 1
|
|
recommended_enemies = 4
|
|
reroll_friendly = 1
|
|
enemy_minimum_age = 0
|
|
|
|
announce_span = "danger"
|
|
announce_text = "There are Syndicate agents on the station!\n\
|
|
<span class='danger'>Traitors</span>: Accomplish your objectives.\n\
|
|
<span class='notice'>Crew</span>: Do not let the traitors succeed!"
|
|
|
|
var/list/datum/mind/pre_traitors = list()
|
|
var/traitors_possible = 4 //hard limit on traitors if scaling is turned off
|
|
var/num_modifier = 0 // Used for gamemodes, that are a child of traitor, that need more than the usual.
|
|
var/antag_datum = /datum/antagonist/traitor //what type of antag to create
|
|
var/traitors_required = TRUE //Will allow no traitors
|
|
|
|
|
|
/datum/game_mode/traitor/pre_setup()
|
|
|
|
if(CONFIG_GET(flag/protect_roles_from_antagonist))
|
|
restricted_jobs += protected_jobs
|
|
|
|
if(CONFIG_GET(flag/protect_assistant_from_antagonist))
|
|
restricted_jobs += "Assistant"
|
|
|
|
var/num_traitors = 1
|
|
|
|
var/tsc = CONFIG_GET(number/traitor_scaling_coeff)
|
|
if(tsc)
|
|
num_traitors = max(1, min(round(num_players() / (tsc * 2)) + 2 + num_modifier, round(num_players() / tsc) + num_modifier))
|
|
else
|
|
num_traitors = max(1, min(num_players(), traitors_possible))
|
|
|
|
for(var/j = 0, j < num_traitors, j++)
|
|
if (!antag_candidates.len)
|
|
break
|
|
var/datum/mind/traitor = antag_pick(antag_candidates)
|
|
pre_traitors += traitor
|
|
traitor.special_role = traitor_name
|
|
traitor.restricted_roles = restricted_jobs
|
|
//log_game("[key_name(traitor)] has been selected as a [traitor_name]") | yogs - redundant
|
|
antag_candidates.Remove(traitor)
|
|
|
|
var/enough_tators = !traitors_required || pre_traitors.len > 0
|
|
|
|
if(!enough_tators)
|
|
setup_error = "Not enough traitor candidates"
|
|
return FALSE
|
|
else
|
|
return TRUE
|
|
|
|
|
|
/datum/game_mode/traitor/post_setup()
|
|
for(var/datum/mind/traitor in pre_traitors)
|
|
var/datum/antagonist/traitor/new_antag = new antag_datum()
|
|
addtimer(CALLBACK(traitor, /datum/mind.proc/add_antag_datum, new_antag), rand(10,100))
|
|
if(!exchange_blue)
|
|
exchange_blue = -1 //Block latejoiners from getting exchange objectives
|
|
..()
|
|
|
|
//We're not actually ready until all traitors are assigned.
|
|
gamemode_ready = FALSE
|
|
addtimer(VARSET_CALLBACK(src, gamemode_ready, TRUE), 101)
|
|
return TRUE
|
|
|
|
/datum/game_mode/traitor/make_antag_chance(mob/living/carbon/human/character) //Assigns traitor to latejoiners
|
|
var/tsc = CONFIG_GET(number/traitor_scaling_coeff)
|
|
var/traitorcap = min(round(GLOB.joined_player_list.len / (tsc * 2)) + 2 + num_modifier, round(GLOB.joined_player_list.len / tsc) + num_modifier)
|
|
if((SSticker.mode.traitors.len + pre_traitors.len) >= traitorcap) //Upper cap for number of latejoin antagonists
|
|
return
|
|
if((SSticker.mode.traitors.len + pre_traitors.len) <= (traitorcap - 2) || prob(100 / (tsc * 2)))
|
|
if(antag_flag in character.client.prefs.be_special)
|
|
if(!is_banned_from(character.ckey, list(ROLE_TRAITOR, ROLE_SYNDICATE)) && !QDELETED(character))
|
|
if(age_check(character.client))
|
|
if(!(character.job in restricted_jobs))
|
|
add_latejoin_traitor(character.mind)
|
|
|
|
/datum/game_mode/traitor/proc/add_latejoin_traitor(datum/mind/character)
|
|
var/datum/antagonist/traitor/new_antag = new antag_datum()
|
|
character.add_antag_datum(new_antag)
|
|
|
|
/datum/game_mode/traitor/generate_report()
|
|
return "Although more specific threats are commonplace, you should always remain vigilant for Syndicate agents aboard your station. Syndicate communications have implied that many \
|
|
Nanotrasen employees are Syndicate agents with hidden memories that may be activated at a moment's notice, so it's possible that these agents might not even know their positions."
|