initial commit - cross reference with 5th port - obviously has compile errors

code/modules/awaymissions/mission_code/Academy.dm

@@ -0,0 +1,348 @@
+//Academy Areas
+
+/area/awaymission/academy
+	name = "Academy Asteroids"
+	icon_state = "away"
+
+/area/awaymission/academy/headmaster
+	name = "Academy Fore Block"
+	icon_state = "away1"
+
+/area/awaymission/academy/classrooms
+	name = "Academy Classroom Block"
+	icon_state = "away2"
+
+/area/awaymission/academy/academyaft
+	name = "Academy Ship Aft Block"
+	icon_state = "away3"
+
+/area/awaymission/academy/academygate
+	name = "Academy Gateway"
+	icon_state = "away4"
+
+/area/awaymission/academy/academycellar
+	name = "Academy Cellar"
+	icon_state = "away4"
+
+/area/awaymission/academy/academyengine
+	name = "Academy Engine"
+	icon_state = "away4"
+
+//Academy Items
+
+/obj/singularity/academy
+	dissipate = 0
+	move_self = 0
+	grav_pull = 1
+
+/obj/singularity/academy/admin_investigate_setup()
+	return
+
+/obj/singularity/academy/process()
+	eat()
+	if(prob(1))
+		mezzer()
+
+
+/obj/item/clothing/glasses/meson/truesight
+	name = "The Lens of Truesight"
+	desc = "I can see forever!"
+	icon_state = "monocle"
+	item_state = "headset"
+
+
+/obj/structure/academy_wizard_spawner
+	name = "Academy Defensive System"
+	desc = "Made by Abjuration Inc"
+	icon = 'icons/obj/cult.dmi'
+	icon_state = "forge"
+	anchored = 1
+	var/health = 200
+	var/mob/living/current_wizard = null
+	var/next_check = 0
+	var/cooldown = 600
+	var/faction = "wizard"
+	var/broken = 0
+	var/braindead_check = 0
+
+/obj/structure/academy_wizard_spawner/New()
+	START_PROCESSING(SSobj, src)
+
+/obj/structure/academy_wizard_spawner/process()
+	if(next_check < world.time)
+		if(!current_wizard)
+			for(var/mob/living/L in player_list)
+				if(L.z == src.z && L.stat != DEAD && !(faction in L.faction))
+					summon_wizard()
+					break
+		else
+			if(current_wizard.stat == DEAD)
+				current_wizard = null
+				summon_wizard()
+			if(!current_wizard.client)
+				if(!braindead_check)
+					braindead_check = 1
+				else
+					braindead_check = 0
+					give_control()
+		next_check = world.time + cooldown
+
+/obj/structure/academy_wizard_spawner/proc/give_control()
+	if(!current_wizard)
+		return
+	spawn(0)
+		var/list/mob/dead/observer/candidates = pollCandidates("Do you want to play as Wizard Academy Defender?", "wizard", null, ROLE_WIZARD)
+		var/mob/dead/observer/chosen = null
+
+		if(candidates.len)
+			chosen = pick(candidates)
+			message_admins("[key_name_admin(chosen)] was spawned as Wizard Academy Defender")
+			current_wizard.ghostize() // on the off chance braindead defender gets back in
+			current_wizard.key = chosen.key
+
+/obj/structure/academy_wizard_spawner/proc/summon_wizard()
+	var/turf/T = src.loc
+
+	var/mob/living/carbon/human/wizbody = new(T)
+	wizbody.equipOutfit(/datum/outfit/wizard/academy)
+	var/obj/item/weapon/implant/exile/Implant = new/obj/item/weapon/implant/exile(wizbody)
+	Implant.implant(wizbody)
+	wizbody.faction |= "wizard"
+	wizbody.real_name = "Academy Teacher"
+	wizbody.name = "Academy Teacher"
+
+	var/datum/mind/wizmind = new /datum/mind()
+	wizmind.name = "Wizard Defender"
+	wizmind.special_role = "Academy Defender"
+	var/datum/objective/O = new("Protect Wizard Academy from the intruders")
+	wizmind.objectives += O
+	wizmind.transfer_to(wizbody)
+	ticker.mode.wizards |= wizmind
+
+	wizmind.AddSpell(new /obj/effect/proc_holder/spell/targeted/ethereal_jaunt)
+	wizmind.AddSpell(new /obj/effect/proc_holder/spell/targeted/projectile/magic_missile)
+	wizmind.AddSpell(new /obj/effect/proc_holder/spell/dumbfire/fireball)
+
+	current_wizard = wizbody
+
+	give_control()
+
+/obj/structure/academy_wizard_spawner/proc/update_status()
+	if(health<0)
+		visible_message("<span class='warning'>[src] breaks down!</span>")
+		icon_state = "forge_off"
+		STOP_PROCESSING(SSobj, src)
+		broken = 1
+
+/obj/structure/academy_wizard_spawner/attackby(obj/item/weapon/W, mob/living/user, params)
+	add_fingerprint(user)
+	user.changeNext_move(CLICK_CD_MELEE)
+	if(!broken)
+		health -= W.force
+		update_status()
+	..()
+
+/obj/structure/academy_wizard_spawner/bullet_act(obj/item/projectile/Proj)
+	if(!broken)
+		if((Proj.damage_type == BRUTE || Proj.damage_type == BURN))
+			health -= Proj.damage
+			update_status()
+	..()
+	return
+
+/datum/outfit/wizard/academy
+	name = "Academy Wizard"
+	r_pocket = null
+	r_hand = null
+	suit = /obj/item/clothing/suit/wizrobe/red
+	head = /obj/item/clothing/head/wizard/red
+	backpack_contents = list(/obj/item/weapon/storage/box/survival = 1)
+
+/obj/item/weapon/dice/d20/fate
+	name = "Die of Fate"
+	desc = "A die with twenty sides. You can feel unearthly energies radiating from it. Using this might be VERY risky."
+	icon_state = "d20"
+	sides = 20
+	var/reusable = 1
+	var/used = 0
+	var/rigged = -1
+
+/obj/item/weapon/dice/d20/fate/one_use
+	reusable = 0
+
+/obj/item/weapon/dice/d20/fate/diceroll(mob/user)
+	..()
+	if(!used)
+		if(!ishuman(user) || !user.mind || (user.mind in ticker.mode.wizards))
+			user << "<span class='warning'>You feel the magic of the dice is restricted to ordinary humans!</span>"
+			return
+		if(rigged > 0)
+			effect(user,rigged)
+		else
+			effect(user,result)
+
+/obj/item/weapon/dice/d20/fate/equipped(mob/user, slot)
+	if(!ishuman(user) || !user.mind || (user.mind in ticker.mode.wizards))
+		user << "<span class='warning'>You feel the magic of the dice is restricted to ordinary humans! You should leave it alone.</span>"
+		user.drop_item()
+
+
+/obj/item/weapon/dice/d20/fate/proc/effect(var/mob/living/carbon/human/user,roll)
+	if(!reusable)
+		used = 1
+	visible_message("<span class='userdanger'>The die flare briefly.</span>")
+	switch(roll)
+		if(1)
+			//Dust
+			user.dust()
+		if(2)
+			//Death
+			user.death()
+		if(3)
+			//Swarm of creatures
+			for(var/direction in alldirs)
+				var/turf/T = get_turf(src)
+				new /mob/living/simple_animal/hostile/creature(get_step(T,direction))
+		if(4)
+			//Destroy Equipment
+			for (var/obj/item/I in user)
+				if (istype(I, /obj/item/weapon/implant))
+					continue
+				qdel(I)
+		if(5)
+			//Monkeying
+			user.monkeyize()
+		if(6)
+			//Cut speed
+			var/datum/species/S = user.dna.species
+			S.speedmod += 1
+		if(7)
+			//Throw
+			user.Stun(3)
+			user.adjustBruteLoss(50)
+			var/throw_dir = pick(cardinal)
+			var/atom/throw_target = get_edge_target_turf(user, throw_dir)
+			user.throw_at(throw_target, 200, 4)
+		if(8)
+			//Fueltank Explosion
+			explosion(src.loc,-1,0,2, flame_range = 2)
+		if(9)
+			//Cold
+			var/datum/disease/D = new /datum/disease/cold
+			user.ForceContractDisease(D)
+		if(10)
+			//Nothing
+			visible_message("<span class='notice'>[src] roll perfectly.</span>")
+		if(11)
+			//Cookie
+			var/obj/item/weapon/reagent_containers/food/snacks/cookie/C = new(get_turf(src))
+			C.name = "Cookie of Fate"
+		if(12)
+			//Healing
+			user.revive(full_heal = 1, admin_revive = 1)
+		if(13)
+			//Mad Dosh
+			var/turf/Start = get_turf(src)
+			for(var/direction in alldirs)
+				var/turf/T = get_step(Start,direction)
+				if(rand(0,1))
+					new /obj/item/stack/spacecash/c1000(T)
+				else
+					var/obj/item/weapon/storage/bag/money/M = new(T)
+					for(var/i in 1 to rand(5,50))
+						new /obj/item/weapon/coin/gold(M)
+		if(14)
+			//Free Gun
+			new /obj/item/weapon/gun/projectile/revolver/mateba(get_turf(src))
+		if(15)
+			//Random One-use spellbook
+			new /obj/item/weapon/spellbook/oneuse/random(get_turf(src))
+		if(16)
+			//Servant & Servant Summon
+			var/mob/living/carbon/human/H = new(get_turf(src))
+			H.equipOutfit(/datum/outfit/butler)
+			var/datum/mind/servant_mind = new /datum/mind()
+			var/datum/objective/O = new("Serve [user.real_name].")
+			servant_mind.objectives += O
+			servant_mind.transfer_to(H)
+
+			var/list/mob/dead/observer/candidates = pollCandidates("Do you want to play as [user.real_name] Servant?", "wizard")
+			var/mob/dead/observer/chosen = null
+
+			if(candidates.len)
+				chosen = pick(candidates)
+				message_admins("[key_name_admin(chosen)] was spawned as Dice Servant")
+				H.key = chosen.key
+
+			var/obj/effect/proc_holder/spell/targeted/summonmob/S = new
+			S.target_mob = H
+			user.mind.AddSpell(S)
+
+		if(17)
+			//Tator Kit
+			new /obj/item/weapon/storage/box/syndicate/(get_turf(src))
+		if(18)
+			//Captain ID
+			new /obj/item/weapon/card/id/captains_spare(get_turf(src))
+		if(19)
+			//Instrinct Resistance
+			user << "<span class='notice'>You feel robust.</span>"
+			var/datum/species/S = user.dna.species
+			S.brutemod *= 0.5
+			S.burnmod *= 0.5
+			S.coldmod *= 0.5
+		if(20)
+			//Free wizard!
+			user.mind.make_Wizard()
+
+
+/datum/outfit/butler
+	name = "Butler"
+	uniform = /obj/item/clothing/under/suit_jacket/really_black
+	shoes = /obj/item/clothing/shoes/laceup
+	head = /obj/item/clothing/head/bowler
+	glasses = /obj/item/clothing/glasses/monocle
+	gloves = /obj/item/clothing/gloves/color/white
+
+/obj/effect/proc_holder/spell/targeted/summonmob
+	name = "Summon Servant"
+	desc = "This spell can be used to call your servant, whenever you need it."
+	charge_max = 100
+	clothes_req = 0
+	invocation = "JE VES"
+	invocation_type = "whisper"
+	range = -1
+	level_max = 0 //cannot be improved
+	cooldown_min = 100
+	include_user = 1
+
+	var/mob/living/target_mob
+
+	action_icon_state = "summons"
+
+/obj/effect/proc_holder/spell/targeted/summonmob/cast(list/targets,mob/user = usr)
+	if(!target_mob)
+		return
+	var/turf/Start = get_turf(user)
+	for(var/direction in alldirs)
+		var/turf/T = get_step(Start,direction)
+		if(!T.density)
+			target_mob.Move(T)
+
+/obj/structure/ladder/unbreakable/rune
+	name = "Teleportation Rune"
+	desc = "Could lead anywhere."
+	icon = 'icons/obj/rune.dmi'
+	icon_state = "1"
+	color = rgb(0,0,255)
+
+/obj/structure/ladder/unbreakable/rune/update_icon()
+	return
+
+/obj/structure/ladder/unbreakable/rune/show_fluff_message(up,mob/user)
+	user.visible_message("[user] activates \the [src].","<span class='notice'>You activate \the [src].</span>")
+
+/obj/structure/ladder/can_use(mob/user)
+	if(user.mind in ticker.mode.wizards)
+		return 0
+	return 1

code/modules/awaymissions/mission_code/Cabin.dm

@@ -0,0 +1,133 @@
+/*Cabin areas*/
+/area/awaymission/snowforest
+	name = "Snow Forest"
+	icon_state = "away"
+	requires_power = 0
+	luminosity = 1
+	lighting_use_dynamic = DYNAMIC_LIGHTING_ENABLED
+
+/area/awaymission/cabin
+	name = "Cabin"
+	icon_state = "away2"
+	requires_power = 1
+	luminosity = 0
+	lighting_use_dynamic = DYNAMIC_LIGHTING_ENABLED
+
+/area/awaymission/snowforest/lumbermill
+	name = "Lumbermill"
+	icon_state = "away3"
+
+
+
+
+
+/*Cabin code*/
+/obj/structure/fireplace
+	name = "fireplace"
+	desc = "warm and toasty"
+	icon = 'icons/obj/stationobjs.dmi'
+	icon_state = "fireplace-active"
+	density = 0
+	var/active = 1
+
+/obj/structure/fireplace/initialize()
+	..()
+	toggleFireplace()
+
+/obj/structure/fireplace/attack_hand(mob/living/user)
+	if(active)
+		active = 0
+		toggleFireplace()
+	else
+		..()
+
+
+/obj/structure/fireplace/attackby(obj/item/W,mob/living/user,params)
+	if(!active)
+		if(W.is_hot())
+			active = 1
+			toggleFireplace()
+		else
+			return ..()
+	else
+		W.fire_act()
+
+/obj/structure/fireplace/proc/toggleFireplace()
+	if(active)
+		SetLuminosity(8)
+		icon_state = "fireplace-active"
+	else
+		SetLuminosity(0)
+		icon_state = "fireplace"
+
+/obj/structure/fireplace/extinguish()
+	if(active)
+		active = 0
+		toggleFireplace()
+
+/obj/structure/fireplace/fire_act()
+	if(!active)
+		active = 1
+		toggleFireplace()
+
+/obj/machinery/recycler/lumbermill
+	name = "lumbermill saw"
+	desc = "Faster then the cartoons!"
+	emagged = 2 //Always gibs people
+	item_recycle_sound = 'sound/weapons/chainsawhit.ogg'
+
+/obj/machinery/recycler/lumbermill/recycle_item(obj/item/weapon/grown/log/L)
+	if(!istype(L))
+		return
+	else
+		var/potency = L.seed.potency
+		..()
+		new L.plank_type(src.loc, 1 + round(potency / 25))
+
+/mob/living/simple_animal/chicken/rabbit/normal
+	icon_state = "b_rabbit"
+	icon_living = "b_rabbit"
+	icon_dead = "b_rabbit_dead"
+	icon_prefix = "b_rabbit"
+	minbodytemp = 0
+	eggsleft = 0
+	egg_type = null
+	speak = list()
+
+/*Cabin's forest*/
+/datum/mapGenerator/snowy
+	modules = list(/datum/mapGeneratorModule/snow/pineTrees, \
+	/datum/mapGeneratorModule/snow/deadTrees, \
+	/datum/mapGeneratorModule/snow/randBushes, \
+	/datum/mapGeneratorModule/snow/randIceRocks, \
+	/datum/mapGeneratorModule/snow/bunnies)
+
+/datum/mapGeneratorModule/snow/checkPlaceAtom(turf/T)
+	if(istype(T,/turf/open/floor/plating/asteroid/snow))
+		return ..(T)
+	return 0
+
+/datum/mapGeneratorModule/snow/pineTrees
+	spawnableAtoms = list(/obj/structure/flora/tree/pine = 30)
+
+/datum/mapGeneratorModule/snow/deadTrees
+	spawnableAtoms = list(/obj/structure/flora/tree/dead = 10)
+
+/datum/mapGeneratorModule/snow/randBushes
+	spawnableAtoms = list()
+
+/datum/mapGeneratorModule/snow/randBushes/New()
+	..()
+	spawnableAtoms = typesof(/obj/structure/flora/ausbushes)
+	for(var/i in spawnableAtoms)
+		spawnableAtoms[i] = 1
+
+/datum/mapGeneratorModule/snow/bunnies
+	//spawnableAtoms = list(/mob/living/simple_animal/chicken/rabbit/normal = 0.1)
+	spawnableAtoms = list(/mob/living/simple_animal/chicken/rabbit = 0.5)
+
+/datum/mapGeneratorModule/snow/randIceRocks
+	spawnableAtoms = list(/obj/structure/flora/rock/icy = 5, /obj/structure/flora/rock/pile/icy = 5)
+
+/obj/effect/landmark/mapGenerator/snowy
+	mapGeneratorType = /datum/mapGenerator/snowy

code/modules/awaymissions/mission_code/blackmarketpackers.dm

@@ -0,0 +1,22 @@
+//Packer Ship Areas
+
+/area/awaymission/BMPship
+	name = "BMP Asteroids"
+	icon_state = "away"
+	luminosity = 0
+
+
+/area/awaymission/BMPship/Aft
+	name = "Aft Block"
+	icon_state = "away1"
+	requires_power = 1
+
+/area/awaymission/BMPship/Midship
+	name = "Midship Block"
+	icon_state = "away2"
+	requires_power = 1
+
+/area/awaymission/BMPship/Fore
+	name = "Fore Block"
+	icon_state = "away3"
+	requires_power = 1

code/modules/awaymissions/mission_code/centcomAway.dm

@@ -0,0 +1,63 @@
+//centcomAway areas
+
+/area/awaymission/centcomAway
+	name = "XCC-P5831"
+	icon_state = "away"
+	requires_power = 0
+
+/area/awaymission/centcomAway/general
+	name = "XCC-P5831"
+	music = "music/ambigen3.ogg"
+
+/area/awaymission/centcomAway/maint
+	name = "XCC-P5831 Maintenance"
+	icon_state = "away1"
+	music = "music/ambisin1.ogg"
+
+/area/awaymission/centcomAway/thunderdome
+	name = "XCC-P5831 Thunderdome"
+	icon_state = "away2"
+	music = "music/ambisin2.ogg"
+
+/area/awaymission/centcomAway/cafe
+	name = "XCC-P5831 Kitchen Arena"
+	icon_state = "away3"
+	music = "music/ambisin3.ogg"
+
+/area/awaymission/centcomAway/courtroom
+	name = "XCC-P5831 Courtroom"
+	icon_state = "away4"
+	music = "music/ambisin4.ogg"
+
+/area/awaymission/centcomAway/hangar
+	name = "XCC-P5831 Hangars"
+	icon_state = "away4"
+	music = "music/ambigen5.ogg"
+
+//centcomAway items
+
+/obj/item/weapon/paper/pamphlet/ccaInfo
+	name = "Visitor Info Pamphlet"
+	info = "<b> XCC-P5831 Visitor Information </b><br>\
+	Greetings, visitor, to  XCC-P5831! As you may know, this outpost was once \
+	used as Nanotrasen's CENTRAL COMMAND STATION, organizing and coordinating company \
+	projects across the vastness of space. <br>\
+	Since the completion of the much more efficient CC-A5831 on March 8, 2553, XCC-P5831 no longer \
+	acts as NT's base of operations but still plays a very important role its corporate affairs; \
+	serving as a supply and repair depot, as well as being host to its most important legal proceedings\
+	and the thrilling pay-per-view broadcasts of <i>PLASTEEL CHEF</i> and <i>THUNDERDOME LIVE</i>.<br> \
+	We hope you enjoy your stay!"
+
+/obj/item/weapon/paper/ccaMemo
+	name = "Memo to XCC-P5831 QM"
+	info = "<b>From: XCC-P5831 Management Office</b><br>\
+	<b>To: Rolf Ingram, XCC-P5831 Quartermaster</b><br>\
+	Hey, Rolf, once you pack that gateway into the ferry hangar, <i>make absolutely sure</i> \
+	to deactivate it! As you may know, SS13 has recently got its network up and running, \
+	which means that until we get this gate shipped off to the next colonization staging \
+	area, they'll be able to hop straight in here if its hooked up on our end.<br>\
+	Obviously, that's something I'd very much rather avoid. Our forensics and medical \
+	teams never did figure out what happened that last time... and I can't wrap my head \
+	around it myself. Why would a shuttle full of evacuees all snap and beat each other \
+	to death the moment they reached safety?<br>\
+	- D. Cereza"

code/modules/awaymissions/mission_code/challenge.dm

@@ -0,0 +1,35 @@
+//Challenge Areas
+
+/area/awaymission/challenge/start
+	name = "Where Am I?"
+	icon_state = "away"
+
+/area/awaymission/challenge/main
+	name = "Danger Room"
+	icon_state = "away1"
+	requires_power = 0
+
+/area/awaymission/challenge/end
+	name = "Administration"
+	icon_state = "away2"
+	requires_power = 0
+
+
+/obj/machinery/power/emitter/energycannon
+	name = "Energy Cannon"
+	desc = "A heavy duty industrial laser"
+	icon = 'icons/obj/singularity.dmi'
+	icon_state = "emitter"
+	anchored = 1
+	density = 1
+
+	use_power = 0
+	idle_power_usage = 0
+	active_power_usage = 0
+
+	active = 1
+	locked = 1
+	state = 2
+
+/obj/machinery/power/emitter/energycannon/RefreshParts()
+	return

code/modules/awaymissions/mission_code/researchbase.dm

@@ -0,0 +1,64 @@
+//Research Base Areas//--
+
+/area/awaymission/research
+	name = "Research Outpost"
+	icon_state = "away"
+	luminosity = 0
+	lighting_use_dynamic = DYNAMIC_LIGHTING_ENABLED
+
+/area/awaymission/research/interior
+	name = "Research Inside"
+	requires_power = 1
+	icon_state = "away2"
+
+/area/awaymission/research/interior/cryo
+	name = "Research Cryostasis Room"
+	icon_state = "medbay"
+
+/area/awaymission/research/interior/clonestorage
+	name = "Research Clone Storage"
+	icon_state = "cloning"
+
+/area/awaymission/research/interior/genetics
+	name = "Research Genetics Research"
+	icon_state = "genetics"
+
+/area/awaymission/research/interior/engineering
+	name = "Research Engineering"
+	icon_state = "engine"
+
+/area/awaymission/research/interior/security
+	name = "Research Security"
+	icon_state = "security"
+
+/area/awaymission/research/interior/secure
+	name = "Research Secure Vault"
+
+/area/awaymission/research/interior/maint
+	name = "Research Maintenance"
+	icon_state = "maintcentral"
+
+/area/awaymission/research/interior/dorm
+	name = "Research Dorms"
+	icon_state = "Sleep"
+
+/area/awaymission/research/interior/escapepods
+	name = "Research Escape Wing"
+	icon_state = "exit"
+
+/area/awaymission/research/interior/gateway
+	name = "Research Gateway"
+	icon_state = "start"
+
+/area/awaymission/research/interior/bathroom
+	name = "Research Bathrooms"
+	icon_state = "restrooms"
+
+/area/awaymission/research/interior/medbay
+	name = "Research Medbay"
+	icon_state = "medbay"
+
+/area/awaymission/research/exterior
+	name = "Research Exterior"
+	icon_state = "unknown"
+

code/modules/awaymissions/mission_code/snowdin.dm

@@ -0,0 +1,279 @@
+//Snow Valley Areas//--
+
+/area/awaymission/snowdin
+	name = "Snowdin Tundra Plains"
+	icon_state = "away"
+	requires_power = 0
+	luminosity = 1
+	lighting_use_dynamic = DYNAMIC_LIGHTING_ENABLED
+
+/area/awaymission/snowdin/post
+	name = "Snowdin Outpost"
+	requires_power = 1
+
+/area/awaymission/snowdin/igloo
+	name = "Snowdin Igloos"
+	icon_state = "away2"
+
+/area/awaymission/snowdin/cave
+	name = "Snowdin Caves"
+	icon_state = "away2"
+	luminosity = 0
+
+/area/awaymission/snowdin/base
+	name = "Snowdin Main Base"
+	icon_state = "away3"
+	requires_power = 1
+
+/area/awaymission/snowdin/dungeon1
+	name = "Snowdin Depths"
+	icon_state = "away2"
+	luminosity = 0
+
+/area/awaymission/snowdin/sekret
+	name = "Snowdin Operations"
+	icon_state = "away3"
+	requires_power = 1
+
+//notes for lore or treasure hints wow//--
+
+/obj/item/weapon/paper/crumpled/snowdin/snowdingatewaynotice
+	name = "scribbled note"
+	info = {"The gateway has been inactive for months, engineers think its due to the recent drop in tempature fucking with the
+	circuitry or something. Without a constant supply of resources from central command, our stock is getting awfully low. Some of the security members have taken to
+	using the sparse rifle ammo left to hunting some of the wildlife to try and keep our food supply from emptying. God forbid if the heating goes out, I don't want to
+	die as a fucking popsicle down here."}
+
+/obj/item/weapon/paper/crumpled/snowdin/misc1
+	name = "Mission Prologe"
+	info = {"Holy shit, what a rush! Those Nanotrasen bastards didn't even know what hit 'em! All five of us dropped in right on the captain, didn't even have time to yell! We were in and out with that disk in mere minutes!
+	Crew didn't even know what was happening till the delta alert went down and by then were were already gone. We got a case to drink on the way home to celebrate, fuckin' job well done!"}
+
+/obj/item/weapon/paper/crumpled/snowdin/keys
+	name = "scribbled note"
+	info = {"As a notice for anyone looking to borrow an ATV, some asshat lost the key set for all the vehicles. Nobody has yet to actually come forward about the potential where-abouts, either due to embarrassment or fear of
+	reprecussions. I hope they enjoy walking through that shit snow during the next shipment because I sure as hell ain't."}
+
+/obj/item/weapon/paper/snowdin/snowdinlog
+	name = "Activity Log"
+	info = {"<b><center>ACTIVITY LOG</b></center><br><br><b>June 3rd</b><br>We've moved to the main base in the valley finally, apparently establishing a listening system on a planet
+	that never stops fucking snowing is a great idea. There's a few outposts further south we'll be supplying from the main gateway. The summer months are enough already, I can only imagine how bad it'll be during winter.<br><br><b>August 23rd</b><br>
+	The colder months are finally hitting, some of the machinery seems to be having trouble starting up sometimes. Central sent some portable heaters to help keep the airlocks from
+	freezing shut along with a couple storage crates with supplies. Nothing on the radio so far, what the hell do they even expect to hear down here, anyway?<br><br><b>September 15th</b>
+	<br>Another supply shipment through the gateway, they've sent some heavier sets of clothes for the coming winter months. Central said they might encounter issues with shipments
+	during December to Feburary, so we should try to be frugal with the next shipment.<br><br><b>November 20th</b><br>Final shipment from central for the next few months. Going outside
+	for more than 10-15 minutes without losing feeling in your fingers is difficult. We've finally gotten a signal on the radio, its mostly some weird static though. One of the researchers is trying to decypher it.
+	<br><br><b>December 10th</b><br>Signal has gotten much stronger, it almost seems like its coming from under us according to what the researcher managed to decypher. We're waiting from the go from central before investigating.<br><br>
+	<i>The rest of the paper seems to be a mixture of scribles and smudged ink.</i> "}
+
+/obj/item/weapon/paper/snowdin/snowdinlog2
+	name = "Activity Log"
+	info = {"<b><center>ACTIVITY LOG</b></center><br><br><b>June 14th</b><br>Movement to the second post is finally done. We're located on the most-southern area of the valley with a similar objective as the northen post.
+	Theres two mid-way stops on the eastern and western sides of the valley so movement inbetween bases isn't horrible. Not too big of a fan of relying on the northen base for
+	equal supply distribution, though.<br><br><b>August 27h</b><br>First shipment arrived finally, about 4 days after the gateway shipped. Insulation on these buildings is awful, thank god for the spare heaters at least.<br><br>
+	<b>September 20th</b><br>Another shipment arrival, standard shit. Our radios have been picking up a weird signal during the nights recently, we've sent the transcripts over to the northen
+	base to be decyphered. Probably some drunk russians or something equally stupid.<br><br><b>November 24th</b><br>We've lost communications with the northern base after recieving the last
+	shipment of supplies. The snow has really kicked up recently, shits almost like a constant blizzard right now. Maybe it'll drop down soon so we can get a word in.<br><br>
+	<i>The rest of the paper seems to be a mixture of scribles and smudged ink.</i> "}
+
+obj/item/weapon/paper/snowdin/secnotice
+	name = "Security Notice"
+	info = {"You have been assigned a postion on a listening outpost. Here you'll be watching over a several crewmembers assigned to watching signals of the general area.
+	 As not much is expected in terms of issues, we've only assigned one guard per outpost. Crewmembers are expected to keep to their regulated work schedules and may be
+	 disciplined properly if found slacking. Food hording is heavily discouraged as all outposts will be sharing from the same shipment every 2-3 months. Hording of supplies
+	 should be punished severely as to prevent future incidients. Mutiny and/or rioting should be reported to central and dealt with swiftly. You're here to secure and protect
+	 Nanotrasen assets, not be a police officer. Do what you must, but make sure its not messy."}
+
+obj/item/weapon/paper/snowdin/syndienotice
+	name = "Assignment Notice"
+	info = {"You've been assigned as an agent to listen in on Nanotrasen activities from passing ships and nearby stations. The outpost you've been assigned to is under lays of solid
+	ice and we've supplied you with a scrambler to help avoid Nanotrasen discovery, as they've recently built a listening post of their own aboveground. Get aquainted with your new
+	crewmates, because you're gonna be here for awhile. Enjoy the free syndicakes."}
+
+obj/item/weapon/paper/crumpled/snowdin/syndielava
+	name = "scribbled note"
+	info = {"Some cracks in the ice nearby have exposed some sort of hidden magma stream under all this shit ice. I don't know whats worse at this point honestly; freezing to death or
+	burning alive."}
+
+obj/item/weapon/paper/crumpled/snowdin/lootstructures
+	name = "scribbled note"
+	info = {"From what we've seen so far, theres a ton of iced over ruins down here in the caves. We sent a few men out to check things out and they never came back, so we decided to
+	border up majority of the ruins. We've heard some weird shit coming out of these caves and I'm not gonna find out the hard way myself."}
+
+obj/item/weapon/paper/crumpled/snowdin/shovel
+	name = "shoveling duties"
+	info = {"Snow piles up bad here all-year round, even worse during the winter months. Keeping a constant rotation of shoveling that shit out of the way of the airlocks and keeping the paths decently clear
+	is a good step towards not getting stuck walking through knee-deep snow."}
+
+//lootspawners//--
+
+/obj/effect/spawner/lootdrop/snowdin
+	name = "why are you using this dummy"
+	lootdoubles = 0
+	lootcount = 1
+	loot = list(/obj/item/weapon/bikehorn = 100)
+
+/obj/effect/spawner/lootdrop/snowdin/dungeonlite
+	name = "dungeon lite"
+	loot = list(/obj/item/weapon/melee/classic_baton = 11,
+				/obj/item/weapon/melee/classic_baton/telescopic = 12,
+				/obj/item/weapon/spellbook/oneuse/smoke = 10,
+				/obj/item/weapon/spellbook/oneuse/blind = 10,
+				/obj/item/weapon/storage/firstaid/regular = 45,
+				/obj/item/weapon/storage/firstaid/toxin = 35,
+				/obj/item/weapon/storage/firstaid/brute = 27,
+				/obj/item/weapon/storage/firstaid/fire = 27,
+				/obj/item/weapon/storage/toolbox/syndicate = 12,
+				/obj/item/weapon/grenade/plastic/c4 = 7,
+				/obj/item/weapon/grenade/clusterbuster/smoke = 15,
+				/obj/item/clothing/under/chameleon = 13,
+				/obj/item/clothing/shoes/chameleon = 10,
+				/obj/item/borg/upgrade/ddrill = 3,
+				/obj/item/borg/upgrade/soh = 3)
+
+/obj/effect/spawner/lootdrop/snowdin/dungeonmid
+	name = "dungeon mid"
+	loot = list(/obj/item/weapon/defibrillator/compact = 6,
+				/obj/item/weapon/storage/firstaid/tactical = 35,
+				/obj/item/weapon/shield/energy = 6,
+				/obj/item/weapon/shield/riot/tele = 12,
+				/obj/item/weapon/dnainjector/lasereyesmut = 7,
+				/obj/item/weapon/gun/magic/wand/fireball/inert = 3,
+				/obj/item/weapon/pneumatic_cannon = 15,
+				/obj/item/weapon/melee/energy/sword = 7,
+				/obj/item/weapon/spellbook/oneuse/knock = 15,
+				/obj/item/weapon/spellbook/oneuse/summonitem = 20,
+				/obj/item/weapon/spellbook/oneuse/forcewall = 17,
+				/obj/item/weapon/storage/backpack/holding = 12,
+				/obj/item/weapon/grenade/spawnergrenade/manhacks = 6,
+				/obj/item/weapon/grenade/spawnergrenade/spesscarp = 7,
+				/obj/item/weapon/grenade/clusterbuster/inferno = 3,
+				/obj/item/stack/sheet/mineral/diamond{amount = 15} = 10,
+				/obj/item/stack/sheet/mineral/uranium{amount = 15} = 10,
+				/obj/item/stack/sheet/mineral/plasma{amount = 15} = 10,
+				/obj/item/stack/sheet/mineral/gold{amount = 15} = 10,
+				/obj/item/weapon/spellbook/oneuse/barnyard = 4,
+				/obj/item/weapon/pickaxe/drill/diamonddrill = 6,
+				/obj/item/borg/upgrade/vtec = 7,
+				/obj/item/borg/upgrade/disablercooler = 7)
+
+
+/obj/effect/spawner/lootdrop/snowdin/dungeonheavy
+	name = "dungeon heavy"
+	loot = list(/obj/item/weapon/twohanded/singularityhammer = 25,
+				/obj/item/weapon/twohanded/mjollnir = 10,
+				/obj/item/weapon/twohanded/fireaxe = 25,
+				/obj/item/organ/brain/alien = 17,
+				/obj/item/weapon/twohanded/dualsaber = 15,
+				/obj/item/organ/heart/demon = 7,
+				/obj/item/weapon/gun/projectile/automatic/c20r/unrestricted = 16,
+				/obj/item/weapon/gun/magic/wand/resurrection/inert = 15,
+				/obj/item/weapon/gun/magic/wand/resurrection = 10,
+				/obj/item/device/radio/uplink/old = 2,
+				/obj/item/weapon/spellbook/oneuse/charge = 12,
+				/obj/item/weapon/grenade/clusterbuster/spawner_manhacks = 15,
+				/obj/item/weapon/spellbook/oneuse/fireball = 10,
+				/obj/item/weapon/pickaxe/drill/jackhammer = 30,
+				/obj/item/borg/upgrade/syndicate = 13,
+				/obj/item/borg/upgrade/selfrepair = 17)
+
+/obj/effect/spawner/lootdrop/snowdin/dungeonmisc
+	name = "dungeon misc"
+	lootdoubles = 2
+	lootcount = 1
+
+	loot = list(/obj/item/stack/sheet/mineral/snow{amount = 25} = 10,
+				/obj/item/toy/snowball = 15,
+				/obj/item/weapon/shovel = 10,
+				/obj/item/weapon/twohanded/spear = 8,
+				)
+
+//special items//--
+
+/obj/item/clothing/under/syndicate/coldres
+	name = "insulated tactical turtleneck"
+	desc = "A non-descript and slightly suspicious looking turtleneck with digital camouflage cargo pants. The interior has been padded with special insulation for both warmth and protection"
+	armor = list(melee = 20, bullet = 10, laser = 0,energy = 5, bomb = 0, bio = 0, rad = 0)
+	cold_protection = CHEST|GROIN|ARMS|LEGS
+	min_cold_protection_temperature = FIRE_SUIT_MIN_TEMP_PROTECT
+/obj/item/clothing/shoes/combat/coldres
+	name = "insulated combat boots"
+	desc = "High speed, low drag combat boots, now with an added layer of insulation."
+	min_cold_protection_temperature = FIRE_SUIT_MIN_TEMP_PROTECT
+
+/obj/item/weapon/gun/magic/wand/fireball/inert
+	name = "weakened wand of fireball"
+	desc = "This wand shoots scorching balls of fire that explode into destructive flames. The years of the cold have weakened the magic inside the wand."
+	max_charges = 4
+
+/obj/item/weapon/gun/magic/wand/resurrection/inert
+	name = "weakened wand of healing"
+	desc = "This wand uses healing magics to heal and revive. The years of the cold have weakened the magic inside the wand."
+	max_charges = 5
+
+/obj/item/device/radio/uplink/old
+	name = "dusty radio"
+	desc = "A dusty looking radio."
+
+/obj/item/device/radio/uplink/old/New()
+	..()
+	hidden_uplink.name = "dusty radio"
+	hidden_uplink.telecrystals = 10
+
+obj/effect/mob_spawn/human/syndicatesoldier/coldres
+	name = "Syndicate Snow Operative"
+	uniform = /obj/item/clothing/under/syndicate/coldres
+	shoes = /obj/item/clothing/shoes/combat/coldres
+	radio = /obj/item/device/radio/headset/syndicate/alt
+	pocket1 = /obj/item/weapon/gun/projectile/automatic/pistol
+	pocket2 = /obj/item/weapon/card/id/syndicate
+	has_id = 0
+
+obj/effect/mob_spawn/human/syndicatesoldier/coldres/alive
+	name = "sleeper"
+	mob_name = "Syndicate Snow Operative"
+	icon = 'icons/obj/Cryogenic2.dmi'
+	icon_state = "sleeper"
+	roundstart = FALSE
+	death = FALSE
+	implants = list(/obj/item/weapon/implant/exile)
+	faction = "syndicate"
+	flavour_text = {"You are a syndicate operative recently awoken from cyrostatis in an underground outpost. Monitor Nanotrasen communications and record infomation. All intruders should be
+	disposed of swirfly to assure no gathered infomation is stolen or lost. Try not to wander too far from the outpost as the caves can be a deadly place even for a trained operative such as yourself."}
+
+obj/effect/mob_spawn/human/syndicatesoldier/coldres/alive/female
+	mob_gender = FEMALE
+
+//mobs//--
+
+/mob/living/simple_animal/hostile/poison/giant_spider/ice //spiders dont usually like tempatures of 140 kelvin who knew
+	name = "giant ice spider"
+	atmos_requirements = list("min_oxy" = 0, "max_oxy" = 0, "min_tox" = 0, "max_tox" = 0, "min_co2" = 0, "max_co2" = 0, "min_n2" = 0, "max_n2" = 0)
+	minbodytemp = 0
+	maxbodytemp = 1500
+	color = rgb(114,228,250)
+
+/mob/living/simple_animal/hostile/poison/giant_spider/nurse/ice
+	name = "giant ice spider"
+	atmos_requirements = list("min_oxy" = 0, "max_oxy" = 0, "min_tox" = 0, "max_tox" = 0, "min_co2" = 0, "max_co2" = 0, "min_n2" = 0, "max_n2" = 0)
+	minbodytemp = 0
+	maxbodytemp = 1500
+	color = rgb(114,228,250)
+
+/mob/living/simple_animal/hostile/poison/giant_spider/hunter/ice
+	name = "giant ice spider"
+	atmos_requirements = list("min_oxy" = 0, "max_oxy" = 0, "min_tox" = 0, "max_tox" = 0, "min_co2" = 0, "max_co2" = 0, "min_n2" = 0, "max_n2" = 0)
+	minbodytemp = 0
+	maxbodytemp = 1500
+	color = rgb(114,228,250)
+
+//objs//--
+
+/obj/structure/flora/rock/icy
+	name = "icy rock"
+	color = rgb(114,228,250)
+
+/obj/structure/flora/rock/pile/icy
+	name = "icey rocks"
+	color = rgb(114,228,250)
+

code/modules/awaymissions/mission_code/spacebattle.dm

@@ -0,0 +1,33 @@
+//Spacebattle Areas
+
+/area/awaymission/spacebattle
+	name = "Space Battle"
+	icon_state = "away"
+	requires_power = 0
+
+/area/awaymission/spacebattle/cruiser
+	name = "Nanotrasen Cruiser"
+
+/area/awaymission/spacebattle/syndicate1
+	name = "Syndicate Assault Ship 1"
+
+/area/awaymission/spacebattle/syndicate2
+	name = "Syndicate Assault Ship 2"
+
+/area/awaymission/spacebattle/syndicate3
+	name = "Syndicate Assault Ship 3"
+
+/area/awaymission/spacebattle/syndicate4
+	name = "Syndicate War Sphere 1"
+
+/area/awaymission/spacebattle/syndicate5
+	name = "Syndicate War Sphere 2"
+
+/area/awaymission/spacebattle/syndicate6
+	name = "Syndicate War Sphere 3"
+
+/area/awaymission/spacebattle/syndicate7
+	name = "Syndicate Fighter"
+
+/area/awaymission/spacebattle/secret
+	name = "Hidden Chamber"

code/modules/awaymissions/mission_code/stationCollision.dm

@@ -0,0 +1,197 @@
+/* Station-Collision(sc) away mission map specific stuff
+ *
+ * Notes:
+ *		Feel free to use parts of this map, or even all of it for your own project. Just include me in the credits :)
+ *
+ *		Some of this code unnecessary, but the intent is to add a little bit of everything to serve as examples
+ *		for anyone who wants to make their own stuff.
+ *
+ * Contains:
+ *		Areas
+ *		Landmarks
+ *		Guns
+ *		Safe code hints
+ *		Captain's safe
+ *		Modified Nar-Sie
+ */
+
+/*
+ * Areas
+ */
+ //Gateroom gets its own APC specifically for the gate
+ /area/awaymission/gateroom
+
+ //Library, medbay, storage room
+ /area/awaymission/southblock
+
+ //Arrivals, security, hydroponics, shuttles (since they dont move, they dont need specific areas)
+ /area/awaymission/arrivalblock
+
+ //Crew quarters, cafeteria, chapel
+ /area/awaymission/midblock
+
+ //engineering, bridge (not really north but it doesnt really need its own APC)
+ /area/awaymission/northblock
+
+ //That massive research room
+ /area/awaymission/research
+
+//Syndicate shuttle
+/area/awaymission/syndishuttle
+
+
+/*
+ * Landmarks - Instead of spawning a new object type, I'll spawn the bible using a landmark!
+ */
+/obj/effect/landmark/sc_bible_spawner
+	name = "Safecode hint spawner"
+
+/obj/effect/landmark/sc_bible_spawner/New()
+	var/obj/item/weapon/storage/book/bible/B = new /obj/item/weapon/storage/book/bible/booze(src.loc)
+	B.name = "The Holy book of the Geometer"
+	B.deity_name = "Narsie"
+	B.icon_state = "melted"
+	B.item_state = "melted"
+	new /obj/item/weapon/paper/sc_safehint_paper_bible(B)
+	new /obj/item/weapon/pen(B)
+	qdel(src)
+
+/*
+ * Guns - I'm making these specifically so that I dont spawn a pile of fully loaded weapons on the map.
+ */
+//Captain's retro laser - Fires practice laser shots instead.
+obj/item/weapon/gun/energy/laser/retro/sc_retro
+	name ="retro laser"
+	icon_state = "retro"
+	desc = "An older model of the basic lasergun, no longer used by Nanotrasen's security or military forces."
+//	projectile_type = "/obj/item/projectile/practice"
+	clumsy_check = 0 //No sense in having a harmless gun blow up in the clowns face
+
+//Syndicate sub-machine guns.
+/obj/item/weapon/gun/projectile/automatic/c20r/sc_c20r
+
+/obj/item/weapon/gun/projectile/automatic/c20r/sc_c20r/New()
+	..()
+	for(var/ammo in magazine.stored_ammo)
+		if(prob(95)) //95% chance
+			magazine.stored_ammo -= ammo
+
+//Barman's shotgun
+/obj/item/weapon/gun/projectile/shotgun/sc_pump
+
+/obj/item/weapon/gun/projectile/shotgun/sc_pump/New()
+	..()
+	for(var/ammo in magazine.stored_ammo)
+		if(prob(95)) //95% chance
+			magazine.stored_ammo -= ammo
+
+//Lasers
+/obj/item/weapon/gun/energy/laser/practice/sc_laser
+	name = "Old laser"
+	desc = "A once potent weapon, years of dust have collected in the chamber and lens of this weapon, weakening the beam significantly."
+	clumsy_check = 0
+
+/*
+ * Safe code hints
+ */
+
+//These vars hold the code itself, they'll be generated at round-start
+var/sc_safecode1 = "[rand(0,9)]"
+var/sc_safecode2 = "[rand(0,9)]"
+var/sc_safecode3 = "[rand(0,9)]"
+var/sc_safecode4 = "[rand(0,9)]"
+var/sc_safecode5 = "[rand(0,9)]"
+
+//Pieces of paper actually containing the hints
+/obj/item/weapon/paper/sc_safehint_paper_prison
+	name = "smudged paper"
+
+/obj/item/weapon/paper/sc_safehint_paper_prison/New()
+	info = "<i>The ink is smudged, you can only make out a couple numbers:</i> '[sc_safecode1]**[sc_safecode4]*'"
+
+/obj/item/weapon/paper/sc_safehint_paper_hydro
+	name = "shredded paper"
+/obj/item/weapon/paper/sc_safehint_paper_hydro/New()
+	info = "<i>Although the paper is shredded, you can clearly see the number:</i> '[sc_safecode2]'"
+
+/obj/item/weapon/paper/sc_safehint_paper_caf
+	name = "blood-soaked paper"
+	//This does not have to be in New() because it is a constant. There are no variables in it i.e. [sc_safcode]
+	info = "<font color=red><i>This paper is soaked in blood, it is impossible to read any text.</i></font>"
+
+/obj/item/weapon/paper/sc_safehint_paper_bible
+	name = "hidden paper"
+/obj/item/weapon/paper/sc_safehint_paper_bible/New()
+	info = {"<i>It would appear that the pen hidden with the paper had leaked ink over the paper.
+			However you can make out the last three digits:</i>'[sc_safecode3][sc_safecode4][sc_safecode5]'
+			"}
+
+/obj/item/weapon/paper/sc_safehint_paper_shuttle
+	info = {"<b>Target:</b> Research-station Epsilon<br>
+			<b>Objective:</b> Prototype weaponry. The captain likely keeps them locked in her safe.<br>
+			<br>
+			Our on-board spy has learned the code and has hidden away a few copies of the code around the station. Unfortunatly he has been captured by security
+			Your objective is to split up, locate any of the papers containing the captain's safe code, open the safe and
+			secure anything found inside. If possible, recover the imprisioned syndicate operative and receive the code from him.<br>
+			<br>
+			<u>As always, eliminate anyone who gets in the way.</u><br>
+			<br>
+			Your assigned ship is designed specifically for penetrating the hull of another station or ship with minimal damage to operatives.
+			It is completely fly-by-wire meaning you have just have to enjoy the ride and when the red light comes on... find something to hold onto!
+			"}
+/*
+ * Captain's safe
+ */
+/obj/item/weapon/storage/secure/safe/sc_ssafe
+	name = "Captain's secure safe"
+
+/obj/item/weapon/storage/secure/safe/sc_ssafe/New()
+	..()
+	l_code = "[sc_safecode1][sc_safecode2][sc_safecode3][sc_safecode4][sc_safecode5]"
+	l_set = 1
+	new /obj/item/weapon/gun/energy/mindflayer(src)
+	new /obj/item/device/soulstone(src)
+	new /obj/item/clothing/suit/space/hardsuit/cult(src)
+	//new /obj/item/weapon/teleportation_scroll(src)
+	new /obj/item/weapon/ore/diamond(src)
+
+/*
+ * Modified Nar-Sie
+ */
+/obj/singularity/narsie/sc_Narsie
+	desc = "Your body becomes weak and your feel your mind slipping away as you try to comprehend what you know can't be possible."
+	move_self = 0 //Contianed narsie does not move!
+	grav_pull = 0 //Contained narsie does not pull stuff in!
+	var/uneatable = list(/turf/open/space, /obj/effect/overlay, /mob/living/simple_animal/hostile/construct)
+//Override this to prevent no adminlog runtimes and admin warnings about a singularity without containment
+/obj/singularity/narsie/sc_Narsie/admin_investigate_setup()
+	return
+
+/obj/singularity/narsie/sc_Narsie/process()
+	eat()
+	if(prob(25))
+		mezzer()
+
+/obj/singularity/narsie/sc_Narsie/consume(atom/A)
+	if(is_type_in_list(A, uneatable))
+		return 0
+	if (istype(A,/mob/living))
+		var/mob/living/L = A
+		L.gib()
+	else if(istype(A,/obj/))
+		var/obj/O = A
+		O.ex_act(1)
+		if(O) qdel(O)
+	else if(isturf(A))
+		var/turf/T = A
+		if(T.intact)
+			for(var/obj/O in T.contents)
+				if(O.level != 1)
+					continue
+				if(O.invisibility == INVISIBILITY_MAXIMUM)
+					src.consume(O)
+		T.ChangeTurf(/turf/open/space)
+	return
+
+/obj/singularity/narsie/sc_Narsie/ex_act()
+	return

code/modules/awaymissions/mission_code/wildwest.dm

@@ -0,0 +1,163 @@
+/* Code for the Wild West map by Brotemis
+ * Contains:
+ *		Wish Granter
+ *		Meat Grinder
+ */
+
+//Wild West Areas
+
+/area/awaymission/wwmines
+	name = "Wild West Mines"
+	icon_state = "away1"
+	luminosity = 1
+	requires_power = 0
+
+/area/awaymission/wwgov
+	name = "Wild West Mansion"
+	icon_state = "away2"
+	luminosity = 1
+	requires_power = 0
+
+/area/awaymission/wwrefine
+	name = "Wild West Refinery"
+	icon_state = "away3"
+	luminosity = 1
+	requires_power = 0
+
+/area/awaymission/wwvault
+	name = "Wild West Vault"
+	icon_state = "away3"
+	luminosity = 0
+
+/area/awaymission/wwvaultdoors
+	name = "Wild West Vault Doors"  // this is to keep the vault area being entirely lit because of requires_power
+	icon_state = "away2"
+	requires_power = 0
+	luminosity = 0
+
+/*
+ * Wish Granter
+ */
+/obj/machinery/wish_granter_dark
+	name = "Wish Granter"
+	desc = "You're not so sure about this, anymore..."
+	icon = 'icons/obj/device.dmi'
+	icon_state = "syndbeacon"
+
+	anchored = 1
+	density = 1
+	use_power = 0
+
+	var/chargesa = 1
+	var/insistinga = 0
+
+/obj/machinery/wish_granter_dark/attack_hand(mob/living/carbon/human/user)
+	usr.set_machine(src)
+
+	if(chargesa <= 0)
+		user << "The Wish Granter lies silent."
+		return
+
+	else if(!istype(user, /mob/living/carbon/human))
+		user << "You feel a dark stirring inside of the Wish Granter, something you want nothing of. Your instincts are better than any man's."
+		return
+
+	else if(is_special_character(user))
+		user << "Even to a heart as dark as yours, you know nothing good will come of this.  Something instinctual makes you pull away."
+
+	else if (!insistinga)
+		user << "Your first touch makes the Wish Granter stir, listening to you.  Are you really sure you want to do this?"
+		insistinga++
+
+	else
+		chargesa--
+		insistinga = 0
+		var/wish = input("You want...","Wish") as null|anything in list("Power","Wealth","Immortality","To Kill","Peace")
+		switch(wish)
+			if("Power")
+				user << "<B>Your wish is granted, but at a terrible cost...</B>"
+				user << "The Wish Granter punishes you for your selfishness, claiming your soul and warping your body to match the darkness in your heart."
+				user.dna.add_mutation(LASEREYES)
+				user.dna.add_mutation(COLDRES)
+				user.dna.add_mutation(XRAY)
+				user.set_species(/datum/species/shadow)
+			if("Wealth")
+				user << "<B>Your wish is granted, but at a terrible cost...</B>"
+				user << "The Wish Granter punishes you for your selfishness, claiming your soul and warping your body to match the darkness in your heart."
+				new /obj/structure/closet/syndicate/resources/everything(loc)
+				user.set_species(/datum/species/shadow)
+			if("Immortality")
+				user << "<B>Your wish is granted, but at a terrible cost...</B>"
+				user << "The Wish Granter punishes you for your selfishness, claiming your soul and warping your body to match the darkness in your heart."
+				user.verbs += /mob/living/carbon/proc/immortality
+				user.set_species(/datum/species/shadow)
+			if("To Kill")
+				user << "<B>Your wish is granted, but at a terrible cost...</B>"
+				user << "The Wish Granter punishes you for your wickedness, claiming your soul and warping your body to match the darkness in your heart."
+				ticker.mode.traitors += user.mind
+				user.mind.special_role = "traitor"
+				var/datum/objective/hijack/hijack = new
+				hijack.owner = user.mind
+				user.mind.objectives += hijack
+				user << "<B>Your inhibitions are swept away, the bonds of loyalty broken, you are free to murder as you please!</B>"
+				var/obj_count = 1
+				for(var/datum/objective/OBJ in user.mind.objectives)
+					user << "<B>Objective #[obj_count]</B>: [OBJ.explanation_text]"
+					obj_count++
+				user.set_species(/datum/species/shadow)
+			if("Peace")
+				user << "<B>Whatever alien sentience that the Wish Granter possesses is satisfied with your wish. There is a distant wailing as the last of the Faithless begin to die, then silence.</B>"
+				user << "You feel as if you just narrowly avoided a terrible fate..."
+				for(var/mob/living/simple_animal/hostile/faithless/F in mob_list)
+					F.death()
+
+
+///////////////Meatgrinder//////////////
+
+
+/obj/effect/meatgrinder
+	name = "Meat Grinder"
+	desc = "What is that thing?"
+	density = 1
+	anchored = 1
+	icon = 'icons/mob/blob.dmi'
+	icon_state = "blobpod"
+	var/triggered = 0
+
+/obj/effect/meatgrinder/Crossed(AM as mob|obj)
+	Bumped(AM)
+
+/obj/effect/meatgrinder/Bumped(mob/M as mob|obj)
+
+	if(triggered)
+		return
+
+	if(istype(M, /mob/living/carbon/human) && M.stat != DEAD && M.ckey)
+		for(var/mob/O in viewers(world.view, src.loc))
+		visible_message("<span class='warning'>[M] triggered the [src]!</span>")
+		triggered = 1
+
+		var/datum/effect_system/spark_spread/s = new /datum/effect_system/spark_spread
+		s.set_up(3, 1, src)
+		s.start()
+		explosion(M, 1, 0, 0, 0)
+		qdel(src)
+
+/////For the Wishgranter///////////
+
+/mob/living/carbon/proc/immortality() //Mob proc so people cant just clone themselves to get rid of the shadowperson race. No hiding your wickedness.
+	set category = "Immortality"
+	set name = "Resurrection"
+
+	var/mob/living/carbon/C = usr
+	if(!C.stat)
+		C << "<span class='notice'>You're not dead yet!</span>"
+		return
+	C << "<span class='notice'>Death is not your end!</span>"
+
+	spawn(rand(80,120))
+		C.revive(full_heal = 1, admin_revive = 1)
+		C << "<span class='notice'>You have regenerated.</span>"
+		C.visible_message("<span class='warning'>[usr] appears to wake from the dead, having healed all wounds.</span>")
+		C.update_canmove()
+	return 1