diff --git a/code/__DEFINES/tgs.config.dm b/code/__DEFINES/tgs.config.dm
index a40b5d4663..9f4f63a1fc 100644
--- a/code/__DEFINES/tgs.config.dm
+++ b/code/__DEFINES/tgs.config.dm
@@ -1,4 +1,5 @@
 #define TGS_EXTERNAL_CONFIGURATION
+#define TGS_V3_API
 #define TGS_DEFINE_AND_SET_GLOBAL(Name, Value) GLOBAL_VAR_INIT(##Name, ##Value); GLOBAL_PROTECT(##Name)
 #define TGS_READ_GLOBAL(Name) GLOB.##Name
 #define TGS_WRITE_GLOBAL(Name, Value) GLOB.##Name = ##Value
diff --git a/code/__DEFINES/tgs.dm b/code/__DEFINES/tgs.dm
index db4f046ec3..dcccfc9295 100644
--- a/code/__DEFINES/tgs.dm
+++ b/code/__DEFINES/tgs.dm
@@ -107,6 +107,22 @@
 	var/commit			//full sha of compiled commit
 	var/origin_commit	//full sha of last known remote commit. This may be null if the TGS repository is not currently tracking a remote branch
 
+//represents a version of tgstation-server
+/datum/tgs_version
+	var/suite			//The suite version, can be >=3
+
+	//this group of variables can be null to represent a wild card
+	var/major					//The major version
+	var/minor					//The minor version
+	var/patch					//The patch version
+
+	var/raw_parameter			//The unparsed parameter
+	var/deprefixed_parameter	//The version only bit of raw_parameter
+
+//if the tgs_version is a wildcard version
+/datum/tgs_version/proc/Wildcard()
+	return
+
 //represents a merge of a GitHub pull request
 /datum/tgs_revision_information/test_merge
 	var/number				//pull request number
@@ -155,22 +171,22 @@
 
 //FUNCTIONS
 
-//Returns the respective string version of the API
+//Returns the respective supported /datum/tgs_version of the API
 /world/proc/TgsMaximumAPIVersion()
 	return
 
 /world/proc/TgsMinimumAPIVersion()
 	return
 
-//Gets the current version of the server tools running the server
-/world/proc/TgsVersion()
-	return
-
 //Returns TRUE if the world was launched under the server tools and the API matches, FALSE otherwise
 //No function below this succeeds if it returns FALSE
 /world/proc/TgsAvailable()
 	return
 
+//Gets the current /datum/tgs_version of the server tools running the server
+/world/proc/TgsVersion()
+	return
+
 /world/proc/TgsInstanceName()
 	return
 
diff --git a/code/__HELPERS/unsorted.dm b/code/__HELPERS/unsorted.dm
index 9cced1fdc7..2cb088c654 100644
--- a/code/__HELPERS/unsorted.dm
+++ b/code/__HELPERS/unsorted.dm
@@ -1543,3 +1543,25 @@ GLOBAL_DATUM_INIT(dview_mob, /mob/dview, new)
 	for(var/each_item in items_list)
 		for(var/i in 1 to items_list[each_item])
 			new each_item(where_to)
+
+//sends a message to chat
+//config_setting should be one of the following
+//null - noop
+//empty string - use TgsTargetBroadcast with admin_only = FALSE
+//other string - use TgsChatBroadcast with the tag that matches config_setting, only works with TGS4, if using TGS3 the above method is used
+/proc/send2chat(message, config_setting)
+	if(config_setting == null || !world.TgsAvailable())
+		return
+	var/datum/tgs_version/version = world.TgsVersion()
+	if(config_setting == "" || version.suite == 3)
+		world.TgsTargetedChatBroadcast(message, FALSE)
+		return
+
+	var/list/channels_to_use = list()
+	for(var/I in world.TgsChatChannelInfo())
+		var/datum/tgs_chat_channel/channel = I
+		if(channel.tag == config_setting)
+			channels_to_use += channel
+
+	if(channels_to_use.len)
+		world.TgsChatBroadcast()
\ No newline at end of file
diff --git a/code/controllers/configuration/entries/general.dm b/code/controllers/configuration/entries/general.dm
index 2e5b8a1852..95fd3d308e 100644
--- a/code/controllers/configuration/entries/general.dm
+++ b/code/controllers/configuration/entries/general.dm
@@ -392,6 +392,13 @@
 	config_entry_value = 50
 
 /datum/config_entry/flag/irc_announce_new_game
+	deprecated_by = /datum/config_entry/string/chat_announce_new_game
+
+/datum/config_entry/flag/irc_announce_new_game/DeprecationUpdate(value)
+	return ""	//default broadcast
+
+/datum/config_entry/string/chat_announce_new_game
+	config_entry_value = null
 
 /datum/config_entry/flag/debug_admin_hrefs
 
diff --git a/code/controllers/subsystem/server_maint.dm b/code/controllers/subsystem/server_maint.dm
index 9e926b29a1..b77c78c4bb 100644
--- a/code/controllers/subsystem/server_maint.dm
+++ b/code/controllers/subsystem/server_maint.dm
@@ -81,8 +81,8 @@ SUBSYSTEM_DEF(server_maint)
 			co.ehjax_send(data = "roundrestart")
 		if(server)	//if you set a server location in config.txt, it sends you there instead of trying to reconnect to the same world address. -- NeoFite
 			C << link("byond://[server]")
-	var/tgsversion = world.TgsVersion()
+	var/datum/tgs_version/tgsversion = world.TgsVersion()
 	if(tgsversion)
-		SSblackbox.record_feedback("text", "server_tools", 1, tgsversion)
+		SSblackbox.record_feedback("text", "server_tools", 1, tgsversion.raw_parameter)
 
 #undef PING_BUFFER_TIME
diff --git a/code/controllers/subsystem/ticker.dm b/code/controllers/subsystem/ticker.dm
index f48aa632de..fe994facdc 100755
--- a/code/controllers/subsystem/ticker.dm
+++ b/code/controllers/subsystem/ticker.dm
@@ -158,8 +158,7 @@ SUBSYSTEM_DEF(ticker)
 			for(var/client/C in GLOB.clients)
 				window_flash(C, ignorepref = TRUE) //let them know lobby has opened up.
 			to_chat(world, "<span class='boldnotice'>Welcome to [station_name()]!</span>")
-			if(CONFIG_GET(flag/irc_announce_new_game))
-				world.TgsTargetedChatBroadcast("New round starting on [SSmapping.config.map_name]!", FALSE)
+			send2chat("New round starting on [SSmapping.config.map_name]!", CONFIG_GET(string/chat_announce_new_game))
 			current_state = GAME_STATE_PREGAME
 			//Everyone who wants to be an observer is now spawned
 			create_observers()
diff --git a/code/datums/helper_datums/getrev.dm b/code/datums/helper_datums/getrev.dm
index 7d040a4982..0b0fed407c 100644
--- a/code/datums/helper_datums/getrev.dm
+++ b/code/datums/helper_datums/getrev.dm
@@ -27,7 +27,8 @@
 
 	for(var/line in testmerge)
 		var/datum/tgs_revision_information/test_merge/tm = line
-		msg += "Test merge active of PR #[tm.number] commit [tm.commit]"
+		msg += "Test merge active of PR #[tm.number] commit [tm.pull_request_commit]"
+		SSblackbox.record_feedback("associative", "testmerged_prs", 1, list("number" = "[tm.number]", "commit" = "[tm.pull_request_commit]", "title" = "[tm.title]", "author" = "[tm.author]"))
 
 	if(commit && commit != originmastercommit)
 		msg += "HEAD: [commit]"
@@ -75,7 +76,8 @@
 	else if(!pc)
 		msg += "No commit information"
 	if(world.TgsAvailable())
-		msg += "Server tools version: [world.TgsVersion()]"
+		var/datum/tgs_version/version = world.TgsVersion()
+		msg += "Server tools version: [version.raw_parameter]"
 
 	// Game mode odds
 	msg += "<br><b>Current Informational Settings:</b>"
diff --git a/code/game/world.dm b/code/game/world.dm
index 6b380e0f94..0e21641abc 100644
--- a/code/game/world.dm
+++ b/code/game/world.dm
@@ -18,7 +18,7 @@ GLOBAL_LIST(topic_status_cache)
 
 	make_datum_references_lists()	//initialises global lists for referencing frequently used datums (so that we only ever do it once)
 
-	TgsNew()
+	TgsNew(minimum_required_security_level = TGS_SECURITY_TRUSTED)
 
 	GLOB.revdata = new
 
diff --git a/code/modules/error_handler/error_handler.dm b/code/modules/error_handler/error_handler.dm
index 418b75e1ce..6a3d2c2233 100644
--- a/code/modules/error_handler/error_handler.dm
+++ b/code/modules/error_handler/error_handler.dm
@@ -19,6 +19,13 @@ GLOBAL_VAR_INIT(total_runtimes_skipped, 0)
 		log_world("The bug with recursion runtimes has been fixed. Please remove the snowflake check from world/Error in [__FILE__]:[__LINE__]")
 		return //this will never happen.
 
+	else if(copytext(E.name,1,18) == "Out of resources!")//18 == length() of that string + 1
+		log_world("BYOND out of memory. Restarting")
+		log_game("BYOND out of memory. Restarting")
+		TgsEndProcess()
+		Reboot(reason = 1)
+		return ..()
+
 	if (islist(stack_trace_storage))
 		for (var/line in splittext(E.desc, "\n"))
 			if (text2ascii(line) != 32)
diff --git a/code/modules/tgs/core/core.dm b/code/modules/tgs/core/core.dm
index 61f1e71d2e..70252cfb49 100644
--- a/code/modules/tgs/core/core.dm
+++ b/code/modules/tgs/core/core.dm
@@ -1,47 +1,60 @@
-/world/TgsNew(datum/tgs_event_handler/event_handler)
-	var/tgs_version = world.params[TGS_VERSION_PARAMETER]
-	if(!tgs_version)
+/world/TgsNew(datum/tgs_event_handler/event_handler, minimum_required_security_level = TGS_SECURITY_ULTRASAFE)
+	var/current_api = TGS_READ_GLOBAL(tgs)
+	if(current_api)
+		TGS_ERROR_LOG("TgsNew(): TGS API datum already set ([current_api])! Was TgsNew() called more than once?")
 		return
 
-	var/path = SelectTgsApi(tgs_version)
-	if(!path)
-		TGS_ERROR_LOG("Found unsupported API version: [tgs_version]. If this is a valid version please report this, backporting is done on demand.")
+#ifdef TGS_V3_API
+	minimum_required_security_level = TGS_SECURITY_TRUSTED
+#endif
+	var/raw_parameter = world.params[TGS_VERSION_PARAMETER]
+	if(!raw_parameter)
+		return
 
-	TGS_INFO_LOG("Activating API for version [tgs_version]")
-	var/datum/tgs_api/new_api = new path
+	var/datum/tgs_version/version = new(raw_parameter)
+	if(!version.Valid(FALSE))
+		TGS_ERROR_LOG("Failed to validate TGS version parameter: [raw_parameter]!")
+		return
 
-	var/result = new_api.OnWorldNew(event_handler ? event_handler : new /datum/tgs_event_handler/tgs_default)
-	if(result && result != TGS_UNIMPLEMENTED)
-		TGS_WRITE_GLOBAL(tgs, new_api)
-	else
+	var/api_datum
+	switch(version.suite)
+		if(3)
+#ifndef TGS_V3_API
+			TGS_ERROR_LOG("Detected V3 API but TGS_V3_API isn't defined!")
+#else
+			switch(version.major)
+				if(2)
+					api_datum = /datum/tgs_api/v3210
+#endif
+		if(4)
+			switch(version.major)
+				if(0)
+					api_datum = /datum/tgs_api/v4
+
+	var/datum/tgs_version/max_api_version = TgsMaximumAPIVersion();
+	if(version.suite != null && version.major != null && version.minor != null && version.patch != null && version.deprefixed_parameter > max_api_version.deprefixed_parameter)
+		TGS_ERROR_LOG("Detected unknown API version! Defaulting to latest. Update the DMAPI to fix this problem.")
+		api_datum = /datum/tgs_api/latest
+
+	if(!api_datum)
+		TGS_ERROR_LOG("Found unsupported API version: [raw_parameter]. If this is a valid version please report this, backporting is done on demand.")
+		return
+
+	TGS_INFO_LOG("Activating API for version [version.deprefixed_parameter]")
+	var/datum/tgs_api/new_api = new api_datum(version)
+
+	TGS_WRITE_GLOBAL(tgs, new_api)
+
+	var/result = new_api.OnWorldNew(event_handler, minimum_required_security_level)
+	if(!result || result == TGS_UNIMPLEMENTED)
+		TGS_WRITE_GLOBAL(tgs, null)
 		TGS_ERROR_LOG("Failed to activate API!")
 
-/world/proc/SelectTgsApi(tgs_version)
-	//remove the old 3.0 header
-	tgs_version = replacetext(tgs_version, "/tg/station 13 Server v", "")
-
-	var/list/version_bits = splittext(tgs_version, ".")
-
-	var/super = text2num(version_bits[1])
-	var/major = text2num(version_bits[2])
-	var/minor = text2num(version_bits[3])
-	var/patch = text2num(version_bits[4])
-
-	switch(super)
-		if(3)
-			switch(major)
-				if(2)
-					return /datum/tgs_api/v3210
-
-	if(super != null && major != null && minor != null && patch != null && tgs_version > TgsMaximumAPIVersion())
-		TGS_ERROR_LOG("Detected unknown API version! Defaulting to latest. Update the DMAPI to fix this problem.")
-		return /datum/tgs_api/latest
-
 /world/TgsMaximumAPIVersion()
-	return "4.0.0.0"
+	return new /datum/tgs_version("4.0.x.x")
 
 /world/TgsMinimumAPIVersion()
-	return "3.2.0.0"
+	return new /datum/tgs_version("3.2.0.0")
 
 /world/TgsInitializationComplete()
 	var/datum/tgs_api/api = TGS_READ_GLOBAL(tgs)
@@ -71,7 +84,9 @@
 	return TGS_READ_GLOBAL(tgs) != null
 
 /world/TgsVersion()
-	return world.params[TGS_VERSION_PARAMETER]
+	var/datum/tgs_api/api = TGS_READ_GLOBAL(tgs)
+	if(api)
+		return api.version
 
 /world/TgsInstanceName()
 	var/datum/tgs_api/api = TGS_READ_GLOBAL(tgs)
@@ -116,6 +131,11 @@
 	if(api)
 		api.ChatPrivateMessage(message, user)
 
+/world/TgsSecurityLevel()
+	var/datum/tgs_api/api = TGS_READ_GLOBAL(tgs)
+	if(api)
+		api.SecurityLevel()
+
 /*
 The MIT License
 
diff --git a/code/modules/tgs/core/datum.dm b/code/modules/tgs/core/datum.dm
index 6af39a75df..fb2508059a 100644
--- a/code/modules/tgs/core/datum.dm
+++ b/code/modules/tgs/core/datum.dm
@@ -1,9 +1,14 @@
 TGS_DEFINE_AND_SET_GLOBAL(tgs, null)
 
 /datum/tgs_api
+	var/datum/tgs_version/version
+
+/datum/tgs_api/New(datum/tgs_version/version)
+	. = ..()
+	src.version = version
 
 /datum/tgs_api/latest
-	parent_type = /datum/tgs_api/v3210
+	parent_type = /datum/tgs_api/v4
 
 TGS_PROTECT_DATUM(/datum/tgs_api)
 
@@ -46,6 +51,9 @@ TGS_PROTECT_DATUM(/datum/tgs_api)
 /datum/tgs_api/proc/ChatPrivateMessage(message, admin_only)
 	return TGS_UNIMPLEMENTED
 
+/datum/tgs_api/proc/SecurityLevel()
+	return TGS_UNIMPLEMENTED
+
 /*
 The MIT License
 
diff --git a/code/modules/tgs/core/default_event_handler.dm b/code/modules/tgs/core/default_event_handler.dm
deleted file mode 100644
index 716715bb26..0000000000
--- a/code/modules/tgs/core/default_event_handler.dm
+++ /dev/null
@@ -1,30 +0,0 @@
-/datum/tgs_event_handler/tgs_default/HandleEvent(event_code)
-	//TODO
-	return
-
-/*
-The MIT License
-
-Copyright (c) 2017 Jordan Brown
-
-Permission is hereby granted, free of charge,
-to any person obtaining a copy of this software and
-associated documentation files (the "Software"), to
-deal in the Software without restriction, including
-without limitation the rights to use, copy, modify,
-merge, publish, distribute, sublicense, and/or sell
-copies of the Software, and to permit persons to whom
-the Software is furnished to do so,
-subject to the following conditions:
-
-The above copyright notice and this permission notice
-shall be included in all copies or substantial portions of the Software.
-
-THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
-EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
-OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
-IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR
-ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
-TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
-SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
-*/
diff --git a/code/modules/tgs/core/tgs_version.dm b/code/modules/tgs/core/tgs_version.dm
new file mode 100644
index 0000000000..b97745611f
--- /dev/null
+++ b/code/modules/tgs/core/tgs_version.dm
@@ -0,0 +1,22 @@
+/datum/tgs_version/New(raw_parameter)
+	src.raw_parameter = raw_parameter
+	deprefixed_parameter = replacetext(raw_parameter, "/tg/station 13 Server v", "")
+	var/list/version_bits = splittext(deprefixed_parameter, ".")
+
+	suite = text2num(version_bits[1])
+	if(version_bits.len > 1)
+		major = text2num(version_bits[2])
+		if(version_bits.len > 2)
+			minor = text2num(version_bits[3])
+			if(version_bits.len == 4)
+				patch = text2num(version_bits[4])
+
+/datum/tgs_version/proc/Valid(allow_wildcards = FALSE)
+	if(suite == null)
+		return FALSE
+	if(allow_wildcards)
+		return TRUE
+	return !Wildcard()
+
+/datum/tgs_version/Wildcard()
+	return major == null || minor == null || patch == null
diff --git a/code/modules/tgs/includes.dm b/code/modules/tgs/includes.dm
index 7ca906c840..247f1fda5d 100644
--- a/code/modules/tgs/includes.dm
+++ b/code/modules/tgs/includes.dm
@@ -1,6 +1,10 @@
 #include "core\_definitions.dm"
 #include "core\core.dm"
 #include "core\datum.dm"
-#include "core\default_event_handler.dm"
+#include "core\tgs_version.dm"
+#ifdef TGS_V3_API
 #include "v3210\api.dm"
 #include "v3210\commands.dm"
+#endif
+#include "v4\api.dm"
+#include "v4\commands.dm"
diff --git a/code/modules/tgs/v3210/api.dm b/code/modules/tgs/v3210/api.dm
index 2a95f7861e..c536995b04 100644
--- a/code/modules/tgs/v3210/api.dm
+++ b/code/modules/tgs/v3210/api.dm
@@ -56,8 +56,9 @@
 /datum/tgs_api/v3210/proc/file2list(filename)
 	return splittext(trim_left(trim_right(file2text(filename))), "\n")
 
-/datum/tgs_api/v3210/OnWorldNew(datum/tgs_event_handler/event_handler)	//don't use event handling in this version
+/datum/tgs_api/v3210/OnWorldNew(datum/tgs_event_handler/event_handler, minimum_required_security_level)	//don't use event handling in this version
 	. = FALSE
+
 	comms_key = world.params[SERVICE_WORLD_PARAM]
 	instance_name = world.params[SERVICE_INSTANCE_PARAM]
 	if(!instance_name)
@@ -170,6 +171,7 @@
 	var/datum/tgs_revision_information/ri = new
 	ri.commit = commit
 	ri.origin_commit = originmastercommit
+	return ri
 
 /datum/tgs_api/v3210/EndProcess()
 	sleep(world.tick_lag)	//flush the buffers
@@ -187,9 +189,12 @@
 /datum/tgs_api/v3210/ChatTargetedBroadcast(message, admin_only)
 	ExportService("[admin_only ? SERVICE_REQUEST_IRC_ADMIN_CHANNEL_MESSAGE : SERVICE_REQUEST_IRC_BROADCAST] [message]")
 
-/datum/tgs_api/v3210/ChatPrivateMessage(message, admin_only)
+/datum/tgs_api/v3210/ChatPrivateMessage(message, datum/tgs_chat_user/user)
 	return TGS_UNIMPLEMENTED
 
+/datum/tgs_api/v3210/SecurityLevel()
+	return TGS_SECURITY_TRUSTED
+
 #undef REBOOT_MODE_NORMAL
 #undef REBOOT_MODE_HARD
 #undef REBOOT_MODE_SHUTDOWN
diff --git a/code/modules/tgs/v4/api.dm b/code/modules/tgs/v4/api.dm
new file mode 100644
index 0000000000..b61cddbeba
--- /dev/null
+++ b/code/modules/tgs/v4/api.dm
@@ -0,0 +1,342 @@
+#define TGS4_PARAM_INFO_JSON "tgs_json"
+
+#define TGS4_INTEROP_ACCESS_IDENTIFIER "tgs_tok"
+
+#define TGS4_RESPONSE_SUCCESS "tgs_succ"
+
+#define TGS4_TOPIC_CHANGE_PORT "tgs_port"
+#define TGS4_TOPIC_CHANGE_REBOOT_MODE "tgs_rmode"
+#define TGS4_TOPIC_CHAT_COMMAND "tgs_chat_comm"
+#define TGS4_TOPIC_EVENT "tgs_event"
+#define TGS4_TOPIC_INTEROP_RESPONSE "tgs_interop"
+
+#define TGS4_COMM_NEW_PORT "tgs_new_port"
+#define TGS4_COMM_VALIDATE "tgs_validate"
+#define TGS4_COMM_SERVER_PRIMED "tgs_prime"
+#define TGS4_COMM_WORLD_REBOOT "tgs_reboot"
+#define TGS4_COMM_END_PROCESS "tgs_kill"
+#define TGS4_COMM_CHAT "tgs_chat_send"
+
+#define TGS4_PARAMETER_COMMAND "tgs_com"
+#define TGS4_PARAMETER_DATA "tgs_data"
+
+#define TGS4_PORT_CRITFAIL_MESSAGE " Must exit to let watchdog reboot..."
+
+#define EXPORT_TIMEOUT_DS 200
+
+/datum/tgs_api/v4
+	var/access_identifier
+	var/instance_name
+	var/json_path
+	var/chat_channels_json_path
+	var/chat_commands_json_path
+	var/server_commands_json_path
+	var/reboot_mode = TGS_REBOOT_MODE_NORMAL
+	var/security_level
+
+	var/requesting_new_port = FALSE
+
+	var/list/intercepted_message_queue
+
+	var/list/custom_commands
+
+	var/list/cached_test_merges
+	var/datum/tgs_revision_information/cached_revision
+
+	var/datum/tgs_event_handler/event_handler
+
+	var/export_lock = FALSE
+	var/list/last_interop_response
+
+/datum/tgs_api/v4/ApiVersion()
+	return "4.0.0.0"
+
+/datum/tgs_api/v4/OnWorldNew(datum/tgs_event_handler/event_handler, minimum_required_security_level)
+	json_path = world.params[TGS4_PARAM_INFO_JSON]
+	if(!json_path)
+		TGS_ERROR_LOG("Missing [TGS4_PARAM_INFO_JSON] world parameter!")
+		return
+	var/json_file = file2text(json_path)
+	if(!json_file)
+		TGS_ERROR_LOG("Missing specified json file: [json_path]")
+		return
+	var/cached_json = json_decode(json_file)
+	if(!cached_json)
+		TGS_ERROR_LOG("Failed to decode info json: [json_file]")
+		return
+
+	access_identifier = cached_json["accessIdentifier"]
+	server_commands_json_path = cached_json["serverCommandsJson"]
+
+	if(cached_json["apiValidateOnly"])
+		TGS_INFO_LOG("Validating API and exiting...")
+		Export(TGS4_COMM_VALIDATE, list(TGS4_PARAMETER_DATA = "[minimum_required_security_level]"))
+		del(world)
+
+	security_level = cached_json["securityLevel"]
+	chat_channels_json_path = cached_json["chatChannelsJson"]
+	chat_commands_json_path = cached_json["chatCommandsJson"]
+	src.event_handler = event_handler
+	instance_name = cached_json["instanceName"]
+
+	ListCustomCommands()
+
+	var/list/revisionData = cached_json["revision"]
+	if(revisionData)
+		cached_revision = new
+		cached_revision.commit = revisionData["commitSha"]
+		cached_revision.origin_commit = revisionData["originCommitSha"]
+
+	cached_test_merges = list()
+	var/list/json = cached_json["testMerges"]
+	for(var/entry in json)
+		var/datum/tgs_revision_information/test_merge/tm = new
+		tm.time_merged = text2num(entry["timeMerged"])
+
+		var/list/revInfo = entry["revision"]
+		if(revInfo)
+			tm.commit = revInfo["commitSha"]
+			tm.origin_commit = revInfo["originCommitSha"]
+
+		tm.title = entry["titleAtMerge"]
+		tm.body = entry["bodyAtMerge"]
+		tm.url = entry["url"]
+		tm.author = entry["author"]
+		tm.number = entry["number"]
+		tm.pull_request_commit = entry["pullRequestRevision"]
+		tm.comment = entry["comment"]
+
+		cached_test_merges += tm
+
+	return TRUE
+
+/datum/tgs_api/v4/OnInitializationComplete()
+	Export(TGS4_COMM_SERVER_PRIMED)
+
+	var/tgs4_secret_sleep_offline_sauce = 24051994
+	var/old_sleep_offline = world.sleep_offline
+	world.sleep_offline = tgs4_secret_sleep_offline_sauce
+	sleep(1)
+	if(world.sleep_offline == tgs4_secret_sleep_offline_sauce)	//if not someone changed it
+		world.sleep_offline = old_sleep_offline
+
+/datum/tgs_api/v4/OnTopic(T)
+	var/list/params = params2list(T)
+	var/their_sCK = params[TGS4_INTEROP_ACCESS_IDENTIFIER]
+	if(!their_sCK)
+		return FALSE	//continue world/Topic
+
+	if(their_sCK != access_identifier)
+		return "Invalid comms key!";
+
+	var/command = params[TGS4_PARAMETER_COMMAND]
+	if(!command)
+		return "No command!"
+
+	. = TGS4_RESPONSE_SUCCESS
+
+	switch(command)
+		if(TGS4_TOPIC_CHAT_COMMAND)
+			var/result = HandleCustomCommand(params[TGS4_PARAMETER_DATA])
+			if(result == null)
+				result = "Error running chat command!"
+			return result
+		if(TGS4_TOPIC_EVENT)
+			intercepted_message_queue = list()
+			var/list/event_notification = json_decode(params[TGS4_PARAMETER_DATA])
+			var/list/event_parameters = event_notification["Parameters"]
+
+			var/list/event_call = list(event_notification["Type"])
+			if(event_parameters)
+				event_call += event_parameters
+
+			if(event_handler != null)
+				event_handler.HandleEvent(arglist(event_call))
+
+			. = json_encode(intercepted_message_queue)
+			intercepted_message_queue = null
+			return
+		if(TGS4_TOPIC_INTEROP_RESPONSE)
+			last_interop_response = json_decode(params[TGS4_PARAMETER_DATA])
+			return
+		if(TGS4_TOPIC_CHANGE_PORT)
+			var/new_port = text2num(params[TGS4_PARAMETER_DATA])
+			if (!(new_port > 0))
+				return "Invalid port: [new_port]"
+
+			//the topic still completes, miraculously
+			//I honestly didn't believe byond could do it
+			if(event_handler != null)
+				event_handler.HandleEvent(TGS_EVENT_PORT_SWAP, new_port)
+			if(!world.OpenPort(new_port))
+				return "Port change failed!"
+			return
+		if(TGS4_TOPIC_CHANGE_REBOOT_MODE)
+			var/new_reboot_mode = text2num(params[TGS4_PARAMETER_DATA])
+			if(event_handler != null)
+				event_handler.HandleEvent(TGS_EVENT_REBOOT_MODE_CHANGE, reboot_mode, new_reboot_mode)
+			reboot_mode = new_reboot_mode
+			return
+
+	return "Unknown command: [command]"
+
+/datum/tgs_api/v4/proc/Export(command, list/data, override_requesting_new_port = FALSE)
+	if(!data)
+		data = list()
+	data[TGS4_PARAMETER_COMMAND] = command
+	var/json = json_encode(data)
+
+	while(requesting_new_port && !override_requesting_new_port)
+		sleep(1)
+
+	//we need some port open at this point to facilitate return communication
+	if(!world.port)
+		requesting_new_port = TRUE
+		if(!world.OpenPort(0)) //open any port
+			TGS_ERROR_LOG("Unable to open random port to retrieve new port![TGS4_PORT_CRITFAIL_MESSAGE]")
+			del(world)
+
+		//request a new port
+		export_lock = FALSE
+		var/list/new_port_json = Export(TGS4_COMM_NEW_PORT, list(TGS4_PARAMETER_DATA = "[world.port]"), TRUE)	//stringify this on purpose
+
+		if(!new_port_json)
+			TGS_ERROR_LOG("No new port response from server![TGS4_PORT_CRITFAIL_MESSAGE]")
+			del(world)
+
+		var/new_port = new_port_json[TGS4_PARAMETER_DATA]
+		if(!isnum(new_port) || new_port <= 0)
+			TGS_ERROR_LOG("Malformed new port json ([json_encode(new_port_json)])![TGS4_PORT_CRITFAIL_MESSAGE]")
+			del(world)
+
+		if(new_port != world.port && !world.OpenPort(new_port))
+			TGS_ERROR_LOG("Unable to open port [new_port]![TGS4_PORT_CRITFAIL_MESSAGE]")
+			del(world)
+		requesting_new_port = FALSE
+
+	while(export_lock)
+		sleep(1)
+	export_lock = TRUE
+
+	last_interop_response = null
+	fdel(server_commands_json_path)
+	text2file(json, server_commands_json_path)
+
+	for(var/I = 0; I < EXPORT_TIMEOUT_DS && !last_interop_response; ++I)
+		sleep(1)
+
+	if(!last_interop_response)
+		TGS_ERROR_LOG("Failed to get export result for: [json]")
+	else
+		. = last_interop_response
+
+	export_lock = FALSE
+
+/datum/tgs_api/v4/OnReboot()
+	var/list/result = Export(TGS4_COMM_WORLD_REBOOT)
+	if(!result)
+		return
+
+	//okay so the standard TGS4 proceedure is: right before rebooting change the port to whatever was sent to us in the above json's data parameter
+
+	var/port = result[TGS4_PARAMETER_DATA]
+	if(!isnum(port))
+		return	//this is valid, server may just want use to reboot
+
+	if(port == 0)
+		//to byond 0 means any port and "none" means close vOv
+		port = "none"
+
+	if(!world.OpenPort(port))
+		TGS_ERROR_LOG("Unable to set port to [port]!")
+
+/datum/tgs_api/v4/InstanceName()
+	return instance_name
+
+/datum/tgs_api/v4/TestMerges()
+	return cached_test_merges
+
+/datum/tgs_api/v4/EndProcess()
+	Export(TGS4_COMM_END_PROCESS)
+
+/datum/tgs_api/v4/Revision()
+	return cached_revision
+
+/datum/tgs_api/v4/ChatBroadcast(message, list/channels)
+	var/list/ids
+	if(length(channels))
+		ids = list()
+		for(var/I in channels)
+			var/datum/tgs_chat_channel/channel = I
+			ids += channel.id
+	message = list("message" = message, "channelIds" = ids)
+	if(intercepted_message_queue)
+		intercepted_message_queue += list(message)
+	else
+		Export(TGS4_COMM_CHAT, message)
+
+/datum/tgs_api/v4/ChatTargetedBroadcast(message, admin_only)
+	var/list/channels = list()
+	for(var/I in ChatChannelInfo())
+		var/datum/tgs_chat_channel/channel = I
+		if (!channel.is_private_channel && ((channel.is_admin_channel && admin_only) || (!channel.is_admin_channel && !admin_only)))
+			channels += channel.id
+	message = list("message" = message, "channelIds" = channels)
+	if(intercepted_message_queue)
+		intercepted_message_queue += list(message)
+	else
+		Export(TGS4_COMM_CHAT, message)
+
+/datum/tgs_api/v4/ChatPrivateMessage(message, datum/tgs_chat_user/user)
+	message = list("message" = message, "channelIds" = list(user.channel.id))
+	if(intercepted_message_queue)
+		intercepted_message_queue += list(message)
+	else
+		Export(TGS4_COMM_CHAT, message)
+
+/datum/tgs_api/v4/ChatChannelInfo()
+	. = list()
+	//no caching cause tgs may change this
+	var/list/json = json_decode(file2text(chat_channels_json_path))
+	for(var/I in json)
+		. += DecodeChannel(I)
+
+/datum/tgs_api/v4/proc/DecodeChannel(channel_json)
+	var/datum/tgs_chat_channel/channel = new
+	channel.id = channel_json["id"]
+	channel.friendly_name = channel_json["friendlyName"]
+	channel.connection_name = channel_json["connectionName"]
+	channel.is_admin_channel = channel_json["isAdminChannel"]
+	channel.is_private_channel = channel_json["isPrivateChannel"]
+	channel.custom_tag = channel_json["tag"]
+	return channel
+
+/datum/tgs_api/v4/SecurityLevel()
+	return security_level
+
+/*
+The MIT License
+
+Copyright (c) 2017 Jordan Brown
+
+Permission is hereby granted, free of charge,
+to any person obtaining a copy of this software and
+associated documentation files (the "Software"), to
+deal in the Software without restriction, including
+without limitation the rights to use, copy, modify,
+merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom
+the Software is furnished to do so,
+subject to the following conditions:
+
+The above copyright notice and this permission notice
+shall be included in all copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
+EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
+OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
+IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR
+ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
+TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
+SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
+*/
diff --git a/code/modules/tgs/v4/commands.dm b/code/modules/tgs/v4/commands.dm
new file mode 100644
index 0000000000..af21a86fb6
--- /dev/null
+++ b/code/modules/tgs/v4/commands.dm
@@ -0,0 +1,69 @@
+/datum/tgs_api/v4/proc/ListCustomCommands()
+	var/results = list()
+	custom_commands = list()
+	for(var/I in typesof(/datum/tgs_chat_command) - /datum/tgs_chat_command)
+		var/datum/tgs_chat_command/stc = new I
+		var/command_name = stc.name
+		if(!command_name || findtext(command_name, " ") || findtext(command_name, "'") || findtext(command_name, "\""))
+			TGS_ERROR_LOG("Custom command [command_name] ([I]) can't be used as it is empty or contains illegal characters!")
+			continue
+
+		if(results[command_name])
+			var/datum/other = custom_commands[command_name]
+			TGS_ERROR_LOG("Custom commands [other.type] and [I] have the same name (\"[command_name]\"), only [other.type] will be available!")
+			continue
+		results += list(list("name" = command_name, "help_text" = stc.help_text, "admin_only" = stc.admin_only))
+		custom_commands[command_name] = stc
+
+	var/commands_file = chat_commands_json_path
+	if(!commands_file)
+		return
+	text2file(json_encode(results), commands_file)
+
+/datum/tgs_api/v4/proc/HandleCustomCommand(command_json)
+	var/list/data = json_decode(command_json)
+	var/command = data["command"]
+	var/user = data["user"]
+	var/params = data["params"]
+
+	var/datum/tgs_chat_user/u = new
+	u.id = user["id"]
+	u.friendly_name = user["friendlyName"]
+	u.mention = user["mention"]
+	u.channel = DecodeChannel(user["channel"])
+
+	var/datum/tgs_chat_command/sc = custom_commands[command]
+	if(sc)
+		var/result = sc.Run(u, params)
+		if(result == null)
+			result = ""
+		return result
+	return "Unknown command: [command]!"
+
+/*
+
+The MIT License
+
+Copyright (c) 2017 Jordan Brown
+
+Permission is hereby granted, free of charge,
+to any person obtaining a copy of this software and
+associated documentation files (the "Software"), to
+deal in the Software without restriction, including
+without limitation the rights to use, copy, modify,
+merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom
+the Software is furnished to do so,
+subject to the following conditions:
+
+The above copyright notice and this permission notice
+shall be included in all copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
+EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
+OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
+IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR
+ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
+TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
+SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
+*/
diff --git a/config/config.txt b/config/config.txt
index b91e8fce33..30c13cfdf7 100644
--- a/config/config.txt
+++ b/config/config.txt
@@ -448,8 +448,14 @@ MINUTE_CLICK_LIMIT 400
 ##How long to wait between messaging admins about occurences of a unique error
 #ERROR_MSG_DELAY 50
 
-## Send a message to IRC when starting a new game
-#IRC_ANNOUNCE_NEW_GAME
+## Chat Announce Options
+## Various messages to be sent to game chats
+## Uncommenting these will enable them, by default they will be broadcast to Game chat channels on TGS3 or non-admin channels on TGS4
+## If using TGS4, the string option can be set as a chat channel tag to limit the message to channels of that tag type (case-sensitive)
+## i.e. CHAT_ANNOUNCE_NEW_GAME chat_channel_tag
+
+## Send a message with the station name starting a new game
+#CHAT_ANNOUNCE_NEW_GAME
 
 ## Allow admin hrefs that don't use the new token system, will eventually be removed
 DEBUG_ADMIN_HREFS
diff --git a/tools/tgs4_scripts/PostCompile.bat b/tools/tgs4_scripts/PostCompile.bat
deleted file mode 100644
index 47aae169c6..0000000000
--- a/tools/tgs4_scripts/PostCompile.bat
+++ /dev/null
@@ -1,3 +0,0 @@
-@echo off
-
-powershell -NoProfile -ExecutionPolicy Bypass -File PostCompile.ps1 -game_path %1
diff --git a/tools/tgs4_scripts/PostCompile.ps1 b/tools/tgs4_scripts/PostCompile.ps1
deleted file mode 100644
index 8e46fa8061..0000000000
--- a/tools/tgs4_scripts/PostCompile.ps1
+++ /dev/null
@@ -1,18 +0,0 @@
-param(
-    $game_path
-)
-
-Write-Host "Deploying tgstation compilation..."
-
-cd $game_path
-
-mkdir build
-
-#.github is a little special cause of the prefix
-mv .github build/.github
-
-mv * build   #thank god it's that easy 
-
-&"build/tools/deploy.sh" $game_path $game_path/build
-
-Remove-Item build -Recurse