runtime cleanup!

This reverts commit ceebde6620.
2017-02-07 23:30:59 -06:00
parent ceebde6620
commit 463bcc2f31
135 changed files with 366168 additions and 0 deletions
@@ -0,0 +1,62 @@
+/proc/gibs(atom/location, list/viruses, datum/dna/MobDNA)
+	new /obj/effect/gibspawner/generic(location,viruses,MobDNA)
+
+/proc/hgibs(atom/location, list/viruses, datum/dna/MobDNA)
+	new /obj/effect/gibspawner/human(location,viruses,MobDNA)
+
+/proc/xgibs(atom/location, list/viruses)
+	new /obj/effect/gibspawner/xeno(location,viruses)
+
+/proc/robogibs(atom/location, list/viruses)
+	new /obj/effect/gibspawner/robot(location,viruses)
+
+/obj/effect/gibspawner
+	var/sparks = 0 //whether sparks spread on Gib()
+	var/virusProb = 20 //the chance for viruses to spread on the gibs
+	var/list/gibtypes = list()
+	var/list/gibamounts = list()
+	var/list/gibdirections = list() //of lists
+
+/obj/effect/gibspawner/New(location, var/list/viruses, var/datum/dna/MobDNA)
+	..()
+
+	Gib(loc,viruses,MobDNA)
+
+/obj/effect/gibspawner/proc/Gib(atom/location, list/viruses = list(), datum/dna/MobDNA = null)
+	if(gibtypes.len != gibamounts.len || gibamounts.len != gibdirections.len)
+		world << "<span class='danger'>Gib list length mismatch!</span>"
+		return
+
+	var/obj/effect/decal/cleanable/blood/gibs/gib = null
+
+	if(sparks)
+		var/datum/effect_system/spark_spread/s = new /datum/effect_system/spark_spread
+		s.set_up(2, 1, location)
+		s.start()
+
+	for(var/i = 1, i<= gibtypes.len, i++)
+		if(gibamounts[i])
+			for(var/j = 1, j<= gibamounts[i], j++)
+				var/gibType = gibtypes[i]
+				gib = new gibType(location)
+				if(istype(location,/mob/living/carbon))
+					var/mob/living/carbon/digester = location
+					digester.stomach_contents += gib
+
+				if(viruses.len > 0)
+					for(var/datum/disease/D in viruses)
+						if(prob(virusProb))
+							var/datum/disease/viruus = D.Copy(1)
+							gib.viruses += viruus
+							viruus.holder = gib
+
+				if(MobDNA)
+					gib.blood_DNA[MobDNA.unique_enzymes] = MobDNA.blood_type
+				else if(istype(src, /obj/effect/gibspawner/generic)) // Probably a monkey
+					gib.blood_DNA["Non-human DNA"] = "A+"
+				var/list/directions = gibdirections[i]
+				if(istype(loc,/turf))
+					if(directions.len)
+						gib.streak(directions)
+
+	qdel(src)
@@ -0,0 +1,25 @@
+/obj/item/device/boobytrap
+	name = "booby trap"
+	desc = null //Different examine for traitors
+	item_state = "electronic"
+	icon_state = "boobytrap"
+	w_class = 1
+	throw_range = 4
+	throw_speed = 1
+	flags = NOBLUDGEON
+	force = 3
+	attack_verb = list("trapped", "rused", "tricked")
+	materials = list(MAT_METAL=50, MAT_GLASS=30)
+	origin_tech = "syndicate=1;combat=3;engineering=3"
+
+/obj/item/device/boobytrap/proc/blow()
+	explosion(src.loc,0,0,2,4,flame_range = 4)
+	qdel(src)
+
+/obj/item/device/boobytrap/examine(mob/user)
+	..()
+	if(user.mind in ticker.mode.traitors) //No nuke ops because the device is excluded from nuclear
+		user << "A small device used to rig lockers and boxes with an explosive surprise. \
+		To use, simply attach it to a box or a locker."
+	else
+		user << "A suspicious array of delicate wires and parts."
@@ -0,0 +1,35 @@
+/obj/item/modkit
+	name = "modification kit"
+	desc = "A one-use kit, which enables kinetic accelerators to retain their \
+		charge when away from a bioelectric source, renders them immune to \
+		interference with other accelerators, as well as allowing less \
+		dextrous races to use the tool."
+	icon = 'icons/obj/objects.dmi'
+	icon_state = "modkit"
+	origin_tech = "programming=2;materials=2;magnets=4"
+	var/uses = 1
+
+/obj/item/modkit/afterattack(obj/item/weapon/gun/energy/kinetic_accelerator/C, mob/user)
+	..()
+	if(!uses)
+		qdel(src)
+		return
+	if(!istype(C))
+		user << "<span class='warning'>This kit can only modify kinetic \
+			accelerators!</span>"
+		return ..()
+	// RIP the 'improved improved improved improved kinetic accelerator
+	if(C.holds_charge && C.unique_frequency)
+		user << "<span class='warning'>This kinetic accelerator already has \
+			these upgrades.</span>"
+		return ..()
+
+	user <<"<span class='notice'>You modify the [C], adjusting the trigger \
+		guard and internal capacitor.</span>"
+	C.name = "improved [C.name]"
+	C.holds_charge = TRUE
+	C.unique_frequency = TRUE
+	C.trigger_guard = TRIGGER_GUARD_ALLOW_ALL
+	uses--
+	if(!uses)
+		qdel(src)