initial commit - cross reference with 5th port - obviously has compile errors

code/game/objects/items/weapons/implants/implant.dm

@@ -0,0 +1,82 @@
+/obj/item/weapon/implant
+	name = "implant"
+	icon = 'icons/obj/implants.dmi'
+	icon_state = "generic" //Shows up as the action button icon
+	origin_tech = "materials=2;biotech=3;programming=2"
+	actions_types = list(/datum/action/item_action/hands_free/activate)
+	var/activated = 1 //1 for implant types that can be activated, 0 for ones that are "always on" like mindshield implants
+	var/implanted = null
+	var/mob/living/imp_in = null
+	item_color = "b"
+	var/allow_multiple = 0
+	var/uses = -1
+	flags = DROPDEL
+
+
+/obj/item/weapon/implant/proc/trigger(emote, mob/source)
+	return
+
+/obj/item/weapon/implant/proc/activate()
+	return
+
+/obj/item/weapon/implant/ui_action_click()
+	activate("action_button")
+
+
+//What does the implant do upon injection?
+//return 1 if the implant injects
+//return -1 if the implant fails to inject
+//return 0 if there is no room for implant
+/obj/item/weapon/implant/proc/implant(var/mob/source, var/mob/user)
+	var/obj/item/weapon/implant/imp_e = locate(src.type) in source
+	if(!allow_multiple && imp_e && imp_e != src)
+		if(imp_e.uses < initial(imp_e.uses)*2)
+			if(uses == -1)
+				imp_e.uses = -1
+			else
+				imp_e.uses = min(imp_e.uses + uses, initial(imp_e.uses)*2)
+			qdel(src)
+			return 1
+		else
+			return 0
+
+	src.loc = source
+	imp_in = source
+	implanted = 1
+	if(activated)
+		for(var/X in actions)
+			var/datum/action/A = X
+			A.Grant(source)
+	if(istype(source, /mob/living/carbon/human))
+		var/mob/living/carbon/human/H = source
+		H.sec_hud_set_implants()
+
+	if(user)
+		add_logs(user, source, "implanted", object="[name]")
+
+	return 1
+
+/obj/item/weapon/implant/proc/removed(var/mob/source)
+	src.loc = null
+	imp_in = null
+	implanted = 0
+	for(var/X in actions)
+		var/datum/action/A = X
+		A.Grant(source)
+	if(istype(source, /mob/living/carbon/human))
+		var/mob/living/carbon/human/H = source
+		H.sec_hud_set_implants()
+
+	return 1
+
+/obj/item/weapon/implant/Destroy()
+	if(imp_in)
+		removed(imp_in)
+	return ..()
+
+/obj/item/weapon/implant/proc/get_data()
+	return "No information available"
+
+/obj/item/weapon/implant/dropped(mob/user)
+	. = 1
+	..()

code/game/objects/items/weapons/implants/implant_chem.dm

@@ -0,0 +1,68 @@
+/obj/item/weapon/implant/chem
+	name = "chem implant"
+	desc = "Injects things."
+	icon_state = "reagents"
+	origin_tech = "materials=3;biotech=4"
+	flags = OPENCONTAINER
+
+/obj/item/weapon/implant/chem/get_data()
+	var/dat = {"<b>Implant Specifications:</b><BR>
+				<b>Name:</b> Robust Corp MJ-420 Prisoner Management Implant<BR>
+				<b>Life:</b> Deactivates upon death but remains within the body.<BR>
+				<b>Important Notes: Due to the system functioning off of nutrients in the implanted subject's body, the subject<BR>
+				will suffer from an increased appetite.</B><BR>
+				<HR>
+				<b>Implant Details:</b><BR>
+				<b>Function:</b> Contains a small capsule that can contain various chemicals. Upon receiving a specially encoded signal<BR>
+				the implant releases the chemicals directly into the blood stream.<BR>
+				<b>Special Features:</b>
+				<i>Micro-Capsule</i>- Can be loaded with any sort of chemical agent via the common syringe and can hold 50 units.<BR>
+				Can only be loaded while still in its original case.<BR>
+				<b>Integrity:</b> Implant will last so long as the subject is alive."}
+	return dat
+
+/obj/item/weapon/implant/chem/New()
+	..()
+	create_reagents(50)
+	tracked_implants += src
+
+/obj/item/weapon/implant/chem/Destroy()
+	..()
+	tracked_implants -= src
+
+
+
+
+/obj/item/weapon/implant/chem/trigger(emote, mob/source)
+	if(emote == "deathgasp")
+		activate(reagents.total_volume)
+
+/obj/item/weapon/implant/chem/activate(cause)
+	if(!cause || !imp_in)
+		return 0
+	var/mob/living/carbon/R = imp_in
+	var/injectamount = null
+	if (cause == "action_button")
+		injectamount = reagents.total_volume
+	else
+		injectamount = cause
+	reagents.trans_to(R, injectamount)
+	R << "<span class='italics'>You hear a faint beep.</span>"
+	if(!reagents.total_volume)
+		R << "<span class='italics'>You hear a faint click from your chest.</span>"
+		qdel(src)
+
+
+/obj/item/weapon/implantcase/chem
+	name = "implant case - 'Remote Chemical'"
+	desc = "A glass case containing a remote chemical implant."
+
+/obj/item/weapon/implantcase/chem/New()
+	imp = new /obj/item/weapon/implant/chem(src)
+	..()
+	
+/obj/item/weapon/implantcase/chem/attackby(obj/item/weapon/W, mob/user, params)
+	if(imp)
+		imp.attackby(W, user, params)
+	else 
+		return ..()

code/game/objects/items/weapons/implants/implant_clown.dm

@@ -0,0 +1,30 @@
+/obj/item/weapon/implant/sad_trombone
+	name = "sad trombone implant"
+	activated = 0
+
+/obj/item/weapon/implant/sad_trombone/get_data()
+	var/dat = {"<b>Implant Specifications:</b><BR>
+				<b>Name:</b> Honk Co. Sad Trombone Implant<BR>
+				<b>Life:</b> Activates upon death.<BR>
+				"}
+	return dat
+
+/obj/item/weapon/implant/sad_trombone/trigger(emote, mob/source)
+	if(emote == "deathgasp")
+		playsound(loc, 'sound/misc/sadtrombone.ogg', 50, 0)
+
+/obj/item/weapon/implanter/sad_trombone
+	name = "implanter (sad_trombone)"
+
+/obj/item/weapon/implanter/sad_trombone/New()
+	imp = new /obj/item/weapon/implant/sad_trombone(src)
+	..()
+
+
+/obj/item/weapon/implantcase/sad_trombone
+	name = "implant case - 'Sad Trombone'"
+	desc = "A glass case containing a sad trombone implant."
+
+/obj/item/weapon/implantcase/sad_trombone/New()
+	imp = new /obj/item/weapon/implant/sad_trombone(src)
+	..()

code/game/objects/items/weapons/implants/implant_explosive.dm

@@ -0,0 +1,117 @@
+/obj/item/weapon/implant/explosive
+	name = "microbomb implant"
+	desc = "And boom goes the weasel."
+	icon_state = "explosive"
+	origin_tech = "materials=2;combat=3;biotech=4;syndicate=4"
+	var/weak = 2
+	var/medium = 0.8
+	var/heavy = 0.4
+	var/delay = 7
+
+/obj/item/weapon/implant/explosive/get_data()
+	var/dat = {"<b>Implant Specifications:</b><BR>
+				<b>Name:</b> Robust Corp RX-78 Employee Management Implant<BR>
+				<b>Life:</b> Activates upon death.<BR>
+				<b>Important Notes:</b> Explodes<BR>
+				<HR>
+				<b>Implant Details:</b><BR>
+				<b>Function:</b> Contains a compact, electrically detonated explosive that detonates upon receiving a specially encoded signal or upon host death.<BR>
+				<b>Special Features:</b> Explodes<BR>
+				"}
+	return dat
+
+/obj/item/weapon/implant/explosive/trigger(emote, mob/source)
+	if(emote == "deathgasp")
+		activate("death")
+
+/obj/item/weapon/implant/explosive/activate(cause)
+	if(!cause || !imp_in)
+		return 0
+	if(cause == "action_button" && alert(imp_in, "Are you sure you want to activate your [name]? This will cause you to explode!", "[name] Confirmation", "Yes", "No") != "Yes")
+		return 0
+	heavy = round(heavy)
+	medium = round(medium)
+	weak = round(weak)
+	imp_in << "<span class='notice'>You activate your [name].</span>"
+	var/turf/boomturf = get_turf(imp_in)
+	var/area/A = get_area(boomturf)
+	message_admins("[key_name_admin(imp_in)]<A HREF='?_src_=holder;adminmoreinfo=\ref[imp_in]'>?</A> (<A HREF='?_src_=holder;adminplayerobservefollow=\ref[imp_in]'>FLW</A>) has activated their [name] at <A HREF='?_src_=holder;adminplayerobservecoodjump=1;X=[imp_in.x];Y=[imp_in.y];Z=[imp_in.z]'>[A.name] (JMP)</a>.")
+//If the delay is short, just blow up already jeez
+	if(delay <= 7)
+		explosion(src,heavy,medium,weak,weak, flame_range = weak)
+		if(imp_in)
+			imp_in.gib(1)
+		qdel(src)
+		return
+	timed_explosion()
+
+/obj/item/weapon/implant/explosive/implant(mob/source)
+	var/obj/item/weapon/implant/explosive/imp_e = locate(src.type) in source
+	if(imp_e && imp_e != src)
+		imp_e.heavy += heavy
+		imp_e.medium += medium
+		imp_e.weak += weak
+		imp_e.delay += delay
+		qdel(src)
+		return 1
+
+	return ..()
+
+/obj/item/weapon/implant/explosive/proc/timed_explosion()
+	imp_in.visible_message("<span class = 'warning'>[imp_in] starts beeping ominously!</span>")
+	playsound(loc, 'sound/items/timer.ogg', 30, 0)
+	sleep(delay/4)
+	if(imp_in && !imp_in.stat)
+		imp_in.visible_message("<span class = 'warning'>[imp_in] doubles over in pain!</span>")
+		imp_in.Weaken(7)
+	playsound(loc, 'sound/items/timer.ogg', 30, 0)
+	sleep(delay/4)
+	playsound(loc, 'sound/items/timer.ogg', 30, 0)
+	sleep(delay/4)
+	playsound(loc, 'sound/items/timer.ogg', 30, 0)
+	sleep(delay/4)
+	explosion(src,heavy,medium,weak,weak, flame_range = weak)
+	if(imp_in)
+		imp_in.gib(1)
+	qdel(src)
+
+/obj/item/weapon/implant/explosive/macro
+	name = "macrobomb implant"
+	desc = "And boom goes the weasel. And everything else nearby."
+	icon_state = "explosive"
+	origin_tech = "materials=3;combat=5;biotech=4;syndicate=5"
+	weak = 16
+	medium = 8
+	heavy = 4
+	delay = 70
+
+/obj/item/weapon/implant/explosive/macro/implant(mob/source)
+	var/obj/item/weapon/implant/explosive/imp_e = locate(src.type) in source
+	if(imp_e && imp_e != src)
+		return 0
+	imp_e = locate(/obj/item/weapon/implant/explosive) in source
+	if(imp_e && imp_e != src)
+		heavy += imp_e.heavy
+		medium += imp_e.medium
+		weak += imp_e.weak
+		delay += imp_e.delay
+		qdel(imp_e)
+
+	return ..()
+
+
+/obj/item/weapon/implanter/explosive
+	name = "implanter (explosive)"
+
+/obj/item/weapon/implanter/explosive/New()
+	imp = new /obj/item/weapon/implant/explosive(src)
+	..()
+
+
+/obj/item/weapon/implantcase/explosive
+	name = "implant case - 'Explosive'"
+	desc = "A glass case containing an explosive implant."
+
+/obj/item/weapon/implantcase/explosive/New()
+	imp = new /obj/item/weapon/implant/explosive(src)
+	..()

code/game/objects/items/weapons/implants/implant_freedom.dm

@@ -0,0 +1,51 @@
+/obj/item/weapon/implant/freedom
+	name = "freedom implant"
+	desc = "Use this to escape from those evil Red Shirts."
+	icon_state = "freedom"
+	item_color = "r"
+	origin_tech = "combat=5;magnets=3;biotech=4;syndicate=2"
+	uses = 4
+
+
+/obj/item/weapon/implant/freedom/activate()
+	uses--
+	imp_in << "You feel a faint click."
+	if(iscarbon(imp_in))
+		var/mob/living/carbon/C_imp_in = imp_in
+		C_imp_in.uncuff()
+	if(!uses)
+		qdel(src)
+
+
+/obj/item/weapon/implant/freedom/get_data()
+	var/dat = {"
+<b>Implant Specifications:</b><BR>
+<b>Name:</b> Freedom Beacon<BR>
+<b>Life:</b> optimum 5 uses<BR>
+<b>Important Notes:</b> <font color='red'>Illegal</font><BR>
+<HR>
+<b>Implant Details:</b> <BR>
+<b>Function:</b> Transmits a specialized cluster of signals to override handcuff locking
+mechanisms<BR>
+<b>Special Features:</b><BR>
+<i>Neuro-Scan</i>- Analyzes certain shadow signals in the nervous system<BR>
+<HR>
+No Implant Specifics"}
+	return dat
+
+
+/obj/item/weapon/implanter/freedom
+	name = "implanter (freedom)"
+
+/obj/item/weapon/implanter/freedom/New()
+	imp = new /obj/item/weapon/implant/freedom(src)
+	..()
+
+
+/obj/item/weapon/implantcase/freedom
+	name = "implant case - 'Freedom'"
+	desc = "A glass case containing a freedom implant."
+
+/obj/item/weapon/implantcase/freedom/New()
+	imp = new /obj/item/weapon/implant/freedom(src)
+	..()

code/game/objects/items/weapons/implants/implant_krav_maga.dm

@@ -0,0 +1,40 @@
+/obj/item/weapon/implant/krav_maga
+	name = "krav maga implant"
+	desc = "Teaches you the arts of Krav Maga in 5 short instructional videos beamed directly into your eyeballs."
+	icon = 'icons/obj/wizard.dmi'
+	icon_state ="scroll2"
+	activated = 1
+	origin_tech = "materials=2;biotech=4;combat=5;syndicate=4"
+	var/datum/martial_art/krav_maga/style = new
+
+/obj/item/weapon/implant/krav_maga/get_data()
+	var/dat = {"<b>Implant Specifications:</b><BR>
+				<b>Name:</b> Krav Maga Implant<BR>
+				<b>Life:</b> 4 hours after death of host<BR>
+				<b>Implant Details:</b> <BR>
+				<b>Function:</b> Teaches even the clumsiest host the arts of Krav Maga."}
+	return dat
+
+/obj/item/weapon/implant/krav_maga/activate()
+	var/mob/living/carbon/human/H = imp_in
+	if(!ishuman(H))
+		return
+	if(istype(H.martial_art, /datum/martial_art/krav_maga))
+		style.remove(H)
+	else
+		style.teach(H,1)
+
+/obj/item/weapon/implanter/krav_maga
+	name = "implanter (krav maga)"
+
+/obj/item/weapon/implanter/krav_maga/New()
+	imp = new /obj/item/weapon/implant/krav_maga(src)
+	..()
+
+/obj/item/weapon/implantcase/krav_maga
+	name = "implant case - 'Krav Maga'"
+	desc = "A glass case containing an implant that can teach the user the arts of Krav Maga."
+
+/obj/item/weapon/implantcase/krav_maga/New()
+	imp = new /obj/item/weapon/implant/krav_maga(src)
+	..()

code/game/objects/items/weapons/implants/implant_loyality.dm

@@ -0,0 +1,65 @@
+/obj/item/weapon/implant/mindshield
+	name = "mindshield implant"
+	desc = "Protects against brainwashing."
+	origin_tech = "materials=2;biotech=4;programming=4"
+	activated = 0
+
+/obj/item/weapon/implant/mindshield/get_data()
+	var/dat = {"<b>Implant Specifications:</b><BR>
+				<b>Name:</b> Nanotrasen Employee Management Implant<BR>
+				<b>Life:</b> Ten years.<BR>
+				<b>Important Notes:</b> Personnel injected with this device are much more resistant to brainwashing.<BR>
+				<HR>
+				<b>Implant Details:</b><BR>
+				<b>Function:</b> Contains a small pod of nanobots that protects the host's mental functions from manipulation.<BR>
+				<b>Special Features:</b> Will prevent and cure most forms of brainwashing.<BR>
+				<b>Integrity:</b> Implant will last so long as the nanobots are inside the bloodstream."}
+	return dat
+
+
+/obj/item/weapon/implant/mindshield/implant(mob/target)
+	if(..())
+		if((target.mind in (ticker.mode.head_revolutionaries | ticker.mode.get_gang_bosses())))
+			target.visible_message("<span class='warning'>[target] seems to resist the implant!</span>", "<span class='warning'>You feel something interfering with your mental conditioning, but you resist it!</span>")
+			removed(target, 1)
+			qdel(src)
+			return -1
+		if(target.mind in ticker.mode.get_gangsters())
+			ticker.mode.remove_gangster(target.mind)
+			target.visible_message("<span class='warning'>[src] was destroyed in the process!</span>", "<span class='notice'>You feel a sense of peace and security. You are now protected from brainwashing.</span>")
+			removed(target, 1)
+			qdel(src)
+			return -1
+		if(target.mind in ticker.mode.revolutionaries)
+			ticker.mode.remove_revolutionary(target.mind)
+		if((target.mind in ticker.mode.cult) || (target.mind in ticker.mode.blue_deity_prophets|ticker.mode.red_deity_prophets|ticker.mode.red_deity_followers|ticker.mode.blue_deity_followers))
+			target << "<span class='warning'>You feel something interfering with your mental conditioning, but you resist it!</span>"
+		else
+			target << "<span class='notice'>You feel a sense of peace and security. You are now protected from brainwashing.</span>"
+		return 1
+	return 0
+
+/obj/item/weapon/implant/mindshield/removed(mob/target, var/silent = 0)
+	if(..())
+		if(target.stat != DEAD && !silent)
+			target << "<span class='boldnotice'>Your mind suddenly feels terribly vulnerable. You are no longer safe from brainwashing.</span>"
+		return 1
+	return 0
+
+
+/obj/item/weapon/implanter/mindshield
+	name = "implanter (mindshield)"
+
+/obj/item/weapon/implanter/mindshield/New()
+	imp = new /obj/item/weapon/implant/mindshield(src)
+	..()
+	update_icon()
+
+
+/obj/item/weapon/implantcase/mindshield
+	name = "implant case - 'Mindshield'"
+	desc = "A glass case containing a mindshield implant."
+
+/obj/item/weapon/implantcase/mindshield/New()
+	imp = new /obj/item/weapon/implant/mindshield(src)
+	..()

code/game/objects/items/weapons/implants/implant_misc.dm

@@ -0,0 +1,63 @@
+/obj/item/weapon/implant/weapons_auth
+	name = "firearms authentication implant"
+	desc = "Lets you shoot your guns"
+	icon_state = "auth"
+	origin_tech = "magnets=2;programming=7;biotech=5;syndicate=5"
+	activated = 0
+
+/obj/item/weapon/implant/weapons_auth/get_data()
+	var/dat = {"<b>Implant Specifications:</b><BR>
+				<b>Name:</b> Firearms Authentication Implant<BR>
+				<b>Life:</b> 4 hours after death of host<BR>
+				<b>Implant Details:</b> <BR>
+				<b>Function:</b> Allows operation of implant-locked weaponry, preventing equipment from falling into enemy hands."}
+	return dat
+
+
+/obj/item/weapon/implant/adrenalin
+	name = "adrenal implant"
+	desc = "Removes all stuns and knockdowns."
+	icon_state = "adrenal"
+	origin_tech = "materials=2;biotech=4;combat=3;syndicate=4"
+	uses = 3
+
+/obj/item/weapon/implant/adrenalin/get_data()
+	var/dat = {"<b>Implant Specifications:</b><BR>
+				<b>Name:</b> Cybersun Industries Adrenaline Implant<BR>
+				<b>Life:</b> Five days.<BR>
+				<b>Important Notes:</b> <font color='red'>Illegal</font><BR>
+				<HR>
+				<b>Implant Details:</b> Subjects injected with implant can activate an injection of medical cocktails.<BR>
+				<b>Function:</b> Removes stuns, increases speed, and has a mild healing effect.<BR>
+				<b>Integrity:</b> Implant can only be used three times before reserves are depleted."}
+	return dat
+
+/obj/item/weapon/implant/adrenalin/activate()
+	uses--
+	imp_in << "<span class='notice'>You feel a sudden surge of energy!</span>"
+	imp_in.SetStunned(0)
+	imp_in.SetWeakened(0)
+	imp_in.SetParalysis(0)
+	imp_in.adjustStaminaLoss(-75)
+	imp_in.lying = 0
+	imp_in.update_canmove()
+
+	imp_in.reagents.add_reagent("synaptizine", 10)
+	imp_in.reagents.add_reagent("omnizine", 10)
+	imp_in.reagents.add_reagent("stimulants", 10)
+	if(!uses)
+		qdel(src)
+
+
+/obj/item/weapon/implant/emp
+	name = "emp implant"
+	desc = "Triggers an EMP."
+	icon_state = "emp"
+	origin_tech = "biotech=3;magnets=4;syndicate=1"
+	uses = 3
+
+/obj/item/weapon/implant/emp/activate()
+	uses--
+	empulse(imp_in, 3, 5)
+	if(!uses)
+		qdel(src)

code/game/objects/items/weapons/implants/implant_storage.dm

@@ -0,0 +1,51 @@
+/obj/item/weapon/storage/internal/implant
+	name = "bluespace pocket"
+	max_w_class = 3
+	max_combined_w_class = 6
+	cant_hold = list(/obj/item/weapon/disk/nuclear)
+	silent = 1
+
+
+/obj/item/weapon/implant/storage
+	name = "storage implant"
+	desc = "Stores up to two big items in a bluespace pocket."
+	icon_state = "storage"
+	origin_tech = "materials=2;magnets=4;bluespace=5;syndicate=4"
+	item_color = "r"
+	var/obj/item/weapon/storage/internal/implant/storage
+
+/obj/item/weapon/implant/storage/New()
+	..()
+	storage = new /obj/item/weapon/storage/internal/implant(src)
+
+/obj/item/weapon/implant/storage/activate()
+	storage.MouseDrop(imp_in)
+
+/obj/item/weapon/implant/storage/removed(source)
+	if(..())
+		storage.close_all()
+		for(var/obj/item/I in storage)
+			storage.remove_from_storage(I, get_turf(source))
+		return 1
+
+/obj/item/weapon/implant/storage/implant(mob/source)
+	var/obj/item/weapon/implant/storage/imp_e = locate(src.type) in source
+	if(imp_e)
+		imp_e.storage.storage_slots += storage.storage_slots
+		imp_e.storage.max_combined_w_class += storage.max_combined_w_class
+		imp_e.storage.contents += storage.contents
+
+		storage.close_all()
+		storage.show_to(source)
+
+		qdel(src)
+		return 1
+
+	return ..()
+
+/obj/item/weapon/implanter/storage
+	name = "implanter (storage)"
+
+/obj/item/weapon/implanter/storage/New()
+	imp = new /obj/item/weapon/implant/storage(src)
+	..()

code/game/objects/items/weapons/implants/implant_track.dm

@@ -0,0 +1,37 @@
+/obj/item/weapon/implant/tracking
+	name = "tracking implant"
+	desc = "Track with this."
+	activated = 0
+	origin_tech = "materials=2;magnets=2;programming=2;biotech=2"
+
+
+/obj/item/weapon/implant/tracking/New()
+	..()
+	tracked_implants += src
+
+/obj/item/weapon/implant/tracking/Destroy()
+	..()
+	tracked_implants -= src
+
+/obj/item/weapon/implanter/tracking/New()
+	imp = new /obj/item/weapon/implant/tracking( src )
+	..()
+/obj/item/weapon/implanter/tracking/gps/New()
+	imp = new /obj/item/device/gps/mining/internal( src )
+	..()
+
+/obj/item/weapon/implant/tracking/get_data()
+	var/dat = {"<b>Implant Specifications:</b><BR>
+				<b>Name:</b> Tracking Beacon<BR>
+				<b>Life:</b> 10 minutes after death of host<BR>
+				<b>Important Notes:</b> None<BR>
+				<HR>
+				<b>Implant Details:</b> <BR>
+				<b>Function:</b> Continuously transmits low power signal. Useful for tracking.<BR>
+				<b>Special Features:</b><BR>
+				<i>Neuro-Safe</i>- Specialized shell absorbs excess voltages self-destructing the chip if
+				a malfunction occurs thereby securing safety of subject. The implant will melt and
+				disintegrate into bio-safe elements.<BR>
+				<b>Integrity:</b> Gradient creates slight risk of being overcharged and frying the
+				circuitry. As a result neurotoxins can cause massive damage."}
+	return dat

code/game/objects/items/weapons/implants/implantcase.dm

@@ -0,0 +1,88 @@
+/obj/item/weapon/implantcase
+	name = "implant case"
+	desc = "A glass case containing an implant."
+	icon = 'icons/obj/items.dmi'
+	icon_state = "implantcase-0"
+	item_state = "implantcase"
+	throw_speed = 2
+	throw_range = 5
+	w_class = 1
+	origin_tech = "materials=1;biotech=2"
+	materials = list(MAT_GLASS=500)
+	var/obj/item/weapon/implant/imp = null
+
+
+/obj/item/weapon/implantcase/update_icon()
+	if(imp)
+		icon_state = "implantcase-[imp.item_color]"
+		origin_tech = imp.origin_tech
+		reagents = imp.reagents
+	else
+		icon_state = "implantcase-0"
+		origin_tech = initial(origin_tech)
+		reagents = null
+
+
+/obj/item/weapon/implantcase/attackby(obj/item/weapon/W, mob/user, params)
+	if(istype(W, /obj/item/weapon/pen))
+		var/t = stripped_input(user, "What would you like the label to be?", name, null)
+		if(user.get_active_hand() != W)
+			return
+		if(!in_range(src, user) && loc != user)
+			return
+		if(t)
+			name = "implant case - '[t]'"
+		else
+			name = "implant case"
+	else if(istype(W, /obj/item/weapon/implanter))
+		var/obj/item/weapon/implanter/I = W
+		if(I.imp)
+			if(imp || I.imp.implanted)
+				return
+			I.imp.loc = src
+			imp = I.imp
+			I.imp = null
+			update_icon()
+			I.update_icon()
+		else
+			if(imp)
+				if(I.imp)
+					return
+				imp.loc = I
+				I.imp = imp
+				imp = null
+				update_icon()
+			I.update_icon()
+
+	else
+		return ..()
+
+/obj/item/weapon/implantcase/New()
+	..()
+	update_icon()
+
+
+/obj/item/weapon/implantcase/tracking
+	name = "implant case - 'Tracking'"
+	desc = "A glass case containing a tracking implant."
+
+/obj/item/weapon/implantcase/tracking/New()
+	imp = new /obj/item/weapon/implant/tracking(src)
+	..()
+
+
+/obj/item/weapon/implantcase/weapons_auth
+	name = "implant case - 'Firearms Authentication'"
+	desc = "A glass case containing a firearms authentication implant."
+
+/obj/item/weapon/implantcase/weapons_auth/New()
+	imp = new /obj/item/weapon/implant/weapons_auth(src)
+	..()
+
+/obj/item/weapon/implantcase/adrenaline
+	name = "implant case - 'Adrenaline'"
+	desc = "A glass case containing an adrenaline implant."
+
+/obj/item/weapon/implantcase/adrenaline/New()
+	imp = new /obj/item/weapon/implant/adrenalin(src)
+	..()

code/game/objects/items/weapons/implants/implantchair.dm

@@ -0,0 +1,147 @@
+//This file was auto-corrected by findeclaration.exe on 25.5.2012 20:42:32
+
+/obj/machinery/implantchair
+	name = "mindshield implanter"
+	desc = "Used to implant occupants with mindshield implants."
+	icon = 'icons/obj/machines/implantchair.dmi'
+	icon_state = "implantchair"
+	density = 1
+	opacity = 0
+	anchored = 1
+
+	var/ready = 1
+	var/malfunction = 0
+	var/list/obj/item/weapon/implant/mindshield/implant_list = list()
+	var/max_implants = 5
+	var/injection_cooldown = 600
+	var/replenish_cooldown = 6000
+	var/replenishing = 0
+	var/injecting = 0
+
+/obj/machinery/implantchair/proc
+	go_out()
+	put_mob(mob/living/carbon/M)
+	implant(var/mob/M)
+	add_implants()
+
+
+/obj/machinery/implantchair/New()
+	..()
+	add_implants()
+
+
+/obj/machinery/implantchair/attack_hand(mob/user)
+	user.set_machine(src)
+	var/health_text = ""
+	if(src.occupant)
+		if(src.occupant.health <= -100)
+			health_text = "<FONT color=red>Dead</FONT>"
+		else if(src.occupant.health < 0)
+			health_text = "<FONT color=red>[round(src.occupant.health,0.1)]</FONT>"
+		else
+			health_text = "[round(src.occupant.health,0.1)]"
+
+	var/dat ="<B>Implanter Status</B><BR>"
+
+	dat +="<B>Current occupant:</B> [src.occupant ? "<BR>Name: [src.occupant]<BR>Health: [health_text]<BR>" : "<FONT color=red>None</FONT>"]<BR>"
+	dat += "<B>Implants:</B> [src.implant_list.len ? "[implant_list.len]" : "<A href='?src=\ref[src];replenish=1'>Replenish</A>"]<BR>"
+	if(src.occupant)
+		dat += "[src.ready ? "<A href='?src=\ref[src];implant=1'>Implant</A>" : "Recharging"]<BR>"
+	user.set_machine(src)
+	user << browse(dat, "window=implant")
+	onclose(user, "implant")
+
+
+/obj/machinery/implantchair/Topic(href, href_list)
+	if(..())
+		return
+	if(href_list["implant"])
+		if(src.occupant)
+			injecting = 1
+			go_out()
+			ready = 0
+			spawn(injection_cooldown)
+				ready = 1
+
+	if(href_list["replenish"])
+		ready = 0
+		spawn(replenish_cooldown)
+			add_implants()
+			ready = 1
+
+	updateUsrDialog()
+
+
+/obj/machinery/implantchair/go_out(mob/M)
+	if(!occupant)
+		return
+	if(M == occupant) // so that the guy inside can't eject himself -Agouri
+		return
+	occupant.loc = loc
+	occupant.reset_perspective(null)
+	if(injecting)
+		implant(src.occupant)
+		injecting = 0
+	occupant = null
+	icon_state = "implantchair"
+	return
+
+
+/obj/machinery/implantchair/put_mob(mob/living/carbon/M)
+	if(!iscarbon(M))
+		usr << "<span class='warning'>The [src.name] cannot hold this!</span>"
+		return
+	if(src.occupant)
+		usr << "<span class='warning'>The [src.name] is already occupied!</span>"
+		return
+	M.stop_pulling()
+	M.loc = src
+	M.reset_perspective(src)
+	src.occupant = M
+	src.add_fingerprint(usr)
+	icon_state = "implantchair_on"
+	return 1
+
+
+/obj/machinery/implantchair/implant(mob/M)
+	if (!istype(M, /mob/living/carbon))
+		return
+	if(!implant_list.len)
+		return
+	for(var/obj/item/weapon/implant/mindshield/imp in implant_list)
+		if(!imp)
+			continue
+		if(istype(imp, /obj/item/weapon/implant/mindshield))
+			M.visible_message("<span class='warning'>[M] has been implanted by the [src.name].</span>")
+
+			if(imp.implant(M))
+				implant_list -= imp
+			break
+	return
+
+
+/obj/machinery/implantchair/add_implants()
+	for(var/i=0, i<src.max_implants, i++)
+		var/obj/item/weapon/implant/mindshield/I = new /obj/item/weapon/implant/mindshield(src)
+		implant_list += I
+	return
+
+/obj/machinery/implantchair/verb/get_out()
+	set name = "Eject occupant"
+	set category = "Object"
+	set src in oview(1)
+	if(usr.stat != 0)
+		return
+	src.go_out(usr)
+	add_fingerprint(usr)
+	return
+
+
+/obj/machinery/implantchair/verb/move_inside()
+	set name = "Move Inside"
+	set category = "Object"
+	set src in oview(1)
+	if(usr.stat != 0 || stat & (NOPOWER|BROKEN))
+		return
+	put_mob(usr)
+	return

code/game/objects/items/weapons/implants/implanter.dm

@@ -0,0 +1,77 @@
+/obj/item/weapon/implanter
+	name = "implanter"
+	desc = "A sterile automatic implant injector."
+	icon = 'icons/obj/items.dmi'
+	icon_state = "implanter0"
+	item_state = "syringe_0"
+	throw_speed = 3
+	throw_range = 5
+	w_class = 2
+	origin_tech = "materials=2;biotech=3"
+	materials = list(MAT_METAL=600, MAT_GLASS=200)
+	var/obj/item/weapon/implant/imp = null
+
+
+/obj/item/weapon/implanter/update_icon()
+	if(imp)
+		icon_state = "implanter1"
+		origin_tech = imp.origin_tech
+	else
+		icon_state = "implanter0"
+		origin_tech = initial(origin_tech)
+
+
+/obj/item/weapon/implanter/attack(mob/living/carbon/M, mob/user)
+	if(!iscarbon(M))
+		return
+	if(user && imp)
+		if(M != user)
+			M.visible_message("<span class='warning'>[user] is attemping to implant [M].</span>")
+
+		var/turf/T = get_turf(M)
+		if(T && (M == user || do_after(user, 50)))
+			if(user && M && (get_turf(M) == T) && src && imp)
+				if(imp.implant(M, user))
+					if (M == user)
+						user << "<span class='notice'>You implant yourself.</span>"
+					else
+						M.visible_message("[user] has implanted [M].", "<span class='notice'>[user] implants you.</span>")
+					imp = null
+					update_icon()
+
+/obj/item/weapon/implanter/attackby(obj/item/weapon/W, mob/user, params)
+	if(istype(W, /obj/item/weapon/pen))
+		var/t = stripped_input(user, "What would you like the label to be?", name, null)
+		if(user.get_active_hand() != W)
+			return
+		if(!in_range(src, user) && loc != user)
+			return
+		if(t)
+			name = "implanter ([t])"
+		else
+			name = "implanter"
+	else
+		return ..()
+
+/obj/item/weapon/implanter/New()
+	..()
+	spawn(1)
+		update_icon()
+
+
+
+
+/obj/item/weapon/implanter/adrenalin
+	name = "implanter (adrenalin)"
+
+/obj/item/weapon/implanter/adrenalin/New()
+	imp = new /obj/item/weapon/implant/adrenalin(src)
+	..()
+
+
+/obj/item/weapon/implanter/emp
+	name = "implanter (EMP)"
+
+/obj/item/weapon/implanter/emp/New()
+	imp = new /obj/item/weapon/implant/emp(src)
+	..()

code/game/objects/items/weapons/implants/implantpad.dm

@@ -0,0 +1,76 @@
+/obj/item/weapon/implantpad
+	name = "implantpad"
+	desc = "Used to modify implants."
+	icon = 'icons/obj/items.dmi'
+	icon_state = "implantpad-0"
+	item_state = "electronic"
+	throw_speed = 3
+	throw_range = 5
+	w_class = 2
+	var/obj/item/weapon/implantcase/case = null
+	var/broadcasting = null
+	var/listening = 1
+
+
+/obj/item/weapon/implantpad/update_icon()
+	if(case)
+		icon_state = "implantpad-1"
+	else
+		icon_state = "implantpad-0"
+
+
+/obj/item/weapon/implantpad/attack_hand(mob/user)
+	if(case && (user.l_hand == src || user.r_hand == src))
+		user.put_in_active_hand(case)
+
+		case.add_fingerprint(user)
+		case = null
+
+		add_fingerprint(user)
+		update_icon()
+	else
+		return ..()
+
+
+/obj/item/weapon/implantpad/attackby(obj/item/weapon/implantcase/C, mob/user, params)
+	if(istype(C, /obj/item/weapon/implantcase))
+		if(!case)
+			if(!user.unEquip(C))
+				return
+			C.loc = src
+			case = C
+		update_icon()
+	else
+		return ..()
+
+/obj/item/weapon/implantpad/attack_self(mob/user)
+	user.set_machine(src)
+	var/dat = "<B>Implant Mini-Computer:</B><HR>"
+	if(case)
+		if(case.imp)
+			if(istype(case.imp, /obj/item/weapon/implant))
+				dat += case.imp.get_data()
+		else
+			dat += "The implant casing is empty."
+	else
+		dat += "Please insert an implant casing!"
+	user << browse(dat, "window=implantpad")
+	onclose(user, "implantpad")
+
+
+/obj/item/weapon/implantpad/Topic(href, href_list)
+	..()
+	if(usr.stat)
+		return
+	if((usr.contents.Find(src)) || ((in_range(src, usr) && istype(loc, /turf))))
+		usr.set_machine(src)
+
+		if(istype(loc, /mob))
+			attack_self(loc)
+		else
+			for(var/mob/M in viewers(1, src))
+				if(M.client)
+					attack_self(M)
+		add_fingerprint(usr)
+	else
+		usr << browse(null, "window=implantpad")

code/game/objects/items/weapons/implants/implantuplink.dm

@@ -0,0 +1,34 @@
+/obj/item/weapon/implant/uplink
+	name = "uplink implant"
+	desc = "Sneeki breeki."
+	icon = 'icons/obj/radio.dmi'
+	icon_state = "radio"
+	origin_tech = "materials=4;magnets=4;programming=4;biotech=4;syndicate=5;bluespace=5"
+
+/obj/item/weapon/implant/uplink/New()
+	hidden_uplink = new(src)
+	hidden_uplink.telecrystals = 10
+	..()
+
+/obj/item/weapon/implant/uplink/implant(mob/user)
+	var/obj/item/weapon/implant/imp_e = locate(src.type) in user
+	if(imp_e && imp_e != src)
+		imp_e.hidden_uplink.telecrystals += hidden_uplink.telecrystals
+		qdel(src)
+		return 1
+
+	if(..())
+		hidden_uplink.owner = "[user.key]"
+		return 1
+	return 0
+
+/obj/item/weapon/implant/uplink/activate()
+	if(hidden_uplink)
+		hidden_uplink.interact(usr)
+
+/obj/item/weapon/implanter/uplink
+	name = "implanter (uplink)"
+
+/obj/item/weapon/implanter/uplink/New()
+	imp = new /obj/item/weapon/implant/uplink(src)
+	..()