initial commit - cross reference with 5th port - obviously has compile errors

code/modules/tgui/states/admin.dm

@@ -0,0 +1,12 @@
+ /**
+  * tgui state: admin_state
+  *
+  * Checks that the user is an admin, end-of-story.
+ **/
+
+/var/global/datum/ui_state/admin_state/admin_state = new()
+
+/datum/ui_state/admin_state/can_use_topic(src_object, mob/user)
+	if(check_rights_for(user.client, R_ADMIN))
+		return UI_INTERACTIVE
+	return UI_CLOSE

code/modules/tgui/states/always.dm

@@ -0,0 +1,11 @@
+
+ /**
+  * tgui state: always_state
+  *
+  * Always grants the user UI_INTERACTIVE. Period.
+ **/
+
+/var/global/datum/ui_state/always_state/always_state = new()
+
+/datum/ui_state/always_state/can_use_topic(src_object, mob/user)
+	return UI_INTERACTIVE

code/modules/tgui/states/conscious.dm

@@ -0,0 +1,12 @@
+ /**
+  * tgui state: conscious_state
+  *
+  * Only checks if the user is conscious.
+ **/
+
+/var/global/datum/ui_state/conscious_state/conscious_state = new()
+
+/datum/ui_state/conscious_state/can_use_topic(src_object, mob/user)
+	if(user.stat == CONSCIOUS)
+		return UI_INTERACTIVE
+	return UI_CLOSE

code/modules/tgui/states/contained.dm

@@ -0,0 +1,12 @@
+ /**
+  * tgui state: contained_state
+  *
+  * Checks that the user is inside the src_object.
+ **/
+
+/var/global/datum/ui_state/contained_state/contained_state = new()
+
+/datum/ui_state/contained_state/can_use_topic(atom/src_object, mob/user)
+	if(!src_object.contains(user))
+		return UI_CLOSE
+	return user.shared_ui_interaction(src_object)

code/modules/tgui/states/deep_inventory.dm

@@ -0,0 +1,12 @@
+ /**
+  * tgui state: deep_inventory_state
+  *
+  * Checks that the src_object is in the user's deep (backpack, box, toolbox, etc) inventory.
+ **/
+
+/var/global/datum/ui_state/deep_inventory_state/deep_inventory_state = new()
+
+/datum/ui_state/deep_inventory_state/can_use_topic(src_object, mob/user)
+	if(!user.contains(src_object))
+		return UI_CLOSE
+	return user.shared_ui_interaction(src_object)

code/modules/tgui/states/default.dm

@@ -0,0 +1,60 @@
+ /**
+  * tgui state: default_state
+  *
+  * Checks a number of things -- mostly physical distance for humans and view for robots.
+ **/
+
+/var/global/datum/ui_state/default/default_state = new()
+
+/datum/ui_state/default/can_use_topic(src_object, mob/user)
+	return user.default_can_use_topic(src_object) // Call the individual mob-overriden procs.
+
+/mob/proc/default_can_use_topic(src_object)
+	return UI_CLOSE // Don't allow interaction by default.
+
+/mob/living/default_can_use_topic(src_object)
+	. = shared_ui_interaction(src_object)
+	if(. > UI_CLOSE && loc)
+		. = min(., loc.contents_ui_distance(src_object, src)) // Check the distance...
+	if(. == UI_INTERACTIVE) // Non-human living mobs can only look, not touch.
+		return UI_UPDATE
+
+/mob/living/carbon/human/default_can_use_topic(src_object)
+	. = shared_ui_interaction(src_object)
+	if(. > UI_CLOSE)
+		. = min(., shared_living_ui_distance(src_object)) // Check the distance...
+		// Derp a bit if we have brain loss.
+		if(prob(getBrainLoss()))
+			return UI_UPDATE
+
+/mob/living/silicon/robot/default_can_use_topic(src_object)
+	. = shared_ui_interaction(src_object)
+	if(. <= UI_DISABLED)
+		return
+
+	// Robots can interact with anything they can see.
+	if(get_dist(src, src_object) <= client.view)
+		return UI_INTERACTIVE
+	return UI_DISABLED // Otherwise they can keep the UI open.
+
+/mob/living/silicon/ai/default_can_use_topic(src_object)
+	. = shared_ui_interaction(src_object)
+	if(. < UI_INTERACTIVE)
+		return
+
+	// The AI can interact with anything it can see nearby, or with cameras.
+	if((get_dist(src, src_object) <= client.view) || cameranet.checkTurfVis(get_turf_pixel(src_object)))
+		return UI_INTERACTIVE
+	return UI_CLOSE
+
+/mob/living/simple_animal/drone/default_can_use_topic(src_object)
+	. = shared_ui_interaction(src_object)
+	if(. > UI_CLOSE)
+		. = min(., shared_living_ui_distance(src_object)) // Drones can only use things they're near.
+
+/mob/living/silicon/pai/default_can_use_topic(src_object)
+	// pAIs can only use themselves and the owner's radio.
+	if((src_object == src || src_object == radio) && !stat)
+		return UI_INTERACTIVE
+	else
+		return ..()

code/modules/tgui/states/hands.dm

@@ -0,0 +1,25 @@
+ /**
+  * tgui state: hands_state
+  *
+  * Checks that the src_object is in the user's hands.
+ **/
+
+/var/global/datum/ui_state/hands_state/hands_state = new()
+
+/datum/ui_state/hands_state/can_use_topic(src_object, mob/user)
+	. = user.shared_ui_interaction(src_object)
+	if(. > UI_CLOSE)
+		return min(., user.hands_can_use_topic(src_object))
+
+/mob/proc/hands_can_use_topic(src_object)
+	return UI_CLOSE
+
+/mob/living/hands_can_use_topic(src_object)
+	if(src_object in get_both_hands(src))
+		return UI_INTERACTIVE
+	return UI_CLOSE
+
+/mob/living/silicon/robot/hands_can_use_topic(src_object)
+	if(activated(src_object))
+		return UI_INTERACTIVE
+	return UI_CLOSE

code/modules/tgui/states/human_adjacent.dm

@@ -0,0 +1,17 @@
+
+ /**
+  * tgui state: human_adjacent_state
+  *
+  * In addition to default checks, only allows interaction for a
+  * human adjacent user.
+ **/
+
+/var/global/datum/ui_state/human_adjacent_state/human_adjacent_state = new()
+
+/datum/ui_state/human_adjacent_state/can_use_topic(src_object, mob/user)
+	. = user.default_can_use_topic(src_object)
+
+	var/dist = get_dist(src_object, user)
+	if((dist > 1) || (!ishuman(user)))
+		// Can't be used unless adjacent and human, even with TK
+		. = min(., UI_UPDATE)

code/modules/tgui/states/inventory.dm

@@ -0,0 +1,12 @@
+ /**
+  * tgui state: inventory_state
+  *
+  * Checks that the src_object is in the user's top-level (hand, ear, pocket, belt, etc) inventory.
+ **/
+
+/var/global/datum/ui_state/inventory_state/inventory_state = new()
+
+/datum/ui_state/inventory_state/can_use_topic(src_object, mob/user)
+	if(!(src_object in user))
+		return UI_CLOSE
+	return user.shared_ui_interaction(src_object)

code/modules/tgui/states/not_incapacitated.dm

@@ -0,0 +1,29 @@
+ /**
+  * tgui state: not_incapacitated_state
+  *
+  * Checks that the user isn't incapacitated
+ **/
+
+/var/global/datum/ui_state/not_incapacitated_state/not_incapacitated_state = new()
+
+ /**
+  * tgui state: not_incapacitated_turf_state
+  *
+  * Checks that the user isn't incapacitated and that their loc is a turf
+ **/
+
+/var/global/datum/ui_state/not_incapacitated_state/not_incapacitated_turf_state = new(no_turfs = TRUE)
+
+/datum/ui_state/not_incapacitated_state
+	var/turf_check = FALSE
+
+/datum/ui_state/not_incapacitated_state/New(loc, no_turfs = FALSE)
+	..()
+	turf_check = no_turfs
+
+/datum/ui_state/not_incapacitated_state/can_use_topic(src_object, mob/user)
+	if(user.stat)
+		return UI_CLOSE
+	if(user.incapacitated() || user.lying || (turf_check && !isturf(user.loc)))
+		return UI_DISABLED
+	return UI_INTERACTIVE

code/modules/tgui/states/notcontained.dm

@@ -0,0 +1,26 @@
+ /**
+  * tgui state: notcontained_state
+  *
+  * Checks that the user is not inside src_object, and then makes the default checks.
+ **/
+
+/var/global/datum/ui_state/notcontained_state/notcontained_state = new()
+
+/datum/ui_state/notcontained_state/can_use_topic(atom/src_object, mob/user)
+	. = user.shared_ui_interaction(src_object)
+	if(. > UI_CLOSE)
+		return min(., user.notcontained_can_use_topic(src_object))
+
+/mob/proc/notcontained_can_use_topic(src_object)
+	return UI_CLOSE
+
+/mob/living/notcontained_can_use_topic(atom/src_object)
+	if(src_object.contains(src))
+		return UI_CLOSE // Close if we're inside it.
+	return default_can_use_topic(src_object)
+
+/mob/living/silicon/notcontained_can_use_topic(src_object)
+	return default_can_use_topic(src_object) // Silicons use default bevhavior.
+
+/mob/living/simple_animal/drone/notcontained_can_use_topic(src_object)
+	return default_can_use_topic(src_object) // Drones use default bevhavior.

code/modules/tgui/states/physical.dm

@@ -0,0 +1,24 @@
+ /**
+  * tgui state: physical_state
+  *
+  * Short-circuits the default state to only check physical distance.
+ **/
+
+/var/global/datum/ui_state/physical/physical_state = new()
+
+/datum/ui_state/physical/can_use_topic(src_object, mob/user)
+	. = user.shared_ui_interaction(src_object)
+	if(. > UI_CLOSE)
+		return min(., user.physical_can_use_topic(src_object))
+
+/mob/proc/physical_can_use_topic(src_object)
+	return UI_CLOSE
+
+/mob/living/physical_can_use_topic(src_object)
+	return shared_living_ui_distance(src_object)
+
+/mob/living/silicon/physical_can_use_topic(src_object)
+	return max(UI_UPDATE, shared_living_ui_distance(src_object)) // Silicons can always see.
+
+/mob/living/silicon/ai/physical_can_use_topic(src_object)
+	return UI_UPDATE // AIs are not physical.

code/modules/tgui/states/self.dm

@@ -0,0 +1,12 @@
+ /**
+  * tgui state: self_state
+  *
+  * Only checks that the user and src_object are the same.
+ **/
+
+/var/global/datum/ui_state/self_state/self_state = new()
+
+/datum/ui_state/self_state/can_use_topic(src_object, mob/user)
+	if(src_object != user)
+		return UI_CLOSE
+	return user.shared_ui_interaction(src_object)

code/modules/tgui/states/zlevel.dm

@@ -0,0 +1,14 @@
+ /**
+  * tgui state: z_state
+  *
+  * Only checks that the Z-level of the user and src_object are the same.
+ **/
+
+/var/global/datum/ui_state/z_state/z_state = new()
+
+/datum/ui_state/z_state/can_use_topic(src_object, mob/user)
+	var/turf/turf_obj = get_turf(src_object)
+	var/turf/turf_usr = get_turf(user)
+	if(turf_obj && turf_usr && turf_obj.z == turf_usr.z)
+		return UI_INTERACTIVE
+	return UI_CLOSE