ports BSQL to go along with tools

There, now you can shut up about it not being ported you meme

code/modules/bsql/core/connection.dm

@@ -0,0 +1,68 @@
+/datum/BSQL_Connection
+	var/id
+	var/connection_type
+
+BSQL_PROTECT_DATUM(/datum/BSQL_Connection)
+
+/datum/BSQL_Connection/New(connection_type, asyncTimeout, blockingTimeout, threadLimit)
+	if(asyncTimeout == null)
+		asyncTimeout = BSQL_DEFAULT_TIMEOUT
+	if(blockingTimeout == null)
+		blockingTimeout = asyncTimeout
+	if(threadLimit == null)
+		threadLimit = BSQL_DEFAULT_THREAD_LIMIT
+
+	src.connection_type = connection_type
+
+	world._BSQL_InitCheck(src)
+
+	var/error = world._BSQL_Internal_Call("CreateConnection", connection_type, "[asyncTimeout]", "[blockingTimeout]", "[threadLimit]")
+	if(error)
+		BSQL_ERROR(error)
+		return
+
+	id = world._BSQL_Internal_Call("GetConnection")
+	if(!id)
+		BSQL_ERROR("BSQL library failed to provide connect operation for connection id [id]([connection_type])!")
+
+BSQL_DEL_PROC(/datum/BSQL_Connection)
+	var/error
+	if(id)
+		error = world._BSQL_Internal_Call("ReleaseConnection", id)
+	. = ..()
+	if(error)
+		BSQL_ERROR(error)
+
+/datum/BSQL_Connection/BeginConnect(ipaddress, port, username, password, database)
+	var/error = world._BSQL_Internal_Call("OpenConnection", id, ipaddress, "[port]", username, password, database)
+	if(error)
+		BSQL_ERROR(error)
+		return
+
+	var/op_id = world._BSQL_Internal_Call("GetOperation")
+	if(!op_id)
+		BSQL_ERROR("Library failed to provide connect operation for connection id [id]([connection_type])!")
+		return
+
+	return new /datum/BSQL_Operation(src, op_id)
+
+
+/datum/BSQL_Connection/BeginQuery(query)
+	var/error = world._BSQL_Internal_Call("NewQuery", id, query)
+	if(error)
+		BSQL_ERROR(error)
+		return
+
+	var/op_id = world._BSQL_Internal_Call("GetOperation")
+	if(!op_id)
+		BSQL_ERROR("Library failed to provide query operation for connection id [id]([connection_type])!")
+		return
+
+	return new /datum/BSQL_Operation/Query(src, op_id)
+	
+/datum/BSQL_Connection/Quote(str)
+	if(!str)
+		return null;
+	. = world._BSQL_Internal_Call("QuoteString", id, "[str]")
+	if(!.)
+		BSQL_ERROR("Library failed to provide quote for [str]!")

code/modules/bsql/core/library.dm

@@ -0,0 +1,43 @@
+/world/proc/_BSQL_Internal_Call(func, ...)
+	var/list/call_args = args.Copy(2)
+	BSQL_Debug("[.....]: [args[1]]([call_args.Join(", ")])")
+	. = call(_BSQL_Library_Path(), func)(arglist(call_args))
+	BSQL_Debug("Result: [. == null ? "NULL" : "\"[.]\""]")
+
+/world/proc/_BSQL_Library_Path()
+	return system_type == MS_WINDOWS ? "BSQL.dll" : "libBSQL.so"
+
+/world/proc/_BSQL_InitCheck(datum/BSQL_Connection/caller)
+	var/static/library_initialized = FALSE
+	if(_BSQL_Initialized())
+		return
+	var/libPath = _BSQL_Library_Path()
+	if(!fexists(libPath))
+		BSQL_DEL_CALL(caller)
+		BSQL_ERROR("Could not find [libPath]!")
+		return
+
+	var/version = _BSQL_Internal_Call("Version")
+	if(version != BSQL_VERSION)
+		BSQL_DEL_CALL(caller)
+		BSQL_ERROR("BSQL DMAPI version mismatch! Expected [BSQL_VERSION], got [version == null ? "NULL" : version]!")
+		return
+
+	var/result = _BSQL_Internal_Call("Initialize")
+	if(result)
+		BSQL_DEL_CALL(caller)
+		BSQL_ERROR(result)
+		return
+	_BSQL_Initialized(TRUE)
+
+/world/proc/_BSQL_Initialized(new_val)
+	var/static/bsql_library_initialized = FALSE
+	if(new_val != null)
+		bsql_library_initialized = new_val
+	return bsql_library_initialized
+
+/world/BSQL_Shutdown()
+	if(!_BSQL_Initialized())
+		return
+	_BSQL_Internal_Call("Shutdown")
+	_BSQL_Initialized(FALSE)

code/modules/bsql/core/operation.dm

@@ -0,0 +1,47 @@
+/datum/BSQL_Operation
+	var/datum/BSQL_Connection/connection
+	var/id
+
+BSQL_PROTECT_DATUM(/datum/BSQL_Operation)
+
+/datum/BSQL_Operation/New(datum/BSQL_Connection/connection, id)
+	src.connection = connection
+	src.id = id
+
+BSQL_DEL_PROC(/datum/BSQL_Operation)
+	var/error
+	if(!BSQL_IS_DELETED(connection))
+		error = world._BSQL_Internal_Call("ReleaseOperation", connection.id, id)
+	. = ..()
+	if(error)
+		BSQL_ERROR(error)
+
+/datum/BSQL_Operation/IsComplete()
+	if(BSQL_IS_DELETED(connection))
+		return TRUE
+	var/result = world._BSQL_Internal_Call("OpComplete", connection.id, id)
+	if(!result)
+		BSQL_ERROR("Error fetching operation [id] for connection [connection.id]!")
+		return
+	return result == "DONE"
+
+/datum/BSQL_Operation/GetError()
+	if(BSQL_IS_DELETED(connection))
+		return "Connection deleted!"
+	return world._BSQL_Internal_Call("GetError", connection.id, id)
+
+/datum/BSQL_Operation/GetErrorCode()
+	if(BSQL_IS_DELETED(connection))
+		return -2
+	return text2num(world._BSQL_Internal_Call("GetErrorCode", connection.id, id))
+
+/datum/BSQL_Operation/WaitForCompletion()
+	if(BSQL_IS_DELETED(connection))
+		return
+	var/error = world._BSQL_Internal_Call("BlockOnOperation", connection.id, id)
+	if(error)
+		if(error == "Operation timed out!")	//match this with the implementation
+			return FALSE
+		BSQL_ERROR("Error waiting for operation [id] for connection [connection.id]! [error]")
+		return
+	return TRUE

code/modules/bsql/core/query.dm

@@ -0,0 +1,35 @@
+/datum/BSQL_Operation/Query
+	var/last_result_json
+	var/list/last_result
+
+BSQL_PROTECT_DATUM(/datum/BSQL_Operation/Query)
+
+/datum/BSQL_Operation/Query/CurrentRow()
+	return last_result
+
+/datum/BSQL_Operation/Query/IsComplete()
+	//whole different ballgame here
+	if(BSQL_IS_DELETED(connection))
+		return TRUE
+	var/result = world._BSQL_Internal_Call("ReadyRow", connection.id, id)
+	switch(result)
+		if("DONE")
+			//load the data
+			LoadQueryResult()
+			return TRUE
+		if("NOTDONE")
+			return FALSE
+		else
+			BSQL_ERROR(result)
+			
+/datum/BSQL_Operation/Query/WaitForCompletion()
+	. = ..()
+	if(.)
+		LoadQueryResult()
+
+/datum/BSQL_Operation/Query/proc/LoadQueryResult()
+	last_result_json = world._BSQL_Internal_Call("GetRow", connection.id, id)
+	if(last_result_json)
+		last_result = json_decode(last_result_json)
+	else
+		last_result = null