initial commit - cross reference with 5th port - obviously has compile errors

code/datums/helper_datums/construction_datum.dm

@@ -0,0 +1,103 @@
+#define FORWARD -1
+#define BACKWARD 1
+
+/datum/construction
+	var/list/steps
+	var/atom/holder
+	var/result
+	var/list/steps_desc
+
+/datum/construction/New(atom)
+	..()
+	holder = atom
+	if(!holder) //don't want this without a holder
+		qdel(src)
+	set_desc(steps.len)
+	return
+
+/datum/construction/proc/next_step()
+	steps.len--
+	if(!steps.len)
+		spawn_result()
+	else
+		set_desc(steps.len)
+	return
+
+/datum/construction/proc/action(atom/used_atom,mob/user)
+	return
+
+/datum/construction/proc/check_step(atom/used_atom,mob/user) //check last step only
+	var/valid_step = is_right_key(used_atom)
+	if(valid_step)
+		if(custom_action(valid_step, used_atom, user))
+			next_step()
+			return 1
+	return 0
+
+/datum/construction/proc/is_right_key(atom/used_atom) // returns current step num if used_atom is of the right type.
+	var/list/L = steps[steps.len]
+	if(istype(used_atom, L["key"]))
+		return steps.len
+	return 0
+
+/datum/construction/proc/custom_action(step, used_atom, user)
+	return 1
+
+/datum/construction/proc/check_all_steps(atom/used_atom,mob/user) //check all steps, remove matching one.
+	for(var/i=1;i<=steps.len;i++)
+		var/list/L = steps[i];
+		if(istype(used_atom, L["key"]))
+			if(custom_action(i, used_atom, user))
+				steps[i]=null;//stupid byond list from list removal...
+				listclearnulls(steps);
+				if(!steps.len)
+					spawn_result()
+				return 1
+	return 0
+
+
+/datum/construction/proc/spawn_result()
+	if(result)
+		new result(get_turf(holder))
+		qdel(holder)
+	return
+
+/datum/construction/proc/set_desc(index as num)
+	var/list/step = steps[index]
+	holder.desc = step["desc"]
+	return
+
+/datum/construction/reversible
+	var/index
+
+/datum/construction/reversible/New(atom)
+	..()
+	index = steps.len
+	return
+
+/datum/construction/reversible/proc/update_index(diff as num)
+	index+=diff
+	if(index==0)
+		spawn_result()
+	else
+		set_desc(index)
+	return
+
+/datum/construction/reversible/is_right_key(atom/used_atom) // returns index step
+	var/list/L = steps[index]
+	if(istype(used_atom, L["key"]))
+		return FORWARD //to the first step -> forward
+	else if(L["backkey"] && istype(used_atom, L["backkey"]))
+		return BACKWARD //to the last step -> backwards
+	return 0
+
+/datum/construction/reversible/check_step(atom/used_atom,mob/user)
+	var/diff = is_right_key(used_atom)
+	if(diff)
+		if(custom_action(index, diff, used_atom, user))
+			update_index(diff)
+			return 1
+	return 0
+
+/datum/construction/reversible/custom_action(index, diff, used_atom, user)
+	return 1

code/datums/helper_datums/events.dm

@@ -0,0 +1,68 @@
+/*
+ * WARRANTY VOID IF CODE USED
+ */
+
+
+/datum/events
+	var/list/events
+
+/datum/events/New()
+	..()
+	events = new
+
+/datum/events/proc/addEventType(event_type as text)
+	if(!(event_type in events) || !islist(events[event_type]))
+		events[event_type] = list()
+		return 1
+	return
+
+
+//	Arguments: event_type as text, proc_holder as datum, proc_name as text
+//	Returns: New event, null on error.
+/datum/events/proc/addEvent(event_type as text, proc_holder, proc_name as text)
+	if(!event_type || !proc_holder || !proc_name)
+		return
+	addEventType(event_type)
+	var/list/event = events[event_type]
+	var/datum/event/E = new /datum/event(proc_holder,proc_name)
+	event += E
+	return E
+
+//  Arguments: event_type as text, any number of additional arguments to pass to event handler
+//  Returns: null
+/datum/events/proc/fireEvent()
+	//world << "Events in [args[1]] called"
+	var/list/event = listgetindex(events,args[1])
+	if(istype(event))
+		spawn(0)
+			for(var/datum/event/E in event)
+				if(!E.Fire(arglist(args.Copy(2))))
+					clearEvent(args[1],E)
+	return
+
+// Arguments: event_type as text, E as /datum/event
+// Returns: 1 if event cleared, null on error
+
+/datum/events/proc/clearEvent(event_type as text, datum/event/E)
+	if(!event_type || !E)
+		return
+	var/list/event = listgetindex(events,event_type)
+	event -= E
+	return 1
+
+
+/datum/event
+	var/listener
+	var/proc_name
+
+/datum/event/New(tlistener,tprocname)
+	listener = tlistener
+	proc_name = tprocname
+	return ..()
+
+/datum/event/proc/Fire()
+	//world << "Event fired"
+	if(listener)
+		call(listener,proc_name)(arglist(args))
+		return 1
+	return

code/datums/helper_datums/getrev.dm

@@ -0,0 +1,61 @@
+var/global/datum/getrev/revdata = new()
+
+/datum/getrev
+	var/parentcommit
+	var/commit
+	var/list/testmerge = list()
+	var/date
+
+/datum/getrev/New()
+	var/head_file = return_file_text(".git/logs/HEAD")
+	var/regex/head_log = new("(\\w{40}) (\\w{40}).+> (\\d{10}).+\n\\Z")
+	head_log.Find(head_file)
+	parentcommit = head_log.group[1]
+	commit = head_log.group[2]
+	var/unix_time = text2num(head_log.group[3])
+	if(SERVERTOOLS && fexists("..\\prtestjob.lk"))
+		testmerge = file2list("..\\prtestjob.lk")
+	date = unix2date(unix_time)
+	world.log << "Running /tg/ revision:"
+	world.log << "[date]"
+	world.log << commit
+	if(testmerge.len)
+		for(var/line in testmerge)
+			if(line)
+				world.log << "Test merge active of PR #[line]"
+		world.log << "Based off master commit [parentcommit]"
+	world.log << "Current map - [MAP_NAME]" //can't think of anywhere better to put it
+
+/client/verb/showrevinfo()
+	set category = "OOC"
+	set name = "Show Server Revision"
+	set desc = "Check the current server code revision"
+
+	if(revdata.commit)
+		src << "<b>Server revision compiled on:</b> [revdata.date]"
+		if(revdata.testmerge.len)
+			for(var/line in revdata.testmerge)
+				if(line)
+					src << "Test merge active of PR <a href='[config.githuburl]/pull/[line]'>#[line]</a>"
+			src << "Based off master commit <a href='[config.githuburl]/commit/[revdata.parentcommit]'>[revdata.parentcommit]</a>"
+		else
+			src << "<a href='[config.githuburl]/commit/[revdata.commit]'>[revdata.commit]</a>"
+	else
+		src << "Revision unknown"
+	src << "<b>Current Infomational Settings:</b>"
+	src << "Protect Authority Roles From Traitor: [config.protect_roles_from_antagonist]"
+	src << "Protect Assistant Role From Traitor: [config.protect_assistant_from_antagonist]"
+	src << "Enforce Human Authority: [config.enforce_human_authority]"
+	src << "Allow Latejoin Antagonists: [config.allow_latejoin_antagonists]"
+	src << "Enforce Continuous Rounds: [config.continuous.len] of [config.modes.len] roundtypes"
+	src << "Allow Midround Antagonists: [config.midround_antag.len] of [config.modes.len] roundtypes"
+	if(config.show_game_type_odds)
+		src <<"<b>Game Mode Odds:</b>"
+		var/sum = 0
+		for(var/i=1,i<=config.probabilities.len,i++)
+			sum += config.probabilities[config.probabilities[i]]
+		for(var/i=1,i<=config.probabilities.len,i++)
+			if(config.probabilities[config.probabilities[i]] > 0)
+				var/percentage = round(config.probabilities[config.probabilities[i]] / sum * 100, 0.1)
+				src << "[config.probabilities[i]] [percentage]%"
+	return

code/datums/helper_datums/icon_snapshot.dm

@@ -0,0 +1,15 @@
+/datum/icon_snapshot
+	var/name
+	var/icon
+	var/icon_state
+	var/list/overlays
+
+/datum/icon_snapshot/proc/makeImg()
+	if(!icon || !icon_state)
+		return
+	var/obj/temp = new
+	temp.icon = icon
+	temp.icon_state = icon_state
+	temp.overlays = overlays.Copy()
+	var/icon/tempicon = getFlatIcon(temp) // TODO Actually write something less heavy-handed for this
+	return tempicon

code/datums/helper_datums/map_template.dm

@@ -0,0 +1,138 @@
+/datum/map_template
+	var/name = "Default Template Name"
+	var/width = 0
+	var/height = 0
+	var/mappath = null
+	var/mapfile = null
+	var/loaded = 0 // Times loaded this round
+
+/datum/map_template/New(path = null, map = null, rename = null)
+	if(path)
+		mappath = path
+	if(mappath)
+		preload_size(mappath)
+	if(map)
+		mapfile = map
+	if(rename)
+		name = rename
+
+/datum/map_template/proc/preload_size(path)
+	var/bounds = maploader.load_map(file(path), 1, 1, 1, cropMap=FALSE, measureOnly=TRUE)
+	if(bounds)
+		width = bounds[MAP_MAXX] // Assumes all templates are rectangular, have a single Z level, and begin at 1,1,1
+		height = bounds[MAP_MAXY]
+	return bounds
+
+/proc/initTemplateBounds(var/list/bounds)
+	var/list/obj/machinery/atmospherics/atmos_machines = list()
+	var/list/obj/structure/cable/cables = list()
+	var/list/atom/atoms = list()
+
+	for(var/L in block(locate(bounds[MAP_MINX], bounds[MAP_MINY], bounds[MAP_MINZ]),
+	                   locate(bounds[MAP_MAXX], bounds[MAP_MAXY], bounds[MAP_MAXZ])))
+		var/turf/B = L
+		for(var/A in B)
+			atoms += A
+			if(istype(A,/obj/structure/cable))
+				cables += A
+				continue
+			if(istype(A,/obj/machinery/atmospherics))
+				atmos_machines += A
+				continue
+
+	SSobj.setup_template_objects(atoms)
+	SSmachine.setup_template_powernets(cables)
+	SSair.setup_template_machinery(atmos_machines)
+
+/datum/map_template/proc/load(turf/T, centered = FALSE)
+	if(centered)
+		T = locate(T.x - round(width/2) , T.y - round(height/2) , T.z)
+	if(!T)
+		return
+	if(T.x+width > world.maxx)
+		return
+	if(T.y+height > world.maxy)
+		return
+
+	var/list/bounds = maploader.load_map(get_file(), T.x, T.y, T.z, cropMap=TRUE)
+	if(!bounds)
+		return 0
+
+	//initialize things that are normally initialized after map load
+	initTemplateBounds(bounds)
+
+	log_game("[name] loaded at at [T.x],[T.y],[T.z]")
+	return 1
+
+/datum/map_template/proc/get_file()
+	if(mapfile)
+		. = mapfile
+	else if(mappath)
+		. = file(mappath)
+
+	if(!.)
+		world.log << "The file of [src] appears to be empty/non-existent."
+
+/datum/map_template/proc/get_affected_turfs(turf/T, centered = FALSE)
+	var/turf/placement = T
+	if(centered)
+		var/turf/corner = locate(placement.x - round(width/2), placement.y - round(height/2), placement.z)
+		if(corner)
+			placement = corner
+	return block(placement, locate(placement.x+width-1, placement.y+height-1, placement.z))
+
+
+/proc/preloadTemplates(path = "_maps/templates/") //see master controller setup
+	var/list/filelist = flist(path)
+	for(var/map in filelist)
+		var/datum/map_template/T = new(path = "[path][map]", rename = "[map]")
+		map_templates[T.name] = T
+
+	preloadRuinTemplates()
+	preloadShuttleTemplates()
+	preloadShelterTemplates()
+
+/proc/preloadRuinTemplates()
+	// Still supporting bans by filename
+	var/list/banned = generateMapList("config/lavaRuinBlacklist.txt")
+	banned += generateMapList("config/spaceRuinBlacklist.txt")
+
+	for(var/item in subtypesof(/datum/map_template/ruin))
+		var/datum/map_template/ruin/ruin_type = item
+		// screen out the abstract subtypes
+		if(!initial(ruin_type.id))
+			continue
+		var/datum/map_template/ruin/R = new ruin_type()
+
+		if(banned.Find(R.mappath))
+			continue
+
+		map_templates[R.name] = R
+		ruins_templates[R.name] = R
+
+		if(istype(R, /datum/map_template/ruin/lavaland))
+			lava_ruins_templates[R.name] = R
+		else if(istype(R, /datum/map_template/ruin/space))
+			space_ruins_templates[R.name] = R
+
+
+/proc/preloadShuttleTemplates()
+	for(var/item in subtypesof(/datum/map_template/shuttle))
+		var/datum/map_template/shuttle/shuttle_type = item
+		if(!(initial(shuttle_type.suffix)))
+			continue
+
+		var/datum/map_template/shuttle/S = new shuttle_type()
+
+		shuttle_templates[S.shuttle_id] = S
+		map_templates[S.shuttle_id] = S
+
+/proc/preloadShelterTemplates()
+	for(var/item in subtypesof(/datum/map_template/shelter))
+		var/datum/map_template/shelter/shelter_type = item
+		if(!(initial(shelter_type.mappath)))
+			continue
+		var/datum/map_template/shelter/S = new shelter_type()
+
+		shelter_templates[S.shelter_id] = S
+		map_templates[S.shelter_id] = S

code/datums/helper_datums/teleport.dm

@@ -0,0 +1,219 @@
+//wrapper
+/proc/do_teleport(ateleatom, adestination, aprecision=0, afteleport=1, aeffectin=null, aeffectout=null, asoundin=null, asoundout=null)
+	var/datum/teleport/instant/science/D = new
+	if(D.start(arglist(args)))
+		return 1
+	return 0
+
+/datum/teleport
+	var/atom/movable/teleatom //atom to teleport
+	var/atom/destination //destination to teleport to
+	var/precision = 0 //teleport precision
+	var/datum/effect_system/effectin //effect to show right before teleportation
+	var/datum/effect_system/effectout //effect to show right after teleportation
+	var/soundin //soundfile to play before teleportation
+	var/soundout //soundfile to play after teleportation
+	var/force_teleport = 1 //if false, teleport will use Move() proc (dense objects will prevent teleportation)
+
+
+/datum/teleport/proc/start(ateleatom, adestination, aprecision=0, afteleport=1, aeffectin=null, aeffectout=null, asoundin=null, asoundout=null)
+	if(!initTeleport(arglist(args)))
+		return 0
+	return 1
+
+/datum/teleport/proc/initTeleport(ateleatom,adestination,aprecision,afteleport,aeffectin,aeffectout,asoundin,asoundout)
+	if(!setTeleatom(ateleatom))
+		return 0
+	if(!setDestination(adestination))
+		return 0
+	if(!setPrecision(aprecision))
+		return 0
+	setEffects(aeffectin,aeffectout)
+	setForceTeleport(afteleport)
+	setSounds(asoundin,asoundout)
+	return 1
+
+//must succeed
+/datum/teleport/proc/setPrecision(aprecision)
+	if(isnum(aprecision))
+		precision = aprecision
+		return 1
+	return 0
+
+//must succeed
+/datum/teleport/proc/setDestination(atom/adestination)
+	if(istype(adestination))
+		destination = adestination
+		return 1
+	return 0
+
+//must succeed in most cases
+/datum/teleport/proc/setTeleatom(atom/movable/ateleatom)
+	if(istype(ateleatom, /obj/effect) && !istype(ateleatom, /obj/effect/dummy/chameleon))
+		qdel(ateleatom)
+		return 0
+	if(istype(ateleatom))
+		teleatom = ateleatom
+		return 1
+	return 0
+
+//custom effects must be properly set up first for instant-type teleports
+//optional
+/datum/teleport/proc/setEffects(datum/effect_system/aeffectin=null,datum/effect_system/aeffectout=null)
+	effectin = istype(aeffectin) ? aeffectin : null
+	effectout = istype(aeffectout) ? aeffectout : null
+	return 1
+
+//optional
+/datum/teleport/proc/setForceTeleport(afteleport)
+	force_teleport = afteleport
+	return 1
+
+//optional
+/datum/teleport/proc/setSounds(asoundin=null,asoundout=null)
+	soundin = isfile(asoundin) ? asoundin : null
+	soundout = isfile(asoundout) ? asoundout : null
+	return 1
+
+//placeholder
+/datum/teleport/proc/teleportChecks()
+	return 1
+
+/datum/teleport/proc/playSpecials(atom/location,datum/effect_system/effect,sound)
+	if(location)
+		if(effect)
+			addtimer(src, "do_effect", 0, FALSE, location, effect)
+		if(sound)
+			addtimer(src, "do_sound", 0, FALSE, location, sound)
+
+/datum/teleport/proc/do_effect(atom/location, datum/effect_system/effect)
+	src = null
+	effect.attach(location)
+	effect.start()
+
+/datum/teleport/proc/do_sound(atom/location, sound)
+	src = null
+	playsound(location, sound, 60, 1)
+
+//do the monkey dance
+/datum/teleport/proc/doTeleport()
+
+	var/turf/destturf
+	var/turf/curturf = get_turf(teleatom)
+	if(precision)
+		var/list/posturfs = list()
+		var/center = get_turf(destination)
+		if(!center)
+			center = destination
+		for(var/turf/T in range(precision,center))
+			var/area/A = T.loc
+			if(!A.noteleport)
+				posturfs.Add(T)
+
+		destturf = safepick(posturfs)
+	else
+		destturf = get_turf(destination)
+
+	if(!destturf || !curturf)
+		return 0
+
+	var/area/A = get_area(curturf)
+	if(A.noteleport)
+		return 0
+
+	playSpecials(curturf,effectin,soundin)
+
+	if(force_teleport)
+		teleatom.forceMove(destturf)
+		playSpecials(destturf,effectout,soundout)
+	else
+		if(teleatom.Move(destturf))
+			playSpecials(destturf,effectout,soundout)
+	return 1
+
+/datum/teleport/proc/teleport()
+	if(teleportChecks())
+		return doTeleport()
+	return 0
+
+/datum/teleport/instant //teleports when datum is created
+
+	start(ateleatom, adestination, aprecision=0, afteleport=1, aeffectin=null, aeffectout=null, asoundin=null, asoundout=null)
+		if(..())
+			if(teleport())
+				return 1
+		return 0
+
+
+/datum/teleport/instant/science
+
+/datum/teleport/instant/science/setEffects(datum/effect_system/aeffectin,datum/effect_system/aeffectout)
+	if(aeffectin==null || aeffectout==null)
+		var/datum/effect_system/spark_spread/aeffect = new
+		aeffect.set_up(5, 1, teleatom)
+		effectin = effectin || aeffect
+		effectout = effectout || aeffect
+		return 1
+	else
+		return ..()
+
+/datum/teleport/instant/science/setPrecision(aprecision)
+	..()
+	if(istype(teleatom, /obj/item/weapon/storage/backpack/holding))
+		precision = rand(1,100)
+
+	var/list/bagholding = teleatom.search_contents_for(/obj/item/weapon/storage/backpack/holding)
+	if(bagholding.len)
+		precision = max(rand(1,100)*bagholding.len,100)
+		if(istype(teleatom, /mob/living))
+			var/mob/living/MM = teleatom
+			MM << "<span class='warning'>The bluespace interface on your bag of holding interferes with the teleport!</span>"
+	return 1
+
+// Safe location finder
+
+/proc/find_safe_turf(zlevel = ZLEVEL_STATION, list/zlevels)
+	if(!zlevels)
+		zlevels = list(zlevel)
+	var/cycles = 1000
+	for(var/cycle in 1 to cycles)
+		// DRUNK DIALLING WOOOOOOOOO
+		var/x = rand(1, world.maxx)
+		var/y = rand(1, world.maxy)
+		var/z = pick(zlevels)
+		var/random_location = locate(x,y,z)
+
+		if(!(istype(random_location, /turf/open/floor)))
+			continue
+		var/turf/open/floor/F = random_location
+		if(!F.air)
+			continue
+
+		var/datum/gas_mixture/A = F.air
+		var/list/A_gases = A.gases
+		var/trace_gases
+		for(var/id in A_gases)
+			if(id in hardcoded_gases)
+				continue
+			trace_gases = TRUE
+			break
+
+		// Can most things breathe?
+		if(trace_gases)
+			continue
+		if(!(A_gases["o2"] && A_gases["o2"][MOLES] >= 16))
+			continue
+		if(A_gases["plasma"])
+			continue
+		if(A_gases["co2"] && A_gases["co2"][MOLES] >= 10)
+			continue
+
+		// Aim for goldilocks temperatures and pressure
+		if((A.temperature <= 270) || (A.temperature >= 360))
+			continue
+		var/pressure = A.return_pressure()
+		if((pressure <= 20) || (pressure >= 550))
+			continue
+
+		// DING! You have passed the gauntlet, and are "probably" safe.
+		return F

code/datums/helper_datums/topic_input.dm

@@ -0,0 +1,62 @@
+/datum/topic_input
+	var/href
+	var/list/href_list
+
+/datum/topic_input/New(thref,list/thref_list)
+	href = thref
+	href_list = thref_list.Copy()
+	return
+
+/datum/topic_input/proc/get(i)
+	return listgetindex(href_list,i)
+
+/datum/topic_input/proc/getAndLocate(i)
+	var/t = get(i)
+	if(t)
+		t = locate(t)
+	if (istext(t))
+		t = null
+	return t || null
+
+/datum/topic_input/proc/getNum(i)
+	var/t = get(i)
+	if(t)
+		t = text2num(t)
+	return isnum(t) ? t : null
+
+/datum/topic_input/proc/getObj(i)
+	var/t = getAndLocate(i)
+	return isobj(t) ? t : null
+
+/datum/topic_input/proc/getMob(i)
+	var/t = getAndLocate(i)
+	return ismob(t) ? t : null
+
+/datum/topic_input/proc/getTurf(i)
+	var/t = getAndLocate(i)
+	return isturf(t) ? t : null
+
+/datum/topic_input/proc/getAtom(i)
+	return getType(i,/atom)
+
+/datum/topic_input/proc/getArea(i)
+	var/t = getAndLocate(i)
+	return isarea(t) ? t : null
+
+/datum/topic_input/proc/getStr(i)//params should always be text, but...
+	var/t = get(i)
+	return istext(t) ? t : null
+
+/datum/topic_input/proc/getType(i,type)
+	var/t = getAndLocate(i)
+	return istype(t,type) ? t : null
+
+/datum/topic_input/proc/getPath(i)
+	var/t = get(i)
+	if(t)
+		t = text2path(t)
+	return ispath(t) ? t : null
+
+/datum/topic_input/proc/getList(i)
+	var/t = getAndLocate(i)
+	return islist(t) ? t : null