i forgot about this component. Lavaland should have sounds now

2021-11-22 14:18:46 +08:00
parent 8dcfea5817
commit 41e5034005
8 changed files with 200 additions and 30 deletions
@@ -0,0 +1,77 @@
+///Allows you to set a theme for a set of areas without tying them to looping sounds explicitly
+/datum/component/area_sound_manager
+	///area -> looping sound type
+	var/list/area_to_looping_type = list()
+	///Current sound loop
+	var/datum/looping_sound/our_loop
+	///A list of "acceptable" z levels to be on. If you leave this, we're gonna delete ourselves
+	var/list/accepted_zs
+	///The timer id of our current start delay, if it exists
+	var/timerid
+
+/datum/component/area_sound_manager/Initialize(area_loop_pairs, change_on, remove_on, acceptable_zs)
+	if(!ismovable(parent))
+		return
+	area_to_looping_type = area_loop_pairs
+	accepted_zs = acceptable_zs
+	change_the_track()
+
+	RegisterSignal(parent, COMSIG_MOVABLE_MOVED, .proc/react_to_move)
+	RegisterSignal(parent, COMSIG_MOVABLE_Z_CHANGED, .proc/react_to_z_move)
+	RegisterSignal(parent, change_on, .proc/handle_change)
+	RegisterSignal(parent, remove_on, .proc/handle_removal)
+
+/datum/component/area_sound_manager/Destroy(force, silent)
+	QDEL_NULL(our_loop)
+	. = ..()
+
+/datum/component/area_sound_manager/proc/react_to_move(datum/source, atom/oldloc, dir, forced)
+	SIGNAL_HANDLER
+	var/list/loop_lookup = area_to_looping_type
+	if(loop_lookup[get_area(oldloc)] == loop_lookup[get_area(parent)])
+		return
+	change_the_track(TRUE)
+
+/datum/component/area_sound_manager/proc/react_to_z_move(datum/source, old_z, new_z)
+	SIGNAL_HANDLER
+	if(!length(accepted_zs) || (new_z in accepted_zs))
+		return
+	qdel(src)
+
+/datum/component/area_sound_manager/proc/handle_removal(datum/source)
+	SIGNAL_HANDLER
+	qdel(src)
+
+/datum/component/area_sound_manager/proc/handle_change(datum/source)
+	SIGNAL_HANDLER
+	change_the_track()
+
+/datum/component/area_sound_manager/proc/change_the_track(skip_start = FALSE)
+	var/time_remaining = 0
+
+	if(our_loop)
+		var/our_id = our_loop.timerid || timerid
+		if(our_id)
+			time_remaining = timeleft(our_id, SSsound_loops) || 0
+			//Time left will sometimes return negative values, just ignore them and start a new sound loop now
+			time_remaining = max(time_remaining, 0)
+		QDEL_NULL(our_loop)
+
+	var/area/our_area = get_area(parent)
+	var/new_loop_type = area_to_looping_type[our_area]
+	if(!new_loop_type)
+		return
+
+	our_loop = new new_loop_type(parent, FALSE, TRUE, skip_start)
+
+	//If we're still playing, wait a bit before changing the sound so we don't double up
+	if(time_remaining)
+		timerid = addtimer(CALLBACK(src, .proc/start_looping_sound), time_remaining, TIMER_UNIQUE | TIMER_CLIENT_TIME | TIMER_STOPPABLE | TIMER_NO_HASH_WAIT | TIMER_DELETE_ME, SSsound_loops)
+		return
+	timerid = null
+	our_loop.start()
+
+/datum/component/area_sound_manager/proc/start_looping_sound()
+	timerid = null
+	if(our_loop)
+		our_loop.start()
@@ -0,0 +1,44 @@
+///This element just handles creating and destroying an area sound manager that's hooked into weather stuff
+/datum/element/weather_listener
+	element_flags = ELEMENT_BESPOKE
+	id_arg_index = 2
+	var/weather_type
+	//What events to change the track on
+	var/list/sound_change_signals
+	//The weather type we're working with
+	var/weather_trait
+	//The playlist of sounds to draw from. Pass by ref
+	var/list/playlist
+
+
+/datum/element/weather_listener/Attach(datum/target, w_type, trait, weather_playlist)
+	. = ..()
+	if(!weather_type)
+		weather_type = w_type
+		sound_change_signals = list(
+			COMSIG_WEATHER_TELEGRAPH(weather_type),
+			COMSIG_WEATHER_START(weather_type),
+			COMSIG_WEATHER_WINDDOWN(weather_type),
+			COMSIG_WEATHER_END(weather_type)
+		)
+		weather_trait = trait
+		playlist = weather_playlist
+
+	RegisterSignal(target, COMSIG_MOVABLE_Z_CHANGED, .proc/handle_z_level_change, override = TRUE)
+	RegisterSignal(target, COMSIG_MOB_CLIENT_LOGOUT, .proc/handle_logout, override = TRUE)
+
+/datum/element/weather_listener/Detach(datum/source)
+	. = ..()
+	UnregisterSignal(source, COMSIG_MOVABLE_Z_CHANGED, COMSIG_MOB_CLIENT_LOGOUT)
+
+/datum/element/weather_listener/proc/handle_z_level_change(datum/source, old_z, new_z)
+	SIGNAL_HANDLER
+	var/list/fitting_z_levels = SSmapping.levels_by_trait(weather_trait)
+	if(!(new_z in fitting_z_levels))
+		return
+	var/datum/component/our_comp = source.AddComponent(/datum/component/area_sound_manager, playlist, list(), COMSIG_MOB_CLIENT_LOGOUT, fitting_z_levels)
+	our_comp.RegisterSignal(SSdcs, sound_change_signals, /datum/component/area_sound_manager/proc/handle_change)
+
+/datum/element/weather_listener/proc/handle_logout(datum/source, client/this_is_a_null_ref)
+	SIGNAL_HANDLER
+	source.RemoveElement(/datum/element/weather_listener, weather_type, weather_trait, playlist)