implant_loyality.dm has been changed to implant_mindshield.dm, better reflecting it's contents and removing a typo (#36855)

* loyality *fixed a bug that made coding relating to loyalty implants basically impossible * did i say loyalty i meant mindshield * and the .dme as well this commit and last were webeditor but it should work
2018-04-02 17:45:03 -07:00
parent 2d5874d292
commit 496f73bc56
2 changed files with 1 additions and 1 deletions
@@ -0,0 +1,59 @@
+/obj/item/implant/mindshield
+	name = "mindshield implant"
+	desc = "Protects against brainwashing."
+	activated = 0
+
+/obj/item/implant/mindshield/get_data()
+	var/dat = {"<b>Implant Specifications:</b><BR>
+				<b>Name:</b> Nanotrasen Employee Management Implant<BR>
+				<b>Life:</b> Ten years.<BR>
+				<b>Important Notes:</b> Personnel injected with this device are much more resistant to brainwashing.<BR>
+				<HR>
+				<b>Implant Details:</b><BR>
+				<b>Function:</b> Contains a small pod of nanobots that protects the host's mental functions from manipulation.<BR>
+				<b>Special Features:</b> Will prevent and cure most forms of brainwashing.<BR>
+				<b>Integrity:</b> Implant will last so long as the nanobots are inside the bloodstream."}
+	return dat
+
+
+/obj/item/implant/mindshield/implant(mob/living/target, mob/user, silent = FALSE)
+	if(..())
+		if(!target.mind)
+			return TRUE
+
+		if(target.mind.has_antag_datum(/datum/antagonist/brainwashed))
+			target.mind.remove_antag_datum(/datum/antagonist/brainwashed)
+
+		if(target.mind.has_antag_datum(/datum/antagonist/rev/head) || target.mind.unconvertable)
+			if(!silent)
+				target.visible_message("<span class='warning'>[target] seems to resist the implant!</span>", "<span class='warning'>You feel something interfering with your mental conditioning, but you resist it!</span>")
+			removed(target, 1)
+			qdel(src)
+			return FALSE
+
+		var/datum/antagonist/rev/rev = target.mind.has_antag_datum(/datum/antagonist/rev)
+		if(rev)
+			rev.remove_revolutionary(FALSE, user)
+		if(!silent)
+			if(target.mind in SSticker.mode.cult)
+				to_chat(target, "<span class='warning'>You feel something interfering with your mental conditioning, but you resist it!</span>")
+			else
+				to_chat(target, "<span class='notice'>You feel a sense of peace and security. You are now protected from brainwashing.</span>")
+		return TRUE
+	return FALSE
+
+/obj/item/implant/mindshield/removed(mob/target, silent = FALSE, special = 0)
+	if(..())
+		if(target.stat != DEAD && !silent)
+			to_chat(target, "<span class='boldnotice'>Your mind suddenly feels terribly vulnerable. You are no longer safe from brainwashing.</span>")
+		return 1
+	return 0
+
+/obj/item/implanter/mindshield
+	name = "implanter (mindshield)"
+	imp_type = /obj/item/implant/mindshield
+
+/obj/item/implantcase/mindshield
+	name = "implant case - 'Mindshield'"
+	desc = "A glass case containing a mindshield implant."
+	imp_type = /obj/item/implant/mindshield