mirror of
https://github.com/fulpstation/fulpstation.git
synced 2025-12-10 01:57:01 +00:00
5b89dea70f
About The Pull Request VR sleepers now lead to the VR Hub, a place with a bunch of portals that lead you to other areas, or just has chill stuff like a bar. Includes portals to all the old vr maps, the megafauna training simulator map, a soon to be minecraft map, and my crappy game runner where you run away from falling tiles and fight to be the last person to survive. Merges murderdome and syndicate trainer into the vr hub map so they spawn every time with vr. Recall portals now can have multiple exits to support the old vr waypoint system from the hub. Also moves a lot of stuff around in the files to make it more organized. There's now also a ghost role that can access VR as well with infinite spawns. VR NOW HAS A CONFIG OPTION SO ENABLE IT OR VR WILL NOT WORK. Why It's Good For The Game Being a ghost is boring for most people, it's nice to have a place for people to hang out rather than just leave the server. This is also a nice place where people can put gamemodes they're testing or other fun little minigames that can't be main gamemodes. VR currently is not used by really anyone so I don't see anyone getting bothered by this PR as well.
78 lines
2.1 KiB
Plaintext
78 lines
2.1 KiB
Plaintext
GLOBAL_LIST_EMPTY(all_wormholes) // So we can pick wormholes to teleport to
|
|
|
|
/datum/round_event_control/wormholes
|
|
name = "Wormholes"
|
|
typepath = /datum/round_event/wormholes
|
|
max_occurrences = 3
|
|
weight = 2
|
|
min_players = 2
|
|
|
|
|
|
/datum/round_event/wormholes
|
|
announceWhen = 10
|
|
endWhen = 60
|
|
|
|
var/list/pick_turfs = list()
|
|
var/list/wormholes = list()
|
|
var/shift_frequency = 3
|
|
var/number_of_wormholes = 400
|
|
|
|
/datum/round_event/wormholes/setup()
|
|
announceWhen = rand(0, 20)
|
|
endWhen = rand(40, 80)
|
|
|
|
/datum/round_event/wormholes/start()
|
|
for(var/turf/open/floor/T in world)
|
|
if(is_station_level(T.z))
|
|
pick_turfs += T
|
|
|
|
for(var/i = 1, i <= number_of_wormholes, i++)
|
|
var/turf/T = pick(pick_turfs)
|
|
wormholes += new /obj/effect/portal/wormhole(T, null, 0, null, FALSE)
|
|
|
|
/datum/round_event/wormholes/announce(fake)
|
|
priority_announce("Space-time anomalies detected on the station. There is no additional data.", "Anomaly Alert", 'sound/ai/spanomalies.ogg')
|
|
|
|
/datum/round_event/wormholes/tick()
|
|
if(activeFor % shift_frequency == 0)
|
|
for(var/obj/effect/portal/wormhole/O in wormholes)
|
|
var/turf/T = pick(pick_turfs)
|
|
if(T)
|
|
O.forceMove(T)
|
|
|
|
/datum/round_event/wormholes/end()
|
|
QDEL_LIST(wormholes)
|
|
wormholes = null
|
|
|
|
/obj/effect/portal/wormhole
|
|
name = "wormhole"
|
|
desc = "It looks highly unstable; It could close at any moment."
|
|
icon = 'icons/obj/objects.dmi'
|
|
icon_state = "anom"
|
|
mech_sized = TRUE
|
|
|
|
|
|
/obj/effect/portal/wormhole/Initialize(mapload, _creator, _lifespan = 0, obj/effect/portal/_linked, automatic_link = FALSE, turf/hard_target_override, atmos_link_override)
|
|
. = ..()
|
|
GLOB.all_wormholes += src
|
|
|
|
/obj/effect/portal/wormhole/Destroy()
|
|
. = ..()
|
|
GLOB.all_wormholes -= src
|
|
|
|
/obj/effect/portal/wormhole/teleport(atom/movable/M)
|
|
if(iseffect(M)) //sparks don't teleport
|
|
return
|
|
if(M.anchored)
|
|
if(!(ismecha(M) && mech_sized))
|
|
return
|
|
|
|
if(ismovableatom(M))
|
|
if(GLOB.all_wormholes.len)
|
|
var/obj/effect/portal/wormhole/P = pick(GLOB.all_wormholes)
|
|
if(P && isturf(P.loc))
|
|
hard_target = P.loc
|
|
if(!hard_target)
|
|
return
|
|
do_teleport(M, hard_target, 1, 1, 0, 0, channel = TELEPORT_CHANNEL_WORMHOLE) ///You will appear adjacent to the beacon
|