oh boy

code/datums/mind.dm

@@ -63,7 +63,11 @@
 	var/force_escaped = FALSE  // Set by Into The Sunset command of the shuttle manipulator
 	var/list/learned_recipes //List of learned recipe TYPES.
 
+	/// Our skill holder.
+	var/datum/skill_holder/skill_holder
+
 /datum/mind/New(var/key)
+	skill_holder = new
 	src.key = key
 	soulOwner = src
 	martial_art = default_martial_art

code/datums/skills/_skill.dm

@@ -0,0 +1,79 @@
+GLOBAL_LIST_INIT(skill_datums, init_skill_datums())
+
+/proc/init_skill_datums()
+	. = list()
+	for(var/path in subtypesof(/datum/skill))
+		var/datum/skill/S = path
+		if(S.abstract_type == path)
+			continue
+		S = new path
+		.[S.type] = S
+
+/proc/get_skill_datum(path)
+	return GLOB.skill_datums[path]
+
+/proc/sanitize_skill_value(path, value)
+	var/datum/skill/S = get_skill_datum(path)
+	// don't check, if we runtime let it happen.
+	return S.sanitize_value(value)
+
+/proc/is_skill_value_greater(path, existing, new_value)
+	var/datum/skill/S = get_skill_datum(path)
+	// don't check, if we runtime let it happen.
+	return S.is_value_greater(existing, new_value)
+
+/**
+  * Skill datums
+  */
+/datum/skill
+	/// Our name
+	var/name
+	/// Our description
+	var/desc
+	/// Our progression type
+	var/progression_type
+	/// Abstract type
+	var/abstract_type = /datum/skill
+
+/**
+  * Ensures what someone's setting as a value for this skill is valid.
+  */
+/datum/skill/proc/sanitize_value(new_value)
+	return new_value
+
+/**
+  * Checks if a value is greater
+  */
+/datum/skill/proc/is_value_greater(existing, new_value)
+	return new_value > existing
+
+// Just saying, the choice to use different sub-parent-types is to force coders to resolve issues as I won't be implementing custom procs to grab skill levels in a certain context.
+// Aka: So people don't forget to change checks if they change a skill's progression type.
+
+/datum/skill/binary
+	abstract_type = /datum/skill/binary
+	progression_type = SKILL_PROGRESSION_BINARY
+
+/datum/skill/binary/sanitize_value(new_value)
+	return new_value? TRUE : FALSE
+
+/datum/skill/numerical
+	abstract_type = /datum/skill/numerical
+	progression_type = SKILL_PROGRESSION_NUMERICAL
+	/// Max value of this skill
+	var/max_value = 100
+	/// Min value of this skill
+	var/min_value = 0
+
+/datum/skill/numerical/sanitize_value(new_value)
+	return clamp(new_value, min_value, max_value)
+
+/datum/skill/enum
+	abstract_type = /datum/skill/enum
+	progression_type = SKILL_PROGRESSION_ENUM
+	/// Valid values for the skill
+	var/list/valid_values = list()
+
+/datum/skill/enum/sanitize_value(new_value)
+	if(new_value in valid_values)
+		return new_value

code/datums/skills/_skill_holder.dm

@@ -0,0 +1,62 @@
+/**
+  * Skill holder datums
+  */
+/datum/skill_holder
+	/// Our list of skills and values. Lazylist. Associative. Keys are datum typepaths to the skill.
+	var/list/skills
+	/// Same as [skills] but affinities, which are multiplied to increase amount when gaining skills.
+	var/list/skill_affinities
+
+/**
+  * Grabs the value of a skill.
+  */
+/datum/skill_holder/proc/get_skill_value(skill)
+	if(!ispath(skill))
+		CRASH("Invalid get_skill_value call. Use typepaths.")		//until a time when we somehow need text ids for dynamic skills, I'm enforcing this.
+	if(!skills)
+		return null
+	return skills[skill]
+
+/**
+  * Grabs our affinity for a skill. !!This is a multiplier!!
+  */
+/datum/skill_holder/proc/get_skill_affinity(skill)
+	if(!ispath(skill))
+		CRASH("Invalid get_skill_affinity call. Use typepaths.")		//until a time when we somehow need text ids for dynamic skills, I'm enforcing this.
+	if(!skills)
+		return 1
+	return skill_affinities[skill]
+
+/**
+  * Sets the value of a skill.
+  */
+/datum/skill_holder/proc/set_skill_value(skill, value)
+	if(!ispath(skill))
+		CRASH("Invalid set_skill_value call. Use typepaths.")		//until a time when we somehow need text ids for dynamic skills, I'm enforcing this.
+	LAZYINITLIST(skills)
+	value = sanitize_skill_value(skill, value)
+	if(!isnull(value))
+		skills[skill] = value
+		return TRUE
+	return FALSE
+
+/**
+  * Boosts a skill to a value if not aobve
+  */
+/datum/skill_holder/proc/boost_skill_value_to(skill, value)
+	var/current = get_skill_value(skill)
+	if(!is_skill_value_greater(skill, current, value))
+		return FALSE
+	set_skill_value(skill, value)
+	return TRUE
+
+/**
+  * Automatic skill increase, multiplied by skill affinity if existing.
+  * Only works if skill is numerical.
+  */
+/datum/skill_holder/proc/auto_gain_experience(skill, value)
+	if(!ispath(skill, /datum/skill/numerical))
+		CRASH("You cannot auto increment a non numerical skill!")
+	var/current = get_skill_value(skill)
+	var/affinity = get_skill_affinity(skill)
+	bosst_skill_value_to(skill, current + (value * affinity))

code/datums/skills/medical.dm

@@ -0,0 +1,3 @@
+/datum/skill/numerical/surgery
+	name = "Surgery"
+	desc = "How proficient you are at doing surgery."