initial commit - cross reference with 5th port - obviously has compile errors

code/modules/assembly/assembly.dm

@@ -0,0 +1,131 @@
+/obj/item/device/assembly
+	name = "assembly"
+	desc = "A small electronic device that should never exist."
+	icon = 'icons/obj/assemblies/new_assemblies.dmi'
+	icon_state = ""
+	flags = CONDUCT
+	w_class = 2
+	materials = list(MAT_METAL=100)
+	throwforce = 2
+	throw_speed = 3
+	throw_range = 7
+	origin_tech = "magnets=1;engineering=1"
+
+	var/secured = 1
+	var/list/attached_overlays = null
+	var/obj/item/device/assembly_holder/holder = null
+	var/cooldown = 0//To prevent spam
+	var/wire_type = WIRE_RECEIVE | WIRE_PULSE
+	var/attachable = 0 // can this be attached to wires
+	var/datum/wires/connected = null
+
+	var/const/WIRE_RECEIVE = 1			//Allows Pulsed(0) to call Activate()
+	var/const/WIRE_PULSE = 2				//Allows Pulse(0) to act on the holder
+	var/const/WIRE_PULSE_SPECIAL = 4		//Allows Pulse(0) to act on the holders special assembly
+	var/const/WIRE_RADIO_RECEIVE = 8		//Allows Pulsed(1) to call Activate()
+	var/const/WIRE_RADIO_PULSE = 16		//Allows Pulse(1) to send a radio message
+
+/obj/item/device/assembly/proc/on_attach()
+
+/obj/item/device/assembly/proc/on_detach()
+
+/obj/item/device/assembly/proc/holder_movement()							//Called when the holder is moved
+	return
+
+/obj/item/device/assembly/proc/describe()									// Called by grenades to describe the state of the trigger (time left, etc)
+	return "The trigger assembly looks broken!"
+
+
+/obj/item/device/assembly/proc/is_secured(mob/user)
+	if(!secured)
+		user << "<span class='warning'>The [name] is unsecured!</span>"
+		return 0
+	return 1
+
+
+//Called via spawn(10) to have it count down the cooldown var
+/obj/item/device/assembly/proc/process_cooldown()
+	cooldown--
+	if(cooldown <= 0)
+		return 0
+	spawn(10)
+		process_cooldown()
+	return 1
+
+
+//Called when another assembly acts on this one, var/radio will determine where it came from for wire calcs
+/obj/item/device/assembly/proc/pulsed(radio = 0)
+	if(wire_type & WIRE_RECEIVE)
+		spawn(0)
+			activate()
+	if(radio && (wire_type & WIRE_RADIO_RECEIVE))
+		spawn(0)
+			activate()
+	return 1
+
+
+//Called when this device attempts to act on another device, var/radio determines if it was sent via radio or direct
+/obj/item/device/assembly/proc/pulse(radio = 0)
+	if(connected && wire_type)
+		connected.pulse_assembly(src)
+		return 1
+	if(holder && (wire_type & WIRE_PULSE))
+		holder.process_activation(src, 1, 0)
+	if(holder && (wire_type & WIRE_PULSE_SPECIAL))
+		holder.process_activation(src, 0, 1)
+	return 1
+
+
+// What the device does when turned on
+/obj/item/device/assembly/proc/activate()
+	if(!secured || (cooldown > 0))
+		return 0
+	cooldown = 2
+	spawn(10)
+		process_cooldown()
+	return 1
+
+
+/obj/item/device/assembly/proc/toggle_secure()
+	secured = !secured
+	update_icon()
+	return secured
+
+
+/obj/item/device/assembly/attackby(obj/item/weapon/W, mob/user, params)
+	if(isassembly(W))
+		var/obj/item/device/assembly/A = W
+		if((!A.secured) && (!secured))
+			holder = new/obj/item/device/assembly_holder(get_turf(src))
+			holder.assemble(src,A,user)
+			user << "<span class='notice'>You attach and secure \the [A] to \the [src]!</span>"
+		else
+			user << "<span class='warning'>Both devices must be in attachable mode to be attached together.</span>"
+		return
+	if(istype(W, /obj/item/weapon/screwdriver))
+		if(toggle_secure())
+			user << "<span class='notice'>\The [src] is ready!</span>"
+		else
+			user << "<span class='notice'>\The [src] can now be attached!</span>"
+		return
+	..()
+
+
+/obj/item/device/assembly/examine(mob/user)
+	..()
+	if(secured)
+		user << "\The [src] is secured and ready to be used."
+	else
+		user << "\The [src] can be attached to other things."
+
+
+/obj/item/device/assembly/attack_self(mob/user)
+	if(!user)
+		return 0
+	user.set_machine(src)
+	interact(user)
+	return 1
+
+/obj/item/device/assembly/interact(mob/user)
+	return //HTML MENU FOR WIRES GOES HERE
+

code/modules/assembly/bomb.dm

@@ -0,0 +1,165 @@
+/obj/item/device/onetankbomb
+	name = "bomb"
+	icon = 'icons/obj/tank.dmi'
+	item_state = "assembly"
+	throwforce = 5
+	w_class = 3
+	throw_speed = 2
+	throw_range = 4
+	flags = CONDUCT
+	var/status = 0   //0 - not readied //1 - bomb finished with welder
+	var/obj/item/device/assembly_holder/bombassembly = null   //The first part of the bomb is an assembly holder, holding an igniter+some device
+	var/obj/item/weapon/tank/bombtank = null //the second part of the bomb is a plasma tank
+	origin_tech = "materials=1;engineering=1"
+
+/obj/item/device/onetankbomb/examine(mob/user)
+	..()
+	user.examinate(bombtank)
+
+/obj/item/device/onetankbomb/update_icon()
+	if(bombtank)
+		icon_state = bombtank.icon_state
+	if(bombassembly)
+		add_overlay(bombassembly.icon_state)
+		add_overlay(bombassembly.overlays)
+		add_overlay("bomb_assembly")
+
+/obj/item/device/onetankbomb/attackby(obj/item/weapon/W, mob/user, params)
+	if(istype(W, /obj/item/device/analyzer))
+		bombtank.attackby(W, user)
+		return
+	if(istype(W, /obj/item/weapon/wrench) && !status)	//This is basically bomb assembly code inverted. apparently it works.
+
+		user << "<span class='notice'>You disassemble [src].</span>"
+
+		bombassembly.loc = user.loc
+		bombassembly.master = null
+		bombassembly = null
+
+		bombtank.loc = user.loc
+		bombtank.master = null
+		bombtank = null
+
+		qdel(src)
+		return
+	if((istype(W, /obj/item/weapon/weldingtool) && W:welding))
+		if(!status)
+			status = 1
+			bombers += "[key_name(user)] welded a single tank bomb. Temp: [bombtank.air_contents.temperature-T0C]"
+			message_admins("[key_name_admin(user)] welded a single tank bomb. Temp: [bombtank.air_contents.temperature-T0C]")
+			user << "<span class='notice'>A pressure hole has been bored to [bombtank] valve. \The [bombtank] can now be ignited.</span>"
+		else
+			status = 0
+			bombers += "[key_name(user)] unwelded a single tank bomb. Temp: [bombtank.air_contents.temperature-T0C]"
+			user << "<span class='notice'>The hole has been closed.</span>"
+	add_fingerprint(user)
+	..()
+
+/obj/item/device/onetankbomb/attack_self(mob/user) //pressing the bomb accesses its assembly
+	bombassembly.attack_self(user, 1)
+	add_fingerprint(user)
+	return
+
+/obj/item/device/onetankbomb/receive_signal()	//This is mainly called by the sensor through sense() to the holder, and from the holder to here.
+	visible_message("\icon[src] *beep* *beep*", "*beep* *beep*")
+	sleep(10)
+	if(!src)
+		return
+	if(status)
+		bombtank.ignite()	//if its not a dud, boom (or not boom if you made shitty mix) the ignite proc is below, in this file
+	else
+		bombtank.release()
+
+/obj/item/device/onetankbomb/Crossed(atom/movable/AM as mob|obj) //for mousetraps
+	if(bombassembly)
+		bombassembly.Crossed(AM)
+
+/obj/item/device/onetankbomb/on_found(mob/finder) //for mousetraps
+	if(bombassembly)
+		bombassembly.on_found(finder)
+
+
+// ---------- Procs below are for tanks that are used exclusively in 1-tank bombs ----------
+
+/obj/item/weapon/tank/proc/bomb_assemble(W,user)	//Bomb assembly proc. This turns assembly+tank into a bomb
+	var/obj/item/device/assembly_holder/S = W
+	var/mob/M = user
+	if(isigniter(S.a_left) == isigniter(S.a_right))		//Check if either part of the assembly has an igniter, but if both parts are igniters, then fuck it
+		return
+	if(!M.drop_item())			//Remove the assembly from your hands
+		return
+
+	var/obj/item/device/onetankbomb/R = new /obj/item/device/onetankbomb(loc)
+
+	M.remove_from_mob(src)	//Remove the tank from your character,in case you were holding it
+	M.put_in_hands(R)		//Equips the bomb if possible, or puts it on the floor.
+
+	R.bombassembly = S	//Tell the bomb about its assembly part
+	S.master = R		//Tell the assembly about its new owner
+	S.loc = R			//Move the assembly out of the fucking way
+
+	R.bombtank = src	//Same for tank
+	master = R
+	loc = R
+	R.update_icon()
+	return
+
+/obj/item/weapon/tank/proc/ignite()	//This happens when a bomb is told to explode
+	air_contents.assert_gases("plasma", "o2")
+	var/fuel_moles = air_contents.gases["plasma"][MOLES] + air_contents.gases["o2"][MOLES]/6
+	air_contents.garbage_collect()
+
+	var/strength = 1
+
+	var/turf/ground_zero = get_turf(loc)
+	loc = null
+
+	if(air_contents.temperature > (T0C + 400))
+		strength = (fuel_moles/15)
+
+		if(strength >=1)
+			explosion(ground_zero, round(strength,1), round(strength*2,1), round(strength*3,1), round(strength*4,1))
+		else if(strength >=0.5)
+			explosion(ground_zero, 0, 1, 2, 4)
+		else if(strength >=0.2)
+			explosion(ground_zero, -1, 0, 1, 2)
+		else
+			ground_zero.assume_air(air_contents)
+			ground_zero.hotspot_expose(1000, 125)
+
+	else if(air_contents.temperature > (T0C + 250))
+		strength = (fuel_moles/20)
+
+		if(strength >=1)
+			explosion(ground_zero, 0, round(strength,1), round(strength*2,1), round(strength*3,1))
+		else if (strength >=0.5)
+			explosion(ground_zero, -1, 0, 1, 2)
+		else
+			ground_zero.assume_air(air_contents)
+			ground_zero.hotspot_expose(1000, 125)
+
+	else if(air_contents.temperature > (T0C + 100))
+		strength = (fuel_moles/25)
+
+		if (strength >=1)
+			explosion(ground_zero, -1, 0, round(strength,1), round(strength*3,1))
+		else
+			ground_zero.assume_air(air_contents)
+			ground_zero.hotspot_expose(1000, 125)
+
+	else
+		ground_zero.assume_air(air_contents)
+		ground_zero.hotspot_expose(1000, 125)
+
+	air_update_turf()
+	if(master)
+		qdel(master)
+	qdel(src)
+
+/obj/item/weapon/tank/proc/release()	//This happens when the bomb is not welded. Tank contents are just spat out.
+	var/datum/gas_mixture/removed = air_contents.remove(air_contents.total_moles())
+	var/turf/T = get_turf(src)
+	if(!T)
+		return
+	T.assume_air(removed)
+	air_update_turf()

code/modules/assembly/doorcontrol.dm

@@ -0,0 +1,150 @@
+/obj/item/device/assembly/control
+	name = "blast door controller"
+	desc = "A small electronic device able to control a blast door remotely."
+	icon_state = "control"
+	origin_tech = "magnets=1;programming=2"
+	attachable = 1
+	var/id = null
+	var/can_change_id = 0
+
+/obj/item/device/assembly/control/examine(mob/user)
+	..()
+	if(id)
+		user << "<span class='notice'>Its channel ID is '[id]'.</span>"
+
+
+/obj/item/device/assembly/control/activate()
+	cooldown = 1
+	var/openclose
+	for(var/obj/machinery/door/poddoor/M in machines)
+		if(M.id == src.id)
+			if(openclose == null)
+				openclose = M.density
+			spawn(0)
+				if(M)
+					if(openclose)
+						M.open()
+					else
+						M.close()
+				return
+	sleep(10)
+	cooldown = 0
+
+
+/obj/item/device/assembly/control/airlock
+	name = "airlock controller"
+	desc = "A small electronic device able to control an airlock remotely."
+	id = "badmin" // Set it to null for MEGAFUN.
+	var/specialfunctions = OPEN
+	/*
+	Bitflag, 	1= open (OPEN)
+				2= idscan (IDSCAN)
+				4= bolts (BOLTS)
+				8= shock (SHOCK)
+				16= door safties (SAFE)
+	*/
+
+/obj/item/device/assembly/control/airlock/activate()
+	cooldown = 1
+	for(var/obj/machinery/door/airlock/D in airlocks)
+		if(D.id_tag == src.id)
+			if(specialfunctions & OPEN)
+				if(D.density)
+					D.open()
+				else
+					D.close()
+			if(specialfunctions & IDSCAN)
+				D.aiDisabledIdScanner = !D.aiDisabledIdScanner
+			if(specialfunctions & BOLTS)
+				if(!D.wires.is_cut(WIRE_BOLTS) && D.hasPower())
+					D.locked = !D.locked
+					D.update_icon()
+			if(specialfunctions & SHOCK)
+				if(D.secondsElectrified)
+					D.secondsElectrified = -1
+					D.shockedby += "\[[time_stamp()]\][usr](ckey:[usr.ckey])"
+					add_logs(usr, D, "electrified")
+				else
+					D.secondsElectrified = 0
+			if(specialfunctions & SAFE)
+				D.safe = !D.safe
+	sleep(10)
+	cooldown = 0
+
+
+/obj/item/device/assembly/control/massdriver
+	name = "mass driver controller"
+	desc = "A small electronic device able to control a mass driver."
+
+/obj/item/device/assembly/control/massdriver/activate()
+	cooldown = 1
+	for(var/obj/machinery/door/poddoor/M in machines)
+		if (M.id == src.id)
+			spawn( 0 )
+				M.open()
+
+	sleep(10)
+
+	for(var/obj/machinery/mass_driver/M in machines)
+		if(M.id == src.id)
+			M.drive()
+
+	sleep(60)
+
+	for(var/obj/machinery/door/poddoor/M in machines)
+		if (M.id == src.id)
+			spawn( 0 )
+				M.close()
+
+	sleep(10)
+	cooldown = 0
+
+
+/obj/item/device/assembly/control/igniter
+	name = "ignition controller"
+	desc = "A remote controller for a mounted igniter."
+
+/obj/item/device/assembly/control/igniter/activate()
+	cooldown = 1
+	for(var/obj/machinery/sparker/M in machines)
+		if (M.id == src.id)
+			spawn( 0 )
+				M.ignite()
+
+	for(var/obj/machinery/igniter/M in machines)
+		if(M.id == src.id)
+			M.use_power(50)
+			M.on = !M.on
+			M.icon_state = "igniter[M.on]"
+
+	sleep(30)
+	cooldown = 0
+
+
+/obj/item/device/assembly/control/flasher
+	name = "flasher controller"
+	desc = "A remote controller for a mounted flasher."
+
+/obj/item/device/assembly/control/flasher/activate()
+	cooldown = 1
+	for(var/obj/machinery/flasher/M in machines)
+		if(M.id == src.id)
+			spawn(0)
+				M.flash()
+
+	sleep(50)
+	cooldown = 0
+
+
+/obj/item/device/assembly/control/crematorium
+	name = "crematorium controller"
+	desc = "An evil-looking remote controller for a crematorium."
+
+/obj/item/device/assembly/control/crematorium/activate()
+	cooldown = 1
+	for (var/obj/structure/bodycontainer/crematorium/C in crematoriums)
+		if (C.id == id)
+			C.cremate(usr)
+
+	sleep(50)
+	cooldown = 0

code/modules/assembly/flash.dm

@@ -0,0 +1,203 @@
+/obj/item/device/assembly/flash
+	name = "flash"
+	desc = "A powerful and versatile flashbulb device, with applications ranging from disorienting attackers to acting as visual receptors in robot production."
+	icon_state = "flash"
+	item_state = "flashtool"
+	throwforce = 0
+	w_class = 1
+	materials = list(MAT_METAL = 300, MAT_GLASS = 300)
+	origin_tech = "magnets=2;combat=1"
+
+	crit_fail = 0     //Is the flash burnt out?
+	var/times_used = 0 //Number of times it's been used.
+	var/last_used = 0 //last world.time it was used.
+
+
+/obj/item/device/assembly/flash/update_icon(var/flash = 0)
+	cut_overlays()
+	attached_overlays = list()
+	if(crit_fail)
+		add_overlay("flashburnt")
+		attached_overlays += "flashburnt"
+
+	if(flash)
+		add_overlay("flash-f")
+		attached_overlays += "flash-f"
+		spawn(5)
+			update_icon()
+	if(holder)
+		holder.update_icon()
+
+/obj/item/device/assembly/flash/proc/clown_check(mob/living/carbon/human/user)
+	if(user.disabilities & CLUMSY && prob(50))
+		flash_carbon(user, user, 15, 0)
+		return 0
+	return 1
+
+/obj/item/device/assembly/flash/activate()
+	if(!try_use_flash())
+		return 0
+	var/turf/T = get_turf(src)
+	T.visible_message("<span class='disarm'>[src] emits a blinding light!</span>")
+	for(var/mob/living/carbon/M in viewers(3, T))
+		flash_carbon(M, null, 5, 0)
+
+
+/obj/item/device/assembly/flash/proc/burn_out() //Made so you can override it if you want to have an invincible flash from R&D or something.
+	if(!crit_fail)
+		crit_fail = 1
+		update_icon()
+		var/turf/T = get_turf(src)
+		T.visible_message("The [src.name] burns out!")
+
+
+/obj/item/device/assembly/flash/proc/flash_recharge(interval=10)
+	if(prob(times_used * 3)) //The more often it's used in a short span of time the more likely it will burn out
+		burn_out()
+		return 0
+
+	var/deciseconds_passed = world.time - last_used
+	for(var/seconds = deciseconds_passed/10, seconds>=interval, seconds-=interval) //get 1 charge every interval
+		times_used--
+
+	last_used = world.time
+	times_used = max(0, times_used) //sanity
+	return 1
+
+/obj/item/device/assembly/flash/proc/try_use_flash(mob/user = null)
+	flash_recharge(10)
+
+	if(crit_fail)
+		return 0
+
+	playsound(src.loc, 'sound/weapons/flash.ogg', 100, 1)
+	update_icon(1)
+	times_used++
+
+	if(user && !clown_check(user))
+		return 0
+
+	return 1
+
+
+/obj/item/device/assembly/flash/proc/flash_carbon(mob/living/carbon/M, mob/user = null, power = 15, targeted = 1)
+	add_logs(user, M, "flashed", src)
+	if(user && targeted)
+		if(M.weakeyes)
+			M.Weaken(3) //quick weaken bypasses eye protection but has no eye flash
+		if(M.flash_eyes(1, 1))
+			M.confused += power
+			terrible_conversion_proc(M, user)
+			M.Stun(1)
+			visible_message("<span class='disarm'>[user] blinds [M] with the flash!</span>")
+			user << "<span class='danger'>You blind [M] with the flash!</span>"
+			M << "<span class='userdanger'>[user] blinds you with the flash!</span>"
+			if(M.weakeyes)
+				M.Stun(2)
+				M.visible_message("<span class='disarm'>[M] gasps and shields their eyes!</span>", "<span class='userdanger'>You gasp and shield your eyes!</span>")
+		else
+			visible_message("<span class='disarm'>[user] fails to blind [M] with the flash!</span>")
+			user << "<span class='warning'>You fail to blind [M] with the flash!</span>"
+			M << "<span class='danger'>[user] fails to blind you with the flash!</span>"
+	else
+		if(M.flash_eyes())
+			M.confused += power
+
+/obj/item/device/assembly/flash/attack(mob/living/M, mob/user)
+	if(!try_use_flash(user))
+		return 0
+
+	if(iscarbon(M))
+		flash_carbon(M, user, 5, 1)
+		return 1
+
+	else if(issilicon(M))
+		var/mob/living/silicon/robot/R = M
+		add_logs(user, R, "flashed", src)
+		update_icon(1)
+		M.Weaken(3)
+		R.confused += 5
+		R.flash_eyes(affect_silicon = 1)
+		user.visible_message("<span class='disarm'>[user] overloads [R]'s sensors with the flash!</span>", "<span class='danger'>You overload [R]'s sensors with the flash!</span>")
+		return 1
+
+	user.visible_message("<span class='disarm'>[user] fails to blind [M] with the flash!</span>", "<span class='warning'>You fail to blind [M] with the flash!</span>")
+
+
+/obj/item/device/assembly/flash/attack_self(mob/living/carbon/user, flag = 0, emp = 0)
+	if(holder)
+		return 0
+	if(!try_use_flash(user))
+		return 0
+	user.visible_message("<span class='disarm'>[user]'s flash emits a blinding light!</span>", "<span class='danger'>Your flash emits a blinding light!</span>")
+	for(var/mob/living/carbon/M in oviewers(3, null))
+		flash_carbon(M, user, 1, 0)
+
+
+/obj/item/device/assembly/flash/emp_act(severity)
+	if(!try_use_flash() || !loc)
+		return 0
+	for(var/mob/living/carbon/M in viewers(3, loc))
+		flash_carbon(M, null, 10, 0)
+	burn_out()
+	..()
+
+
+/obj/item/device/assembly/flash/proc/terrible_conversion_proc(mob/M, mob/user)
+	if(ishuman(M) && ishuman(user) && M.stat != DEAD)
+		if(user.mind && (user.mind in ticker.mode.head_revolutionaries))
+			if(M.client)
+				if(M.stat == CONSCIOUS)
+					M.mind_initialize() //give them a mind datum if they don't have one.
+					var/resisted
+					if(!isloyal(M))
+						if(user.mind in ticker.mode.head_revolutionaries)
+							if(ticker.mode.add_revolutionary(M.mind))
+								M.Stun(3)
+								times_used -- //Flashes less likely to burn out for headrevs when used for conversion
+							else
+								resisted = 1
+					else
+						resisted = 1
+
+					if(resisted)
+						user << "<span class='warning'>This mind seems resistant to the flash!</span>"
+				else
+					user << "<span class='warning'>They must be conscious before you can convert them!</span>"
+			else
+				user << "<span class='warning'>This mind is so vacant that it is not susceptible to influence!</span>"
+
+
+/obj/item/device/assembly/flash/cyborg
+	origin_tech = null
+
+/obj/item/device/assembly/flash/cyborg/attack(mob/living/M, mob/user)
+	..()
+	cyborg_flash_animation(user)
+
+/obj/item/device/assembly/flash/cyborg/attack_self(mob/user)
+	..()
+	cyborg_flash_animation(user)
+
+/obj/item/device/assembly/flash/cyborg/attackby(obj/item/weapon/W, mob/user, params)
+	return
+
+/obj/item/device/assembly/flash/cyborg/proc/cyborg_flash_animation(mob/living/user)
+	var/atom/movable/overlay/animation = new(user.loc)
+	animation.layer = user.layer + 1
+	animation.icon_state = "blank"
+	animation.icon = 'icons/mob/mob.dmi'
+	animation.master = user
+	flick("blspell", animation)
+	sleep(5)
+	qdel(animation)
+
+
+/obj/item/device/assembly/flash/memorizer
+	name = "memorizer"
+	desc = "If you see this, you're not likely to remember it any time soon."
+	icon = 'icons/obj/device.dmi'
+	icon_state = "memorizer"
+	item_state = "nullrod"
+
+/obj/item/device/assembly/flash/handheld //this is now the regular pocket flashes

code/modules/assembly/health.dm

@@ -0,0 +1,107 @@
+/obj/item/device/assembly/health
+	name = "health sensor"
+	desc = "Used for scanning and monitoring health."
+	icon_state = "health"
+	materials = list(MAT_METAL=800, MAT_GLASS=200)
+	origin_tech = "magnets=1;biotech=1"
+	attachable = 1
+	secured = 0
+
+	var/scanning = 0
+	var/health_scan
+	var/alarm_health = 0
+
+
+
+/obj/item/device/assembly/health/activate()
+	if(!..())
+		return 0//Cooldown check
+	toggle_scan()
+	return 0
+
+/obj/item/device/assembly/health/toggle_secure()
+	secured = !secured
+	if(secured && scanning)
+		START_PROCESSING(SSobj, src)
+	else
+		scanning = 0
+		STOP_PROCESSING(SSobj, src)
+	update_icon()
+	return secured
+
+/obj/item/device/assembly/health/attackby(obj/item/weapon/W as obj, mob/user as mob)
+	if(istype(W, /obj/item/device/multitool))
+		if(alarm_health == 0)
+			alarm_health = -90
+			user.show_message("You toggle [src] to \"detect death\" mode.")
+		else
+			alarm_health = 0
+			user.show_message("You toggle [src] to \"detect critical state\" mode.")
+		return
+	else
+		return ..()
+
+/obj/item/device/assembly/health/process()
+	if(!scanning || !secured)
+		return
+
+	var/atom/A = src
+	if(connected && connected.holder)
+		A = connected.holder
+
+	for(A, A && !ismob(A), A=A.loc);
+	// like get_turf(), but for mobs.
+	var/mob/living/M = A
+
+	if(M)
+		health_scan = M.health
+		if(health_scan <= alarm_health)
+			pulse()
+			audible_message("\icon[src] *beep* *beep*", "*beep* *beep*")
+			toggle_scan()
+		return
+	return
+
+/obj/item/device/assembly/health/proc/toggle_scan()
+	if(!secured)
+		return 0
+	scanning = !scanning
+	if(scanning)
+		START_PROCESSING(SSobj, src)
+	else
+		STOP_PROCESSING(SSobj, src)
+	return
+
+/obj/item/device/assembly/health/interact(mob/user as mob)//TODO: Change this to the wires thingy
+	if(!secured)
+		user.show_message("<span class='warning'>The [name] is unsecured!</span>")
+		return 0
+	var/dat = "<TT><B>Health Sensor</B> <A href='?src=\ref[src];scanning=1'>[scanning?"On":"Off"]</A>"
+	if(scanning && health_scan)
+		dat += "<BR>Health: [health_scan]"
+	user << browse(dat, "window=hscan")
+	onclose(user, "hscan")
+	return
+
+
+/obj/item/device/assembly/health/Topic(href, href_list)
+	..()
+	if(!ismob(usr))
+		return
+
+	var/mob/user = usr
+
+	if(!user.canUseTopic(src))
+		usr << browse(null, "window=hscan")
+		onclose(usr, "hscan")
+		return
+
+	if(href_list["scanning"])
+		toggle_scan()
+
+	if(href_list["close"])
+		usr << browse(null, "window=hscan")
+		return
+
+	attack_self(user)
+	return

code/modules/assembly/helpers.dm

@@ -0,0 +1,16 @@
+// See _DEFINES/is_helpers.dm for type helpers
+
+/*
+Name:	IsSpecialAssembly
+Desc:	If true is an object that can be attached to an assembly holder but is a special thing like a plasma can or door
+*/
+
+/obj/proc/IsSpecialAssembly()
+	return 0
+
+/*
+Name:	IsAssemblyHolder
+Desc:	If true is an object that can hold an assemblyholder object
+*/
+/obj/proc/IsAssemblyHolder()
+	return 0

code/modules/assembly/holder.dm

@@ -0,0 +1,126 @@
+/obj/item/device/assembly_holder
+	name = "Assembly"
+	icon = 'icons/obj/assemblies/new_assemblies.dmi'
+	icon_state = "holder"
+	item_state = "assembly"
+	flags = CONDUCT
+	throwforce = 5
+	w_class = 2
+	throw_speed = 2
+	throw_range = 7
+
+	var/obj/item/device/assembly/a_left = null
+	var/obj/item/device/assembly/a_right = null
+
+/obj/item/device/assembly_holder/IsAssemblyHolder()
+	return 1
+
+
+/obj/item/device/assembly_holder/proc/assemble(obj/item/device/assembly/A, obj/item/device/assembly/A2, mob/user)
+	attach(A,user)
+	attach(A2,user)
+	name = "[A.name]-[A2.name] assembly"
+	update_icon()
+	feedback_add_details("assembly_made","[A.name]-[A2.name]")
+
+/obj/item/device/assembly_holder/proc/attach(obj/item/device/assembly/A, mob/user)
+	if(!A.remove_item_from_storage(src))
+		if(user)
+			user.remove_from_mob(A)
+		A.loc = src
+	A.holder = src
+	A.toggle_secure()
+	if(!a_left)
+		a_left = A
+	else
+		a_right = A
+
+/obj/item/device/assembly_holder/update_icon()
+	cut_overlays()
+	if(a_left)
+		add_overlay("[a_left.icon_state]_left")
+		for(var/O in a_left.attached_overlays)
+			add_overlay("[O]_l")
+
+	if(a_right)
+		var/list/images = list()
+		images += image(icon, icon_state = "[a_right.icon_state]_left")
+		for(var/O in a_right.attached_overlays)
+			images += image(icon, icon_state = "[O]_l")
+		var/matrix = matrix(-1, 0, 0, 0, 1, 0)
+		for(var/image/I in images)
+			I.transform = matrix
+			add_overlay(I)
+
+	if(master)
+		master.update_icon()
+
+/obj/item/device/assembly_holder/Crossed(atom/movable/AM as mob|obj)
+	if(a_left)
+		a_left.Crossed(AM)
+	if(a_right)
+		a_right.Crossed(AM)
+
+/obj/item/device/assembly_holder/on_found(mob/finder)
+	if(a_left)
+		a_left.on_found(finder)
+	if(a_right)
+		a_right.on_found(finder)
+
+/obj/item/device/assembly_holder/Move()
+	..()
+	if(a_left && a_right)
+		a_left.holder_movement()
+		a_right.holder_movement()
+	return
+
+/obj/item/device/assembly_holder/attack_hand()//Perhapse this should be a holder_pickup proc instead, can add if needbe I guess
+	if(a_left && a_right)
+		a_left.holder_movement()
+		a_right.holder_movement()
+	..()
+	return
+
+/obj/item/device/assembly_holder/attackby(obj/item/weapon/W, mob/user, params)
+	if(istype(W, /obj/item/weapon/screwdriver))
+		var/turf/T = get_turf(src)
+		if(!T)
+			return 0
+		if(a_left)
+			a_left.holder = null
+			a_left.loc = T
+		if(a_right)
+			a_right.holder = null
+			a_right.loc = T
+		qdel(src)
+	else
+		..()
+
+/obj/item/device/assembly_holder/attack_self(mob/user)
+	src.add_fingerprint(user)
+	if(!a_left || !a_right)
+		user << "<span class='danger'>Assembly part missing!</span>"
+		return
+	if(istype(a_left,a_right.type))//If they are the same type it causes issues due to window code
+		switch(alert("Which side would you like to use?",,"Left","Right"))
+			if("Left")
+				a_left.attack_self(user)
+			if("Right")
+				a_right.attack_self(user)
+		return
+	else
+		a_left.attack_self(user)
+		a_right.attack_self(user)
+
+
+/obj/item/device/assembly_holder/proc/process_activation(obj/D, normal = 1, special = 1)
+	if(!D)
+		return 0
+	if((normal) && (a_right) && (a_left))
+		if(a_right != D)
+			a_right.pulsed(0)
+		if(a_left != D)
+			a_left.pulsed(0)
+	if(master)
+		master.receive_signal()
+	return 1

code/modules/assembly/igniter.dm

@@ -0,0 +1,34 @@
+/obj/item/device/assembly/igniter
+	name = "igniter"
+	desc = "A small electronic device able to ignite combustable substances."
+	icon_state = "igniter"
+	materials = list(MAT_METAL=500, MAT_GLASS=50)
+	origin_tech = "magnets=1"
+	var/datum/effect_system/spark_spread/sparks = new /datum/effect_system/spark_spread
+	heat = 1000
+
+/obj/item/device/assembly/igniter/New()
+	..()
+	sparks.set_up(2, 0, src)
+	sparks.attach(src)
+
+/obj/item/device/assembly/igniter/Destroy()
+	qdel(sparks)
+	sparks = null
+	return ..()
+
+
+/obj/item/device/assembly/igniter/activate()
+	if(!..())
+		return 0//Cooldown check
+	var/turf/location = get_turf(loc)
+	if(location)
+		location.hotspot_expose(1000,1000)
+	sparks.start()
+	return 1
+
+
+/obj/item/device/assembly/igniter/attack_self(mob/user)
+	activate()
+	add_fingerprint(user)
+	return

code/modules/assembly/infrared.dm

@@ -0,0 +1,236 @@
+/obj/item/device/assembly/infra
+	name = "infrared emitter"
+	desc = "Emits a visible or invisible beam and is triggered when the beam is interrupted.\n<span class='notice'>Alt-click to rotate it clockwise.</span>"
+	icon_state = "infrared"
+	materials = list(MAT_METAL=1000, MAT_GLASS=500)
+	origin_tech = "magnets=2;materials=2"
+
+	var/on = 0
+	var/visible = 0
+	var/obj/effect/beam/i_beam/first = null
+	var/obj/effect/beam/i_beam/last = null
+
+
+/obj/item/device/assembly/infra/New()
+	..()
+	START_PROCESSING(SSobj, src)
+
+/obj/item/device/assembly/infra/Destroy()
+	if(first)
+		qdel(first)
+	return ..()
+
+/obj/item/device/assembly/infra/describe()
+	return "The infrared trigger is [on?"on":"off"]."
+
+/obj/item/device/assembly/infra/activate()
+	if(!..())
+		return 0//Cooldown check
+	on = !on
+	update_icon()
+	return 1
+
+/obj/item/device/assembly/infra/toggle_secure()
+	secured = !secured
+	if(secured)
+		START_PROCESSING(SSobj, src)
+	else
+		on = 0
+		if(first)
+			qdel(first)
+		STOP_PROCESSING(SSobj, src)
+	update_icon()
+	return secured
+
+/obj/item/device/assembly/infra/update_icon()
+	cut_overlays()
+	attached_overlays = list()
+	if(on)
+		add_overlay("infrared_on")
+		attached_overlays += "infrared_on"
+
+	if(holder)
+		holder.update_icon()
+	return
+
+/obj/item/device/assembly/infra/process()
+	if(!on)
+		if(first)
+			qdel(first)
+		return
+	if(!secured)
+		return
+	if(first && last)
+		last.process()
+		return
+	var/turf/T = get_turf(src)
+	if(T)
+		var/obj/effect/beam/i_beam/I = new /obj/effect/beam/i_beam(T)
+		I.master = src
+		I.density = 1
+		I.setDir(dir)
+		first = I
+		step(I, I.dir)
+		if(first)
+			I.density = 0
+			I.vis_spread(visible)
+			I.limit = 8
+			I.process()
+
+/obj/item/device/assembly/infra/attack_hand()
+	qdel(first)
+	..()
+	return
+
+/obj/item/device/assembly/infra/Move()
+	var/t = dir
+	..()
+	setDir(t)
+	qdel(first)
+	return
+
+/obj/item/device/assembly/infra/holder_movement()
+	if(!holder)
+		return 0
+//	setDir(holder.dir)
+	qdel(first)
+	return 1
+
+/obj/item/device/assembly/infra/proc/trigger_beam()
+	if((!secured)||(!on)||(cooldown > 0))
+		return 0
+	pulse(0)
+	audible_message("\icon[src] *beep* *beep*", null, 3)
+	cooldown = 2
+	addtimer(src, "process_cooldown", 10)
+
+/obj/item/device/assembly/infra/interact(mob/user)//TODO: change this this to the wire control panel
+	if(is_secured(user))
+		user.set_machine(src)
+		var/dat = "<TT><B>Infrared Laser</B>\n<B>Status</B>: [on ? "<A href='?src=\ref[src];state=0'>On</A>" : "<A href='?src=\ref[src];state=1'>Off</A>"]<BR>\n<B>Visibility</B>: [visible ? "<A href='?src=\ref[src];visible=0'>Visible</A>" : "<A href='?src=\ref[src];visible=1'>Invisible</A>"]<BR>\n</TT>"
+		dat += "<BR><BR><A href='?src=\ref[src];refresh=1'>Refresh</A>"
+		dat += "<BR><BR><A href='?src=\ref[src];close=1'>Close</A>"
+		user << browse(dat, "window=infra")
+		onclose(user, "infra")
+		return
+
+/obj/item/device/assembly/infra/Topic(href, href_list)
+	..()
+	if(usr.incapacitated() || !in_range(loc, usr))
+		usr << browse(null, "window=infra")
+		onclose(usr, "infra")
+		return
+	if(href_list["state"])
+		on = !(on)
+		update_icon()
+	if(href_list["visible"])
+		visible = !(visible)
+		if(first)
+			first.vis_spread(visible)
+	if(href_list["close"])
+		usr << browse(null, "window=infra")
+		return
+	if(usr)
+		attack_self(usr)
+
+/obj/item/device/assembly/infra/verb/rotate()//This could likely be better
+	set name = "Rotate Infrared Laser"
+	set category = "Object"
+	set src in usr
+
+	if(usr.incapacitated())
+		return
+
+	setDir(turn(dir, 90))
+	return
+
+/obj/item/device/assembly/infra/AltClick(mob/user)
+	..()
+	if(user.incapacitated())
+		user << "<span class='warning'>You can't do that right now!</span>"
+		return
+	if(!in_range(src, user))
+		return
+	else
+		rotate()
+
+
+
+/***************************IBeam*********************************/
+
+/obj/effect/beam/i_beam
+	name = "infrared beam"
+	icon = 'icons/obj/projectiles.dmi'
+	icon_state = "ibeam"
+	var/obj/effect/beam/i_beam/next = null
+	var/obj/effect/beam/i_beam/previous = null
+	var/obj/item/device/assembly/infra/master = null
+	var/limit = null
+	var/visible = 0
+	var/left = null
+	anchored = 1
+
+
+/obj/effect/beam/i_beam/proc/hit()
+	if(master)
+		master.trigger_beam()
+	qdel(src)
+	return
+
+/obj/effect/beam/i_beam/proc/vis_spread(v)
+	visible = v
+	if(next)
+		next.vis_spread(v)
+
+
+/obj/effect/beam/i_beam/process()
+	if((loc.density || !(master)))
+		qdel(src)
+		return
+	if(left > 0)
+		left--
+	if(left < 1)
+		if(!(visible))
+			invisibility = INVISIBILITY_ABSTRACT
+		else
+			invisibility = 0
+	else
+		invisibility = 0
+
+	if(!next && (limit > 0))
+		var/obj/effect/beam/i_beam/I = new /obj/effect/beam/i_beam(loc)
+		I.master = master
+		I.density = 1
+		I.setDir(dir)
+		I.previous = src
+		next = I
+		step(I, I.dir)
+		if(next)
+			I.density = 0
+			I.vis_spread(visible)
+			I.limit = limit - 1
+			master.last = I
+			I.process()
+
+/obj/effect/beam/i_beam/Bump()
+	qdel(src)
+	return
+
+/obj/effect/beam/i_beam/Bumped()
+	hit()
+
+/obj/effect/beam/i_beam/Crossed(atom/movable/AM as mob|obj)
+	if(istype(AM, /obj/effect/beam))
+		return
+	hit()
+
+/obj/effect/beam/i_beam/Destroy()
+	if(master.first == src)
+		master.first = null
+	if(next)
+		qdel(next)
+		next = null
+	if(previous)
+		previous.next = null
+		master.last = previous
+	return ..()

code/modules/assembly/mousetrap.dm

@@ -0,0 +1,141 @@
+/obj/item/device/assembly/mousetrap
+	name = "mousetrap"
+	desc = "A handy little spring-loaded trap for catching pesty rodents."
+	icon_state = "mousetrap"
+	materials = list(MAT_METAL=100)
+	origin_tech = "combat=1;materials=2;engineering=1"
+	attachable = 1
+	var/armed = 0
+
+
+/obj/item/device/assembly/mousetrap/examine(mob/user)
+	..()
+	if(armed)
+		user << "It looks like it's armed."
+
+/obj/item/device/assembly/mousetrap/activate()
+	if(..())
+		armed = !armed
+		if(!armed)
+			if(ishuman(usr))
+				var/mob/living/carbon/human/user = usr
+				if((user.getBrainLoss() >= 60) || user.disabilities & CLUMSY && prob(50))
+					user << "<span class='warning'>Your hand slips, setting off the trigger!</span>"
+					pulse(0)
+		update_icon()
+		if(usr)
+			playsound(usr.loc, 'sound/weapons/handcuffs.ogg', 30, 1, -3)
+
+/obj/item/device/assembly/mousetrap/describe()
+	return "The pressure switch is [armed?"primed":"safe"]."
+
+/obj/item/device/assembly/mousetrap/update_icon()
+	if(armed)
+		icon_state = "mousetraparmed"
+	else
+		icon_state = "mousetrap"
+	if(holder)
+		holder.update_icon()
+
+/obj/item/device/assembly/mousetrap/proc/triggered(mob/target, type = "feet")
+	if(!armed)
+		return
+	var/obj/item/bodypart/affecting = null
+	if(ishuman(target))
+		var/mob/living/carbon/human/H = target
+		if(PIERCEIMMUNE in H.dna.species.specflags)
+			playsound(src.loc, 'sound/effects/snap.ogg', 50, 1)
+			armed = 0
+			update_icon()
+			pulse(0)
+			return 0
+		switch(type)
+			if("feet")
+				if(!H.shoes)
+					affecting = H.get_bodypart(pick("l_leg", "r_leg"))
+					H.Weaken(3)
+			if("l_hand", "r_hand")
+				if(!H.gloves)
+					affecting = H.get_bodypart(type)
+					H.Stun(3)
+		if(affecting)
+			if(affecting.take_damage(1, 0))
+				H.update_damage_overlays(0)
+			H.updatehealth()
+	else if(ismouse(target))
+		var/mob/living/simple_animal/mouse/M = target
+		visible_message("<span class='boldannounce'>SPLAT!</span>")
+		M.splat()
+	playsound(src.loc, 'sound/effects/snap.ogg', 50, 1)
+	armed = 0
+	update_icon()
+	pulse(0)
+
+
+/obj/item/device/assembly/mousetrap/attack_self(mob/living/carbon/human/user)
+	if(!armed)
+		user << "<span class='notice'>You arm [src].</span>"
+	else
+		if(((user.getBrainLoss() >= 60) || user.disabilities & CLUMSY) && prob(50))
+			var/which_hand = "l_hand"
+			if(!user.hand)
+				which_hand = "r_hand"
+			triggered(user, which_hand)
+			user.visible_message("<span class='warning'>[user] accidentally sets off [src], breaking their fingers.</span>", \
+								 "<span class='warning'>You accidentally trigger [src]!</span>")
+			return
+		user << "<span class='notice'>You disarm [src].</span>"
+	armed = !armed
+	update_icon()
+	playsound(user.loc, 'sound/weapons/handcuffs.ogg', 30, 1, -3)
+
+
+/obj/item/device/assembly/mousetrap/attack_hand(mob/living/carbon/human/user)
+	if(armed)
+		if(((user.getBrainLoss() >= 60) || user.disabilities & CLUMSY) && prob(50))
+			var/which_hand = "l_hand"
+			if(!user.hand)
+				which_hand = "r_hand"
+			triggered(user, which_hand)
+			user.visible_message("<span class='warning'>[user] accidentally sets off [src], breaking their fingers.</span>", \
+								 "<span class='warning'>You accidentally trigger [src]!</span>")
+			return
+	..()
+
+
+/obj/item/device/assembly/mousetrap/Crossed(atom/movable/AM as mob|obj)
+	if(armed)
+		if(ishuman(AM))
+			var/mob/living/carbon/H = AM
+			if(H.m_intent == "run")
+				triggered(H)
+				H.visible_message("<span class='warning'>[H] accidentally steps on [src].</span>", \
+								  "<span class='warning'>You accidentally step on [src]</span>")
+		else if(isanimal(AM))
+			var/mob/living/simple_animal/SA = AM
+			if(!SA.flying)
+				triggered(AM)
+		else if(AM.density) // For mousetrap grenades, set off by anything heavy
+			triggered(AM)
+	..()
+
+
+/obj/item/device/assembly/mousetrap/on_found(mob/finder)
+	if(armed)
+		finder.visible_message("<span class='warning'>[finder] accidentally sets off [src], breaking their fingers.</span>", \
+							   "<span class='warning'>You accidentally trigger [src]!</span>")
+		triggered(finder, finder.hand ? "l_hand" : "r_hand")
+		return 1	//end the search!
+	return 0
+
+
+/obj/item/device/assembly/mousetrap/hitby(A as mob|obj)
+	if(!armed)
+		return ..()
+	visible_message("<span class='warning'>[src] is triggered by [A].</span>")
+	triggered(null)
+
+
+/obj/item/device/assembly/mousetrap/armed
+	icon_state = "mousetraparmed"
+	armed = 1

code/modules/assembly/proximity.dm

@@ -0,0 +1,168 @@
+/obj/item/device/assembly/prox_sensor
+	name = "proximity sensor"
+	desc = "Used for scanning and alerting when someone enters a certain proximity."
+	icon_state = "prox"
+	materials = list(MAT_METAL=800, MAT_GLASS=200)
+	origin_tech = "magnets=1;engineering=1"
+	attachable = 1
+
+	var/scanning = 0
+	var/timing = 0
+	var/time = 10
+	var/sensitivity = 1
+	var/atom/oldloc
+	var/list/turfs_around = list()
+
+/obj/item/device/assembly/prox_sensor/proc/toggle_scan()
+
+
+/obj/item/device/assembly/prox_sensor/proc/sense()
+
+
+/obj/item/device/assembly/prox_sensor/New()
+	..()
+	START_PROCESSING(SSobj, src)
+	oldloc = loc
+
+/obj/item/device/assembly/prox_sensor/describe()
+	if(timing)
+		return "<span class='notice'>The proximity sensor is arming.</span>"
+	return "The proximity sensor is [scanning?"armed":"disarmed"]."
+
+/obj/item/device/assembly/prox_sensor/on_attach(datum/wires/w)
+	handle_move(w.holder)
+
+/obj/item/device/assembly/prox_sensor/on_detach(datum/wires/w)
+	handle_move(w.holder.loc)
+
+/obj/item/device/assembly/prox_sensor/activate()
+	if(!..())
+		return 0//Cooldown check
+	timing = !timing
+	update_icon()
+	return 1
+
+
+/obj/item/device/assembly/prox_sensor/toggle_secure()
+	secured = !secured
+	if(!secured)
+		scanning = 0
+		timing = 0
+	update_icon()
+	return secured
+
+
+/obj/item/device/assembly/prox_sensor/HasProximity(atom/movable/AM as mob|obj)
+	if (istype(AM, /obj/effect/beam))
+		return
+	sense()
+
+
+/obj/item/device/assembly/prox_sensor/sense()
+	if((!secured)||(cooldown > 0))
+		return 0
+	pulse(0)
+	audible_message("\icon[src] *beep* *beep*", null, 3)
+	cooldown = 2
+	addtimer(src, "process_cooldown", 10)
+
+
+/obj/item/device/assembly/prox_sensor/process()
+	if(timing)
+		time--
+		if(time <= 0)
+			timing = 0
+			toggle_scan(1)
+			time = initial(time)
+	handle_move(get_turf(loc))
+
+/obj/item/device/assembly/prox_sensor/dropped()
+	..()
+	if(scanning)
+		addtimer(src, "sense", 0)
+
+
+/obj/item/device/assembly/prox_sensor/toggle_scan(scan)
+	if(!secured)
+		return 0
+	scanning = scan
+	if(scanning)
+		add_to_proximity_list(src, sensitivity)
+	else
+		remove_from_proximity_list(src, sensitivity)
+	oldloc = get_turf(loc)
+	update_icon()
+
+/obj/item/device/assembly/prox_sensor/proc/sensitivity_change(value)
+	var/sense = min(max(sensitivity + value, 0), 5)
+	if(scanning)
+		shift_proximity(src, oldloc, sensitivity, loc, sense)
+	sensitivity = sense
+
+/obj/item/device/assembly/prox_sensor/update_icon()
+	cut_overlays()
+	attached_overlays = list()
+	if(timing)
+		add_overlay("prox_timing")
+		attached_overlays += "prox_timing"
+	if(scanning)
+		add_overlay("prox_scanning")
+		attached_overlays += "prox_scanning"
+	if(holder)
+		holder.update_icon()
+	return
+
+/obj/item/device/assembly/prox_sensor/proc/handle_move(atom/newloc)
+	if(scanning)
+		if(shift_proximity(src, oldloc, sensitivity, newloc, sensitivity))
+			sense()
+			oldloc = newloc
+
+/obj/item/device/assembly/prox_sensor/Move(newloc)
+	..()
+	handle_move(newloc)
+
+
+/obj/item/device/assembly/prox_sensor/interact(mob/user)//TODO: Change this to the wires thingy
+	if(is_secured(user))
+		var/second = time % 60
+		var/minute = (time - second) / 60
+		var/dat = "<TT><B>Proximity Sensor</B>\n[(timing ? "<A href='?src=\ref[src];time=0'>Arming</A>" : "<A href='?src=\ref[src];time=1'>Not Arming</A>")] [minute]:[second]\n<A href='?src=\ref[src];tp=-30'>-</A> <A href='?src=\ref[src];tp=-1'>-</A> <A href='?src=\ref[src];tp=1'>+</A> <A href='?src=\ref[src];tp=30'>+</A>\n</TT>"
+		dat += "<BR><A href='?src=\ref[src];scanning=[scanning?"0'>Armed":"1'>Unarmed"]</A> (Movement sensor active when armed!)"
+		dat += "<BR>Detection range: <A href='?src=\ref[src];sense=down'>-</A> [sensitivity] <A href='?src=\ref[src];sense=up'>+</A>"
+		dat += "<BR><BR><A href='?src=\ref[src];refresh=1'>Refresh</A>"
+		dat += "<BR><BR><A href='?src=\ref[src];close=1'>Close</A>"
+		user << browse(dat, "window=prox")
+		onclose(user, "prox")
+		return
+
+
+/obj/item/device/assembly/prox_sensor/Topic(href, href_list)
+	..()
+	if(usr.incapacitated() || !in_range(loc, usr))
+		usr << browse(null, "window=prox")
+		onclose(usr, "prox")
+		return
+
+	if(href_list["sense"])
+		sensitivity_change(((href_list["sense"] == "up") ? 1 : -1))
+
+	if(href_list["scanning"])
+		toggle_scan(text2num(href_list["scanning"]))
+
+	if(href_list["time"])
+		timing = text2num(href_list["time"])
+		update_icon()
+
+	if(href_list["tp"])
+		var/tp = text2num(href_list["tp"])
+		time += tp
+		time = min(max(round(time), 0), 600)
+
+	if(href_list["close"])
+		usr << browse(null, "window=prox")
+		return
+
+	if(usr)
+		attack_self(usr)
+

code/modules/assembly/shock_kit.dm

@@ -0,0 +1,42 @@
+/obj/item/assembly/shock_kit
+	name = "electrohelmet assembly"
+	desc = "This appears to be made from both an electropack and a helmet."
+	icon = 'icons/obj/assemblies.dmi'
+	icon_state = "shock_kit"
+	var/obj/item/clothing/head/helmet/part1 = null
+	var/obj/item/device/electropack/part2 = null
+	w_class = 5
+	flags = CONDUCT
+
+/obj/item/assembly/shock_kit/Destroy()
+	qdel(part1)
+	qdel(part2)
+	return ..()
+
+/obj/item/assembly/shock_kit/attackby(obj/item/weapon/W, mob/user, params)
+	if(istype(W, /obj/item/weapon/wrench))
+		var/turf/T = loc
+		if(ismob(T))
+			T = T.loc
+		part1.loc = T
+		part2.loc = T
+		part1.master = null
+		part2.master = null
+		part1 = null
+		part2 = null
+		qdel(src)
+		return
+	add_fingerprint(user)
+	return
+
+/obj/item/assembly/shock_kit/attack_self(mob/user)
+	part1.attack_self(user)
+	part2.attack_self(user)
+	add_fingerprint(user)
+	return
+
+/obj/item/assembly/shock_kit/receive_signal()
+	if(istype(loc, /obj/structure/chair/e_chair))
+		var/obj/structure/chair/e_chair/C = loc
+		C.shock()
+	return

code/modules/assembly/signaler.dm

@@ -0,0 +1,191 @@
+/obj/item/device/assembly/signaler
+	name = "remote signaling device"
+	desc = "Used to remotely activate devices."
+	icon_state = "signaller"
+	item_state = "signaler"
+	materials = list(MAT_METAL=400, MAT_GLASS=120)
+	origin_tech = "magnets=1;bluespace=1"
+	wires = WIRE_RECEIVE | WIRE_PULSE | WIRE_RADIO_PULSE | WIRE_RADIO_RECEIVE
+	attachable = 1
+
+	var/code = 30
+	var/frequency = 1457
+	var/delay = 0
+	var/datum/radio_frequency/radio_connection
+
+/obj/item/device/assembly/signaler/New()
+	..()
+	spawn(40)
+		set_frequency(frequency)
+
+
+/obj/item/device/assembly/signaler/Destroy()
+	if(SSradio)
+		SSradio.remove_object(src,frequency)
+	return ..()
+
+/obj/item/device/assembly/signaler/activate()
+	if(cooldown > 0)
+		return 0
+	cooldown = 2
+	spawn(10)
+		process_cooldown()
+
+	signal()
+	return 1
+
+/obj/item/device/assembly/signaler/update_icon()
+	if(holder)
+		holder.update_icon()
+	return
+
+/obj/item/device/assembly/signaler/interact(mob/user, flag1)
+	if(is_secured(user))
+		var/t1 = "-------"
+	//	if ((src.b_stat && !( flag1 )))
+	//		t1 = text("-------<BR>\nGreen Wire: []<BR>\nRed Wire:   []<BR>\nBlue Wire:  []<BR>\n", (src.wires & 4 ? text("<A href='?src=\ref[];wires=4'>Cut Wire</A>", src) : text("<A href='?src=\ref[];wires=4'>Mend Wire</A>", src)), (src.wires & 2 ? text("<A href='?src=\ref[];wires=2'>Cut Wire</A>", src) : text("<A href='?src=\ref[];wires=2'>Mend Wire</A>", src)), (src.wires & 1 ? text("<A href='?src=\ref[];wires=1'>Cut Wire</A>", src) : text("<A href='?src=\ref[];wires=1'>Mend Wire</A>", src)))
+	//	else
+	//		t1 = "-------"	Speaker: [src.listening ? "<A href='byond://?src=\ref[src];listen=0'>Engaged</A>" : "<A href='byond://?src=\ref[src];listen=1'>Disengaged</A>"]<BR>
+		var/dat = {"
+<TT>
+
+<A href='byond://?src=\ref[src];send=1'>Send Signal</A><BR>
+<B>Frequency/Code</B> for signaler:<BR>
+Frequency:
+<A href='byond://?src=\ref[src];freq=-10'>-</A>
+<A href='byond://?src=\ref[src];freq=-2'>-</A>
+[format_frequency(src.frequency)]
+<A href='byond://?src=\ref[src];freq=2'>+</A>
+<A href='byond://?src=\ref[src];freq=10'>+</A><BR>
+
+Code:
+<A href='byond://?src=\ref[src];code=-5'>-</A>
+<A href='byond://?src=\ref[src];code=-1'>-</A>
+[src.code]
+<A href='byond://?src=\ref[src];code=1'>+</A>
+<A href='byond://?src=\ref[src];code=5'>+</A><BR>
+[t1]
+</TT>"}
+		user << browse(dat, "window=radio")
+		onclose(user, "radio")
+		return
+
+
+/obj/item/device/assembly/signaler/Topic(href, href_list)
+	..()
+
+	if(!usr.canmove || usr.stat || usr.restrained() || !in_range(loc, usr))
+		usr << browse(null, "window=radio")
+		onclose(usr, "radio")
+		return
+
+	if (href_list["freq"])
+		var/new_frequency = (frequency + text2num(href_list["freq"]))
+		if(new_frequency < 1200 || new_frequency > 1600)
+			new_frequency = sanitize_frequency(new_frequency)
+		set_frequency(new_frequency)
+
+	if(href_list["code"])
+		src.code += text2num(href_list["code"])
+		src.code = round(src.code)
+		src.code = min(100, src.code)
+		src.code = max(1, src.code)
+
+	if(href_list["send"])
+		spawn( 0 )
+			signal()
+
+	if(usr)
+		attack_self(usr)
+
+	return
+
+
+/obj/item/device/assembly/signaler/proc/signal()
+	if(!radio_connection) return
+
+	var/datum/signal/signal = new
+	signal.source = src
+	signal.encryption = code
+	signal.data["message"] = "ACTIVATE"
+	radio_connection.post_signal(src, signal)
+
+	var/time = time2text(world.realtime,"hh:mm:ss")
+	var/turf/T = get_turf(src)
+	if(usr)
+		lastsignalers.Add("[time] <B>:</B> [usr.key] used [src] @ location ([T.x],[T.y],[T.z]) <B>:</B> [format_frequency(frequency)]/[code]")
+
+
+	return
+/*
+		for(var/obj/item/device/assembly/signaler/S in world)
+			if(!S)
+				continue
+			if(S == src)
+				continue
+			if((S.frequency == src.frequency) && (S.code == src.code))
+				spawn(0)
+					if(S)
+						S.pulse(0)
+		return 0*/
+
+/obj/item/device/assembly/signaler/receive_signal(datum/signal/signal)
+	if(!signal)
+		return 0
+	if(signal.encryption != code)
+		return 0
+	if(!(src.wires & WIRE_RADIO_RECEIVE))
+		return 0
+	pulse(1)
+	audible_message("\icon[src] *beep* *beep*", null, 1)
+	return
+
+
+/obj/item/device/assembly/signaler/proc/set_frequency(new_frequency)
+	if(!SSradio)
+		sleep(20)
+	if(!SSradio)
+		return
+	SSradio.remove_object(src, frequency)
+	frequency = new_frequency
+	radio_connection = SSradio.add_object(src, frequency, RADIO_CHAT)
+	return
+
+// Embedded signaller used in grenade construction.
+// It's necessary because the signaler doens't have an off state.
+// Generated during grenade construction.  -Sayu
+/obj/item/device/assembly/signaler/reciever
+	var/on = 0
+
+/obj/item/device/assembly/signaler/reciever/proc/toggle_safety()
+	on = !on
+
+/obj/item/device/assembly/signaler/reciever/activate()
+	toggle_safety()
+	return 1
+
+/obj/item/device/assembly/signaler/reciever/describe()
+	return "The radio receiver is [on?"on":"off"]."
+
+/obj/item/device/assembly/signaler/reciever/receive_signal(datum/signal/signal)
+	if(!on) return
+	return ..(signal)
+
+
+// Embedded signaller used in anomalies.
+/obj/item/device/assembly/signaler/anomaly
+	name = "anomaly core"
+	desc = "The neutralized core of an anomaly. It'd probably be valuable for research."
+	icon_state = "anomaly core"
+	item_state = "electronic"
+
+/obj/item/device/assembly/signaler/anomaly/receive_signal(datum/signal/signal)
+	if(!signal)
+		return 0
+	if(signal.encryption != code)
+		return 0
+	for(var/obj/effect/anomaly/A in get_turf(src))
+		A.anomalyNeutralize()
+
+/obj/item/device/assembly/signaler/anomaly/attack_self()
+	return

code/modules/assembly/timer.dm

@@ -0,0 +1,118 @@
+/obj/item/device/assembly/timer
+	name = "timer"
+	desc = "Used to time things. Works well with contraptions which has to count down. Tick tock."
+	icon_state = "timer"
+	materials = list(MAT_METAL=500, MAT_GLASS=50)
+	origin_tech = "magnets=1;engineering=1"
+	attachable = 1
+
+	var/timing = 0
+	var/time = 5
+	var/saved_time = 5
+	var/loop = 0
+
+
+/obj/item/device/assembly/timer/New()
+	..()
+	START_PROCESSING(SSobj, src)
+
+/obj/item/device/assembly/timer/describe()
+	if(timing)
+		return "The timer is counting down from [time]!"
+	return "The timer is set for [time] seconds."
+
+
+/obj/item/device/assembly/timer/activate()
+	if(!..())
+		return 0//Cooldown check
+	timing = !timing
+	update_icon()
+	return 1
+
+
+/obj/item/device/assembly/timer/toggle_secure()
+	secured = !secured
+	if(secured)
+		START_PROCESSING(SSobj, src)
+	else
+		timing = 0
+		STOP_PROCESSING(SSobj, src)
+	update_icon()
+	return secured
+
+
+/obj/item/device/assembly/timer/proc/timer_end()
+	if((!secured)||(cooldown > 0))
+		return 0
+	pulse(0)
+	audible_message("\icon[src] *beep* *beep*", null, 3)
+	cooldown = 2
+	spawn(10)
+		process_cooldown()
+		if(loop)
+			timing = 1
+	update_icon()
+
+
+/obj/item/device/assembly/timer/process()
+	if(timing)
+		time--
+		if(time <= 0)
+			timing = 0
+			timer_end()
+			time = saved_time
+
+
+/obj/item/device/assembly/timer/update_icon()
+	cut_overlays()
+	attached_overlays = list()
+	if(timing)
+		add_overlay("timer_timing")
+		attached_overlays += "timer_timing"
+	if(holder)
+		holder.update_icon()
+
+
+/obj/item/device/assembly/timer/interact(mob/user)//TODO: Have this use the wires
+	if(is_secured(user))
+		var/second = time % 60
+		var/minute = (time - second) / 60
+		var/dat = "<TT><B>Timing Unit</B>\n[(timing ? "<A href='?src=\ref[src];time=0'>Timing</A>" : "<A href='?src=\ref[src];time=1'>Not Timing</A>")] [minute]:[second]\n<A href='?src=\ref[src];tp=-30'>-</A> <A href='?src=\ref[src];tp=-1'>-</A> <A href='?src=\ref[src];tp=1'>+</A> <A href='?src=\ref[src];tp=30'>+</A>\n</TT>"
+		dat += "<BR><BR><A href='?src=\ref[src];repeat=[(loop ? "0'>Stop repeating" : "1'>Set to repeat")]</A>"
+		dat += "<BR><BR><A href='?src=\ref[src];refresh=1'>Refresh</A>"
+		dat += "<BR><BR><A href='?src=\ref[src];close=1'>Close</A>"
+		var/datum/browser/popup = new(user, "timer", name)
+		popup.set_content(dat)
+		popup.open()
+
+
+/obj/item/device/assembly/timer/Topic(href, href_list)
+	..()
+	if(usr.incapacitated() || !in_range(loc, usr))
+		usr << browse(null, "window=timer")
+		onclose(usr, "timer")
+		return
+
+	if(href_list["time"])
+		timing = text2num(href_list["time"])
+		if(timing && istype(holder, /obj/item/device/transfer_valve))
+			var/timer_message = "[key_name_admin(usr)](<A HREF='?_src_=holder;adminmoreinfo=\ref[usr]'>?</A>) (<A HREF='?_src_=holder;adminplayerobservefollow=\ref[usr]'>FLW</A>) activated [src] attachment on [holder]."
+			message_admins(timer_message)
+			bombers += timer_message
+			log_game("[key_name(usr)] activated [src] attachment for [loc]")
+		update_icon()
+	if(href_list["repeat"])
+		loop = text2num(href_list["repeat"])
+
+	if(href_list["tp"])
+		var/tp = text2num(href_list["tp"])
+		time += tp
+		time = min(max(round(time), 1), 600)
+		saved_time = time
+
+	if(href_list["close"])
+		usr << browse(null, "window=timer")
+		return
+
+	if(usr)
+		attack_self(usr)

code/modules/assembly/voice.dm

@@ -0,0 +1,90 @@
+/obj/item/device/assembly/voice
+	name = "voice analyzer"
+	desc = "A small electronic device able to record a voice sample, and send a signal when that sample is repeated."
+	icon_state = "voice"
+	materials = list(MAT_METAL=500, MAT_GLASS=50)
+	origin_tech = "magnets=1;engineering=1"
+	flags = HEAR
+	attachable = 1
+	verb_say = "beeps"
+	verb_ask = "beeps"
+	verb_exclaim = "beeps"
+	var/listening = 0
+	var/recorded = "" //the activation message
+	var/mode = 1
+	var/global/list/modes = list("inclusive",
+								 "exclusive",
+								 "recognizer",
+								 "voice sensor")
+
+/obj/item/device/assembly/voice/Hear(message, atom/movable/speaker, message_langs, raw_message, radio_freq, list/spans)
+	if(speaker == src)
+		return
+
+	if(listening && !radio_freq)
+		record_speech(speaker, raw_message)
+	else
+		if(check_activation(speaker, raw_message))
+			spawn(10)
+				pulse(0)
+
+/obj/item/device/assembly/voice/proc/record_speech(atom/movable/speaker, raw_message)
+	switch(mode)
+		if(1)
+			recorded = raw_message
+			listening = 0
+			say("Activation message is '[recorded]'.")
+		if(2)
+			recorded = raw_message
+			listening = 0
+			say("Activation message is '[recorded]'.")
+		if(3)
+			recorded = speaker.GetVoice()
+			listening = 0
+			say("Your voice pattern is saved.")
+		if(4)
+			if(length(raw_message))
+				spawn(10)
+					pulse(0)
+
+/obj/item/device/assembly/voice/proc/check_activation(atom/movable/speaker, raw_message)
+	. = 0
+	switch(mode)
+		if(1)
+			if(findtextEx(raw_message, recorded))
+				. = 1
+		if(2)
+			if(raw_message == recorded)
+				. = 1
+		if(3)
+			if(speaker.GetVoice() == recorded)
+				. = 1
+		if(4)
+			if(length(raw_message))
+				. = 1
+
+/obj/item/device/assembly/voice/attackby(obj/item/weapon/W, mob/user, params)
+	if(istype(W, /obj/item/device/multitool))
+		mode %= modes.len
+		mode++
+		user << "You set [src] into a [modes[mode]] mode."
+		listening = 0
+		recorded = ""
+	else
+		return ..()
+
+/obj/item/device/assembly/voice/activate()
+	if(secured)
+		if(!holder)
+			listening = !listening
+			say("[listening ? "Now" : "No longer"] recording input.")
+
+/obj/item/device/assembly/voice/attack_self(mob/user)
+	if(!user)
+		return 0
+	activate()
+	return 1
+
+/obj/item/device/assembly/voice/toggle_secure()
+	. = ..()
+	listening = 0