'lolman? did you test your code?'

no i did not ms. kevinz

code/modules/plumbing/plumbers/_plumb_machinery.dm

@@ -0,0 +1,97 @@
+/**Basic plumbing object.
+* It doesn't really hold anything special, YET.
+* Objects that are plumbing but not a subtype are as of writing liquid pumps and the reagent_dispenser tank
+* Also please note that the plumbing component is toggled on and off by the component using a signal from default_unfasten_wrench, so dont worry about it
+*/
+/obj/machinery/plumbing
+	name = "pipe thing"
+	icon = 'icons/obj/plumbing/plumbers.dmi'
+	icon_state = "pump"
+	density = TRUE
+	active_power_usage = 30
+	use_power = ACTIVE_POWER_USE
+	resistance_flags = FIRE_PROOF | UNACIDABLE | ACID_PROOF
+	///Plumbing machinery is always gonna need reagents, so we might aswell put it here
+	var/buffer = 50
+	///Flags for reagents, like INJECTABLE, TRANSPARENT bla bla everything thats in DEFINES/reagents.dm
+	var/reagent_flags = TRANSPARENT
+	///wheter we partake in rcd construction or not
+	var/rcd_constructable = TRUE
+	///cost of the plumbing rcd construction
+	var/rcd_cost = 15
+	///delay of constructing it throught the plumbing rcd
+	var/rcd_delay = 10
+
+/obj/machinery/plumbing/Initialize(mapload, bolt = TRUE)
+	. = ..()
+	anchored = bolt
+	create_reagents(buffer, reagent_flags)
+	AddComponent(/datum/component/simple_rotation, ROTATION_ALTCLICK | ROTATION_CLOCKWISE | ROTATION_COUNTERCLOCKWISE | ROTATION_VERBS )
+
+/obj/machinery/plumbing/proc/can_be_rotated(mob/user,rotation_type)
+	return TRUE
+
+/obj/machinery/plumbing/examine(mob/user)
+	. = ..()
+	. += "<span class='notice'>The maximum volume display reads: <b>[reagents.maximum_volume] units</b>.</span>"
+
+/obj/machinery/plumbing/wrench_act(mob/living/user, obj/item/I)
+	..()
+	default_unfasten_wrench(user, I)
+	return TRUE
+
+/obj/machinery/plumbing/plunger_act(obj/item/plunger/P, mob/living/user, reinforced)
+	to_chat(user, "<span class='notice'>You start furiously plunging [name].")
+	if(do_after(user, 30, target = src))
+		to_chat(user, "<span class='notice'>You finish plunging the [name].")
+		reagents.reaction(get_turf(src), TOUCH) //splash on the floor
+		reagents.clear_reagents()
+
+/obj/machinery/plumbing/welder_act(mob/living/user, obj/item/I)
+	. = ..()
+	if(anchored)
+		to_chat(user, "<span class='warning'>The [name] needs to be unbolted to do that!</span")
+	if(I.tool_start_check(user, amount=0))
+		to_chat(user, "<span class='notice'>You start slicing the [name] apart.</span")
+		if(I.use_tool(src, user, rcd_delay * 2, volume=50))
+			deconstruct(TRUE)
+			to_chat(user, "<span class='notice'>You slice the [name] apart.</span")
+			return TRUE
+
+///We can empty beakers in here and everything
+/obj/machinery/plumbing/input
+	name = "input gate"
+	desc = "Can be manually filled with reagents from containers."
+	icon_state = "pipe_input"
+	reagent_flags = TRANSPARENT | REFILLABLE
+	rcd_cost = 5
+	rcd_delay = 5
+
+/obj/machinery/plumbing/input/Initialize(mapload, bolt)
+	. = ..()
+	AddComponent(/datum/component/plumbing/simple_supply, bolt)
+
+///We can fill beakers in here and everything. we dont inheret from input because it has nothing that we need
+/obj/machinery/plumbing/output
+	name = "output gate"
+	desc = "A manual output for plumbing systems, for taking reagents directly into containers."
+	icon_state = "pipe_output"
+	reagent_flags = TRANSPARENT | DRAINABLE
+	rcd_cost = 5
+	rcd_delay = 5
+
+/obj/machinery/plumbing/output/Initialize(mapload, bolt)
+	. = ..()
+	AddComponent(/datum/component/plumbing/simple_demand, bolt)
+
+/obj/machinery/plumbing/tank
+	name = "chemical tank"
+	desc = "A massive chemical holding tank."
+	icon_state = "tank"
+	buffer = 400
+	rcd_cost = 25
+	rcd_delay = 20
+
+/obj/machinery/plumbing/tank/Initialize(mapload, bolt)
+	. = ..()
+	AddComponent(/datum/component/plumbing/tank, bolt)

code/modules/plumbing/plumbers/acclimator.dm

@@ -0,0 +1,105 @@
+//we cant use defines in tgui, so use a string instead of magic numbers
+#define COOLING "Cooling"
+#define HEATING "Heating"
+#define NEUTRAL "Neutral"
+
+///this the plumbing version of a heater/freezer.
+/obj/machinery/plumbing/acclimator
+	name = "chemical acclimator"
+	desc = "An efficient cooler and heater for the perfect showering temperature or illicit chemical factory."
+
+	icon_state = "acclimator"
+	buffer = 200
+
+	///towards wich temperature do we build?
+	var/target_temperature = 300
+	///I cant find a good name for this. Basically if target is 300, and this is 10, it will still target 300 but will start emptying itself at 290 and 310.
+	var/allowed_temperature_difference = 1
+	///cool/heat power
+	var/heater_coefficient = 0.1
+	///Are we turned on or off? this is from the on and off button
+	var/enabled = TRUE
+	///COOLING, HEATING or NEUTRAL. We track this for change, so we dont needlessly update our icon
+	var/acclimate_state
+	/**We can't take anything in, at least till we're emptied. Down side of the round robin chem transfer, otherwise while emptying 5u of an unreacted chem gets added,
+	and you get nasty leftovers
+	*/
+	var/emptying = FALSE
+	var/ui_x = 320
+	var/ui_y = 310
+
+/obj/machinery/plumbing/acclimator/Initialize(mapload, bolt)
+	. = ..()
+	AddComponent(/datum/component/plumbing/acclimator, bolt)
+
+/obj/machinery/plumbing/acclimator/process()
+	if(stat & NOPOWER || !enabled || !reagents.total_volume || reagents.chem_temp == target_temperature)
+		if(acclimate_state != NEUTRAL)
+			acclimate_state = NEUTRAL
+			update_icon()
+		if(!reagents.total_volume)
+			emptying = FALSE
+		return
+
+	if(reagents.chem_temp < target_temperature && acclimate_state != HEATING) //note that we check if the temperature is the same at the start
+		acclimate_state = HEATING
+		update_icon()
+	else if(reagents.chem_temp > target_temperature && acclimate_state != COOLING)
+		acclimate_state = COOLING
+		update_icon()
+	if(!emptying)
+		if(reagents.chem_temp >= target_temperature && target_temperature + allowed_temperature_difference >= reagents.chem_temp) //cooling here
+			emptying = TRUE
+		if(reagents.chem_temp <= target_temperature && target_temperature - allowed_temperature_difference <= reagents.chem_temp) //heating here
+			emptying = TRUE
+
+	reagents.adjust_thermal_energy((target_temperature - reagents.chem_temp) * heater_coefficient * SPECIFIC_HEAT_DEFAULT * reagents.total_volume) //keep constant with chem heater
+	reagents.handle_reactions()
+
+/obj/machinery/plumbing/acclimator/update_icon()
+	icon_state = initial(icon_state)
+	switch(acclimate_state)
+		if(COOLING)
+			icon_state += "_cold"
+		if(HEATING)
+			icon_state += "_hot"
+
+/obj/machinery/plumbing/acclimator/ui_interact(mob/user, datum/tgui/ui)
+	ui = SStgui.try_update_ui(user, src, ui)
+	if(!ui)
+		ui = new(user, src, "ChemAcclimator", name)
+		ui.open()
+
+/obj/machinery/plumbing/acclimator/ui_data(mob/user)
+	var/list/data = list()
+
+	data["enabled"] = enabled
+	data["chem_temp"] = reagents.chem_temp
+	data["target_temperature"] = target_temperature
+	data["allowed_temperature_difference"] = allowed_temperature_difference
+	data["acclimate_state"] = acclimate_state
+	data["max_volume"] = reagents.maximum_volume
+	data["reagent_volume"] = reagents.total_volume
+	data["emptying"] = emptying
+	return data
+
+/obj/machinery/plumbing/acclimator/ui_act(action, params)
+	if(..())
+		return
+	. = TRUE
+	switch(action)
+		if("set_target_temperature")
+			var/target = text2num(params["temperature"])
+			target_temperature = clamp(target, 0, 1000)
+		if("set_allowed_temperature_difference")
+			var/target = text2num(params["temperature"])
+			allowed_temperature_difference = clamp(target, 0, 1000)
+		if("toggle_power")
+			enabled = !enabled
+		if("change_volume")
+			var/target = text2num(params["volume"])
+			reagents.maximum_volume = clamp(round(target), 1, buffer)
+
+#undef COOLING
+#undef HEATING
+#undef NEUTRAL

code/modules/plumbing/plumbers/bottler.dm

@@ -0,0 +1,79 @@
+/obj/machinery/plumbing/bottler
+	name = "chemical bottler"
+	desc = "Puts reagents into containers, like bottles and beakers."
+	icon_state = "bottler"
+	layer = ABOVE_ALL_MOB_LAYER
+	reagent_flags = TRANSPARENT | DRAINABLE
+	rcd_cost = 50
+	rcd_delay = 50
+	buffer = 100
+	///how much do we fill
+	var/wanted_amount = 10
+	///where things are sent
+	var/turf/goodspot = null
+	///where things are taken
+	var/turf/inputspot = null
+	///where beakers that are already full will be sent
+	var/turf/badspot = null
+
+/obj/machinery/plumbing/bottler/Initialize(mapload, bolt)
+	. = ..()
+	AddComponent(/datum/component/plumbing/simple_demand, bolt)
+	setDir(dir)
+
+/obj/machinery/plumbing/bottler/can_be_rotated(mob/user, rotation_type)
+	if(anchored)
+		to_chat(user, "<span class='warning'>It is fastened to the floor!</span>")
+		return FALSE
+	return TRUE
+
+///changes the tile array
+/obj/machinery/plumbing/bottler/setDir(newdir)
+	. = ..()
+	switch(dir)
+		if(NORTH)
+			goodspot = get_step(get_turf(src), NORTH)
+			inputspot = get_step(get_turf(src), SOUTH)
+			badspot  = get_step(get_turf(src), EAST)
+		if(SOUTH)
+			goodspot = get_step(get_turf(src), SOUTH)
+			inputspot = get_step(get_turf(src), NORTH)
+			badspot  = get_step(get_turf(src), WEST)
+		if(WEST)
+			goodspot = get_step(get_turf(src), WEST)
+			inputspot = get_step(get_turf(src), EAST)
+			badspot  = get_step(get_turf(src), NORTH)
+		if(EAST)
+			goodspot = get_step(get_turf(src), EAST)
+			inputspot = get_step(get_turf(src), WEST)
+			badspot  = get_step(get_turf(src), SOUTH)
+
+///changing input ammount with a window
+/obj/machinery/plumbing/bottler/interact(mob/user)
+	. = ..()
+	wanted_amount = clamp(round(input(user,"maximum is 100u","set ammount to fill with") as num|null, 1), 1, 100)
+	reagents.clear_reagents()
+	to_chat(user, "<span class='notice'> The [src] will now fill for [wanted_amount]u.</span>")
+
+/obj/machinery/plumbing/bottler/process()
+	if(machine_stat & NOPOWER)
+		return
+	///see if machine has enough to fill
+	if(reagents.total_volume >= wanted_amount && anchored)
+		var/obj/AM = pick(inputspot.contents)///pick a reagent_container that could be used
+		if(istype(AM, /obj/item/reagent_containers) && (!istype(AM, /obj/item/reagent_containers/hypospray/medipen)))
+			var/obj/item/reagent_containers/B = AM
+			///see if it would overflow else inject
+			if((B.reagents.total_volume + wanted_amount) <= B.reagents.maximum_volume)
+				reagents.trans_to(B, wanted_amount, transfered_by = src)
+				B.forceMove(goodspot)
+				return
+			///glass was full so we move it away
+			AM.forceMove(badspot)
+		if(istype(AM, /obj/item/slime_extract)) ///slime extracts need inject
+			AM.forceMove(goodspot)
+			reagents.trans_to(AM, wanted_amount, transfered_by = src, method = INJECT)
+			return
+		if(istype(AM, /obj/item/slimecross/industrial)) ///no need to move slimecross industrial things
+			reagents.trans_to(AM, wanted_amount, transfered_by = src, method = INJECT)
+			return

code/modules/plumbing/plumbers/destroyer.dm

@@ -0,0 +1,21 @@
+/obj/machinery/plumbing/disposer
+	name = "chemical disposer"
+	desc = "Breaks down chemicals and annihilates them."
+	icon_state = "disposal"
+	///we remove 10 reagents per second
+	var/disposal_rate = 10
+
+/obj/machinery/plumbing/disposer/Initialize(mapload, bolt)
+	. = ..()
+	AddComponent(/datum/component/plumbing/simple_demand, bolt)
+
+/obj/machinery/plumbing/disposer/process()
+	if(stat & NOPOWER)
+		return
+	if(reagents.total_volume)
+		if(icon_state != initial(icon_state) + "_working") //threw it here instead of update icon since it only has two states
+			icon_state = initial(icon_state) + "_working"
+		reagents.remove_any(disposal_rate)
+	else
+		if(icon_state != initial(icon_state))
+			icon_state = initial(icon_state)

code/modules/plumbing/plumbers/fermenter.dm

@@ -0,0 +1,52 @@
+/obj/machinery/plumbing/fermenter //FULLY AUTOMATIC BEER BREWING. TRULY, THE FUTURE.
+	name = "chemical fermenter"
+	desc = "Turns plants into various types of booze."
+	icon_state = "fermenter"
+	layer = ABOVE_ALL_MOB_LAYER
+	reagent_flags = TRANSPARENT | DRAINABLE
+	rcd_cost = 30
+	rcd_delay = 30
+	buffer = 400
+	///input dir
+	var/eat_dir = SOUTH
+
+/obj/machinery/plumbing/fermenter/Initialize(mapload, bolt)
+	. = ..()
+	AddComponent(/datum/component/plumbing/simple_supply, bolt)
+
+/obj/machinery/plumbing/grinder_chemical/can_be_rotated(mob/user, rotation_type)
+	if(anchored)
+		to_chat(user, "<span class='warning'>It is fastened to the floor!</span>")
+		return FALSE
+	return TRUE
+
+/obj/machinery/plumbing/fermenter/setDir(newdir)
+	. = ..()
+	eat_dir = newdir
+
+/obj/machinery/plumbing/fermenter/CanAllowThrough(atom/movable/AM)
+	. = ..()
+	if(!anchored)
+		return
+	var/move_dir = get_dir(loc, AM.loc)
+	if(move_dir == eat_dir)
+		return TRUE
+
+/obj/machinery/plumbing/fermenter/Crossed(atom/movable/AM)
+	. = ..()
+	ferment(AM)
+
+/// uses fermentation proc similar to fermentation barrels
+/obj/machinery/plumbing/fermenter/proc/ferment(atom/AM)
+	if(machine_stat & NOPOWER)
+		return
+	if(reagents.holder_full())
+		return
+	if(!isitem(AM))
+		return
+	if(istype(AM, /obj/item/reagent_containers/food/snacks/grown))
+		var/obj/item/reagent_containers/food/snacks/grown/G = AM
+		if(G.distill_reagent)
+			var/amount = G.seed.potency * 0.25
+			reagents.add_reagent(G.distill_reagent, amount)
+			qdel(G)

code/modules/plumbing/plumbers/filter.dm

@@ -0,0 +1,74 @@
+///chemical plumbing filter. If it's not filtered by left and right, it goes straight.
+/obj/machinery/plumbing/filter
+	name = "chemical filter"
+	desc = "A chemical filter for filtering chemicals. The left and right outputs appear to be from the perspective of the input port."
+	icon_state = "filter"
+	density = FALSE
+	///whitelist of chems id's that go to the left side. Empty to disable port
+	var/list/left = list()
+	///whitelist of chem id's that go to the right side. Empty to disable port
+	var/list/right = list()
+	///whitelist of chems but their name instead of path
+	var/list/english_left = list()
+	///whitelist of chems but their name instead of path
+	var/list/english_right = list()
+	var/ui_x = 320
+	var/ui_y = 310
+
+
+/obj/machinery/plumbing/filter/Initialize(mapload, bolt)
+	. = ..()
+	AddComponent(/datum/component/plumbing/filter, bolt)
+
+/obj/machinery/plumbing/filter/ui_interact(mob/user, ui_key = "main", datum/tgui/ui = null, force_open = FALSE, datum/tgui/master_ui = null, datum/ui_state/state = GLOB.default_state)
+	ui = SStgui.try_update_ui(user, src, ui_key, ui, force_open)
+
+	if(!ui)
+		ui = new(user, src, ui_key, "chemical_filter", name, ui_x, ui_y, master_ui, state)
+		ui.open()
+
+/obj/machinery/plumbing/filter/ui_interact(mob/user, datum/tgui/ui)
+	ui = SStgui.try_update_ui(user, src, ui)
+	if(!ui)
+		ui = new(user, src, "ChemFilter", name)
+		ui.open()
+
+/obj/machinery/plumbing/filter/ui_data(mob/user)
+	var/list/data = list()
+	data["left"] = english_left
+	data["right"] = english_right
+	return data
+
+/obj/machinery/plumbing/filter/ui_act(action, params)
+	if(..())
+		return
+	. = TRUE
+	switch(action)
+		if("add")
+			var/new_chem_name = params["name"]
+			var/chem_id = get_chem_id(new_chem_name)
+			if(chem_id)
+				switch(params["which"])
+					if("left")
+						if(!left.Find(chem_id))
+							english_left += new_chem_name
+							left += chem_id
+					if("right")
+						if(!right.Find(chem_id))
+							english_right += new_chem_name
+							right += chem_id
+			else
+				to_chat(usr, "<span class='warning'>No such known reagent exists!</span>")
+
+		if("remove")
+			var/chem_name = params["reagent"]
+			var/chem_id = get_chem_id(chem_name)
+			switch(params["which"])
+				if("left")
+					if(english_left.Find(chem_name))
+						english_left -= chem_name
+						left -= chem_id
+				if("right")
+					if(english_right.Find(chem_name))
+						english_right -= chem_name
+						right -= chem_id

code/modules/plumbing/plumbers/grinder_chemical.dm

@@ -0,0 +1,58 @@
+/obj/machinery/plumbing/grinder_chemical
+	name = "chemical grinder"
+	desc = "chemical grinder."
+	icon_state = "grinder_chemical"
+	layer = ABOVE_ALL_MOB_LAYER
+	reagent_flags = TRANSPARENT | DRAINABLE
+	rcd_cost = 30
+	rcd_delay = 30
+	buffer = 400
+	var/eat_dir = SOUTH
+
+/obj/machinery/plumbing/grinder_chemical/Initialize(mapload, bolt)
+	. = ..()
+	AddComponent(/datum/component/plumbing/simple_supply, bolt)
+
+/obj/machinery/plumbing/grinder_chemical/can_be_rotated(mob/user, rotation_type)
+	if(anchored)
+		to_chat(user, "<span class='warning'>It is fastened to the floor!</span>")
+		return FALSE
+	return TRUE
+
+/obj/machinery/plumbing/grinder_chemical/setDir(newdir)
+	. = ..()
+	eat_dir = newdir
+
+/obj/machinery/plumbing/grinder_chemical/CanAllowThrough(atom/movable/AM)
+	. = ..()
+	if(!anchored)
+		return
+	var/move_dir = get_dir(loc, AM.loc)
+	if(move_dir == eat_dir)
+		return TRUE
+
+/obj/machinery/plumbing/grinder_chemical/Crossed(atom/movable/AM)
+	. = ..()
+	grind(AM)
+
+/obj/machinery/plumbing/grinder_chemical/proc/grind(atom/AM)
+	if(machine_stat & NOPOWER)
+		return
+	if(reagents.holder_full())
+		return
+	if(!isitem(AM))
+		return
+	var/obj/item/I = AM
+	if(I.juice_results || I.grind_results)
+		if(I.juice_results)
+			I.on_juice()
+			reagents.add_reagent_list(I.juice_results)
+			if(I.reagents)
+				I.reagents.trans_to(src, I.reagents.total_volume, transfered_by = src)
+			qdel(I)
+			return
+		I.on_grind()
+		reagents.add_reagent_list(I.grind_results)
+		if(I.reagents)
+			I.reagents.trans_to(src, I.reagents.total_volume, transfered_by = src)
+		qdel(I)

code/modules/plumbing/plumbers/pill_press.dm

@@ -0,0 +1,107 @@
+///We take a constant input of reagents, and produce a pill once a set volume is reached
+/obj/machinery/plumbing/pill_press
+	name = "pill press"
+	desc = "A press that presses pills."
+	icon_state = "pill_press"
+	///the minimum size a pill can be
+	var/minimum_pill = 5
+	///the maximum size a pill can be
+	var/maximum_pill = 50
+	///the size of the pill
+	var/pill_size = 10
+	///pill name
+	var/pill_name = "factory pill"
+	///the icon_state number for the pill.
+	var/pill_number = RANDOM_PILL_STYLE
+	///list of id's and icons for the pill selection of the ui
+	var/list/pill_styles
+	///list of pills stored in the machine, so we dont have 610 pills on one tile
+	var/list/stored_pills = list()
+	///max amount of pills allowed on our tile before we start storing them instead
+	var/max_floor_pills = 10
+
+/obj/machinery/plumbing/pill_press/examine(mob/user)
+	. = ..()
+	. += "<span class='notice'>The [name] currently has [stored_pills.len] stored. There needs to be less than [max_floor_pills] on the floor to continue dispensing.</span>"
+
+/obj/machinery/plumbing/pill_press/Initialize(mapload, bolt)
+	. = ..()
+	AddComponent(/datum/component/plumbing/simple_demand, bolt)
+
+	//expertly copypasted from chemmasters
+	var/datum/asset/spritesheet/simple/assets = get_asset_datum(/datum/asset/spritesheet/simple/pills)
+	pill_styles = list()
+	for (var/x in 1 to PILL_STYLE_COUNT)
+		var/list/SL = list()
+		SL["id"] = x
+		SL["htmltag"] = assets.icon_tag("pill[x]")
+		pill_styles += list(SL)
+
+/obj/machinery/plumbing/pill_press/process()
+	if(stat & NOPOWER)
+		return
+	if(reagents.total_volume >= pill_size)
+		var/obj/item/reagent_containers/pill/P = new(src)
+		reagents.trans_to(P, pill_size)
+		P.name = pill_name
+		stored_pills += P
+		if(pill_number == RANDOM_PILL_STYLE)
+			P.icon_state = "pill[rand(1,21)]"
+		else
+			P.icon_state = "pill[pill_number]"
+		if(P.icon_state == "pill4") //mirrored from chem masters
+			P.desc = "A tablet or capsule, but not just any, a red one, one taken by the ones not scared of knowledge, freedom, uncertainty and the brutal truths of reality."
+	if(stored_pills.len)
+		var/pill_amount = 0
+		for(var/obj/item/reagent_containers/pill/P in loc)
+			pill_amount++
+			if(pill_amount >= max_floor_pills) //too much so just stop
+				break
+		if(pill_amount < max_floor_pills)
+			var/atom/movable/AM = stored_pills[1] //AM because forceMove is all we need
+			stored_pills -= AM
+			AM.forceMove(drop_location())
+
+
+/obj/machinery/plumbing/pill_press/ui_assets(mob/user)
+	return list(
+		get_asset_datum(/datum/asset/spritesheet/simple/pills),
+	)
+
+/obj/machinery/plumbing/pill_press/ui_interact(mob/user, datum/tgui/ui)
+	ui = SStgui.try_update_ui(user, src, ui)
+	if(!ui)
+		ui = new(user, src, "ChemPress", name)
+		ui.open()
+
+/obj/machinery/plumbing/pill_press/ui_data(mob/user)
+	var/list/data = list()
+	data["pill_style"] = pill_number
+	data["current_volume"] = current_volume
+	data["product_name"] = product_name
+	data["pill_styles"] = pill_styles
+	data["product"] = product
+	data["min_volume"] = min_volume
+	data["max_volume"] = max_volume
+	return data
+
+/obj/machinery/plumbing/pill_press/ui_act(action, params)
+	if(..())
+		return
+	. = TRUE
+	switch(action)
+		if("change_pill_style")
+			pill_number = clamp(text2num(params["id"]), 1 , PILL_STYLE_COUNT)
+		if("change_current_volume")
+			current_volume = clamp(text2num(params["volume"]), min_volume, max_volume)
+		if("change_product_name")
+			product_name = html_encode(params["name"])
+		if("change_product")
+			product = params["product"]
+			if (product == "pill")
+				max_volume = max_pill_volume
+			else if (product == "patch")
+				max_volume = max_patch_volume
+			else if (product == "bottle")
+				max_volume = max_bottle_volume
+			current_volume = clamp(current_volume, min_volume, max_volume)

code/modules/plumbing/plumbers/pumps.dm

@@ -0,0 +1,83 @@
+///We pump liquids from activated(plungerated) geysers to a plumbing outlet. We need to be wired.
+/obj/machinery/power/liquid_pump
+	name = "liquid pump"
+	desc = "Pump up those sweet liquids from under the surface."
+	icon = 'icons/obj/plumbing/plumbers.dmi'
+	icon_state = "pump"
+	anchored = FALSE
+	density = TRUE
+	idle_power_usage = 10
+	active_power_usage = 1000
+	///Are we powered?
+	var/powered = FALSE
+	///units we pump per process (2 seconds)
+	var/pump_power = 2
+	///set to true if the loop couldnt find a geyser in process, so it remembers and stops checking every loop until moved. more accurate name would be absolutely_no_geyser_under_me_so_dont_try
+	var/geyserless = FALSE
+	///The geyser object
+	var/obj/structure/geyser/geyser
+	///volume of our internal buffer
+	var/volume = 200
+
+/obj/machinery/power/liquid_pump/Initialize()
+	. = ..()
+	create_reagents(volume)
+	AddComponent(/datum/component/plumbing/simple_supply, TRUE)
+
+/obj/machinery/power/liquid_pump/attackby(obj/item/W, mob/user, params)
+	if(!powered)
+		if(!anchored)
+			if(default_deconstruction_screwdriver(user, "[initial(icon_state)]_open", "[initial(icon_state)]",W))
+				return
+		if(default_deconstruction_crowbar(W))
+			return
+	return ..()
+
+/obj/machinery/power/liquid_pump/wrench_act(mob/living/user, obj/item/I)
+	..()
+	default_unfasten_wrench(user, I)
+	return TRUE
+///please note that the component has a hook in the parent call, wich handles activating and deactivating
+/obj/machinery/power/liquid_pump/default_unfasten_wrench(mob/user, obj/item/I, time = 20)
+	. = ..()
+	if(. == SUCCESSFUL_UNFASTEN)
+		geyser = null
+		update_icon()
+		powered = FALSE
+		geyserless = FALSE //we switched state, so lets just set this back aswell
+
+/obj/machinery/power/liquid_pump/process()
+	if(!anchored || panel_open)
+		return
+	if(!geyser && !geyserless)
+		for(var/obj/structure/geyser/G in loc.contents)
+			geyser = G
+		if(!geyser) //we didnt find one, abort
+			anchored = FALSE
+			geyserless = TRUE
+			visible_message("<span class='warning'>The [name] makes a sad beep!</span>")
+			playsound(src, 'sound/machines/buzz-sigh.ogg', 50)
+			return
+
+	if(avail(active_power_usage))
+		if(!powered) //we werent powered before this tick so update our sprite
+			powered = TRUE
+			update_icon()
+		add_load(active_power_usage)
+		pump()
+	else if(powered) //we were powered, but now we arent
+		powered = FALSE
+		update_icon()
+///pump up that sweet geyser nectar
+/obj/machinery/power/liquid_pump/proc/pump()
+	if(!geyser || !geyser.reagents)
+		return
+	geyser.reagents.trans_to(src, pump_power)
+
+/obj/machinery/power/liquid_pump/update_icon()
+	if(powered)
+		icon_state = initial(icon_state) + "-on"
+	else if(panel_open)
+		icon_state = initial(icon_state) + "-open"
+	else
+		icon_state = initial(icon_state)

code/modules/plumbing/plumbers/reaction_chamber.dm

@@ -0,0 +1,63 @@
+///a reaction chamber for plumbing. pretty much everything can react, but this one keeps the reagents seperated and only reacts under your given terms
+/obj/machinery/plumbing/reaction_chamber
+	name = "reaction chamber"
+	desc = "Keeps chemicals seperated until given conditions are met."
+	icon_state = "reaction_chamber"
+
+	buffer = 200
+	reagent_flags = TRANSPARENT | NO_REACT
+	/**list of set reagents that the reaction_chamber allows in, and must all be present before mixing is enabled.
+	* example: list(/datum/reagent/water = 20, /datum/reagent/fuel/oil = 50)
+	*/
+	var/list/required_reagents = list()
+	///our reagent goal has been reached, so now we lock our inputs and start emptying
+	var/emptying = FALSE
+
+/obj/machinery/plumbing/reaction_chamber/Initialize(mapload, bolt)
+	. = ..()
+	AddComponent(/datum/component/plumbing/reaction_chamber, bolt)
+
+/obj/machinery/plumbing/reaction_chamber/on_reagent_change()
+	if(reagents.total_volume == 0 && emptying) //we were emptying, but now we aren't
+		emptying = FALSE
+		reagent_flags |= NO_REACT
+
+/obj/machinery/plumbing/reaction_chamber/power_change()
+	. = ..()
+	if(use_power != NO_POWER_USE)
+		icon_state = initial(icon_state) + "_on"
+	else
+		icon_state = initial(icon_state)
+
+/obj/machinery/plumbing/reaction_chamber/ui_interact(mob/user, datum/tgui/ui)
+	ui = SStgui.try_update_ui(user, src, ui)
+	if(!ui)
+		ui = new(user, src, "ChemReactionChamber", name)
+		ui.open()
+
+/obj/machinery/plumbing/reaction_chamber/ui_data(mob/user)
+	var/list/data = list()
+	var/list/text_reagents = list()
+	for(var/A in required_reagents) //make a list where the key is text, because that looks alot better in the ui than a typepath
+		var/datum/reagent/R = A
+		text_reagents[initial(R.name)] = required_reagents[R]
+
+	data["reagents"] = text_reagents
+	data["emptying"] = emptying
+	return data
+
+/obj/machinery/plumbing/reaction_chamber/ui_act(action, params)
+	if(..())
+		return
+	. = TRUE
+	switch(action)
+		if("remove")
+			var/reagent = get_chem_id(params["chem"])
+			if(reagent)
+				required_reagents.Remove(reagent)
+		if("add")
+			var/input_reagent = get_chem_id(params["chem"])
+			if(input_reagent && !required_reagents.Find(input_reagent))
+				var/input_amount = text2num(params["amount"])
+				if(input_amount)
+					required_reagents[input_reagent] = input_amount

code/modules/plumbing/plumbers/splitters.dm

@@ -0,0 +1,50 @@
+///it splits the reagents however you want. So you can "every 60 units, 45 goes left and 15 goes straight". The side direction is EAST, you can change this in the component
+/obj/machinery/plumbing/splitter
+	name = "Chemical Splitter"
+	desc = "A chemical splitter for smart chemical factorization. Waits till a set of conditions is met and then stops all input and splits the buffer evenly or other in two ducts."
+	icon_state = "splitter"
+	buffer = 100
+	density = FALSE
+
+	///constantly switches between TRUE and FALSE. TRUE means the batch tick goes straight, FALSE means the next batch goes in the side duct.
+	var/turn_straight = TRUE
+	///how much we must transfer straight. note input can be as high as 10 reagents per process, usually
+	var/transfer_straight = 5
+	///how much we must transfer to the side
+	var/transfer_side = 5
+	//the maximum you can set the transfer to
+	var/max_transfer = 9
+
+
+/obj/machinery/plumbing/splitter/Initialize(mapload, bolt)
+	. = ..()
+	AddComponent(/datum/component/plumbing/splitter, bolt)
+
+/obj/machinery/plumbing/splitter/ui_interact(mob/user, datum/tgui/ui)
+	ui = SStgui.try_update_ui(user, src, ui)
+	if(!ui)
+		ui = new(user, src, "ChemSplitter", name)
+		ui.open()
+
+/obj/machinery/plumbing/splitter/ui_data(mob/user)
+	var/list/data = list()
+	data["straight"] = transfer_straight
+	data["side"] = transfer_side
+	data["max_transfer"] = max_transfer
+	return data
+
+/obj/machinery/plumbing/splitter/ui_act(action, params)
+	if(..())
+		return
+	. = TRUE
+	switch(action)
+		if("set_amount")
+			var/direction = params["target"]
+			var/value = clamp(text2num(params["amount"]), 1, max_transfer)
+			switch(direction)
+				if("straight")
+					transfer_straight = value
+				if("side")
+					transfer_side = value
+				else
+					return FALSE

code/modules/plumbing/plumbers/synthesizer.dm

@@ -0,0 +1,111 @@
+///A single machine that produces a single chem. Can be placed in unison with others through plumbing to create chemical factories
+/obj/machinery/plumbing/synthesizer
+	name = "chemical synthesizer"
+	desc = "Produces a single chemical at a given volume. Must be plumbed. Most effective when working in unison with other chemical synthesizers, heaters and filters."
+
+	icon_state = "synthesizer"
+	icon = 'icons/obj/plumbing/plumbers.dmi'
+	rcd_cost = 25
+	rcd_delay = 15
+
+	///Amount we produce for every process. Ideally keep under 5 since thats currently the standard duct capacity
+	var/amount = 1
+	///The maximum we can produce for every process
+	buffer = 5
+	///I track them here because I have no idea how I'd make tgui loop like that
+	var/static/list/possible_amounts = list(0,1,2,3,4,5)
+	///The reagent we are producing. We are a typepath, but are also typecast because there's several occations where we need to use initial.
+	var/datum/reagent/reagent_id = null
+	///straight up copied from chem dispenser. Being a subtype would be extremely tedious and making it global would restrict potential subtypes using different dispensable_reagents
+	var/list/dispensable_reagents = list(
+		/datum/reagent/aluminium,
+		/datum/reagent/bromine,
+		/datum/reagent/carbon,
+		/datum/reagent/chlorine,
+		/datum/reagent/copper,
+		/datum/reagent/consumable/ethanol,
+		/datum/reagent/fluorine,
+		/datum/reagent/hydrogen,
+		/datum/reagent/iodine,
+		/datum/reagent/iron,
+		/datum/reagent/lithium,
+		/datum/reagent/mercury,
+		/datum/reagent/nitrogen,
+		/datum/reagent/oxygen,
+		/datum/reagent/phosphorus,
+		/datum/reagent/potassium,
+		/datum/reagent/uranium/radium,
+		/datum/reagent/silicon,
+		/datum/reagent/silver,
+		/datum/reagent/sodium,
+		/datum/reagent/stable_plasma,
+		/datum/reagent/consumable/sugar,
+		/datum/reagent/sulfur,
+		/datum/reagent/toxin/acid,
+		/datum/reagent/water,
+		/datum/reagent/fuel,
+	)
+
+/obj/machinery/plumbing/synthesizer/Initialize(mapload, bolt)
+	. = ..()
+	AddComponent(/datum/component/plumbing/simple_supply, bolt)
+
+/obj/machinery/plumbing/synthesizer/process()
+	if(machine_stat & NOPOWER || !reagent_id || !amount)
+		return
+	if(reagents.total_volume >= amount) //otherwise we get leftovers, and we need this to be precise
+		return
+	reagents.add_reagent(reagent_id, amount)
+
+/obj/machinery/plumbing/synthesizer/ui_interact(mob/user, datum/tgui/ui)
+	ui = SStgui.try_update_ui(user, src, ui)
+	if(!ui)
+		ui = new(user, src, "ChemSynthesizer", name)
+		ui.open()
+
+/obj/machinery/plumbing/synthesizer/ui_data(mob/user)
+	var/list/data = list()
+
+	var/is_hallucinating = user.hallucinating()
+	var/list/chemicals = list()
+
+	for(var/A in dispensable_reagents)
+		var/datum/reagent/R = GLOB.chemical_reagents_list[A]
+		if(R)
+			var/chemname = R.name
+			if(is_hallucinating && prob(5))
+				chemname = "[pick_list_replacements("hallucination.json", "chemicals")]"
+			chemicals.Add(list(list("title" = chemname, "id" = ckey(R.name))))
+	data["chemicals"] = chemicals
+	data["amount"] = amount
+	data["possible_amounts"] = possible_amounts
+
+	data["current_reagent"] = ckey(initial(reagent_id.name))
+	return data
+
+/obj/machinery/plumbing/synthesizer/ui_act(action, params)
+	if(..())
+		return
+	. = TRUE
+	switch(action)
+		if("amount")
+			var/new_amount = text2num(params["target"])
+			if(new_amount in possible_amounts)
+				amount = new_amount
+				. = TRUE
+		if("select")
+			var/new_reagent = GLOB.name2reagent[params["reagent"]]
+			if(new_reagent in dispensable_reagents)
+				reagent_id = new_reagent
+				. = TRUE
+	update_icon()
+	reagents.clear_reagents()
+
+/obj/machinery/plumbing/synthesizer/update_overlays()
+	. = ..()
+	var/mutable_appearance/r_overlay = mutable_appearance(icon, "[icon_state]_overlay")
+	if(reagent_id)
+		r_overlay.color = initial(reagent_id.color)
+	else
+		r_overlay.color = "#FFFFFF"
+	. += r_overlay