mirror of
https://github.com/vgstation-coders/vgstation13.git
synced 2025-12-09 16:14:13 +00:00
7af60a7fb5
-Added a solars_list. The sun will use this list instead of the machines list. I made a proc which decided on whether to use this list or the powernet nodes list depending on what is smallest. I replaced some loops to use this proc. -The sun will reference this list for debugging purposes. The sun will also remove solar equipment in the list which are not connected to a powernet. -Cut down on some duplicated code. -Fixed an issue with solar panels not updating their direction correctly. -Changed the proc updateicon()'s name to update_icon() git-svn-id: http://tgstation13.googlecode.com/svn/trunk@5418 316c924e-a436-60f5-8080-3fe189b3f50e
92 lines
2.0 KiB
Plaintext
92 lines
2.0 KiB
Plaintext
/datum/sun
|
|
var/angle
|
|
var/dx
|
|
var/dy
|
|
var/counter = 50 // to make the vars update during 1st call
|
|
var/rate
|
|
var/list/solars // for debugging purposes, references solars_list at the constructor
|
|
|
|
/datum/sun/New()
|
|
|
|
solars = solars_list
|
|
rate = rand(75,125)/100 // 75% - 125% of standard rotation
|
|
if(prob(50))
|
|
rate = -rate
|
|
|
|
// calculate the sun's position given the time of day
|
|
|
|
/datum/sun/proc/calc_position()
|
|
|
|
counter++
|
|
if(counter<50) // count 50 pticks (50 seconds, roughly - about a 5deg change)
|
|
return
|
|
counter = 0
|
|
|
|
angle = ((rate*world.realtime/100)%360 + 360)%360 // gives about a 60 minute rotation time
|
|
// now 45 - 75 minutes, depending on rate
|
|
// now calculate and cache the (dx,dy) increments for line drawing
|
|
|
|
var/s = sin(angle)
|
|
var/c = cos(angle)
|
|
|
|
if(c == 0)
|
|
|
|
dx = 0
|
|
dy = s
|
|
|
|
else if( abs(s) < abs(c))
|
|
|
|
dx = s / abs(c)
|
|
dy = c / abs(c)
|
|
|
|
else
|
|
dx = s/abs(s)
|
|
dy = c / abs(s)
|
|
|
|
|
|
for(var/obj/machinery/power/M in solars_list)
|
|
|
|
if(!M.powernet)
|
|
solars_list.Remove(M)
|
|
continue
|
|
|
|
// Solar Tracker
|
|
if(istype(M, /obj/machinery/power/tracker))
|
|
var/obj/machinery/power/tracker/T = M
|
|
T.set_angle(angle)
|
|
|
|
// Solar Panel
|
|
else if(istype(M, /obj/machinery/power/solar))
|
|
var/obj/machinery/power/solar/S = M
|
|
if(S.control)
|
|
occlusion(S)
|
|
|
|
|
|
|
|
// for a solar panel, trace towards sun to see if we're in shadow
|
|
|
|
/datum/sun/proc/occlusion(var/obj/machinery/power/solar/S)
|
|
|
|
var/ax = S.x // start at the solar panel
|
|
var/ay = S.y
|
|
|
|
for(var/i = 1 to 20) // 20 steps is enough
|
|
ax += dx // do step
|
|
ay += dy
|
|
|
|
var/turf/T = locate( round(ax,0.5),round(ay,0.5),S.z)
|
|
|
|
if(T.x == 1 || T.x==world.maxx || T.y==1 || T.y==world.maxy) // not obscured if we reach the edge
|
|
break
|
|
|
|
if(T.density) // if we hit a solid turf, panel is obscured
|
|
S.obscured = 1
|
|
return
|
|
|
|
S.obscured = 0 // if hit the edge or stepped 20 times, not obscured
|
|
S.update_solar_exposure()
|
|
|
|
|
|
|
|
|