Radiation rework and subsystem

2017-10-13 10:22:00 -04:00
parent 692e226d24
commit 55e8f6526c
72 changed files with 841 additions and 262 deletions
@@ -0,0 +1,9 @@
+/datum/component/rad_insulation // Yes, this really is just a component to add some vars
+	var/amount					// Multiplier for radiation strength passing through
+	var/protects				// Does this protect things in its contents from being affected?
+	var/contamination_proof		// Can this object be contaminated?
+
+/datum/component/rad_insulation/Initialize(_amount=RAD_MEDIUM_INSULATION, _protects=TRUE, _contamination_proof=TRUE)
+	amount = _amount
+	protects = _protects
+	contamination_proof = _contamination_proof
@@ -0,0 +1,73 @@
+#define RAD_AMOUNT_LOW 50
+#define RAD_AMOUNT_MEDIUM 200
+#define RAD_AMOUNT_HIGH 500
+#define RAD_AMOUNT_EXTREME 1000
+
+/datum/component/radioactive
+	dupe_mode = COMPONENT_DUPE_UNIQUE
+
+	var/hl3_release_date //the half-life measured in ticks
+	var/strength
+	var/can_contaminate
+
+/datum/component/radioactive/Initialize(_strength=0, _half_life=RAD_HALF_LIFE, _can_contaminate=TRUE)
+	strength = _strength
+	hl3_release_date = _half_life
+	can_contaminate = _can_contaminate
+
+	if(istype(parent, /atom)) 
+		RegisterSignal(COMSIG_PARENT_EXAMINE, .proc/rad_examine)
+		if(istype(parent, /obj/item))
+			RegisterSignal(COMSIG_ITEM_ATTACK, .proc/rad_attack)
+			RegisterSignal(COMSIG_ITEM_ATTACK_OBJ, .proc/rad_attack)
+	else
+		CRASH("Something that wasn't an atom was given /datum/component/radioactive")
+		return
+
+	START_PROCESSING(SSradiation, src)
+
+/datum/component/radioactive/Destroy()
+	STOP_PROCESSING(SSradiation, src)
+	return ..()
+
+/datum/component/radioactive/process()
+	radiation_pulse(get_turf(parent),strength,1,FALSE,can_contaminate)
+
+	if(hl3_release_date && prob(50))
+		strength -= strength / hl3_release_date
+		if(strength <= RAD_BACKGROUND_RADIATION)
+			qdel(src)
+
+/datum/component/radioactive/InheritComponent(datum/component/C, i_am_original)
+	if(!i_am_original)
+		return
+	if(!hl3_release_date) // Permanently radioactive things don't get to grow stronger
+		return
+	var/datum/component/radioactive/other = C
+	strength = max(strength, other.strength)
+	return
+
+/datum/component/radioactive/proc/rad_examine(mob/user, atom/thing)
+	var/atom/master = parent
+	var/list/out = list()
+	if(get_dist(master, user) <= 1)
+		out += "The air around [master] feels warm"
+	switch(strength)
+		if(RAD_AMOUNT_LOW to RAD_AMOUNT_MEDIUM)
+			out += "[out ? " and it " : "[master] "]feels weird to look at."
+		if(RAD_AMOUNT_MEDIUM to RAD_AMOUNT_HIGH)
+			out += "[out ? " and it " : "[master] "]seems to be glowing a bit."
+		if(RAD_AMOUNT_HIGH to INFINITY) //At this level the object can contaminate other objects
+			out += "[out ? " and it " : "[master] "]hurts to look at."
+		else
+			out += "."
+	to_chat(user, out.Join())
+
+/datum/component/radioactive/proc/rad_attack(atom/movable/target, mob/living/user)
+	radiation_pulse(get_turf(target), strength/20)
+	target.rad_act(strength/2)
+
+#undef RAD_AMOUNT_LOW
+#undef RAD_AMOUNT_MEDIUM
+#undef RAD_AMOUNT_HIGH
+#undef RAD_AMOUNT_EXTREME