runtime cleanup!

This reverts commit ceebde6620.
2017-02-07 23:30:59 -06:00
parent ceebde6620
commit 463bcc2f31
135 changed files with 366168 additions and 0 deletions
--- a/code/modules/admin/banappearance.dm
+++ b/code/modules/admin/banappearance.dm
@@ -0,0 +1,110 @@
+//ban people from using custom names and appearances. that'll show 'em.
+
+var/appearanceban_runonce	//Updates legacy bans with new info
+var/appearance_keylist[0]	//to store the keys
+
+/proc/appearance_fullban(mob/M, reason)
+	if (!M || !M.key) return
+	appearance_keylist.Add(text("[M.ckey] ## [reason]"))
+	appearance_savebanfile()
+
+/proc/appearance_client_fullban(ckey)
+	if (!ckey) return
+	appearance_keylist.Add(text("[ckey]"))
+	appearance_savebanfile()
+
+//returns a reason if M is banned, returns 0 otherwise
+/proc/appearance_isbanned(mob/M)
+	if(M)
+		for(var/s in appearance_keylist)
+			if(findtext(s, "[M.ckey]") == 1)
+				var/startpos = findtext(s, "## ") + 3
+				if(startpos && startpos < length(s))
+					var/text = copytext(s, startpos, 0)
+					if(text)
+						return text
+				return "Reason Unspecified"
+	return 0
+
+/*
+DEBUG
+/mob/verb/list_all_appearances()
+	set name = "list all appearances"
+
+	for(var/s in appearance_keylist)
+		world << s
+
+/mob/verb/reload_appearances()
+	set name = "reload appearances"
+
+	appearance_loadbanfile()
+*/
+
+/proc/appearance_loadbanfile()
+	if(config.ban_legacy_system)
+		var/savefile/S=new("data/appearance_full.ban")
+		S["keys[0]"] >> appearance_keylist
+		log_admin("Loading appearance_rank")
+		S["runonce"] >> appearanceban_runonce
+
+		if (!length(appearance_keylist))
+			appearance_keylist=list()
+			log_admin("appearance_keylist was empty")
+	else
+		if(!establish_db_connection())
+			world.log << "Database connection failed. Reverting to the legacy ban system."
+			diary << "Database connection failed. Reverting to the legacy ban system."
+			config.ban_legacy_system = 1
+			appearance_loadbanfile()
+			return
+
+		//appearance bans
+		var/DBQuery/query = dbcon.NewQuery("SELECT ckey FROM [format_table_name("ban")] WHERE bantype = 'APPEARANCE_PERMABAN' AND NOT unbanned = 1")
+		query.Execute()
+
+		while(query.NextRow())
+			var/ckey = query.item[1]
+
+			appearance_keylist.Add("[ckey]")
+
+/proc/appearance_savebanfile()
+	var/savefile/S=new("data/appearance_full.ban")
+	S["keys[0]"] << appearance_keylist
+
+/proc/appearance_unban(mob/M)
+	appearance_remove("[M.ckey]")
+	appearance_savebanfile()
+
+
+/proc/appearance_updatelegacybans()
+	if(!appearanceban_runonce)
+		log_admin("Updating appearancefile!")
+		// Updates bans.. Or fixes them. Either way.
+		for(var/T in appearance_keylist)
+			if(!T)
+				continue
+		appearanceban_runonce++	//don't run this update again
+
+
+/proc/appearance_remove(X)
+	for (var/i = 1; i <= length(appearance_keylist); i++)
+		if( findtext(appearance_keylist[i], "[X]") )
+			appearance_keylist.Remove(appearance_keylist[i])
+			appearance_savebanfile()
+			return 1
+	return 0
+
+/*
+/proc/DB_ban_isappearancebanned(var/playerckey)
+	establish_db_connection()
+	if(!dbcon.IsConnected())
+		return
+
+	var/sqlplayerckey = sanitizeSQL(ckey(playerckey))
+
+	var/DBQuery/query = dbcon.NewQuery("SELECT id FROM [format_table_name("ban")] WHERE CKEY = '[sqlplayerckey]' AND ((bantype = 'APPEARANCE_PERMABAN') OR (bantype = 'APPEARANCE_TEMPBAN' AND expiration_time > Now())) AND unbanned != 1")
+	query.Execute()
+	while(query.NextRow())
+		return 1
+	return 0
+*/
--- a/code/modules/admin/sql_notes.dm
+++ b/code/modules/admin/sql_notes.dm
@@ -0,0 +1,217 @@
+/proc/add_note(target_ckey, notetext, timestamp, adminckey, logged = 1, server)
+	if(!dbcon.IsConnected())
+		usr << "<span class='danger'>Failed to establish database connection.</span>"
+		return
+	if(!target_ckey)
+		var/new_ckey = ckey(input(usr,"Who would you like to add a note for?","Enter a ckey",null) as text)
+		if(!new_ckey)
+			return
+		new_ckey = sanitizeSQL(new_ckey)
+		var/DBQuery/query_find_ckey = dbcon.NewQuery("SELECT ckey FROM [format_table_name("player")] WHERE ckey = '[new_ckey]'")
+		if(!query_find_ckey.Execute())
+			var/err = query_find_ckey.ErrorMsg()
+			log_game("SQL ERROR obtaining ckey from player table. Error : \[[err]\]\n")
+			return
+		if(!query_find_ckey.NextRow())
+			if(alert(usr, "[new_ckey] has not been seen before, are you sure you want to add them to the watchlist?", "Unknown ckey", "Yes", "No", "Cancel") != "Yes")
+				return
+		target_ckey = new_ckey
+	var/target_sql_ckey = sanitizeSQL(target_ckey)
+	if(!notetext)
+		notetext = input(usr,"Write your Note","Add Note") as message
+		if(!notetext)
+			return
+	notetext = sanitizeSQL(notetext)
+	if(!timestamp)
+		timestamp = SQLtime()
+	if(!adminckey)
+		adminckey = usr.ckey
+		if(!adminckey)
+			return
+	var/admin_sql_ckey = sanitizeSQL(adminckey)
+	if(!server)
+		if (config && config.server_name)
+			server = config.server_name
+	server = sanitizeSQL(server)
+	var/DBQuery/query_noteadd = dbcon.NewQuery("INSERT INTO [format_table_name("notes")] (ckey, timestamp, notetext, adminckey, server) VALUES ('[target_sql_ckey]', '[timestamp]', '[notetext]', '[admin_sql_ckey]', '[server]')")
+	if(!query_noteadd.Execute())
+		var/err = query_noteadd.ErrorMsg()
+		log_game("SQL ERROR adding new note to table. Error : \[[err]\]\n")
+		return
+	if(logged)
+		log_admin("[key_name(usr)] has added a note to [target_ckey]: [notetext]")
+		message_admins("[key_name_admin(usr)] has added a note to [target_ckey]:<br>[notetext]")
+		show_note(target_ckey)
+
+/proc/remove_note(note_id)
+	var/ckey
+	var/notetext
+	var/adminckey
+	if(!dbcon.IsConnected())
+		usr << "<span class='danger'>Failed to establish database connection.</span>"
+		return
+	if(!note_id)
+		return
+	note_id = text2num(note_id)
+	var/DBQuery/query_find_note_del = dbcon.NewQuery("SELECT ckey, notetext, adminckey FROM [format_table_name("notes")] WHERE id = [note_id]")
+	if(!query_find_note_del.Execute())
+		var/err = query_find_note_del.ErrorMsg()
+		log_game("SQL ERROR obtaining ckey, notetext, adminckey from notes table. Error : \[[err]\]\n")
+		return
+	if(query_find_note_del.NextRow())
+		ckey = query_find_note_del.item[1]
+		notetext = query_find_note_del.item[2]
+		adminckey = query_find_note_del.item[3]
+	var/DBQuery/query_del_note = dbcon.NewQuery("DELETE FROM [format_table_name("notes")] WHERE id = [note_id]")
+	if(!query_del_note.Execute())
+		var/err = query_del_note.ErrorMsg()
+		log_game("SQL ERROR removing note from table. Error : \[[err]\]\n")
+		return
+	log_admin("[key_name(usr)] has removed a note made by [adminckey] from [ckey]: [notetext]")
+	message_admins("[key_name_admin(usr)] has removed a note made by [adminckey] from [ckey]:<br>[notetext]")
+	show_note(ckey)
+
+/proc/edit_note(note_id)
+	if(!dbcon.IsConnected())
+		usr << "<span class='danger'>Failed to establish database connection.</span>"
+		return
+	if(!note_id)
+		return
+	note_id = text2num(note_id)
+	var/target_ckey
+	var/sql_ckey = sanitizeSQL(usr.ckey)
+	var/DBQuery/query_find_note_edit = dbcon.NewQuery("SELECT ckey, notetext, adminckey FROM [format_table_name("notes")] WHERE id = [note_id]")
+	if(!query_find_note_edit.Execute())
+		var/err = query_find_note_edit.ErrorMsg()
+		log_game("SQL ERROR obtaining notetext from notes table. Error : \[[err]\]\n")
+		return
+	if(query_find_note_edit.NextRow())
+		target_ckey = query_find_note_edit.item[1]
+		var/old_note = query_find_note_edit.item[2]
+		var/adminckey = query_find_note_edit.item[3]
+		var/new_note = input("Input new note", "New Note", "[old_note]") as message
+		if(!new_note)
+			return
+		new_note = sanitizeSQL(new_note)
+		var/edit_text = "Edited by [sql_ckey] on [SQLtime()] from<br>[old_note]<br>to<br>[new_note]<hr>"
+		edit_text = sanitizeSQL(edit_text)
+		var/DBQuery/query_update_note = dbcon.NewQuery("UPDATE [format_table_name("notes")] SET notetext = '[new_note]', last_editor = '[sql_ckey]', edits = CONCAT(IFNULL(edits,''),'[edit_text]') WHERE id = [note_id]")
+		if(!query_update_note.Execute())
+			var/err = query_update_note.ErrorMsg()
+			log_game("SQL ERROR editing note. Error : \[[err]\]\n")
+			return
+		log_admin("[key_name(usr)] has edited [target_ckey]'s note made by [adminckey] from [old_note] to [new_note]")
+		message_admins("[key_name_admin(usr)] has edited [target_ckey]'s note made by [adminckey] from<br>[old_note]<br>to<br>[new_note]")
+		show_note(target_ckey)
+
+/proc/show_note(target_ckey, index, linkless = 0)
+	var/output
+	var/navbar
+	var/ruler
+	ruler = "<hr style='background:#000000; border:0; height:3px'>"
+	navbar = "<a href='?_src_=holder;nonalpha=1'>\[All\]</a>|<a href='?_src_=holder;nonalpha=2'>\[#\]</a>"
+	for(var/letter in alphabet)
+		navbar += "|<a href='?_src_=holder;shownote=[letter]'>\[[letter]\]</a>"
+	navbar += "<br><form method='GET' name='search' action='?'>\
+	<input type='hidden' name='_src_' value='holder'>\
+	<input type='text' name='notessearch' value='[index]'>\
+	<input type='submit' value='Search'></form>"
+	if(!linkless)
+		output = navbar
+	if(target_ckey)
+		var/target_sql_ckey = sanitizeSQL(target_ckey)
+		var/DBQuery/query_get_notes = dbcon.NewQuery("SELECT id, timestamp, notetext, adminckey, last_editor, server FROM [format_table_name("notes")] WHERE ckey = '[target_sql_ckey]' ORDER BY timestamp")
+		if(!query_get_notes.Execute())
+			var/err = query_get_notes.ErrorMsg()
+			log_game("SQL ERROR obtaining ckey, notetext, adminckey, last_editor, server from notes table. Error : \[[err]\]\n")
+			return
+		output += "<h2><center>Notes of [target_ckey]</center></h2>"
+		if(!linkless)
+			output += "<center><a href='?_src_=holder;addnote=[target_ckey]'>\[Add Note\]</a></center>"
+		output += ruler
+		while(query_get_notes.NextRow())
+			var/id = query_get_notes.item[1]
+			var/timestamp = query_get_notes.item[2]
+			var/notetext = query_get_notes.item[3]
+			var/adminckey = query_get_notes.item[4]
+			var/last_editor = query_get_notes.item[5]
+			var/server = query_get_notes.item[6]
+			output += "<b>[timestamp] | [server] | [adminckey]</b>"
+			if(!linkless)
+				output += " <a href='?_src_=holder;removenote=[id]'>\[Remove Note\]</a> <a href='?_src_=holder;editnote=[id]'>\[Edit Note\]</a>"
+				if(last_editor)
+					output += " <font size='2'>Last edit by [last_editor] <a href='?_src_=holder;noteedits=[id]'>(Click here to see edit log)</a></font>"
+			output += "<br>[notetext]<hr style='background:#000000; border:0; height:1px'>"
+	else if(index)
+		var/index_ckey
+		var/search
+		output += "<center><a href='?_src_=holder;addnoteempty=1'>\[Add Note\]</a></center>"
+		output += ruler
+		if(!isnum(index))
+			index = sanitizeSQL(index)
+		switch(index)
+			if(1)
+				search = "^."
+			if(2)
+				search = "^\[^\[:alpha:\]\]"
+			else
+				search = "^[index]"
+		var/DBQuery/query_list_notes = dbcon.NewQuery("SELECT DISTINCT ckey FROM [format_table_name("notes")] WHERE ckey REGEXP '[search]' ORDER BY ckey")
+		if(!query_list_notes.Execute())
+			var/err = query_list_notes.ErrorMsg()
+			log_game("SQL ERROR obtaining ckey from notes table. Error : \[[err]\]\n")
+			return
+		while(query_list_notes.NextRow())
+			index_ckey = query_list_notes.item[1]
+			output += "<a href='?_src_=holder;shownoteckey=[index_ckey]'>[index_ckey]</a><br>"
+	else
+		output += "<center><a href='?_src_=holder;addnoteempty=1'>\[Add Note\]</a></center>"
+		output += ruler
+	usr << browse(output, "window=show_notes;size=900x500")
+
+#define NOTESFILE "data/player_notes.sav"
+//if the AUTOCONVERT_NOTES is turned on, anytime a player connects this will be run to try and add all their notes to the databas
+/proc/convert_notes_sql(ckey)
+	var/savefile/notesfile = new(NOTESFILE)
+	if(!notesfile)
+		log_game("Error: Cannot access [NOTESFILE]")
+		return
+	notesfile.cd = "/[ckey]"
+	while(!notesfile.eof)
+		var/notetext
+		notesfile >> notetext
+		var/server
+		if(config && config.server_name)
+			server = config.server_name
+		var/regex/note = new("^(\\d{2}-\\w{3}-\\d{4}) \\| (.+) ~(\\w+)$", "i")
+		note.Find(notetext)
+		var/timestamp = note.group[1]
+		notetext = note.group[2]
+		var/adminckey = note.group[3]
+		var/DBQuery/query_convert_time = dbcon.NewQuery("SELECT ADDTIME(STR_TO_DATE('[timestamp]','%d-%b-%Y'), '0')")
+		if(!query_convert_time.Execute())
+			var/err = query_convert_time.ErrorMsg()
+			log_game("SQL ERROR converting timestamp. Error : \[[err]\]\n")
+			return
+		if(query_convert_time.NextRow())
+			timestamp = query_convert_time.item[1]
+		if(ckey && notetext && timestamp && adminckey && server)
+			add_note(ckey, notetext, timestamp, adminckey, 0, server)
+	notesfile.cd = "/"
+	notesfile.dir.Remove(ckey)
+
+/*alternatively this proc can be run once to pass through every note and attempt to convert it before deleting the file, if done then AUTOCONVERT_NOTES should be turned off
+this proc can take several minutes to execute fully if converting and cause DD to hang if converting a lot of notes; it's not advised to do so while a server is live
+/proc/mass_convert_notes()
+	world << "Beginning mass note conversion"
+	var/savefile/notesfile = new(NOTESFILE)
+	if(!notesfile)
+		log_game("Error: Cannot access [NOTESFILE]")
+		return
+	notesfile.cd = "/"
+	for(var/ckey in notesfile.dir)
+		convert_notes_sql(ckey)
+	world << "Deleting NOTESFILE"
+	fdel(NOTESFILE)
+	world << "Finished mass note conversion, remember to turn off AUTOCONVERT_NOTES"*/
+#undef NOTESFILE
--- a/code/modules/admin/watchlist.dm
+++ b/code/modules/admin/watchlist.dm
@@ -0,0 +1,117 @@
+/client/proc/watchlist_add(target_ckey, browse = 0)
+	if(!target_ckey)
+		var/new_ckey = ckey(input(usr,"Who would you like to add to the watchlist?","Enter a ckey",null) as text)
+		if(!new_ckey)
+			return
+		new_ckey = sanitizeSQL(new_ckey)
+		var/DBQuery/query_watchfind = dbcon.NewQuery("SELECT ckey FROM [format_table_name("player")] WHERE ckey = '[new_ckey]'")
+		if(!query_watchfind.Execute())
+			var/err = query_watchfind.ErrorMsg()
+			log_game("SQL ERROR obtaining ckey from player table. Error : \[[err]\]\n")
+			return
+		if(!query_watchfind.NextRow())
+			if(alert(usr, "[new_ckey] has not been seen before, are you sure you want to add them to the watchlist?", "Unknown ckey", "Yes", "No", "Cancel") != "Yes")
+				return
+		target_ckey = new_ckey
+	var/target_sql_ckey = sanitizeSQL(target_ckey)
+	if(check_watchlist(target_sql_ckey))
+		usr << "<span class='redtext'>[target_sql_ckey] is already on the watchlist.</span>"
+		return
+	var/reason = input(usr,"Please State Reason","Reason") as message
+	if(!reason)
+		return
+	reason = sanitizeSQL(reason)
+	var/timestamp = SQLtime()
+	var/adminckey = usr.ckey
+	if(!adminckey)
+		return
+	var/admin_sql_ckey = sanitizeSQL(adminckey)
+	var/DBQuery/query_watchadd = dbcon.NewQuery("INSERT INTO [format_table_name("watch")] (ckey, reason, adminckey, timestamp) VALUES ('[target_sql_ckey]', '[reason]', '[admin_sql_ckey]', '[timestamp]')")
+	if(!query_watchadd.Execute())
+		var/err = query_watchadd.ErrorMsg()
+		log_game("SQL ERROR during adding new watch entry. Error : \[[err]\]\n")
+		return
+	log_admin("[key_name(usr)] has added [target_ckey] to the watchlist - Reason: [reason]")
+	message_admins("[key_name_admin(usr)] has added [target_ckey] to the watchlist - Reason: [reason]", 1)
+	if(browse)
+		watchlist_show(target_sql_ckey)
+
+/client/proc/watchlist_remove(target_ckey, browse = 0)
+	var/target_sql_ckey = sanitizeSQL(target_ckey)
+	var/DBQuery/query_watchdel = dbcon.NewQuery("DELETE FROM [format_table_name("watch")] WHERE ckey = '[target_sql_ckey]'")
+	if(!query_watchdel.Execute())
+		var/err = query_watchdel.ErrorMsg()
+		log_game("SQL ERROR during removing watch entry. Error : \[[err]\]\n")
+		return
+	log_admin("[key_name(usr)] has removed [target_ckey] from the watchlist")
+	message_admins("[key_name_admin(usr)] has removed [target_ckey] from the watchlist", 1)
+	if(browse)
+		watchlist_show()
+
+/client/proc/watchlist_edit(target_ckey, browse = 0)
+	var/target_sql_ckey = sanitizeSQL(target_ckey)
+	var/DBQuery/query_watchreason = dbcon.NewQuery("SELECT reason FROM [format_table_name("watch")] WHERE ckey = '[target_sql_ckey]'")
+	if(!query_watchreason.Execute())
+		var/err = query_watchreason.ErrorMsg()
+		log_game("SQL ERROR obtaining reason from watch table. Error : \[[err]\]\n")
+		return
+	if(query_watchreason.NextRow())
+		var/watch_reason = query_watchreason.item[1]
+		var/new_reason = input("Input new reason", "New Reason", "[watch_reason]") as message
+		new_reason = sanitizeSQL(new_reason)
+		if(!new_reason)
+			return
+		var/sql_ckey = sanitizeSQL(usr.ckey)
+		var/edit_text = "Edited by [sql_ckey] on [SQLtime()] from<br>[watch_reason]<br>to<br>[new_reason]<hr>"
+		edit_text = sanitizeSQL(edit_text)
+		var/DBQuery/query_watchupdate = dbcon.NewQuery("UPDATE [format_table_name("watch")] SET reason = '[new_reason]', last_editor = '[sql_ckey]', edits = CONCAT(IFNULL(edits,''),'[edit_text]') WHERE ckey = '[target_sql_ckey]'")
+		if(!query_watchupdate.Execute())
+			var/err = query_watchupdate.ErrorMsg()
+			log_game("SQL ERROR editing watchlist reason. Error : \[[err]\]\n")
+			return
+		log_admin("[key_name(usr)] has edited [target_ckey]'s watchlist reason from [watch_reason] to [new_reason]")
+		message_admins("[key_name_admin(usr)] has edited [target_ckey]'s watchlist reason from<br>[watch_reason]<br>to<br>[new_reason]")
+		if(browse)
+			watchlist_show(target_sql_ckey)
+
+/client/proc/watchlist_show(search)
+	var/output
+	output += "<form method='GET' name='search' action='?'>\
+	<input type='hidden' name='_src_' value='holder'>\
+	<input type='text' name='watchsearch' value='[search]'>\
+	<input type='submit' value='Search'></form>"
+	output += "<a href='?_src_=holder;watchshow=1'>\[Clear Search\]</a> <a href='?_src_=holder;watchaddbrowse=1'>\[Add Ckey\]</a>"
+	output += "<hr style='background:#000000; border:0; height:3px'>"
+	if(search)
+		search = "^[search]"
+	else
+		search = "^."
+	search = sanitizeSQL(search)
+	var/DBQuery/query_watchlist = dbcon.NewQuery("SELECT ckey, reason, adminckey, timestamp, last_editor FROM [format_table_name("watch")] WHERE ckey REGEXP '[search]' ORDER BY ckey")
+	if(!query_watchlist.Execute())
+		var/err = query_watchlist.ErrorMsg()
+		log_game("SQL ERROR obtaining ckey, reason, adminckey, timestamp, last_editor from watch table. Error : \[[err]\]\n")
+		return
+	while(query_watchlist.NextRow())
+		var/ckey = query_watchlist.item[1]
+		var/reason = query_watchlist.item[2]
+		var/adminckey = query_watchlist.item[3]
+		var/timestamp = query_watchlist.item[4]
+		var/last_editor = query_watchlist.item[5]
+		output += "<b>[ckey]</b> | Added by <b>[adminckey]</b> on <b>[timestamp]</b> <a href='?_src_=holder;watchremovebrowse=[ckey]'>\[Remove\]</a> <a href='?_src_=holder;watcheditbrowse=[ckey]'>\[Edit Reason\]</a>"
+		if(last_editor)
+			output += " <font size='2'>Last edit by [last_editor] <a href='?_src_=holder;watcheditlog=[ckey]'>(Click here to see edit log)</a></font>"
+		output += "<br>[reason]<hr style='background:#000000; border:0; height:1px'>"
+	usr << browse(output, "window=watchwin;size=900x500")
+
+/client/proc/check_watchlist(target_ckey)
+	var/target_sql_ckey = sanitizeSQL(target_ckey)
+	var/DBQuery/query_watch = dbcon.NewQuery("SELECT reason FROM [format_table_name("watch")] WHERE ckey = '[target_sql_ckey]'")
+	if(!query_watch.Execute())
+		var/err = query_watch.ErrorMsg()
+		log_game("SQL ERROR obtaining reason from watch table. Error : \[[err]\]\n")
+		return
+	if(query_watch.NextRow())
+		return query_watch.item[1]
+	else
+		return 0