/proc/create_message(type, target_ckey, admin_ckey, text, timestamp, server, secret, logged = 1, browse)
	if(!dbcon.IsConnected())
		usr << "<span class='danger'>Failed to establish database connection.</span>"
		return
	if(!type)
		return
	if(!target_ckey && (type == "note" || type == "message" || type == "watchlist entry"))
		var/new_ckey = ckey(input(usr,"Who would you like to create a [type] for?","Enter a ckey",null) as null|text)
		if(!new_ckey)
			return
		new_ckey = sanitizeSQL(new_ckey)
		var/DBQuery/query_find_ckey = dbcon.NewQuery("SELECT ckey FROM [format_table_name("player")] WHERE ckey = '[new_ckey]'")
		if(!query_find_ckey.Execute())
			var/err = query_find_ckey.ErrorMsg()
			log_game("SQL ERROR obtaining ckey from player table. Error : \[[err]\]\n")
			return
		if(!query_find_ckey.NextRow())
			if(alert(usr, "[new_ckey] has not been seen before, are you sure you want to create a [type] for them?", "Unknown ckey", "Yes", "No", "Cancel") != "Yes")
				return
		target_ckey = new_ckey
	if(target_ckey)
		target_ckey = sanitizeSQL(target_ckey)
	if(!admin_ckey)
		admin_ckey = usr.ckey
		if(!admin_ckey)
			return
	admin_ckey = sanitizeSQL(admin_ckey)
	if(!target_ckey)
		target_ckey = admin_ckey
	if(!text)
		text = input(usr,"Write your [type]","Create [type]") as null|message
		if(!text)
			return
	text = sanitizeSQL(text)
	if(!timestamp)
		timestamp = SQLtime()
	if(!server)
		if (config && config.server_name)
			server = config.server_name
	server = sanitizeSQL(server)
	if(isnull(secret))
		switch(alert("Hide note from being viewed by players?", "Secret note?","Yes","No","Cancel"))
			if("Yes")
				secret = 1
			if("No")
				secret = 0
			else
				return
	var/DBQuery/query_create_message = dbcon.NewQuery("INSERT INTO [format_table_name("messages")] (type, targetckey, adminckey, text, timestamp, server, secret) VALUES ('[type]', '[target_ckey]', '[admin_ckey]', '[text]', '[timestamp]', '[server]', '[secret]')")
	if(!query_create_message.Execute())
		var/err = query_create_message.ErrorMsg()
		log_game("SQL ERROR creating new [type] in messages table. Error : \[[err]\]\n")
		return
	if(logged)
		log_admin("[key_name(usr)] has created a [type][type == ("note"||"message"||"watchlist entry") ? " for [target_ckey]" : ""]: [text]")
		message_admins("[key_name_admin(usr)] has created a [type][type == ("note"||"message"||"watchlist entry") ? " for [target_ckey]" : ""]:<br>[text]")
		if(browse)
			browse_messages("[type]")
		else
			browse_messages(target_ckey = target_ckey)

/proc/delete_message(message_id, logged = 1, browse)
	if(!dbcon.IsConnected())
		usr << "<span class='danger'>Failed to establish database connection.</span>"
		return
	message_id = text2num(message_id)
	if(!message_id)
		return
	var/type
	var/target_ckey
	var/text
	var/DBQuery/query_find_del_message = dbcon.NewQuery("SELECT type, targetckey, adminckey, text FROM [format_table_name("messages")] WHERE id = [message_id]")
	if(!query_find_del_message.Execute())
		var/err = query_find_del_message.ErrorMsg()
		log_game("SQL ERROR obtaining type, targetckey, adminckey text from messages table. Error : \[[err]\]\n")
		return
	if(query_find_del_message.NextRow())
		type = query_find_del_message.item[1]
		target_ckey = query_find_del_message.item[2]
		text = query_find_del_message.item[4]
	var/DBQuery/query_del_message = dbcon.NewQuery("DELETE FROM [format_table_name("messages")] WHERE id = [message_id]")
	if(!query_del_message.Execute())
		var/err = query_del_message.ErrorMsg()
		log_game("SQL ERROR deleting [type] from messages table. Error : \[[err]\]\n")
		return
	if(logged)
		log_admin("[key_name(usr)] has deleted a [type][type == ("note"||"message"||"watchlist entry") ? " for" : " made by"] [target_ckey]: [text]")
		message_admins("[key_name_admin(usr)] has deleted a [type][type == ("note"||"message"||"watchlist entry") ? " for" : " made by"] [target_ckey]:<br>[text]")
		if(browse)
			browse_messages("[type]")
		else
			browse_messages(target_ckey = target_ckey)

/proc/edit_message(message_id, browse)
	if(!dbcon.IsConnected())
		usr << "<span class='danger'>Failed to establish database connection.</span>"
		return
	message_id = text2num(message_id)
	if(!message_id)
		return
	var/DBQuery/query_find_edit_message = dbcon.NewQuery("SELECT type, targetckey, adminckey, text FROM [format_table_name("messages")] WHERE id = [message_id]")
	if(!query_find_edit_message.Execute())
		var/err = query_find_edit_message.ErrorMsg()
		log_game("SQL ERROR obtaining type, targetckey, adminckey, text from messages table. Error : \[[err]\]\n")
		return
	if(query_find_edit_message.NextRow())
		var/type = query_find_edit_message.item[1]
		var/target_ckey = query_find_edit_message.item[2]
		var/admin_ckey = query_find_edit_message.item[3]
		var/old_text = query_find_edit_message.item[4]
		var/editor_ckey = sanitizeSQL(usr.ckey)
		var/new_text = input("Input new [type]", "New [type]", "[old_text]") as null|message
		if(!new_text)
			return
		new_text = sanitizeSQL(new_text)
		var/edit_text = sanitizeSQL("Edited by [editor_ckey] on [SQLtime()] from<br>[old_text]<br>to<br>[new_text]<hr>")
		var/DBQuery/query_edit_message = dbcon.NewQuery("UPDATE [format_table_name("messages")] SET text = '[new_text]', lasteditor = '[editor_ckey]', edits = CONCAT(IFNULL(edits,''),'[edit_text]') WHERE id = [message_id]")
		if(!query_edit_message.Execute())
			var/err = query_edit_message.ErrorMsg()
			log_game("SQL ERROR editing messages table. Error : \[[err]\]\n")
			return
		log_admin("[key_name(usr)] has edited a [type] [type == ("note"||"message"||"watchlist entry") ? " for [target_ckey]" : ""] made by [admin_ckey] from [old_text] to [new_text]")
		message_admins("[key_name_admin(usr)] has edited a [type] [type == ("note"||"message"||"watchlist entry") ? " for [target_ckey]" : ""] made by [admin_ckey] from<br>[old_text]<br>to<br>[new_text]")
		if(browse)
			browse_messages("[type]")
		else
			browse_messages(target_ckey = target_ckey)

/proc/toggle_message_secrecy(message_id)
	if(!dbcon.IsConnected())
		usr << "<span class='danger'>Failed to establish database connection.</span>"
		return
	message_id = text2num(message_id)
	if(!message_id)
		return
	var/DBQuery/query_find_message_secret = dbcon.NewQuery("SELECT type, targetckey, adminckey, secret FROM [format_table_name("messages")] WHERE id = [message_id]")
	if(!query_find_message_secret.Execute())
		var/err = query_find_message_secret.ErrorMsg()
		log_game("SQL ERROR obtaining type, targetckey, adminckey, secret from messages table. Error : \[[err]\]\n")
		return
	if(query_find_message_secret.NextRow())
		var/type = query_find_message_secret.item[1]
		var/target_ckey = query_find_message_secret.item[2]
		var/admin_ckey = query_find_message_secret.item[3]
		var/secret = text2num(query_find_message_secret.item[4])
		var/editor_ckey = sanitizeSQL(usr.ckey)
		var/edit_text = "Made [secret ? "not secret" : "secret"] by [editor_ckey] on [SQLtime()]<hr>"
		var/DBQuery/query_message_secret = dbcon.NewQuery("UPDATE [format_table_name("messages")] SET secret = NOT secret, lasteditor = '[editor_ckey]', edits = CONCAT(IFNULL(edits,''),'[edit_text]') WHERE id = [message_id]")
		if(!query_message_secret.Execute())
			var/err = query_message_secret.ErrorMsg()
			log_game("SQL ERROR toggling message secrecy. Error : \[[err]\]\n")
			return
		log_admin("[key_name(usr)] has toggled [target_ckey]'s [type] made by [admin_ckey] to [secret ? "not secret" : "secret"]")
		message_admins("[key_name_admin(usr)] has toggled [target_ckey]'s [type] made by [admin_ckey] to [secret ? "not secret" : "secret"]")
		browse_messages(target_ckey = target_ckey)

/proc/browse_messages(type, target_ckey, index, linkless = 0)
	if(!dbcon.IsConnected())
		usr << "<span class='danger'>Failed to establish database connection.</span>"
		return
	var/output
	var/ruler = "<hr style='background:#000000; border:0; height:3px'>"
	var/navbar = "<a href='?_src_=holder;nonalpha=1'>\[All\]</a>|<a href='?_src_=holder;nonalpha=2'>\[#\]</a>"
	for(var/letter in alphabet)
		navbar += "|<a href='?_src_=holder;showmessages=[letter]'>\[[letter]\]</a>"
	navbar += "|<a href='?_src_=holder;showmemo=1'>\[Memos\]</a>|<a href='?_src_=holder;showwatch=1'>\[Watchlist\]</a>"
	navbar += "<br><form method='GET' name='search' action='?'>\
	<input type='hidden' name='_src_' value='holder'>\
	<input type='text' name='searchmessages' value='[index]'>\
	<input type='submit' value='Search'></form>"
	if(!linkless)
		output = navbar
	if(type == "memo" || type == "watchlist entry")
		if(type == "memo")
			output += "<h2><center>Admin memos</h2>"
			output += "<a href='?_src_=holder;addmemo=1'>\[Add memo\]</a></center>"
		else if(type == "watchlist entry")
			output += "<h2><center>Watchlist entries</h2>"
			output += "<a href='?_src_=holder;addwatchempty=1'>\[Add watchlist entry\]</a></center>"
		output += ruler
		var/DBQuery/query_get_type_messages = dbcon.NewQuery("SELECT id, targetckey, adminckey, text, timestamp, server, lasteditor FROM [format_table_name("messages")] WHERE type = '[type]'")
		if(!query_get_type_messages.Execute())
			var/err = query_get_type_messages.ErrorMsg()
			log_game("SQL ERROR obtaining id, targetckey, adminckey, text, timestamp, server, lasteditor from messages table. Error : \[[err]\]\n")
			return
		while(query_get_type_messages.NextRow())
			var/id = query_get_type_messages.item[1]
			var/t_ckey = query_get_type_messages.item[2]
			var/admin_ckey = query_get_type_messages.item[3]
			var/text = query_get_type_messages.item[4]
			var/timestamp = query_get_type_messages.item[5]
			var/server = query_get_type_messages.item[6]
			var/editor_ckey = query_get_type_messages.item[7]
			output += "<b>"
			if(type == "watchlist entry")
				output += "[t_ckey] | "
			output += "[timestamp] | [server] | [admin_ckey]</b>"
			output += " <a href='?_src_=holder;deletemessageempty=[id]'>\[Delete\]</a>"
			output += " <a href='?_src_=holder;editmessageempty=[id]'>\[Edit\]</a>"
			if(editor_ckey)
				output += " <font size='2'>Last edit by [editor_ckey] <a href='?_src_=holder;messageedits=[id]'>(Click here to see edit log)</a></font>"
			output += "<br>[text]<hr style='background:#000000; border:0; height:1px'>"
	if(target_ckey)
		target_ckey = sanitizeSQL(target_ckey)
		var/DBQuery/query_get_messages = dbcon.NewQuery("SELECT type, secret, id, adminckey, text, timestamp, server, lasteditor FROM [format_table_name("messages")] WHERE type <> 'memo' AND targetckey = '[target_ckey]' ORDER BY timestamp")
		if(!query_get_messages.Execute())
			var/err = query_get_messages.ErrorMsg()
			log_game("SQL ERROR obtaining type, secret, id, adminckey, text, timestamp, server, lasteditor from messages table. Error : \[[err]\]\n")
			return
		var/messagedata
		var/watchdata
		var/notedata
		while(query_get_messages.NextRow())
			type = query_get_messages.item[1]
			if(type == "memo")
				continue
			var/secret = text2num(query_get_messages.item[2])
			if(linkless && secret)
				continue
			var/id = query_get_messages.item[3]
			var/admin_ckey = query_get_messages.item[4]
			var/text = query_get_messages.item[5]
			var/timestamp = query_get_messages.item[6]
			var/server = query_get_messages.item[7]
			var/editor_ckey = query_get_messages.item[8]
			var/data
			data += "<b>[timestamp] | [server] | [admin_ckey]</b>"
			if(!linkless)
				data += " <a href='?_src_=holder;deletemessage=[id]'>\[Delete\]</a>"
				if(type == "note")
					data += " <a href='?_src_=holder;secretmessage=[id]'>[secret ? "<b>\[Secret\]</b>" : "\[Not secret\]"]</a>"
				data += " <a href='?_src_=holder;editmessage=[id]'>\[Edit\]</a>"
				if(editor_ckey)
					data += " <font size='2'>Last edit by [editor_ckey] <a href='?_src_=holder;messageedits=[id]'>(Click here to see edit log)</a></font>"
			data += "<br>[text]<hr style='background:#000000; border:0; height:1px'>"
			switch(type)
				if("message")
					messagedata += data
				if("watchlist entry")
					watchdata += data
				if("note")
					notedata += data
		output += "<h2><center>[target_ckey]</center></h2><center>"
		if(!linkless)
			output += "<a href='?_src_=holder;addmessage=[target_ckey]'>\[Add message\]</a>"
			output += " <a href='?_src_=holder;addwatch=[target_ckey]'>\[Add to watchlist\]</a>"
			output += " <a href='?_src_=holder;addnote=[target_ckey]'>\[Add note\]</a>"
			output += " <a href='?_src_=holder;showmessageckey=[target_ckey]'>\[Refresh page\]</a></center>"
		else
			output += " <a href='?_src_=holder;showmessageckeylinkless=[target_ckey]'>\[Refresh page\]</a></center>"
		output += ruler
		if(messagedata)
			output += "<h4>Messages</h4>"
			output += messagedata
		if(watchdata)
			output += "<h4>Watchlist</h4>"
			output += watchdata
		if(notedata)
			output += "<h4>Notes</h4>"
			output += notedata
	if(index)
		var/index_ckey
		var/search
		output += "<center><a href='?_src_=holder;addmessageempty=1'>\[Add message\]</a><a href='?_src_=holder;addwatchempty=1'>\[Add watchlist entry\]</a><a href='?_src_=holder;addnoteempty=1'>\[Add note\]</a></center>"
		output += ruler
		if(!isnum(index))
			index = sanitizeSQL(index)
		switch(index)
			if(1)
				search = "^."
			if(2)
				search = "^\[^\[:alpha:\]\]"
			else
				search = "^[index]"
		var/DBQuery/query_list_messages = dbcon.NewQuery("SELECT DISTINCT targetckey FROM [format_table_name("messages")] WHERE type <> 'memo' AND targetckey REGEXP '[search]' ORDER BY targetckey")
		if(!query_list_messages.Execute())
			var/err = query_list_messages.ErrorMsg()
			log_game("SQL ERROR obtaining distinct targetckey from messages table. Error : \[[err]\]\n")
			return
		while(query_list_messages.NextRow())
			index_ckey = query_list_messages.item[1]
			output += "<a href='?_src_=holder;showmessageckey=[index_ckey]'>[index_ckey]</a><br>"
	else if(!type && !target_ckey && !index)
		output += "<center></a> <a href='?_src_=holder;addmessageempty=1'>\[Add message\]</a><a href='?_src_=holder;addwatchempty=1'>\[Add watchlist entry\]</a><a href='?_src_=holder;addnoteempty=1'>\[Add note\]</a></center>"
		output += ruler
	usr << browse(output, "window=browse_messages;size=900x500")

proc/get_message_output(type, target_ckey)
	if(!dbcon.IsConnected())
		usr << "<span class='danger'>Failed to establish database connection.</span>"
		return
	if(!type)
		return
	var/output
	if(target_ckey)
		target_ckey = sanitizeSQL(target_ckey)
	var/query = "SELECT id, adminckey, text, timestamp, lasteditor FROM [format_table_name("messages")] WHERE type = '[type]'"
	if(type == "message" || type == "watchlist entry")
		query += " AND targetckey = '[target_ckey]'"
	var/DBQuery/query_get_message_output = dbcon.NewQuery(query)
	if(!query_get_message_output.Execute())
		var/err = query_get_message_output.ErrorMsg()
		log_game("SQL ERROR obtaining id, adminckey, text, timestamp, lasteditor from messages table. Error : \[[err]\]\n")
		return
	while(query_get_message_output.NextRow())
		var/id = query_get_message_output.item[1]
		var/admin_ckey = query_get_message_output.item[2]
		var/text = query_get_message_output.item[3]
		var/timestamp = query_get_message_output.item[4]
		var/editor_ckey = query_get_message_output.item[5]
		switch(type)
			if("message")
				output += "<font color='red' size='3'><b>Admin message left by <span class='prefix'>[admin_ckey]</span> on [timestamp]</b></font>"
				output += "<br><font color='red'>[text]</font>"
				delete_message(id, 0)
			if("watchlist entry")
				message_admins("<font color='red'><B>Notice: </B></font><font color='blue'>[key_name_admin(target_ckey)] is on the watchlist and has just connected - Reason: [text]</font>")
				send2irc_adminless_only("Watchlist", "[key_name(target_ckey)] is on the watchlist and has just connected - Reason: [text]")
			if("memo")
				output += "<span class='memo'>Memo by <span class='prefix'>[admin_ckey]</span> on [timestamp]"
				if(editor_ckey)
					output += "<br><span class='memoedit'>Last edit by [editor_ckey] <A href='?_src_=holder;messageedits=[id]'>(Click here to see edit log)</A></span>"
				output += "<br>[text]</span><br>"
	return output

#define NOTESFILE "data/player_notes.sav"
//if the AUTOCONVERT_NOTES is turned on, anytime a player connects this will be run to try and add all their notes to the databas
/proc/convert_notes_sql(ckey)
	var/savefile/notesfile = new(NOTESFILE)
	if(!notesfile)
		log_game("Error: Cannot access [NOTESFILE]")
		return
	notesfile.cd = "/[ckey]"
	while(!notesfile.eof)
		var/notetext
		notesfile >> notetext
		var/server
		if(config && config.server_name)
			server = config.server_name
		var/regex/note = new("^(\\d{2}-\\w{3}-\\d{4}) \\| (.+) ~(\\w+)$", "i")
		note.Find(notetext)
		var/timestamp = note.group[1]
		notetext = note.group[2]
		var/admin_ckey = note.group[3]
		var/DBQuery/query_convert_time = dbcon.NewQuery("SELECT ADDTIME(STR_TO_DATE('[timestamp]','%d-%b-%Y'), '0')")
		if(!query_convert_time.Execute())
			var/err = query_convert_time.ErrorMsg()
			log_game("SQL ERROR converting timestamp. Error : \[[err]\]\n")
			return
		if(query_convert_time.NextRow())
			timestamp = query_convert_time.item[1]
		if(ckey && notetext && timestamp && admin_ckey && server)
			create_message("note", ckey, admin_ckey, notetext, timestamp, server, 1, 0)
	notesfile.cd = "/"
	notesfile.dir.Remove(ckey)

/*alternatively this proc can be run once to pass through every note and attempt to convert it before deleting the file, if done then AUTOCONVERT_NOTES should be turned off
this proc can take several minutes to execute fully if converting and cause DD to hang if converting a lot of notes; it's not advised to do so while a server is live
/proc/mass_convert_notes()
	world << "Beginning mass note conversion"
	var/savefile/notesfile = new(NOTESFILE)
	if(!notesfile)
		log_game("Error: Cannot access [NOTESFILE]")
		return
	notesfile.cd = "/"
	for(var/ckey in notesfile.dir)
		convert_notes_sql(ckey)
	world << "Deleting NOTESFILE"
	fdel(NOTESFILE)
	world << "Finished mass note conversion, remember to turn off AUTOCONVERT_NOTES"*/
#undef NOTESFILE