initial commit - cross reference with 5th port - obviously has compile errors

code/datums/diseases/advance/advance.dm

@@ -0,0 +1,456 @@
+/*
+
+	Advance Disease is a system for Virologist to Engineer their own disease with symptoms that have effects and properties
+	which add onto the overall disease.
+
+	If you need help with creating new symptoms or expanding the advance disease, ask for Giacom on #coderbus.
+
+*/
+
+var/list/archive_diseases = list()
+
+// The order goes from easy to cure to hard to cure.
+var/list/advance_cures = 	list(
+									"sodiumchloride", "sugar", "orangejuice",
+									"spaceacillin", "salglu_solution", "ethanol",
+									"leporazine", "synaptizine", "lipolicide",
+									"silver", "gold"
+								)
+
+/*
+
+	PROPERTIES
+
+ */
+
+/datum/disease/advance
+
+	name = "Unknown" // We will always let our Virologist name our disease.
+	desc = "An engineered disease which can contain a multitude of symptoms."
+	form = "Advance Disease" // Will let med-scanners know that this disease was engineered.
+	agent = "advance microbes"
+	max_stages = 5
+	spread_text = "Unknown"
+	viable_mobtypes = list(/mob/living/carbon/human, /mob/living/carbon/monkey)
+
+	// NEW VARS
+
+	var/list/symptoms = list() // The symptoms of the disease.
+	var/id = ""
+	var/processing = 0
+
+/*
+
+	OLD PROCS
+
+ */
+
+/datum/disease/advance/New(var/process = 1, var/datum/disease/advance/D)
+
+	// Setup our dictionary if it hasn't already.
+	if(!dictionary_symptoms.len)
+		for(var/symp in list_symptoms)
+			var/datum/symptom/S = new symp
+			dictionary_symptoms[S.id] = symp
+
+	if(!istype(D))
+		D = null
+	// Generate symptoms if we weren't given any.
+
+	if(!symptoms || !symptoms.len)
+
+		if(!D || !D.symptoms || !D.symptoms.len)
+			symptoms = GenerateSymptoms(0, 2)
+		else
+			for(var/datum/symptom/S in D.symptoms)
+				symptoms += new S.type
+
+	Refresh()
+	..(process, D)
+	return
+
+/datum/disease/advance/Destroy()
+	if(processing)
+		for(var/datum/symptom/S in symptoms)
+			S.End(src)
+	return ..()
+
+// Randomly pick a symptom to activate.
+/datum/disease/advance/stage_act()
+	..()
+	if(symptoms && symptoms.len)
+
+		if(!processing)
+			processing = 1
+			for(var/datum/symptom/S in symptoms)
+				S.Start(src)
+
+		for(var/datum/symptom/S in symptoms)
+			S.Activate(src)
+	else
+		CRASH("We do not have any symptoms during stage_act()!")
+
+// Compares type then ID.
+/datum/disease/advance/IsSame(datum/disease/advance/D)
+
+	if(!(istype(D, /datum/disease/advance)))
+		return 0
+
+	if(src.GetDiseaseID() != D.GetDiseaseID())
+		return 0
+	return 1
+
+// To add special resistances.
+/datum/disease/advance/cure(resistance=1)
+	if(affected_mob)
+		var/id = "[GetDiseaseID()]"
+		if(resistance && !(id in affected_mob.resistances))
+			affected_mob.resistances[id] = id
+		remove_virus()
+	qdel(src)	//delete the datum to stop it processing
+
+// Returns the advance disease with a different reference memory.
+/datum/disease/advance/Copy(process = 0)
+	return new /datum/disease/advance(process, src, 1)
+
+/*
+
+	NEW PROCS
+
+ */
+
+// Mix the symptoms of two diseases (the src and the argument)
+/datum/disease/advance/proc/Mix(datum/disease/advance/D)
+	if(!(src.IsSame(D)))
+		var/list/possible_symptoms = shuffle(D.symptoms)
+		for(var/datum/symptom/S in possible_symptoms)
+			AddSymptom(new S.type)
+
+/datum/disease/advance/proc/HasSymptom(datum/symptom/S)
+	for(var/datum/symptom/symp in symptoms)
+		if(symp.id == S.id)
+			return 1
+	return 0
+
+// Will generate new unique symptoms, use this if there are none. Returns a list of symptoms that were generated.
+/datum/disease/advance/proc/GenerateSymptoms(level_min, level_max, amount_get = 0)
+
+	var/list/generated = list() // Symptoms we generated.
+
+	// Generate symptoms. By default, we only choose non-deadly symptoms.
+	var/list/possible_symptoms = list()
+	for(var/symp in list_symptoms)
+		var/datum/symptom/S = new symp
+		if(S.level >= level_min && S.level <= level_max)
+			if(!HasSymptom(S))
+				possible_symptoms += S
+
+	if(!possible_symptoms.len)
+		return generated
+
+	// Random chance to get more than one symptom
+	var/number_of = amount_get
+	if(!amount_get)
+		number_of = 1
+		while(prob(20))
+			number_of += 1
+
+	for(var/i = 1; number_of >= i && possible_symptoms.len; i++)
+		generated += pick_n_take(possible_symptoms)
+
+	return generated
+
+/datum/disease/advance/proc/Refresh(new_name = 0)
+	//world << "[src.name] \ref[src] - REFRESH!"
+	var/list/properties = GenerateProperties()
+	AssignProperties(properties)
+	id = null
+
+	if(!archive_diseases[GetDiseaseID()])
+		if(new_name)
+			AssignName()
+		archive_diseases[GetDiseaseID()] = src // So we don't infinite loop
+		archive_diseases[GetDiseaseID()] = new /datum/disease/advance(0, src, 1)
+
+	var/datum/disease/advance/A = archive_diseases[GetDiseaseID()]
+	AssignName(A.name)
+
+//Generate disease properties based on the effects. Returns an associated list.
+/datum/disease/advance/proc/GenerateProperties()
+
+	if(!symptoms || !symptoms.len)
+		CRASH("We did not have any symptoms before generating properties.")
+		return
+
+	var/list/properties = list("resistance" = 1, "stealth" = 1, "stage_rate" = 1, "transmittable" = 1, "severity" = 0)
+
+	for(var/datum/symptom/S in symptoms)
+
+		properties["resistance"] += S.resistance
+		properties["stealth"] += S.stealth
+		properties["stage_rate"] += S.stage_speed
+		properties["transmittable"] += S.transmittable
+		properties["severity"] = max(properties["severity"], S.severity) // severity is based on the highest severity symptom
+
+	return properties
+
+// Assign the properties that are in the list.
+/datum/disease/advance/proc/AssignProperties(list/properties = list())
+
+	if(properties && properties.len)
+		switch(properties["stealth"])
+			if(2)
+				visibility_flags = HIDDEN_SCANNER
+			if(3 to INFINITY)
+				visibility_flags = HIDDEN_SCANNER|HIDDEN_PANDEMIC
+
+		// The more symptoms we have, the less transmittable it is but some symptoms can make up for it.
+		SetSpread(Clamp(2 ** (properties["transmittable"] - symptoms.len), BLOOD, AIRBORNE))
+		permeability_mod = max(Ceiling(0.4 * properties["transmittable"]), 1)
+		cure_chance = 15 - Clamp(properties["resistance"], -5, 5) // can be between 10 and 20
+		stage_prob = max(properties["stage_rate"], 2)
+		SetSeverity(properties["severity"])
+		GenerateCure(properties)
+	else
+		CRASH("Our properties were empty or null!")
+
+
+// Assign the spread type and give it the correct description.
+/datum/disease/advance/proc/SetSpread(spread_id)
+	switch(spread_id)
+		if(NON_CONTAGIOUS)
+			spread_text = "None"
+		if(SPECIAL)
+			spread_text = "None"
+		if(CONTACT_GENERAL, CONTACT_HANDS, CONTACT_FEET)
+			spread_text = "On contact"
+		if(AIRBORNE)
+			spread_text = "Airborne"
+		if(BLOOD)
+			spread_text = "Blood"
+
+	spread_flags = spread_id
+
+/datum/disease/advance/proc/SetSeverity(level_sev)
+
+	switch(level_sev)
+
+		if(-INFINITY to 0)
+			severity = NONTHREAT
+		if(1)
+			severity = MINOR
+		if(2)
+			severity = MEDIUM
+		if(3)
+			severity = HARMFUL
+		if(4)
+			severity = DANGEROUS
+		if(5 to INFINITY)
+			severity = BIOHAZARD
+		else
+			severity = "Unknown"
+
+
+// Will generate a random cure, the less resistance the symptoms have, the harder the cure.
+/datum/disease/advance/proc/GenerateCure(list/properties = list())
+	if(properties && properties.len)
+		var/res = Clamp(properties["resistance"] - (symptoms.len / 2), 1, advance_cures.len)
+		//world << "Res = [res]"
+		cures = list(advance_cures[res])
+
+		// Get the cure name from the cure_id
+		var/datum/reagent/D = chemical_reagents_list[cures[1]]
+		cure_text = D.name
+
+
+	return
+
+// Randomly generate a symptom, has a chance to lose or gain a symptom.
+/datum/disease/advance/proc/Evolve(min_level, max_level)
+	var/s = safepick(GenerateSymptoms(min_level, max_level, 1))
+	if(s)
+		AddSymptom(s)
+		Refresh(1)
+	return
+
+// Randomly remove a symptom.
+/datum/disease/advance/proc/Devolve()
+	if(symptoms.len > 1)
+		var/s = safepick(symptoms)
+		if(s)
+			RemoveSymptom(s)
+			Refresh(1)
+	return
+
+// Name the disease.
+/datum/disease/advance/proc/AssignName(name = "Unknown")
+	src.name = name
+	return
+
+// Return a unique ID of the disease.
+/datum/disease/advance/GetDiseaseID()
+	if(!id)
+		var/list/L = list()
+		for(var/datum/symptom/S in symptoms)
+			L += S.id
+		L = sortList(L) // Sort the list so it doesn't matter which order the symptoms are in.
+		var/result = jointext(L, ":")
+		id = result
+	return id
+
+
+// Add a symptom, if it is over the limit (with a small chance to be able to go over)
+// we take a random symptom away and add the new one.
+/datum/disease/advance/proc/AddSymptom(datum/symptom/S)
+
+	if(HasSymptom(S))
+		return
+
+	if(symptoms.len < 5 + rand(-1, 1))
+		symptoms += S
+	else
+		RemoveSymptom(pick(symptoms))
+		symptoms += S
+	return
+
+// Simply removes the symptom.
+/datum/disease/advance/proc/RemoveSymptom(datum/symptom/S)
+	symptoms -= S
+	return
+
+/*
+
+	Static Procs
+
+*/
+
+// Mix a list of advance diseases and return the mixed result.
+/proc/Advance_Mix(var/list/D_list)
+
+	//world << "Mixing!!!!"
+
+	var/list/diseases = list()
+
+	for(var/datum/disease/advance/A in D_list)
+		diseases += A.Copy()
+
+	if(!diseases.len)
+		return null
+	if(diseases.len <= 1)
+		return pick(diseases) // Just return the only entry.
+
+	var/i = 0
+	// Mix our diseases until we are left with only one result.
+	while(i < 20 && diseases.len > 1)
+
+		i++
+
+		var/datum/disease/advance/D1 = pick(diseases)
+		diseases -= D1
+
+		var/datum/disease/advance/D2 = pick(diseases)
+		D2.Mix(D1)
+
+	 // Should be only 1 entry left, but if not let's only return a single entry
+	//world << "END MIXING!!!!!"
+	var/datum/disease/advance/to_return = pick(diseases)
+	to_return.Refresh(1)
+	return to_return
+
+/proc/SetViruses(datum/reagent/R, list/data)
+	if(data)
+		var/list/preserve = list()
+		if(istype(data) && data["viruses"])
+			for(var/datum/disease/A in data["viruses"])
+				preserve += A.Copy()
+			R.data = data.Copy()
+		if(preserve.len)
+			R.data["viruses"] = preserve
+
+/proc/AdminCreateVirus(client/user)
+
+	if(!user)
+		return
+
+	var/i = 5
+
+	var/datum/disease/advance/D = new(0, null)
+	D.symptoms = list()
+
+	var/list/symptoms = list()
+	symptoms += "Done"
+	symptoms += list_symptoms.Copy()
+	do
+		if(user)
+			var/symptom = input(user, "Choose a symptom to add ([i] remaining)", "Choose a Symptom") in symptoms
+			if(isnull(symptom))
+				return
+			else if(istext(symptom))
+				i = 0
+			else if(ispath(symptom))
+				var/datum/symptom/S = new symptom
+				if(!D.HasSymptom(S))
+					D.symptoms += S
+					i -= 1
+	while(i > 0)
+
+	if(D.symptoms.len > 0)
+
+		var/new_name = stripped_input(user, "Name your new disease.", "New Name")
+		if(!new_name)
+			return
+		D.AssignName(new_name)
+		D.Refresh()
+
+		for(var/datum/disease/advance/AD in SSdisease.processing)
+			AD.Refresh()
+
+		for(var/mob/living/carbon/human/H in shuffle(living_mob_list))
+			if(H.z != 1)
+				continue
+			if(!H.HasDisease(D))
+				H.ForceContractDisease(D)
+				break
+
+		var/list/name_symptoms = list()
+		for(var/datum/symptom/S in D.symptoms)
+			name_symptoms += S.name
+		message_admins("[key_name_admin(user)] has triggered a custom virus outbreak of [D.name]! It has these symptoms: [english_list(name_symptoms)]")
+
+/*
+/mob/verb/test()
+
+	for(var/datum/disease/D in SSdisease.processing)
+		src << "<a href='?_src_=vars;Vars=\ref[D]'>[D.name] - [D.holder]</a>"
+*/
+
+
+/datum/disease/advance/proc/totalStageSpeed()
+	var/total_stage_speed = 0
+	for(var/i in symptoms)
+		var/datum/symptom/S = i
+		total_stage_speed += S.stage_speed
+	return total_stage_speed
+
+/datum/disease/advance/proc/totalStealth()
+	var/total_stealth = 0
+	for(var/i in symptoms)
+		var/datum/symptom/S = i
+		total_stealth += S.stealth
+	return total_stealth
+
+/datum/disease/advance/proc/totalResistance()
+	var/total_resistance = 0
+	for(var/i in symptoms)
+		var/datum/symptom/S = i
+		total_resistance += S.resistance
+	return total_resistance
+
+/datum/disease/advance/proc/totalTransmittable()
+	var/total_transmittable = 0
+	for(var/i in symptoms)
+		var/datum/symptom/S = i
+		total_transmittable += S.transmittable
+	return total_transmittable
+
+#undef RANDOM_STARTING_LEVEL

code/datums/diseases/advance/presets.dm

@@ -0,0 +1,59 @@
+// Cold
+
+/datum/disease/advance/cold/New(var/process = 1, var/datum/disease/advance/D, var/copy = 0)
+	if(!D)
+		name = "Cold"
+		symptoms = list(new/datum/symptom/sneeze)
+	..(process, D, copy)
+
+
+// Flu
+
+/datum/disease/advance/flu/New(var/process = 1, var/datum/disease/advance/D, var/copy = 0)
+	if(!D)
+		name = "Flu"
+		symptoms = list(new/datum/symptom/cough)
+	..(process, D, copy)
+
+
+// Voice Changing
+
+/datum/disease/advance/voice_change/New(var/process = 1, var/datum/disease/advance/D, var/copy = 0)
+	if(!D)
+		name = "Epiglottis Mutation"
+		symptoms = list(new/datum/symptom/voice_change)
+	..(process, D, copy)
+
+
+// Toxin Filter
+
+/datum/disease/advance/heal/New(var/process = 1, var/datum/disease/advance/D, var/copy = 0)
+	if(!D)
+		name = "Liver Enhancer"
+		symptoms = list(new/datum/symptom/heal)
+	..(process, D, copy)
+
+
+// Hullucigen
+
+/datum/disease/advance/hullucigen/New(var/process = 1, var/datum/disease/advance/D, var/copy = 0)
+	if(!D)
+		name = "Reality Impairment"
+		symptoms = list(new/datum/symptom/hallucigen)
+	..(process, D, copy)
+
+// Sensory Restoration
+
+/datum/disease/advance/sensory_restoration/New(var/process = 1, var/datum/disease/advance/D, var/copy = 0)
+	if(!D)
+		name = "Reality Enhancer"
+		symptoms = list(new/datum/symptom/sensory_restoration)
+	..(process, D, copy)
+
+// Sensory Destruction
+
+/datum/disease/advance/sensory_destruction/New(var/process = 1, var/datum/disease/advance/D, var/copy = 0)
+	if(!D)
+		name = "Reality Destruction"
+		symptoms = list(new/datum/symptom/sensory_destruction)
+	..(process, D, copy)

code/datums/diseases/advance/symptoms/beard.dm

@@ -0,0 +1,49 @@
+/*
+//////////////////////////////////////
+Facial Hypertrichosis
+
+	Very very Noticable.
+	Decreases resistance slightly.
+	Decreases stage speed.
+	Reduced transmittability
+	Intense Level.
+
+BONUS
+	Makes the mob grow a massive beard, regardless of gender.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/beard
+
+	name = "Facial Hypertrichosis"
+	stealth = -3
+	resistance = -1
+	stage_speed = -3
+	transmittable = -1
+	level = 4
+	severity = 1
+
+/datum/symptom/beard/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/M = A.affected_mob
+		if(istype(M, /mob/living/carbon/human))
+			var/mob/living/carbon/human/H = M
+			switch(A.stage)
+				if(1, 2)
+					H << "<span class='warning'>Your chin itches.</span>"
+					if(H.facial_hair_style == "Shaved")
+						H.facial_hair_style = "Jensen Beard"
+						H.update_hair()
+				if(3, 4)
+					H << "<span class='warning'>You feel tough.</span>"
+					if(!(H.facial_hair_style == "Dwarf Beard") && !(H.facial_hair_style == "Very Long Beard") && !(H.facial_hair_style == "Full Beard"))
+						H.facial_hair_style = "Full Beard"
+						H.update_hair()
+				else
+					H << "<span class='warning'>You feel manly!</span>"
+					if(!(H.facial_hair_style == "Dwarf Beard") && !(H.facial_hair_style == "Very Long Beard"))
+						H.facial_hair_style = pick("Dwarf Beard", "Very Long Beard")
+						H.update_hair()
+	return

code/datums/diseases/advance/symptoms/choking.dm

@@ -0,0 +1,53 @@
+/*
+//////////////////////////////////////
+
+Choking
+
+	Very very noticable.
+	Lowers resistance.
+	Decreases stage speed.
+	Decreases transmittablity tremendously.
+	Moderate Level.
+
+Bonus
+	Inflicts spikes of oxyloss
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/choking
+
+	name = "Choking"
+	stealth = -3
+	resistance = -2
+	stage_speed = -2
+	transmittable = -4
+	level = 3
+	severity = 3
+
+/datum/symptom/choking/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/M = A.affected_mob
+		switch(A.stage)
+			if(1, 2)
+				M << "<span class='warning'>[pick("You're having difficulty breathing.", "Your breathing becomes heavy.")]</span>"
+			if(3, 4)
+				M << "<span class='warning'><b>[pick("Your windpipe feels like a straw.", "Your breathing becomes tremendously difficult.")]</span>"
+				Choke_stage_3_4(M, A)
+				M.emote("gasp")
+			else
+				M << "<span class='userdanger'>[pick("You're choking!", "You can't breathe!")]</span>"
+				Choke(M, A)
+				M.emote("gasp")
+	return
+
+/datum/symptom/choking/proc/Choke_stage_3_4(mob/living/M, datum/disease/advance/A)
+	var/get_damage = sqrt(21+A.totalStageSpeed()*0.5)+sqrt(16+A.totalStealth())
+	M.adjustOxyLoss(get_damage)
+	return 1
+
+/datum/symptom/choking/proc/Choke(mob/living/M, datum/disease/advance/A)
+	var/get_damage = sqrt(21+A.totalStageSpeed()*0.5)+sqrt(16+A.totalStealth()*5)
+	M.adjustOxyLoss(get_damage)
+	return 1

code/datums/diseases/advance/symptoms/confusion.dm

@@ -0,0 +1,40 @@
+/*
+//////////////////////////////////////
+
+Confusion
+
+	Little bit hidden.
+	Lowers resistance.
+	Decreases stage speed.
+	Not very transmittable.
+	Intense Level.
+
+Bonus
+	Makes the affected mob be confused for short periods of time.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/confusion
+
+	name = "Confusion"
+	stealth = 1
+	resistance = -1
+	stage_speed = -3
+	transmittable = 0
+	level = 4
+	severity = 2
+
+
+/datum/symptom/confusion/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/carbon/M = A.affected_mob
+		switch(A.stage)
+			if(1, 2, 3, 4)
+				M << "<span class='warning'>[pick("Your head hurts.", "Your mind blanks for a moment.")]</span>"
+			else
+				M << "<span class='userdanger'>You can't think straight!</span>"
+				M.confused = min(100, M.confused + 8)
+
+	return

code/datums/diseases/advance/symptoms/cough.dm

@@ -0,0 +1,40 @@
+/*
+//////////////////////////////////////
+
+Coughing
+
+	Noticable.
+	Little Resistance.
+	Doesn't increase stage speed much.
+	Transmittable.
+	Low Level.
+
+BONUS
+	Will force the affected mob to drop small items!
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/cough
+
+	name = "Cough"
+	stealth = -1
+	resistance = 3
+	stage_speed = 1
+	transmittable = 2
+	level = 1
+	severity = 1
+
+/datum/symptom/cough/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/M = A.affected_mob
+		switch(A.stage)
+			if(1, 2, 3)
+				M << "<span notice='warning'>[pick("You swallow excess mucus.", "You lightly cough.")]</span>"
+			else
+				M.emote("cough")
+				var/obj/item/I = M.get_active_hand()
+				if(I && I.w_class == 1)
+					M.drop_item()
+	return

code/datums/diseases/advance/symptoms/damage_converter.dm

@@ -0,0 +1,64 @@
+/*
+//////////////////////////////////////
+
+Damage Converter
+
+	Little bit hidden.
+	Lowers resistance tremendously.
+	Decreases stage speed tremendously.
+	Reduced transmittablity
+	Intense Level.
+
+Bonus
+	Slowly converts brute/fire damage to toxin.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/damage_converter
+
+	name = "Toxic Compensation"
+	stealth = 1
+	resistance = -4
+	stage_speed = -4
+	transmittable = -2
+	level = 4
+
+/datum/symptom/damage_converter/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB * 10))
+		var/mob/living/M = A.affected_mob
+		switch(A.stage)
+			if(4, 5)
+				Convert(M)
+	return
+
+/datum/symptom/damage_converter/proc/Convert(mob/living/M)
+
+	var/get_damage = rand(1, 2)
+
+	if(istype(M, /mob/living/carbon/human))
+		var/mob/living/carbon/human/H = M
+
+		var/list/parts = H.get_damaged_bodyparts(1,1) //1,1 because it needs inputs.
+
+		if(!parts.len)
+			return
+
+		for(var/obj/item/bodypart/L in parts)
+			L.heal_damage(get_damage, get_damage, 0)
+		M.adjustToxLoss(get_damage*parts.len)
+
+	else
+		if(M.getFireLoss() > 0 || M.getBruteLoss() > 0)
+			M.adjustFireLoss(-get_damage)
+			M.adjustBruteLoss(-get_damage)
+			M.adjustToxLoss(get_damage)
+		else
+			return
+
+	return 1
+
+
+
+

code/datums/diseases/advance/symptoms/deafness.dm

@@ -0,0 +1,43 @@
+/*
+//////////////////////////////////////
+
+Deafness
+
+	Slightly noticable.
+	Lowers resistance.
+	Decreases stage speed slightly.
+	Decreases transmittablity.
+	Intense Level.
+
+Bonus
+	Causes intermittent loss of hearing.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/deafness
+
+	name = "Deafness"
+	stealth = -1
+	resistance = -2
+	stage_speed = -1
+	transmittable = -3
+	level = 4
+	severity = 3
+
+/datum/symptom/deafness/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/M = A.affected_mob
+		switch(A.stage)
+			if(3, 4)
+				M << "<span class='warning'>[pick("You hear a ringing in your ear.", "Your ears pop.")]</span>"
+			if(5)
+				if(!(M.ear_deaf))
+					M << "<span class='userdanger'>Your ears pop and begin ringing loudly!</span>"
+					M.setEarDamage(-1,INFINITY) //Shall be enough
+					spawn(200)
+						if(M)
+							M << "<span class='warning'>The ringing in your ears fades...</span>"
+							M.setEarDamage(-1,0)
+	return

code/datums/diseases/advance/symptoms/dizzy.dm

@@ -0,0 +1,38 @@
+/*
+//////////////////////////////////////
+
+Dizziness
+
+	Hidden.
+	Lowers resistance considerably.
+	Decreases stage speed.
+	Reduced transmittability
+	Intense Level.
+
+Bonus
+	Shakes the affected mob's screen for short periods.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/dizzy // Not the egg
+
+	name = "Dizziness"
+	stealth = 2
+	resistance = -2
+	stage_speed = -3
+	transmittable = -1
+	level = 4
+	severity = 2
+
+/datum/symptom/dizzy/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/M = A.affected_mob
+		switch(A.stage)
+			if(1, 2, 3, 4)
+				M << "<span class='warning'>[pick("You feel dizzy.", "Your head spins.")]</span>"
+			else
+				M << "<span class='userdanger'>A wave of dizziness washes over you!</span>"
+				M.Dizzy(5)
+	return

code/datums/diseases/advance/symptoms/fever.dm

@@ -0,0 +1,41 @@
+/*
+//////////////////////////////////////
+
+Fever
+
+	No change to hidden.
+	Increases resistance.
+	Increases stage speed.
+	Little transmittable.
+	Low level.
+
+Bonus
+	Heats up your body.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/fever
+
+	name = "Fever"
+	stealth = 0
+	resistance = 3
+	stage_speed = 3
+	transmittable = 2
+	level = 2
+	severity = 2
+
+/datum/symptom/fever/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/carbon/M = A.affected_mob
+		M << "<span class='warning'>[pick("You feel hot.", "You feel like you're burning.")]</span>"
+		if(M.bodytemperature < BODYTEMP_HEAT_DAMAGE_LIMIT)
+			Heat(M, A)
+
+	return
+
+/datum/symptom/fever/proc/Heat(mob/living/M, datum/disease/advance/A)
+	var/get_heat = (sqrt(21+A.totalTransmittable()*2))+(sqrt(20+A.totalStageSpeed()*3))
+	M.bodytemperature = min(M.bodytemperature + (get_heat * A.stage), BODYTEMP_HEAT_DAMAGE_LIMIT - 1)
+	return 1

code/datums/diseases/advance/symptoms/fire.dm

@@ -0,0 +1,57 @@
+/*
+//////////////////////////////////////
+
+Spontaneous Combustion
+
+	Slightly hidden.
+	Lowers resistance tremendously.
+	Decreases stage tremendously.
+	Decreases transmittablity tremendously.
+	Fatal Level.
+
+Bonus
+	Ignites infected mob.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/fire
+
+	name = "Spontaneous Combustion"
+	stealth = 1
+	resistance = -4
+	stage_speed = -4
+	transmittable = -4
+	level = 6
+	severity = 5
+
+/datum/symptom/fire/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/M = A.affected_mob
+		switch(A.stage)
+			if(3)
+				M << "<span class='warning'>[pick("You feel hot.", "You hear a crackling noise.", "You smell smoke.")]</span>"
+			if(4)
+				Firestacks_stage_4(M, A)
+				M.IgniteMob()
+				M << "<span class='userdanger'>Your skin bursts into flames!</span>"
+				M.emote("scream")
+			if(5)
+				Firestacks_stage_5(M, A)
+				M.IgniteMob()
+				M << "<span class='userdanger'>Your skin erupts into an inferno!</span>"
+				M.emote("scream")
+	return
+
+/datum/symptom/fire/proc/Firestacks_stage_4(mob/living/M, datum/disease/advance/A)
+	var/get_stacks = (sqrt(20+A.totalStageSpeed()*2))-(sqrt(16+A.totalStealth()))
+	M.adjust_fire_stacks(get_stacks)
+	M.adjustFireLoss(get_stacks/2)
+	return 1
+
+/datum/symptom/fire/proc/Firestacks_stage_5(mob/living/M, datum/disease/advance/A)
+	var/get_stacks = (sqrt(20+A.totalStageSpeed()*3))-(sqrt(16+A.totalStealth()))
+	M.adjust_fire_stacks(get_stacks)
+	M.adjustFireLoss(get_stacks)
+	return 1

code/datums/diseases/advance/symptoms/flesh_eating.dm

@@ -0,0 +1,43 @@
+/*
+//////////////////////////////////////
+
+Necrotizing Fasciitis (AKA Flesh-Eating Disease)
+
+	Very very noticable.
+	Lowers resistance tremendously.
+	No changes to stage speed.
+	Decreases transmittablity temrendously.
+	Fatal Level.
+
+Bonus
+	Deals brute damage over time.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/flesh_eating
+
+	name = "Necrotizing Fasciitis"
+	stealth = -3
+	resistance = -4
+	stage_speed = 0
+	transmittable = -4
+	level = 6
+	severity = 5
+
+/datum/symptom/flesh_eating/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/M = A.affected_mob
+		switch(A.stage)
+			if(2,3)
+				M << "<span class='warning'>[pick("You feel a sudden pain across your body.", "Drops of blood appear suddenly on your skin.")]</span>"
+			if(4,5)
+				M << "<span class='userdanger'>[pick("You cringe as a violent pain takes over your body.", "It feels like your body is eating itself inside out.", "IT HURTS.")]</span>"
+				Flesheat(M, A)
+	return
+
+/datum/symptom/flesh_eating/proc/Flesheat(mob/living/M, datum/disease/advance/A)
+	var/get_damage = ((sqrt(16-A.totalStealth()))*5)
+	M.adjustBruteLoss(get_damage)
+	return 1

code/datums/diseases/advance/symptoms/genetics.dm

@@ -0,0 +1,59 @@
+/*
+//////////////////////////////////////
+
+DNA Saboteur
+
+	Very noticable.
+	Lowers resistance tremendously.
+	No changes to stage speed.
+	Decreases transmittablity tremendously.
+	Fatal Level.
+
+Bonus
+	Cleans the DNA of a person and then randomly gives them a disability.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/genetic_mutation
+
+	name = "Deoxyribonucleic Acid Saboteur"
+	stealth = -2
+	resistance = -3
+	stage_speed = 0
+	transmittable = -3
+	level = 6
+	severity = 3
+	var/list/possible_mutations
+	var/archived_dna = null
+
+/datum/symptom/genetic_mutation/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB * 5)) // 15% chance
+		var/mob/living/carbon/M = A.affected_mob
+		if(!M.has_dna())
+			return
+		switch(A.stage)
+			if(4, 5)
+				M << "<span class='warning'>[pick("Your skin feels itchy.", "You feel light headed.")]</span>"
+				M.dna.remove_mutation_group(possible_mutations)
+				randmut(M, possible_mutations)
+	return
+
+// Archive their DNA before they were infected.
+/datum/symptom/genetic_mutation/Start(datum/disease/advance/A)
+	possible_mutations = (bad_mutations | not_good_mutations) - mutations_list[RACEMUT]
+	var/mob/living/carbon/M = A.affected_mob
+	if(M)
+		if(!M.has_dna())
+			return
+		archived_dna = M.dna.struc_enzymes
+
+// Give them back their old DNA when cured.
+/datum/symptom/genetic_mutation/End(datum/disease/advance/A)
+	var/mob/living/carbon/M = A.affected_mob
+	if(M && archived_dna)
+		if(!M.has_dna())
+			return
+		M.dna.struc_enzymes = archived_dna
+		M.domutcheck()

code/datums/diseases/advance/symptoms/hallucigen.dm

@@ -0,0 +1,41 @@
+/*
+//////////////////////////////////////
+
+Hallucigen
+
+	Very noticable.
+	Lowers resistance considerably.
+	Decreases stage speed.
+	Reduced transmittable.
+	Critical Level.
+
+Bonus
+	Makes the affected mob be hallucinated for short periods of time.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/hallucigen
+
+	name = "Hallucigen"
+	stealth = -2
+	resistance = -3
+	stage_speed = -3
+	transmittable = -1
+	level = 5
+	severity = 3
+
+/datum/symptom/hallucigen/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/carbon/M = A.affected_mob
+		switch(A.stage)
+			if(1, 2)
+				M << "<span class='warning'>[pick("Something appears in your peripheral vision, then winks out.", "You hear a faint whispher with no source.", "Your head aches.")]</span>"
+			if(3, 4)
+				M << "<span class='danger'>[pick("Something is following you.", "You are being watched.", "You hear a whisper in your ear.", "Thumping footsteps slam toward you from nowhere.")]</span>"
+			else
+				M << "<span class='userdanger'>[pick("Oh, your head...", "Your head pounds.", "They're everywhere! Run!", "Something in the shadows...")]</span>"
+				M.hallucination += 5
+
+	return

code/datums/diseases/advance/symptoms/headache.dm

@@ -0,0 +1,34 @@
+/*
+//////////////////////////////////////
+
+Headache
+
+	Noticable.
+	Highly resistant.
+	Increases stage speed.
+	Not transmittable.
+	Low Level.
+
+BONUS
+	Displays an annoying message!
+	Should be used for buffing your disease.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/headache
+
+	name = "Headache"
+	stealth = -1
+	resistance = 4
+	stage_speed = 2
+	transmittable = 0
+	level = 1
+	severity = 1
+
+/datum/symptom/headache/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/M = A.affected_mob
+		M << "<span class='warning'>[pick("Your head hurts.", "Your head starts pounding.")]</span>"
+	return

code/datums/diseases/advance/symptoms/heal.dm

@@ -0,0 +1,158 @@
+/*
+//////////////////////////////////////
+
+Healing
+
+	Little bit hidden.
+	Lowers resistance tremendously.
+	Decreases stage speed tremendously.
+	Decreases transmittablity temrendously.
+	Fatal Level.
+
+Bonus
+	Heals toxins in the affected mob's blood stream.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/heal
+
+	name = "Toxic Filter"
+	stealth = 1
+	resistance = -4
+	stage_speed = -4
+	transmittable = -4
+	level = 6
+
+/datum/symptom/heal/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB * 10))
+		var/mob/living/M = A.affected_mob
+		switch(A.stage)
+			if(4, 5)
+				Heal(M, A)
+	return
+
+/datum/symptom/heal/proc/Heal(mob/living/M, datum/disease/advance/A)
+	var/get_damage = (sqrt(20+A.totalStageSpeed())*(1+rand()))
+	M.adjustToxLoss(-get_damage)
+	return 1
+
+/*
+//////////////////////////////////////
+
+Metabolism
+
+	Little bit hidden.
+	Lowers resistance.
+	Decreases stage speed.
+	Decreases transmittablity temrendously.
+	High Level.
+
+Bonus
+	Cures all diseases (except itself) and creates anti-bodies for them until the symptom dies.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/heal/metabolism
+
+	name = "Anti-Bodies Metabolism"
+	stealth = -1
+	resistance = -1
+	stage_speed = -1
+	transmittable = -4
+	level = 3
+	var/list/cured_diseases = list()
+
+/datum/symptom/heal/metabolism/Heal(mob/living/M, datum/disease/advance/A)
+	var/cured = 0
+	for(var/datum/disease/D in M.viruses)
+		if(D != A)
+			cured = 1
+			cured_diseases += D.GetDiseaseID()
+			D.cure()
+	if(cured)
+		M << "<span class='notice'>You feel much better.</span>"
+
+/datum/symptom/heal/metabolism/End(datum/disease/advance/A)
+	// Remove all the diseases we cured.
+	var/mob/living/M = A.affected_mob
+	if(istype(M))
+		if(cured_diseases.len)
+			for(var/res in M.resistances)
+				if(res in cured_diseases)
+					M.resistances -= res
+		M << "<span class='warning'>You feel weaker.</span>"
+
+/*
+//////////////////////////////////////
+
+Longevity
+
+	Medium hidden boost.
+	Large resistance boost.
+	Large stage speed boost.
+	Large transmittablity boost.
+	High Level.
+
+Bonus
+	After a certain amount of time the symptom will cure itself.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/heal/longevity
+
+	name = "Longevity"
+	stealth = 3
+	resistance = 4
+	stage_speed = 4
+	transmittable = 4
+	level = 3
+	var/longevity = 30
+
+/datum/symptom/heal/longevity/Heal(mob/living/M, datum/disease/advance/A)
+	longevity -= 1
+	if(!longevity)
+		A.cure()
+
+/datum/symptom/heal/longevity/Start(datum/disease/advance/A)
+	longevity = rand(initial(longevity) - 5, initial(longevity) + 5)
+
+/*
+//////////////////////////////////////
+
+	DNA Restoration
+
+	Not well hidden.
+	Lowers resistance minorly.
+	Does not affect stage speed.
+	Decreases transmittablity greatly.
+	Very high level.
+
+Bonus
+	Heals brain damage, treats radiation, cleans SE of non-power mutations.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/heal/dna
+
+	name = "Deoxyribonucleic Acid Restoration"
+	stealth = -1
+	resistance = -1
+	stage_speed = 0
+	transmittable = -3
+	level = 5
+
+/datum/symptom/heal/dna/Heal(mob/living/carbon/M, datum/disease/advance/A)
+	var/stage_speed = max( 20 + A.totalStageSpeed(), 0)
+	var/stealth_amount = max( 16 + A.totalStealth(), 0)
+	var/amt_healed = (sqrt(stage_speed*(3+rand())))-(sqrt(stealth_amount*rand()))
+	M.adjustBrainLoss(-amt_healed)
+	//Non-power mutations, excluding race, so the virus does not force monkey -> human transformations.
+	var/list/unclean_mutations = (not_good_mutations|bad_mutations) - mutations_list[RACEMUT]
+	M.dna.remove_mutation_group(unclean_mutations)
+	M.radiation = max(M.radiation - 3, 0)
+	return 1

code/datums/diseases/advance/symptoms/itching.dm

@@ -0,0 +1,34 @@
+/*
+//////////////////////////////////////
+
+Itching
+
+	Not noticable or unnoticable.
+	Resistant.
+	Increases stage speed.
+	Little transmittable.
+	Low Level.
+
+BONUS
+	Displays an annoying message!
+	Should be used for buffing your disease.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/itching
+
+	name = "Itching"
+	stealth = 0
+	resistance = 3
+	stage_speed = 3
+	transmittable = 1
+	level = 1
+	severity = 1
+
+/datum/symptom/itching/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/M = A.affected_mob
+		M << "<span class='warning'>Your [pick("back", "arm", "leg", "elbow", "head")] itches.</span>"
+	return

code/datums/diseases/advance/symptoms/oxygen.dm

@@ -0,0 +1,38 @@
+/*
+//////////////////////////////////////
+
+Self-Respiration
+
+	Slightly hidden.
+	Lowers resistance significantly.
+	Decreases stage speed significantly.
+	Decreases transmittablity tremendously.
+	Fatal Level.
+
+Bonus
+	The body generates salbutamol.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/oxygen
+
+	name = "Self-Respiration"
+	stealth = 1
+	resistance = -3
+	stage_speed = -3
+	transmittable = -4
+	level = 6
+
+/datum/symptom/oxygen/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB * 5))
+		var/mob/living/M = A.affected_mob
+		switch(A.stage)
+			if(4, 5)
+				if (M.reagents.get_reagent_amount("salbutamol") < 20)
+					M.reagents.add_reagent("salbutamol", 20)
+			else
+				if(prob(SYMPTOM_ACTIVATION_PROB * 5))
+					M << "<span class='notice'>[pick("Your lungs feel great.", "You realize you haven't been breathing.", "You don't feel the need to breathe.")]</span>"
+	return

code/datums/diseases/advance/symptoms/sensory.dm

@@ -0,0 +1,101 @@
+/*
+//////////////////////////////////////
+Sensory-Restoration
+	Very very very very noticable.
+	Lowers resistance tremendously.
+	Decreases stage speed tremendously.
+	Decreases transmittablity tremendously.
+	Fatal.
+Bonus
+	The body generates Sensory restorational chemicals.
+	inacusiate for ears
+	antihol for removal of alcohol
+	synaphydramine to purge sensory hallucigens and histamine based impairment
+	mannitol to kickstart the mind
+
+//////////////////////////////////////
+*/
+/datum/symptom/sensory_restoration
+	name = "Sensory Restoration"
+	stealth = -1
+	resistance = -4
+	stage_speed = -4
+	transmittable = -3
+	level = 5
+	severity = 0
+
+/datum/symptom/sensory_restoration/Activate(var/datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB * 3))
+		var/mob/living/M = A.affected_mob
+		switch(A.stage)
+			if(2)
+				if(M.reagents.get_reagent_amount("inacusiate")<10)
+					M.reagents.add_reagent("inacusiate", 10)
+					M << "<span class='notice'>Your hearing feels clearer and crisp.</span>"
+			if(3)
+				if(M.reagents.get_reagent_amount("antihol") < 10 && M.reagents.get_reagent_amount("inacusiate") < 10 )
+					M.reagents.add_reagent_list(list("antihol"=10, "inacusiate"=10))
+					M << "<span class='notice'>You feel sober.</span>"
+			if(4)
+				if(M.reagents.get_reagent_amount("antihol") < 10 && M.reagents.get_reagent_amount("inacusiate") < 10 && M.reagents.get_reagent_amount("synaphydramine") < 10)
+					M.reagents.add_reagent_list(list("antihol"=10, "inacusiate"=10, "synaphydramine"=5))
+					M << "<span class='notice'>You feel focused.</span>"
+			if(5)
+				if(M.reagents.get_reagent_amount("antihol") < 10 && M.reagents.get_reagent_amount("inacusiate") < 10 && M.reagents.get_reagent_amount("synaphydramine") < 10 && M.reagents.get_reagent_amount("mannitol") < 10)
+					M.reagents.add_reagent_list(list("mannitol"=10, "antihol"=10, "inacusiate"=10, "synaphydramine"=10))
+	return
+
+/*
+//////////////////////////////////////
+Sensory-Destruction
+	noticable.
+	Lowers resistance
+	Decreases stage speed tremendously.
+	Decreases transmittablity tremendously.
+	the drugs hit them so hard they have to focus on not dying
+
+Bonus
+	The body generates Sensory destructive chemicals.
+	You cannot taste anything anymore.
+	ethanol for extremely drunk victim
+	mindbreaker to break the mind
+	impedrezene to ruin the brain
+
+//////////////////////////////////////
+*/
+/datum/symptom/sensory_destruction
+	name = "Sensory destruction"
+	stealth = -1
+	resistance = -2
+	stage_speed = -3
+	transmittable = -4
+	level = 6
+	severity = 5
+
+/datum/symptom/sensory_destruction/Activate(var/datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/M = A.affected_mob
+		switch(A.stage)
+			if(1)
+				M << "<span class='warning'>You can't feel anything.</span>"
+			if(2)
+				M << "<span class='warning'>You feel absolutely hammered.</span>"
+				if(prob(10))
+					M.reagents.add_reagent("morphine",rand(5,7))
+			if(3)
+				M.reagents.add_reagent("ethanol",rand(5,7))
+				M << "<span class='warning'>You try to focus on not dying.</span>"
+				if(prob(15))
+					M.reagents.add_reagent("morphine",rand(5,7))
+			if(4)
+				M.reagents.add_reagent_list(list("ethanol" = rand(7,15), "mindbreaker" = rand(5,10)))
+				M << "<span class='warning'>u can count 2 potato!</span>"
+				if(prob(20))
+					M.reagents.add_reagent("morphine",rand(5,7))
+			if(5)
+				M.reagents.add_reagent_list(list("impedrezene" = rand(5,15), "ethanol" = rand(7,20), "mindbreaker" = rand(5,15)))
+				if(prob(25))
+					M.reagents.add_reagent("morphine",rand(5,7))
+	return

code/datums/diseases/advance/symptoms/shedding.dm

@@ -0,0 +1,48 @@
+/*
+//////////////////////////////////////
+Alopecia
+
+	Noticable.
+	Decreases resistance slightly.
+	Reduces stage speed slightly.
+	Transmittable.
+	Intense Level.
+
+BONUS
+	Makes the mob lose hair.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/shedding
+
+	name = "Alopecia"
+	stealth = -1
+	resistance = -1
+	stage_speed = -1
+	transmittable = 2
+	level = 4
+	severity = 1
+
+/datum/symptom/shedding/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/M = A.affected_mob
+		M << "<span class='warning'>[pick("Your scalp itches.", "Your skin feels flakey.")]</span>"
+		if(istype(M, /mob/living/carbon/human))
+			var/mob/living/carbon/human/H = M
+			switch(A.stage)
+				if(3, 4)
+					if(!(H.hair_style == "Bald") && !(H.hair_style == "Balding Hair"))
+						H << "<span class='warning'>Your hair starts to fall out in clumps...</span>"
+						spawn(50)
+							H.hair_style = "Balding Hair"
+							H.update_hair()
+				if(5)
+					if(!(H.facial_hair_style == "Shaved") || !(H.hair_style == "Bald"))
+						H << "<span class='warning'>Your hair starts to fall out in clumps...</span>"
+						spawn(50)
+							H.facial_hair_style = "Shaved"
+							H.hair_style = "Bald"
+							H.update_hair()
+	return

code/datums/diseases/advance/symptoms/shivering.dm

@@ -0,0 +1,40 @@
+/*
+//////////////////////////////////////
+
+Shivering
+
+	No change to hidden.
+	Increases resistance.
+	Increases stage speed.
+	Little transmittable.
+	Low level.
+
+Bonus
+	Cools down your body.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/shivering
+
+	name = "Shivering"
+	stealth = 0
+	resistance = 2
+	stage_speed = 2
+	transmittable = 2
+	level = 2
+	severity = 2
+
+/datum/symptom/shivering/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/carbon/M = A.affected_mob
+		M << "<span class='warning'>[pick("You feel cold.", "You start shivering.")]</span>"
+		if(M.bodytemperature < BODYTEMP_COLD_DAMAGE_LIMIT)
+			Chill(M, A)
+	return
+
+/datum/symptom/shivering/proc/Chill(mob/living/M, datum/disease/advance/A)
+	var/get_cold = (sqrt(16+A.totalStealth()*2))+(sqrt(21+A.totalResistance()*2))
+	M.bodytemperature = min(M.bodytemperature - (get_cold * A.stage), BODYTEMP_COLD_DAMAGE_LIMIT + 1)
+	return 1

code/datums/diseases/advance/symptoms/skin.dm

@@ -0,0 +1,86 @@
+/*
+//////////////////////////////////////
+Vitiligo
+
+	Extremely Noticable.
+	Decreases resistance slightly.
+	Reduces stage speed slightly.
+	Reduces transmission.
+	Critical Level.
+
+BONUS
+	Makes the mob lose skin pigmentation.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/vitiligo
+
+	name = "Vitiligo"
+	stealth = -3
+	resistance = -1
+	stage_speed = -1
+	transmittable = -2
+	level = 4
+	severity = 1
+
+/datum/symptom/vitiligo/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/M = A.affected_mob
+		if(istype(M, /mob/living/carbon/human))
+			var/mob/living/carbon/human/H = M
+			if(H.skin_tone == "albino")
+				return
+			switch(A.stage)
+				if(5)
+					H.skin_tone = "albino"
+					H.update_body(0)
+				else
+					H.visible_message("<span class='warning'>[H] looks a bit pale...</span>", "<span class='notice'>Your skin suddenly appears lighter...</span>")
+
+	return
+
+
+/*
+//////////////////////////////////////
+Revitiligo
+
+	Extremely Noticable.
+	Decreases resistance slightly.
+	Reduces stage speed slightly.
+	Reduces transmission.
+	Critical Level.
+
+BONUS
+	Makes the mob gain skin pigmentation.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/revitiligo
+
+	name = "Revitiligo"
+	stealth = -3
+	resistance = -1
+	stage_speed = -1
+	transmittable = -2
+	level = 4
+	severity = 1
+
+/datum/symptom/revitiligo/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/M = A.affected_mob
+		if(istype(M, /mob/living/carbon/human))
+			var/mob/living/carbon/human/H = M
+			if(H.skin_tone == "african2")
+				return
+			switch(A.stage)
+				if(5)
+					H.skin_tone = "african2"
+					H.update_body(0)
+				else
+					H.visible_message("<span class='warning'>[H] looks a bit dark...</span>", "<span class='notice'>Your skin suddenly appears darker...</span>")
+
+	return

code/datums/diseases/advance/symptoms/sneeze.dm

@@ -0,0 +1,39 @@
+/*
+//////////////////////////////////////
+
+Sneezing
+
+	Very Noticable.
+	Increases resistance.
+	Doesn't increase stage speed.
+	Very transmittable.
+	Low Level.
+
+Bonus
+	Forces a spread type of AIRBORNE
+	with extra range!
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/sneeze
+
+	name = "Sneezing"
+	stealth = -2
+	resistance = 3
+	stage_speed = 0
+	transmittable = 4
+	level = 1
+	severity = 1
+
+/datum/symptom/sneeze/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/M = A.affected_mob
+		switch(A.stage)
+			if(1, 2, 3)
+				M.emote("sniff")
+			else
+				M.emote("sneeze")
+				A.spread(A.holder, 5)
+	return

code/datums/diseases/advance/symptoms/stimulant.dm

@@ -0,0 +1,38 @@
+/*
+//////////////////////////////////////
+
+Stimulant //gotta go fast
+
+	Noticable.
+	Lowers resistance significantly.
+	Decreases stage speed moderately..
+	Decreases transmittablity tremendously.
+	Moderate Level.
+
+Bonus
+	The body generates Ephedrine.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/stimulant
+
+	name = "Stimulant"
+	stealth = -1
+	resistance = -3
+	stage_speed = -2
+	transmittable = -4
+	level = 3
+
+/datum/symptom/stimulant/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB * 10))
+		var/mob/living/M = A.affected_mob
+		switch(A.stage)
+			if(5)
+				if (M.reagents.get_reagent_amount("ephedrine") < 10)
+					M.reagents.add_reagent("ephedrine", 10)
+			else
+				if(prob(SYMPTOM_ACTIVATION_PROB * 5))
+					M << "<span class='notice'>[pick("You feel restless.", "You feel like running laps around the station.")]</span>"
+	return

code/datums/diseases/advance/symptoms/symptoms.dm

@@ -0,0 +1,40 @@
+// Symptoms are the effects that engineered advanced diseases do.
+
+var/list/list_symptoms = subtypesof(/datum/symptom)
+var/list/dictionary_symptoms = list()
+
+var/global/const/SYMPTOM_ACTIVATION_PROB = 3
+
+/datum/symptom
+	// Buffs/Debuffs the symptom has to the overall engineered disease.
+	var/name = ""
+	var/stealth = 0
+	var/resistance = 0
+	var/stage_speed = 0
+	var/transmittable = 0
+	// The type level of the symptom. Higher is harder to generate.
+	var/level = 0
+	// The severity level of the symptom. Higher is more dangerous.
+	var/severity = 0
+	// The hash tag for our diseases, we will add it up with our other symptoms to get a unique id! ID MUST BE UNIQUE!!!
+	var/id = ""
+
+/datum/symptom/New()
+	var/list/S = list_symptoms
+	for(var/i = 1; i <= S.len; i++)
+		if(src.type == S[i])
+			id = "[i]"
+			return
+	CRASH("We couldn't assign an ID!")
+
+// Called when processing of the advance disease, which holds this symptom, starts.
+/datum/symptom/proc/Start(datum/disease/advance/A)
+	return
+
+// Called when the advance disease is going to be deleted or when the advance disease stops processing.
+/datum/symptom/proc/End(datum/disease/advance/A)
+	return
+
+/datum/symptom/proc/Activate(datum/disease/advance/A)
+	return
+

code/datums/diseases/advance/symptoms/viral.dm

@@ -0,0 +1,65 @@
+/*
+//////////////////////////////////////
+Viral adaptation
+
+	Moderate stealth boost.
+	Major Increases to resistance.
+	Reduces stage speed.
+	No change to transmission
+	Critical Level.
+
+BONUS
+	Extremely useful for buffing viruses
+
+//////////////////////////////////////
+*/
+/datum/symptom/viraladaptation
+	name = "Viral self-adaptation"
+	stealth = 3
+	resistance = 5
+	stage_speed = -3
+	transmittable = 0
+	level = 3
+
+/datum/symptom/viraladaptation/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/M = A.affected_mob
+		switch(A.stage)
+			if(1)
+				M << "<span class='notice'>You feel off, but no different from before.</span>"
+			if(5)
+				M << "<span class='notice'>You feel better, but nothing interesting happens.</span>"
+
+/*
+//////////////////////////////////////
+Viral evolution
+
+	Moderate stealth reductopn.
+	Major decreases to resistance.
+	increases stage speed.
+	increase to transmission
+	Critical Level.
+
+BONUS
+	Extremely useful for buffing viruses
+
+//////////////////////////////////////
+*/
+/datum/symptom/viralevolution
+	name = "Viral evolutionary acceleration"
+	stealth = -2
+	resistance = -3
+	stage_speed = 5
+	transmittable = 3
+	level = 3
+
+/datum/symptom/viraladaptation/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/M = A.affected_mob
+		switch(A.stage)
+			if(1)
+				M << "<span class='notice'>You feel better, but no different from before.</span>"
+			if(5)
+				M << "<span class='notice'>You feel off, but nothing interesting happens.</span>"

code/datums/diseases/advance/symptoms/vision.dm

@@ -0,0 +1,87 @@
+/*
+//////////////////////////////////////
+
+Hyphema (Eye bleeding)
+
+	Slightly noticable.
+	Lowers resistance tremendously.
+	Decreases stage speed tremendously.
+	Decreases transmittablity.
+	Critical Level.
+
+Bonus
+	Causes blindness.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/visionloss
+
+	name = "Hyphema"
+	stealth = -1
+	resistance = -4
+	stage_speed = -4
+	transmittable = -3
+	level = 5
+	severity = 4
+
+/datum/symptom/visionloss/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/M = A.affected_mob
+		switch(A.stage)
+			if(1, 2)
+				M << "<span class='warning'>Your eyes itch.</span>"
+			if(3, 4)
+				M << "<span class='warning'><b>Your eyes burn!</b></span>"
+				M.blur_eyes(10)
+				M.adjust_eye_damage(1)
+			else
+				M << "<span class='userdanger'>Your eyes burn horrificly!</span>"
+				M.blur_eyes(20)
+				M.adjust_eye_damage(5)
+				if(M.eye_damage >= 10)
+					M.become_nearsighted()
+					if(prob(M.eye_damage - 10 + 1))
+						if(M.become_blind())
+							M << "<span class='userdanger'>You go blind!</span>"
+
+
+/*
+//////////////////////////////////////
+
+Ocular Restoration
+
+	Noticable.
+	Lowers resistance significantly.
+	Decreases stage speed moderately..
+	Decreases transmittablity tremendously.
+	High level.
+
+Bonus
+	Restores eyesight.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/visionaid
+
+	name = "Ocular Restoration"
+	stealth = -1
+	resistance = -3
+	stage_speed = -2
+	transmittable = -4
+	level = 4
+
+/datum/symptom/visionaid/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB * 5))
+		var/mob/living/M = A.affected_mob
+		switch(A.stage)
+			if(4, 5)
+				if (M.reagents.get_reagent_amount("oculine") < 20)
+					M.reagents.add_reagent("oculine", 20)
+			else
+				if(prob(SYMPTOM_ACTIVATION_PROB * 5))
+					M << "<span class='notice'>[pick("Your eyes feel great.", "You are now blinking manually.", "You don't feel the need to blink.")]</span>"
+	return

code/datums/diseases/advance/symptoms/voice_change.dm

@@ -0,0 +1,48 @@
+/*
+//////////////////////////////////////
+
+Voice Change
+
+	Very Very noticable.
+	Lowers resistance considerably.
+	Decreases stage speed.
+	Reduced transmittable.
+	Fatal Level.
+
+Bonus
+	Changes the voice of the affected mob. Causing confusion in communication.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/voice_change
+
+	name = "Voice Change"
+	stealth = -2
+	resistance = -3
+	stage_speed = -3
+	transmittable = -1
+	level = 6
+	severity = 2
+
+/datum/symptom/voice_change/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+
+		var/mob/living/carbon/M = A.affected_mob
+		switch(A.stage)
+			if(1, 2, 3, 4)
+				M << "<span class='warning'>[pick("Your throat hurts.", "You clear your throat.")]</span>"
+			else
+				if(ishuman(M))
+					var/mob/living/carbon/human/H = M
+					H.SetSpecialVoice(H.dna.species.random_name(H.gender))
+
+	return
+
+/datum/symptom/voice_change/End(datum/disease/advance/A)
+	..()
+	if(ishuman(A.affected_mob))
+		var/mob/living/carbon/human/H = A.affected_mob
+		H.UnsetSpecialVoice()
+	return

code/datums/diseases/advance/symptoms/vomit.dm

@@ -0,0 +1,106 @@
+/*
+//////////////////////////////////////
+
+Vomiting
+
+	Very Very Noticable.
+	Decreases resistance.
+	Doesn't increase stage speed.
+	Little transmittable.
+	Medium Level.
+
+Bonus
+	Forces the affected mob to vomit!
+	Meaning your disease can spread via
+	people walking on vomit.
+	Makes the affected mob lose nutrition and
+	heal toxin damage.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/vomit
+
+	name = "Vomiting"
+	stealth = -2
+	resistance = -1
+	stage_speed = 0
+	transmittable = 1
+	level = 3
+	severity = 4
+
+/datum/symptom/vomit/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB / 2))
+		var/mob/living/M = A.affected_mob
+		switch(A.stage)
+			if(1, 2, 3, 4)
+				M << "<span class='warning'>[pick("You feel nauseous.", "You feel like you're going to throw up!")]</span>"
+			else
+				Vomit(M)
+
+	return
+
+/datum/symptom/vomit/proc/Vomit(mob/living/carbon/M)
+	M.vomit(20)
+
+/*
+//////////////////////////////////////
+
+Vomiting Blood
+
+	Very Very Noticable.
+	Decreases resistance.
+	Decreases stage speed.
+	Little transmittable.
+	Intense level.
+
+Bonus
+	Forces the affected mob to vomit blood!
+	Meaning your disease can spread via
+	people walking on the blood.
+	Makes the affected mob lose health.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/vomit/blood
+
+	name = "Blood Vomiting"
+	stealth = -2
+	resistance = -1
+	stage_speed = -1
+	transmittable = 1
+	level = 4
+	severity = 5
+
+/datum/symptom/vomit/blood/Vomit(mob/living/carbon/M)
+	M.vomit(0, 1)
+
+
+/*
+//////////////////////////////////////
+
+Projectile Vomiting
+
+	Very Very Noticable.
+	Decreases resistance.
+	Doesn't increase stage speed.
+	Little transmittable.
+	Medium Level.
+
+Bonus
+	As normal vomiting, except it will spread further,
+	likely causing more to walk across the vomit.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/vomit/projectile
+
+	name = "Projectile Vomiting"
+	stealth = -2
+	level = 4
+
+/datum/symptom/vomit/projectile/Vomit(mob/living/carbon/M)
+	M.vomit(6,0,1,5,1)

code/datums/diseases/advance/symptoms/weakness.dm

@@ -0,0 +1,44 @@
+/*
+//////////////////////////////////////
+
+Weakness
+
+	Slightly noticeable.
+	Lowers resistance slightly.
+	Decreases stage speed moderately.
+	Decreases transmittablity moderately.
+	Moderate Level.
+
+Bonus
+	Deals stamina damage to the host
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/weakness
+
+	name = "Weakness"
+	stealth = -1
+	resistance = -1
+	stage_speed = -2
+	transmittable = -2
+	level = 3
+	severity = 3
+
+/datum/symptom/weakness/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/M = A.affected_mob
+		switch(A.stage)
+			if(1, 2)
+				M << "<span class='warning'>[pick("You feel weak.", "You feel lazy.")]</span>"
+			if(3, 4)
+				M << "<span class='warning'><b>[pick("You feel very frail.", "You think you might faint.")]</span>"
+				M.adjustStaminaLoss(15)
+			else
+				M << "<span class='userdanger'>[pick("You feel tremendously weak!", "Your body trembles as exhaustion creeps over you.")]</span>"
+				M.adjustStaminaLoss(30)
+				if(M.getStaminaLoss() > 60 && !M.stat)
+					M.visible_message("<span class='warning'>[M] faints!</span>", "<span class='userdanger'>You swoon and faint...</span>")
+					M.AdjustSleeping(5)
+	return

code/datums/diseases/advance/symptoms/weight.dm

@@ -0,0 +1,121 @@
+/*
+//////////////////////////////////////
+
+Weight Gain
+
+	Very Very Noticable.
+	Decreases resistance.
+	Decreases stage speed.
+	Reduced transmittable.
+	Intense Level.
+
+Bonus
+	Increases the weight gain of the mob,
+	forcing it to eventually turn fat.
+//////////////////////////////////////
+*/
+
+/datum/symptom/weight_gain
+
+	name = "Weight Gain"
+	stealth = -3
+	resistance = -3
+	stage_speed = -2
+	transmittable = -2
+	level = 4
+	severity = 1
+
+/datum/symptom/weight_gain/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/M = A.affected_mob
+		switch(A.stage)
+			if(1, 2, 3, 4)
+				M << "<span class='warning'>[pick("You feel blubbery.", "Your stomach hurts.")]</span>"
+			else
+				M.overeatduration = min(M.overeatduration + 100, 600)
+				M.nutrition = min(M.nutrition + 100, NUTRITION_LEVEL_FULL)
+
+	return
+
+
+/*
+//////////////////////////////////////
+
+Weight Loss
+
+	Very Very Noticable.
+	Decreases resistance.
+	Decreases stage speed.
+	Reduced Transmittable.
+	High level.
+
+Bonus
+	Decreases the weight of the mob,
+	forcing it to be skinny.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/weight_loss
+
+	name = "Weight Loss"
+	stealth = -3
+	resistance = -2
+	stage_speed = -2
+	transmittable = -2
+	level = 3
+	severity = 1
+
+/datum/symptom/weight_loss/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/M = A.affected_mob
+		switch(A.stage)
+			if(1, 2, 3, 4)
+				M << "<span class='warning'>[pick("You feel hungry.", "You crave for food.")]</span>"
+			else
+				M << "<span class='warning'><i>[pick("So hungry...", "You'd kill someone for a bite of food...", "Hunger cramps seize you...")]</i></span>"
+				M.overeatduration = max(M.overeatduration - 100, 0)
+				M.nutrition = max(M.nutrition - 100, 0)
+
+	return
+
+/*
+//////////////////////////////////////
+
+Weight Even
+
+	Very Noticable.
+	Decreases resistance.
+	Decreases stage speed.
+	Reduced transmittable.
+	High level.
+
+Bonus
+	Causes the weight of the mob to
+	be even, meaning eating isn't
+	required anymore.
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/weight_even
+
+	name = "Weight Even"
+	stealth = -3
+	resistance = -2
+	stage_speed = -2
+	transmittable = -2
+	level = 4
+
+/datum/symptom/weight_even/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB))
+		var/mob/living/M = A.affected_mob
+		switch(A.stage)
+			if(4, 5)
+				M.overeatduration = 0
+				M.nutrition = NUTRITION_LEVEL_WELL_FED + 50
+
+	return

code/datums/diseases/advance/symptoms/youth.dm

@@ -0,0 +1,55 @@
+/*
+//////////////////////////////////////
+Eternal Youth
+
+	Moderate stealth boost.
+	Increases resistance tremendously.
+	Increases stage speed tremendously.
+	Reduces transmission tremendously.
+	Critical Level.
+
+BONUS
+	Gives you immortality and eternal youth!!!
+	Can be used to buff your virus
+
+//////////////////////////////////////
+*/
+
+/datum/symptom/youth
+
+	name = "Eternal Youth"
+	stealth = 3
+	resistance = 4
+	stage_speed = 4
+	transmittable = -4
+	level = 5
+
+/datum/symptom/youth/Activate(datum/disease/advance/A)
+	..()
+	if(prob(SYMPTOM_ACTIVATION_PROB * 2))
+		var/mob/living/M = A.affected_mob
+		if(istype(M, /mob/living/carbon/human))
+			var/mob/living/carbon/human/H = M
+			switch(A.stage)
+				if(1)
+					if(H.age > 41)
+						H.age = 41
+						H << "<span class='notice'>You haven't had this much energy in years!</span>"
+				if(2)
+					if(H.age > 36)
+						H.age = 36
+						H << "<span class='notice'>You're suddenly in a good mood.</span>"
+				if(3)
+					if(H.age > 31)
+						H.age = 31
+						H << "<span class='notice'>You begin to feel more lithe.</span>"
+				if(4)
+					if(H.age > 26)
+						H.age = 26
+						H << "<span class='notice'>You feel reinvigorated.</span>"
+				if(5)
+					if(H.age > 21)
+						H.age = 21
+						H << "<span class='notice'>You feel like you can take on the world!</span>"
+
+	return