Revert "PLASE"

This reverts commit 8af225e6e3.
2019-11-24 02:44:00 +00:00
parent 8af225e6e3
commit 00601a0c87
2145 changed files with 1387321 additions and 5257 deletions
@@ -0,0 +1,365 @@
+#define CONFUSION_STACK_MAX_MULTIPLIER 2
+/obj/item/assembly/flash
+	name = "flash"
+	desc = "A powerful and versatile flashbulb device, with applications ranging from disorienting attackers to acting as visual receptors in robot production."
+	icon_state = "flash"
+	item_state = "flashtool"
+	lefthand_file = 'icons/mob/inhands/equipment/security_lefthand.dmi'
+	righthand_file = 'icons/mob/inhands/equipment/security_righthand.dmi'
+	throwforce = 0
+	w_class = WEIGHT_CLASS_TINY
+	materials = list(MAT_METAL = 300, MAT_GLASS = 300)
+	crit_fail = FALSE     //Is the flash burnt out?
+	light_color = LIGHT_COLOR_WHITE
+	light_power = FLASH_LIGHT_POWER
+	var/flashing_overlay = "flash-f"
+	var/times_used = 0 //Number of times it's been used.
+	var/burnout_resistance = 0
+	var/last_used = 0 //last world.time it was used.
+	var/cooldown = 0
+	var/last_trigger = 0 //Last time it was successfully triggered.
+
+/obj/item/assembly/flash/suicide_act(mob/living/user)
+	if (crit_fail)
+		user.visible_message("<span class='suicide'>[user] raises \the [src] up to [user.p_their()] eyes and activates it ... but its burnt out!</span>")
+		return SHAME
+	else if (user.eye_blind)
+		user.visible_message("<span class='suicide'>[user] raises \the [src] up to [user.p_their()] eyes and activates it ... but [user.p_theyre()] blind!</span>")
+		return SHAME
+	user.visible_message("<span class='suicide'>[user] raises \the [src] up to [user.p_their()] eyes and activates it! It looks like [user.p_theyre()] trying to commit suicide!</span>")
+	attack(user,user)
+	return FIRELOSS
+
+/obj/item/assembly/flash/update_icon(flash = FALSE)
+	cut_overlays()
+	attached_overlays = list()
+	if(crit_fail)
+		add_overlay("flashburnt")
+		attached_overlays += "flashburnt"
+	if(flash)
+		add_overlay(flashing_overlay)
+		attached_overlays += flashing_overlay
+		addtimer(CALLBACK(src, .proc/update_icon), 5)
+	if(holder)
+		holder.update_icon()
+
+/obj/item/assembly/flash/proc/clown_check(mob/living/carbon/human/user)
+	if(HAS_TRAIT(user, TRAIT_CLUMSY) && prob(50))
+		flash_carbon(user, user, 15, 0)
+		return FALSE
+	return TRUE
+
+/obj/item/assembly/flash/proc/burn_out() //Made so you can override it if you want to have an invincible flash from R&D or something.
+	if(!crit_fail)
+		crit_fail = TRUE
+		update_icon()
+	if(ismob(loc))
+		var/mob/M = loc
+		M.visible_message("<span class='danger'>[src] burns out!</span>","<span class='userdanger'>[src] burns out!</span>")
+	else
+		var/turf/T = get_turf(src)
+		T.visible_message("<span class='danger'>[src] burns out!</span>")
+
+/obj/item/assembly/flash/proc/flash_recharge(interval = 10)
+	var/deciseconds_passed = world.time - last_used
+	for(var/seconds = deciseconds_passed / 10, seconds >= interval, seconds -= interval) //get 1 charge every interval
+		times_used--
+	last_used = world.time
+	times_used = max(0, times_used) //sanity
+	if(max(0, prob(times_used * 3) - burnout_resistance)) //The more often it's used in a short span of time the more likely it will burn out
+		burn_out()
+		return FALSE
+	return TRUE
+
+//BYPASS CHECKS ALSO PREVENTS BURNOUT!
+/obj/item/assembly/flash/proc/AOE_flash(bypass_checks = FALSE, range = 3, power = 5, targeted = FALSE, mob/user)
+	if(!bypass_checks && !try_use_flash())
+		return FALSE
+	var/list/mob/targets = get_flash_targets(get_turf(src), range, FALSE)
+	if(user)
+		targets -= user
+	for(var/mob/living/carbon/C in targets)
+		flash_carbon(C, user, power, targeted, TRUE)
+	return TRUE
+
+/obj/item/assembly/flash/proc/get_flash_targets(atom/target_loc, range = 3, override_vision_checks = FALSE)
+	if(!target_loc)
+		target_loc = loc
+	if(override_vision_checks)
+		return get_hearers_in_view(range, get_turf(target_loc))
+	if(isturf(target_loc) || (ismob(target_loc) && isturf(target_loc.loc)))
+		return viewers(range, get_turf(target_loc))
+	else
+		return typecache_filter_list(target_loc.GetAllContents(), GLOB.typecache_living)
+
+/obj/item/assembly/flash/proc/try_use_flash(mob/user = null)
+	if(crit_fail || (world.time < last_trigger + cooldown))
+		return FALSE
+	last_trigger = world.time
+	playsound(src, 'sound/weapons/flash.ogg', 100, TRUE)
+	flash_lighting_fx(FLASH_LIGHT_RANGE, light_power, light_color)
+	times_used++
+	flash_recharge()
+	update_icon(TRUE)
+	if(user && !clown_check(user))
+		return FALSE
+	return TRUE
+
+/obj/item/assembly/flash/proc/flash_carbon(mob/living/carbon/M, mob/user, power = 15, targeted = TRUE, generic_message = FALSE)
+	if(!istype(M))
+		return
+	if(user)
+		log_combat(user, M, "[targeted? "flashed(targeted)" : "flashed(AOE)"]", src)
+	else //caused by emp/remote signal
+		M.log_message("was [targeted? "flashed(targeted)" : "flashed(AOE)"]",LOG_ATTACK)
+	if(generic_message && M != user)
+		to_chat(M, "<span class='disarm'>[src] emits a blinding light!</span>")
+	if(targeted)
+		if(M.flash_act(1, 1))
+			if(M.confused < power)
+				var/diff = power * CONFUSION_STACK_MAX_MULTIPLIER - M.confused
+				M.confused += min(power, diff)
+			if(user)
+				terrible_conversion_proc(M, user)
+				visible_message("<span class='disarm'>[user] blinds [M] with the flash!</span>")
+				to_chat(user, "<span class='danger'>You blind [M] with the flash!</span>")
+				to_chat(M, "<span class='userdanger'>[user] blinds you with the flash!</span>")
+			else
+				to_chat(M, "<span class='userdanger'>You are blinded by [src]!</span>")
+			var/toblur = 20 - M.eye_blurry
+			if(toblur > 0)
+				M.blur_eyes(toblur)
+		else if(user)
+			visible_message("<span class='disarm'>[user] fails to blind [M] with the flash!</span>")
+			to_chat(user, "<span class='warning'>You fail to blind [M] with the flash!</span>")
+			to_chat(M, "<span class='danger'>[user] fails to blind you with the flash!</span>")
+		else
+			to_chat(M, "<span class='danger'>[src] fails to blind you!</span>")
+	else
+		if(M.flash_act())
+			var/diff = power * CONFUSION_STACK_MAX_MULTIPLIER - M.confused
+			M.confused += min(power, diff)
+
+/obj/item/assembly/flash/attack(mob/living/M, mob/user)
+	if(!try_use_flash(user))
+		return FALSE
+	if(iscarbon(M))
+		flash_carbon(M, user, 20, 1)
+		return TRUE
+	else if(issilicon(M))
+		var/mob/living/silicon/robot/R = M
+		log_combat(user, R, "flashed", src)
+		update_icon(1)
+		R.Knockdown(rand(80,120))
+		var/diff = 5 * CONFUSION_STACK_MAX_MULTIPLIER - M.confused
+		R.confused += min(5, diff)
+		R.flash_act(affect_silicon = 1)
+		user.visible_message("<span class='disarm'>[user] overloads [R]'s sensors with the flash!</span>", "<span class='danger'>You overload [R]'s sensors with the flash!</span>")
+		return TRUE
+
+	user.visible_message("<span class='disarm'>[user] fails to blind [M] with the flash!</span>", "<span class='warning'>You fail to blind [M] with the flash!</span>")
+
+/obj/item/assembly/flash/attack_self(mob/living/carbon/user, flag = 0, emp = 0)
+	if(holder)
+		return FALSE
+	if(!AOE_flash(FALSE, 3, 5, FALSE, user))
+		return FALSE
+	to_chat(user, "<span class='danger'>[src] emits a blinding light!</span>")
+
+/obj/item/assembly/flash/emp_act(severity)
+	. = ..()
+	if(. & EMP_PROTECT_SELF)
+		return
+	if(!try_use_flash())
+		return
+	AOE_flash()
+	burn_out()
+
+/obj/item/assembly/flash/activate()//AOE flash on signal received
+	if(!..())
+		return
+	AOE_flash()
+
+/obj/item/assembly/flash/proc/terrible_conversion_proc(mob/living/carbon/human/H, mob/user)
+	if(istype(H) && ishuman(user) && H.stat != DEAD)
+		if(user.mind)
+			var/datum/antagonist/rev/head/converter = user.mind.has_antag_datum(/datum/antagonist/rev/head)
+			if(!converter)
+				return
+			if(!H.client)
+				to_chat(user, "<span class='warning'>This mind is so vacant that it is not susceptible to influence!</span>")
+				return
+			if(H.stat != CONSCIOUS)
+				to_chat(user, "<span class='warning'>They must be conscious before you can convert [H.p_them()]!</span>")
+				return
+			if(converter.add_revolutionary(H.mind))
+				times_used -- //Flashes less likely to burn out for headrevs when used for conversion
+			else
+				to_chat(user, "<span class='warning'>This mind seems resistant to the flash!</span>")
+
+
+/obj/item/assembly/flash/cyborg
+
+/obj/item/assembly/flash/cyborg/attack(mob/living/M, mob/user)
+	. = ..()
+	new /obj/effect/temp_visual/borgflash(get_turf(src))
+	if(. && !CONFIG_GET(flag/disable_borg_flash_knockdown) && iscarbon(M) && !M.resting && !M.get_eye_protection())
+		M.Knockdown(80)
+
+/obj/item/assembly/flash/cyborg/attack_self(mob/user)
+	..()
+	new /obj/effect/temp_visual/borgflash(get_turf(src))
+
+/obj/item/assembly/flash/cyborg/attackby(obj/item/W, mob/user, params)
+	return
+/obj/item/assembly/flash/cyborg/screwdriver_act(mob/living/user, obj/item/I)
+	return
+
+/obj/item/assembly/flash/memorizer
+	name = "memorizer"
+	desc = "If you see this, you're not likely to remember it any time soon."
+	icon = 'icons/obj/device.dmi'
+	icon_state = "memorizer"
+	item_state = "nullrod"
+
+/obj/item/assembly/flash/handheld //this is now the regular pocket flashes
+
+/obj/item/assembly/flash/armimplant
+	name = "photon projector"
+	desc = "A high-powered photon projector implant normally used for lighting purposes, but also doubles as a flashbulb weapon. Self-repair protocols fix the flashbulb if it ever burns out."
+	var/flashcd = 20
+	var/overheat = 0
+	var/obj/item/organ/cyberimp/arm/flash/I = null
+
+/obj/item/assembly/flash/armimplant/burn_out()
+	if(I && I.owner)
+		to_chat(I.owner, "<span class='warning'>Your photon projector implant overheats and deactivates!</span>")
+		I.Retract()
+	overheat = TRUE
+	addtimer(CALLBACK(src, .proc/cooldown), flashcd * 2)
+
+/obj/item/assembly/flash/armimplant/try_use_flash(mob/user = null)
+	if(overheat)
+		if(I && I.owner)
+			to_chat(I.owner, "<span class='warning'>Your photon projector is running too hot to be used again so quickly!</span>")
+		return FALSE
+	overheat = TRUE
+	addtimer(CALLBACK(src, .proc/cooldown), flashcd)
+	playsound(src, 'sound/weapons/flash.ogg', 100, TRUE)
+	update_icon(1)
+	return TRUE
+
+
+/obj/item/assembly/flash/armimplant/proc/cooldown()
+	overheat = FALSE
+
+/obj/item/assembly/flash/shield
+	name = "strobe shield"
+	desc = "A shield with a built in, high intensity light capable of blinding and disorienting suspects. Takes regular handheld flashes as bulbs."
+	icon = 'icons/obj/items_and_weapons.dmi'
+	icon_state = "flashshield"
+	item_state = "flashshield"
+	lefthand_file = 'icons/mob/inhands/equipment/shields_lefthand.dmi'
+	righthand_file = 'icons/mob/inhands/equipment/shields_righthand.dmi'
+	slot_flags = ITEM_SLOT_BACK
+	force = 10
+	throwforce = 5
+	throw_speed = 2
+	throw_range = 3
+	w_class = WEIGHT_CLASS_BULKY
+	materials = list(MAT_GLASS=7500, MAT_METAL=1000)
+	attack_verb = list("shoved", "bashed")
+	block_chance = 50
+	armor = list("melee" = 50, "bullet" = 50, "laser" = 50, "energy" = 0, "bomb" = 30, "bio" = 0, "rad" = 0, "fire" = 80, "acid" = 70)
+
+/obj/item/assembly/flash/shield/flash_recharge(interval=10)
+	if(times_used >= 4)
+		burn_out()
+		return FALSE
+	return TRUE
+
+/obj/item/assembly/flash/shield/attackby(obj/item/W, mob/user)
+	if(istype(W, /obj/item/assembly/flash/handheld))
+		var/obj/item/assembly/flash/handheld/flash = W
+		if(flash.crit_fail)
+			to_chat(user, "No sense replacing it with a broken bulb.")
+			return
+		else
+			to_chat(user, "You begin to replace the bulb.")
+			if(do_after(user, 20, target = src))
+				if(flash.crit_fail || !flash || QDELETED(flash))
+					return
+				crit_fail = FALSE
+				times_used = 0
+				playsound(src, 'sound/items/deconstruct.ogg', 50, TRUE)
+				update_icon()
+				flash.crit_fail = TRUE
+				flash.update_icon()
+				return
+	..()
+
+/obj/item/assembly/flash/shield/update_icon(flash = FALSE)
+	icon_state = "flashshield"
+	item_state = "flashshield"
+
+	if(crit_fail)
+		icon_state = "riot"
+		item_state = "riot"
+	else if(flash)
+		icon_state = "flashshield_flash"
+		item_state = "flashshield_flash"
+		addtimer(CALLBACK(src, .proc/update_icon), 5)
+
+	if(holder)
+		holder.update_icon()
+
+/obj/item/assembly/flash/shield/hit_reaction(mob/living/carbon/human/owner, atom/movable/hitby, attack_text = "the attack", final_block_chance = 0, damage = 0, attack_type = MELEE_ATTACK)
+	activate()
+	return ..()
+
+//ported from tg - check to make sure it can't appear where it's not supposed to.
+/obj/item/assembly/flash/hypnotic
+	desc = "A modified flash device, programmed to emit a sequence of subliminal flashes that can send a vulnerable target into a hypnotic trance."
+	flashing_overlay = "flash-hypno" //I cannot find this icon no matter how hard I look in tg, so I might just make my own.
+	light_color = LIGHT_COLOR_PINK
+	cooldown = 20
+
+/obj/item/assembly/flash/hypnotic/burn_out()
+	return
+
+/obj/item/assembly/flash/hypnotic/flash_carbon(mob/living/carbon/M, mob/user, power = 15, targeted = TRUE, generic_message = FALSE)
+	if(!istype(M))
+		return
+	if(user)
+		log_combat(user, M, "[targeted? "hypno-flashed(targeted)" : "hypno-flashed(AOE)"]", src)
+	else //caused by emp/remote signal
+		M.log_message("was [targeted? "hypno-flashed(targeted)" : "hypno-flashed(AOE)"]",LOG_ATTACK)
+	if(generic_message && M != user)
+		to_chat(M, "<span class='disarm'>[src] emits a soothing light...</span>")
+	if(targeted)
+		if(M.flash_act(1, 1))
+			var/hypnosis = FALSE
+			if(M.hypnosis_vulnerable())
+				hypnosis = TRUE
+			if(user)
+				user.visible_message("<span class='disarm'>[user] blinds [M] with the flash!</span>", "<span class='danger'>You hypno-flash [M]!</span>")
+
+			if(!hypnosis)
+				to_chat(M, "<span class='notice'>The light makes you feel oddly relaxed...</span>")
+				M.confused += min(M.confused + 10, 20)
+				M.dizziness += min(M.dizziness + 10, 20)
+				M.drowsyness += min(M.drowsyness + 10, 20)
+				M.apply_status_effect(STATUS_EFFECT_PACIFY, 100)
+			else
+				M.apply_status_effect(/datum/status_effect/trance, 200, TRUE)
+
+		else if(user)
+			user.visible_message("<span class='disarm'>[user] fails to blind [M] with the flash!</span>", "<span class='warning'>You fail to hypno-flash [M]!</span>")
+		else
+			to_chat(M, "<span class='danger'>[src] fails to blind you!</span>")
+
+	else if(M.flash_act())
+		to_chat(M, "<span class='notice'>Such a pretty light...</span>")
+		M.confused += min(M.confused + 4, 20)
+		M.dizziness += min(M.dizziness + 4, 20)
+		M.drowsyness += min(M.drowsyness + 4, 20)
@@ -0,0 +1,239 @@
+/obj/item/assembly/infra
+	name = "infrared emitter"
+	desc = "Emits a visible or invisible beam and is triggered when the beam is interrupted."
+	icon_state = "infrared"
+	materials = list(MAT_METAL=1000, MAT_GLASS=500)
+	is_position_sensitive = TRUE
+
+	var/on = FALSE
+	var/visible = FALSE
+	var/maxlength = 8
+	var/list/obj/effect/beam/i_beam/beams
+	var/olddir = 0
+	var/turf/listeningTo
+	var/hearing_range = 3
+
+/obj/item/assembly/infra/Initialize()
+	. = ..()
+	beams = list()
+	START_PROCESSING(SSobj, src)
+
+/obj/item/assembly/infra/ComponentInitialize()
+	. = ..()
+	AddComponent(
+		/datum/component/simple_rotation,
+		ROTATION_ALTCLICK | ROTATION_CLOCKWISE | ROTATION_COUNTERCLOCKWISE | ROTATION_FLIP | ROTATION_VERBS,
+		null,
+		null,
+		CALLBACK(src,.proc/after_rotation)
+		)
+
+/obj/item/assembly/infra/proc/after_rotation()
+	refreshBeam()
+
+/obj/item/assembly/infra/Destroy()
+	STOP_PROCESSING(SSobj, src)
+	listeningTo = null
+	QDEL_LIST(beams)
+	. = ..()
+
+/obj/item/assembly/infra/examine(mob/user)
+	..()
+	to_chat(user, "<span class='notice'>The infrared trigger is [on?"on":"off"].</span>")
+
+/obj/item/assembly/infra/activate()
+	if(!..())
+		return FALSE//Cooldown check
+	on = !on
+	refreshBeam()
+	update_icon()
+	return TRUE
+
+/obj/item/assembly/infra/toggle_secure()
+	secured = !secured
+	if(secured)
+		START_PROCESSING(SSobj, src)
+		refreshBeam()
+	else
+		QDEL_LIST(beams)
+		STOP_PROCESSING(SSobj, src)
+	update_icon()
+	return secured
+
+/obj/item/assembly/infra/update_icon()
+	cut_overlays()
+	attached_overlays = list()
+	if(on)
+		add_overlay("infrared_on")
+		attached_overlays += "infrared_on"
+		if(visible && secured)
+			add_overlay("infrared_visible")
+			attached_overlays += "infrared_visible"
+
+	if(holder)
+		holder.update_icon()
+	return
+
+/obj/item/assembly/infra/dropped()
+	. = ..()
+	if(holder)
+		holder_movement() //sync the dir of the device as well if it's contained in a TTV or an assembly holder
+	else
+		refreshBeam()
+
+/obj/item/assembly/infra/process()
+	if(!on || !secured)
+		refreshBeam()
+		return
+
+/obj/item/assembly/infra/proc/refreshBeam()
+	QDEL_LIST(beams)
+	if(throwing || !on || !secured)
+		return
+	if(holder)
+		if(holder.master) //incase the sensor is part of an assembly that's contained in another item, such as a single tank bomb
+			if(!holder.master.IsSpecialAssembly() || !isturf(holder.master.loc))
+				return
+		else if(!isturf(holder.loc)) //else just check where the holder is
+			return
+	else if(!isturf(loc)) //or just where the fuck we are in general
+		return
+	var/turf/T = get_turf(src)
+	var/_dir = dir
+	var/turf/_T = get_step(T, _dir)
+	if(_T)
+		for(var/i in 1 to maxlength)
+			var/obj/effect/beam/i_beam/I = new(T)
+			if(istype(holder, /obj/item/assembly_holder))
+				var/obj/item/assembly_holder/assembly_holder = holder
+				I.icon_state = "[initial(I.icon_state)]_[(assembly_holder.a_left == src) ? "l":"r"]" //Sync the offset of the beam with the position of the sensor.
+			else if(istype(holder, /obj/item/transfer_valve))
+				I.icon_state = "[initial(I.icon_state)]_ttv"
+			I.density = TRUE
+			if(!I.Move(_T))
+				qdel(I)
+				switchListener(_T)
+				break
+			I.density = FALSE
+			beams += I
+			I.master = src
+			I.setDir(_dir)
+			I.invisibility = visible? 0 : INVISIBILITY_ABSTRACT
+			T = _T
+			_T = get_step(_T, _dir)
+			CHECK_TICK
+
+/obj/item/assembly/infra/on_detach()
+	. = ..()
+	if(!.)
+		return
+	refreshBeam()
+
+/obj/item/assembly/infra/attack_hand()
+	. = ..()
+	refreshBeam()
+
+/obj/item/assembly/infra/Moved()
+	var/t = dir
+	. = ..()
+	setDir(t)
+
+/obj/item/assembly/infra/throw_at(atom/target, range, speed, mob/thrower, spin=1, diagonals_first = 0, datum/callback/callback)
+	. = ..()
+	olddir = dir
+
+/obj/item/assembly/infra/throw_impact()
+	. = ..()
+	if(!olddir)
+		return
+	setDir(olddir)
+	olddir = null
+
+/obj/item/assembly/infra/proc/trigger_beam(atom/movable/AM, turf/location)
+	refreshBeam()
+	switchListener(location)
+	if(!secured || !on || next_activate > world.time)
+		return FALSE
+	pulse(FALSE)
+	audible_message("[icon2html(src, hearers(src))] *beep* *beep* *beep*", null, hearing_range)
+	for(var/CHM in get_hearers_in_view(hearing_range, src))
+		if(ismob(CHM))
+			var/mob/LM = CHM
+			LM.playsound_local(get_turf(src), 'sound/machines/triple_beep.ogg', ASSEMBLY_BEEP_VOLUME, TRUE)
+	next_activate =  world.time + 30
+
+/obj/item/assembly/infra/proc/switchListener(turf/newloc)
+	if(listeningTo == newloc)
+		return
+	if(listeningTo)
+		UnregisterSignal(listeningTo, COMSIG_ATOM_EXITED)
+	RegisterSignal(newloc, COMSIG_ATOM_EXITED, .proc/check_exit)
+	listeningTo = newloc
+
+/obj/item/assembly/infra/proc/check_exit(datum/source, atom/movable/offender)
+	if(QDELETED(src))
+		return
+	if(offender == src || istype(offender,/obj/effect/beam/i_beam))
+		return
+	if (offender && isitem(offender))
+		var/obj/item/I = offender
+		if (I.item_flags & ABSTRACT)
+			return
+	return refreshBeam()
+
+/obj/item/assembly/infra/ui_interact(mob/user)//TODO: change this this to the wire control panel
+	. = ..()
+	if(is_secured(user))
+		user.set_machine(src)
+		var/dat = "<TT><B>Infrared Laser</B></TT>"
+		dat += "<BR><B>Status</B>: [on ? "<A href='?src=[REF(src)];state=0'>On</A>" : "<A href='?src=[REF(src)];state=1'>Off</A>"]"
+		dat += "<BR><B>Visibility</B>: [visible ? "<A href='?src=[REF(src)];visible=0'>Visible</A>" : "<A href='?src=[REF(src)];visible=1'>Invisible</A>"]"
+		dat += "<BR><BR><A href='?src=[REF(src)];refresh=1'>Refresh</A>"
+		dat += "<BR><BR><A href='?src=[REF(src)];close=1'>Close</A>"
+		user << browse(dat, "window=infra")
+		onclose(user, "infra")
+		return
+
+/obj/item/assembly/infra/Topic(href, href_list)
+	..()
+	if(usr.incapacitated() || !in_range(loc, usr))
+		usr << browse(null, "window=infra")
+		onclose(usr, "infra")
+		return
+	if(href_list["state"])
+		on = !(on)
+		update_icon()
+		refreshBeam()
+	if(href_list["visible"])
+		visible = !(visible)
+		update_icon()
+		refreshBeam()
+	if(href_list["close"])
+		usr << browse(null, "window=infra")
+		return
+	if(usr)
+		attack_self(usr)
+
+/obj/item/assembly/infra/setDir()
+	. = ..()
+	refreshBeam()
+
+/***************************IBeam*********************************/
+
+/obj/effect/beam/i_beam
+	name = "infrared beam"
+	icon = 'icons/obj/projectiles.dmi'
+	icon_state = "ibeam"
+	var/obj/item/assembly/infra/master
+	anchored = TRUE
+	density = FALSE
+	pass_flags = PASSTABLE|PASSGLASS|PASSGRILLE|LETPASSTHROW
+
+/obj/effect/beam/i_beam/Crossed(atom/movable/AM as mob|obj)
+	if(istype(AM, /obj/effect/beam))
+		return
+	if (isitem(AM))
+		var/obj/item/I = AM
+		if (I.item_flags & ABSTRACT)
+			return
+	master.trigger_beam(AM, get_turf(src))