ports all the tg junk for icemoon, not yet changed to make it all compile

code/modules/admin/verbs/debug.dm

@@ -705,10 +705,17 @@
 	var/list/names = list()
 	names += "---- Space Ruins ----"
 	for(var/name in SSmapping.space_ruins_templates)
-		names[name] = list(SSmapping.space_ruins_templates[name], ZTRAIT_SPACE_RUINS, /area/space)
+		names[name] = list(SSmapping.space_ruins_templates[name], ZTRAIT_SPACE_RUINS, list(/area/space))
 	names += "---- Lava Ruins ----"
 	for(var/name in SSmapping.lava_ruins_templates)
 		names[name] = list(SSmapping.lava_ruins_templates[name], ZTRAIT_LAVA_RUINS, /area/lavaland/surface/outdoors/unexplored)
+		names[name] = list(SSmapping.lava_ruins_templates[name], ZTRAIT_LAVA_RUINS, list(/area/lavaland/surface/outdoors/unexplored))
+	names += "---- Ice Ruins ----"
+	for(var/name in SSmapping.ice_ruins_templates)
+		names[name] = list(SSmapping.ice_ruins_templates[name], ZTRAIT_ICE_RUINS, list(/area/icemoon/surface/outdoors/unexplored, /area/icemoon/underground/unexplored))
+	names += "---- Ice Underground Ruins ----"
+	for(var/name in SSmapping.ice_ruins_underground_templates)
+		names[name] = list(SSmapping.ice_ruins_underground_templates[name], ZTRAIT_ICE_RUINS_UNDERGROUND, list(/area/icemoon/underground/unexplored))
 
 	var/ruinname = input("Select ruin", "Spawn Ruin") as null|anything in names
 	var/data = names[ruinname]

code/modules/clothing/shoes/miscellaneous.dm

@@ -143,6 +143,13 @@
 	max_heat_protection_temperature = SHOES_MAX_TEMP_PROTECT
 	pocket_storage_component_path = /datum/component/storage/concrete/pockets/shoes
 
+/obj/item/clothing/shoes/winterboots/ice_boots
+	name = "ice hiking boots"
+	desc = "A pair of winter boots with special grips on the bottom, designed to prevent slipping on frozen surfaces."
+	icon_state = "iceboots"
+	item_state = "iceboots"
+	clothing_flags = NOSLIP_ICE
+
 /obj/item/clothing/shoes/winterboots/christmasbootsr
 	name = "red christmas boots"
 	desc = "A pair of fluffy red christmas boots!"

code/modules/mapping/ruins.dm

@@ -11,9 +11,17 @@
 
 		for(var/turf/check in get_affected_turfs(central_turf,1))
 			var/area/new_area = get_area(check)
-			if(!(istype(new_area, allowed_areas)) || check.flags_1 & NO_RUINS_1)
-				valid = FALSE
+			valid = FALSE // set to false before we check
+			if(check.flags_1 & NO_RUINS_1)
 				break
+			for(var/type in allowed_areas)
+				if(istype(new_area, type)) // it's at least one of our types so it's whitelisted
+					valid = TRUE
+					break
+
+			if(!valid)
+				break
+			
 
 		if(!valid)
 			continue
@@ -51,7 +59,7 @@
 	new /obj/effect/landmark/ruin(center, src)
 	return center
 
-/proc/seedRuins(list/z_levels = null, budget = 0, whitelist = /area/space, list/potentialRuins)
+/proc/seedRuins(list/z_levels = null, budget = 0, whitelist = list(/area/space), list/potentialRuins)
 	if(!z_levels || !z_levels.len)
 		WARNING("No Z levels provided - Not generating ruins")
 		return

code/modules/mob/living/carbon/human/human_movement.dm

@@ -22,13 +22,18 @@
 /mob/living/carbon/human/slip(knockdown_amount, obj/O, lube)
 	if(HAS_TRAIT(src, TRAIT_NOSLIPALL))
 		return 0
-	if (!(lube&GALOSHES_DONT_HELP))
+	if (!(lube & GALOSHES_DONT_HELP))
 		if(HAS_TRAIT(src, TRAIT_NOSLIPWATER))
 			return 0
 		if(shoes && istype(shoes, /obj/item/clothing))
 			var/obj/item/clothing/CS = shoes
 			if (CS.clothing_flags & NOSLIP)
 				return 0
+	if (lube & SLIDE_ICE)
+		if(shoes && istype(shoes, /obj/item/clothing))
+			var/obj/item/clothing/CS = shoes
+			if (CS.clothing_flags & NOSLIP_ICE)
+				return FALSE
 	return ..()
 
 /mob/living/carbon/human/experience_pressure_difference()

code/modules/mob/living/simple_animal/hostile/megafauna/blood_drunk_miner.dm

@@ -265,4 +265,12 @@ Difficulty: Medium
 	desc = "The sweet blood, oh, it sings to me."
 	invisibility = 100
 
+/mob/living/simple_animal/hostile/megafauna/blood_drunk_miner/doom
+	name = "hostile-environment miner"
+	desc = "A miner destined to hop across dimensions for all eternity, hunting anomalous creatures."
+	speed = 8
+	move_to_delay = 8
+	ranged_cooldown_time = 8
+	dash_cooldown = 8
+
 #undef MINER_DASH_RANGE

code/modules/mob/living/simple_animal/hostile/megafauna/demonic_frost_miner.dm

@@ -0,0 +1,365 @@
+/*
+Difficulty: Extremely Hard
+*/
+
+/mob/living/simple_animal/hostile/megafauna/demonic_frost_miner
+	name = "demonic-frost miner"
+	desc = "An extremely geared miner, driven crazy or possessed by the demonic forces here, either way a terrifying enemy."
+	health = 1500
+	maxHealth = 1500
+	icon_state = "demonic_miner"
+	icon_living = "demonic_miner"
+	icon = 'icons/mob/icemoon/icemoon_monsters.dmi'
+	attack_verb_continuous = "pummels"
+	attack_verb_simple = "pummels"
+	attack_sound = 'sound/weapons/sonic_jackhammer.ogg'
+	mob_biotypes = MOB_ORGANIC|MOB_HUMANOID
+	light_color = "#E4C7C5"
+	movement_type = GROUND
+	weather_immunities = list("snow")
+	speak_emote = list("roars")
+	armour_penetration = 100
+	melee_damage_lower = 10
+	melee_damage_upper = 10
+	aggro_vision_range = 18 // large vision range so combat doesn't abruptly end when someone runs a bit away
+	rapid_melee = 4
+	speed = 20
+	move_to_delay = 20
+	ranged = TRUE
+	crusher_loot = list(/obj/effect/decal/remains/plasma, /obj/item/crusher_trophy/ice_block_talisman)
+	loot = list(/obj/effect/decal/remains/plasma)
+	wander = FALSE
+	del_on_death = TRUE
+	blood_volume = BLOOD_VOLUME_NORMAL
+	achievement_type = /datum/award/achievement/boss/demonic_miner_kill
+	crusher_achievement_type = /datum/award/achievement/boss/demonic_miner_crusher
+	score_achievement_type = /datum/award/score/demonic_miner_score
+	deathmessage = "falls to the ground, decaying into plasma particles."
+	deathsound = "bodyfall"
+	footstep_type = FOOTSTEP_MOB_HEAVY
+	attack_action_types = list(/datum/action/innate/megafauna_attack/frost_orbs,
+							   /datum/action/innate/megafauna_attack/snowball_machine_gun,
+							   /datum/action/innate/megafauna_attack/ice_shotgun)
+	/// Modifies the speed of the projectiles the demonic frost miner shoots out
+	var/projectile_speed_multiplier = 1
+	/// If the demonic frost miner is in its enraged state
+	var/enraged = FALSE
+	/// If the demonic frost miner is currently transforming to its enraged state
+	var/enraging = FALSE
+
+/mob/living/simple_animal/hostile/megafauna/demonic_frost_miner/Initialize()
+	. = ..()
+	AddComponent(/datum/component/knockback, 7, FALSE, TRUE)
+	AddComponent(/datum/component/lifesteal, 50)
+
+/datum/action/innate/megafauna_attack/frost_orbs
+	name = "Fire Frost Orbs"
+	icon_icon = 'icons/mob/actions/actions_items.dmi'
+	button_icon_state = "sniper_zoom"
+	chosen_message = "<span class='colossus'>You are now sending out frost orbs to track in on a target.</span>"
+	chosen_attack_num = 1
+
+/datum/action/innate/megafauna_attack/snowball_machine_gun
+	name = "Fire Snowball Machine Gun"
+	icon_icon = 'icons/obj/guns/energy.dmi'
+	button_icon_state = "kineticgun"
+	chosen_message = "<span class='colossus'>You are now firing a snowball machine gun at a target.</span>"
+	chosen_attack_num = 2
+
+/datum/action/innate/megafauna_attack/ice_shotgun
+	name = "Fire Ice Shotgun"
+	icon_icon = 'icons/obj/guns/projectile.dmi'
+	button_icon_state = "shotgun"
+	chosen_message = "<span class='colossus'>You are now firing shotgun ice blasts.</span>"
+	chosen_attack_num = 3
+
+/mob/living/simple_animal/hostile/megafauna/demonic_frost_miner/OpenFire()
+	check_enraged()
+	projectile_speed_multiplier = 1 - enraged * 0.25
+	SetRecoveryTime(100, 100)
+
+	if(client)
+		switch(chosen_attack)
+			if(1)
+				frost_orbs()
+			if(2)
+				snowball_machine_gun()
+			if(3)
+				ice_shotgun()
+		return
+
+	var/easy_attack = prob(80 - enraged * 40)
+	chosen_attack = rand(1, 3)
+	switch(chosen_attack)
+		if(1)
+			if(easy_attack)
+				frost_orbs(10, 8)
+			else
+				frost_orbs(5, 16)
+		if(2)
+			if(easy_attack)
+				snowball_machine_gun()
+			else
+				INVOKE_ASYNC(src, .proc/ice_shotgun, 5, list(list(-180, -140, -100, -60, -20, 20, 60, 100, 140), list(-160, -120, -80, -40, 0, 40, 80, 120, 160)))
+				snowball_machine_gun(5 * 8, 5)
+		if(3)
+			if(easy_attack)
+				ice_shotgun()
+			else
+				ice_shotgun(5, list(list(0, 30, 60, 90, 120, 150, 180, 210, 240, 270, 300, 330), list(-30, -15, 0, 15, 30)))
+
+/obj/projectile/frost_orb
+	name = "frost orb"
+	icon_state = "ice_1"
+	damage = 20
+	armour_penetration = 100
+	speed = 10
+	homing_turn_speed = 30
+	damage_type = BURN
+
+/obj/projectile/frost_orb/on_hit(atom/target, blocked = FALSE)
+	. = ..()
+	if(isturf(target) || isobj(target))
+		target.ex_act(EXPLODE_HEAVY)
+
+/obj/projectile/snowball
+	name = "machine-gun snowball"
+	icon_state = "nuclear_particle"
+	damage = 5
+	armour_penetration = 100
+	speed = 4
+	damage_type = BRUTE
+
+/obj/projectile/ice_blast
+	name = "ice blast"
+	icon_state = "ice_2"
+	damage = 15
+	armour_penetration = 100
+	speed = 4
+	damage_type = BRUTE
+
+/obj/projectile/ice_blast/on_hit(atom/target, blocked = FALSE)
+	. = ..()
+	if(isturf(target) || isobj(target))
+		target.ex_act(EXPLODE_HEAVY)
+
+/mob/living/simple_animal/hostile/megafauna/demonic_frost_miner/ex_act(severity, target)
+	adjustBruteLoss(30 * severity - 120)
+	visible_message("<span class='danger'>[src] absorbs the explosion!</span>", "<span class='userdanger'>You absorb the explosion!</span>")
+
+/mob/living/simple_animal/hostile/megafauna/demonic_frost_miner/Goto(target, delay, minimum_distance)
+	if(enraging)
+		return
+	return ..()
+
+/mob/living/simple_animal/hostile/megafauna/demonic_frost_miner/MoveToTarget(list/possible_targets)
+	if(enraging)
+		return
+	return ..()
+
+/mob/living/simple_animal/hostile/megafauna/demonic_frost_miner/Move()
+	if(enraging)
+		return
+	return ..()
+
+/// Shoots out homing frost orbs that explode into ice blast projectiles after a couple seconds
+/mob/living/simple_animal/hostile/megafauna/demonic_frost_miner/proc/frost_orbs(added_delay = 10, shoot_times = 8)
+	for(var/i in 1 to shoot_times)
+		var/turf/startloc = get_turf(src)
+		var/turf/endloc = get_turf(target)
+		if(!endloc)
+			break
+		var/obj/projectile/frost_orb/P = new(startloc)
+		P.preparePixelProjectile(endloc, startloc)
+		P.firer = src
+		if(target)
+			P.original = target
+		P.set_homing_target(target)
+		P.fire(rand(0, 360))
+		addtimer(CALLBACK(P, /obj/projectile/frost_orb/proc/orb_explosion, projectile_speed_multiplier), 20) // make the orbs home in after a second
+		SLEEP_CHECK_DEATH(added_delay)
+	SetRecoveryTime(40, 60)
+
+/// Called when the orb is exploding, shoots out projectiles
+/obj/projectile/frost_orb/proc/orb_explosion(projectile_speed_multiplier)
+	for(var/i in 0 to 5)
+		var/angle = i * 60
+		var/turf/startloc = get_turf(src)
+		var/turf/endloc = get_turf(original)
+		if(!startloc || !endloc)
+			break
+		var/obj/projectile/ice_blast/P = new(startloc)
+		P.speed *= projectile_speed_multiplier
+		P.preparePixelProjectile(endloc, startloc, null, angle + rand(-10, 10))
+		P.firer = firer
+		if(original)
+			P.original = original
+		P.fire()
+	qdel(src)
+
+/// Shoots out snowballs with a random spread
+/mob/living/simple_animal/hostile/megafauna/demonic_frost_miner/proc/snowball_machine_gun(shots = 60, spread = 45)
+	for(var/i in 1 to shots)
+		var/turf/startloc = get_turf(src)
+		var/turf/endloc = get_turf(target)
+		if(!endloc)
+			break
+		var/obj/projectile/P = new /obj/projectile/snowball(startloc)
+		P.speed *= projectile_speed_multiplier
+		P.preparePixelProjectile(endloc, startloc, null, rand(-spread, spread))
+		P.firer = src
+		if(target)
+			P.original = target
+		P.fire()
+		SLEEP_CHECK_DEATH(1)
+	SetRecoveryTime(15, 15)
+
+/// Shoots out ice blasts in a shotgun like pattern
+/mob/living/simple_animal/hostile/megafauna/demonic_frost_miner/proc/ice_shotgun(shots = 5, list/patterns = list(list(-40, -20, 0, 20, 40), list(-30, -10, 10, 30)))
+	for(var/i in 1 to shots)
+		var/list/pattern = patterns[i % length(patterns) + 1] // alternating patterns
+		for(var/spread in pattern)
+			var/turf/startloc = get_turf(src)
+			var/turf/endloc = get_turf(target)
+			if(!endloc)
+				break
+			var/obj/projectile/P = new /obj/projectile/ice_blast(startloc)
+			P.speed *= projectile_speed_multiplier
+			P.preparePixelProjectile(endloc, startloc, null, spread)
+			P.firer = src
+			if(target)
+				P.original = target
+			P.fire()
+		SLEEP_CHECK_DEATH(8)
+	SetRecoveryTime(15, 20)
+
+/// Checks if the demonic frost miner is ready to be enraged
+/mob/living/simple_animal/hostile/megafauna/demonic_frost_miner/proc/check_enraged()
+	if(enraged)
+		return
+	if(health > maxHealth*0.25)
+		return
+	SetRecoveryTime(80, 80)
+	adjustHealth(-maxHealth)
+	enraged = TRUE
+	enraging = TRUE
+	animate(src, pixel_y = pixel_y + 96, time = 100, easing = ELASTIC_EASING)
+	spin(100, 10)
+	SLEEP_CHECK_DEATH(60)
+	playsound(src, 'sound/effects/explosion3.ogg', 100, TRUE)
+	icon_state = "demonic_miner_phase2"
+	animate(src, pixel_y = pixel_y - 96, time = 8, flags = ANIMATION_END_NOW)
+	spin(8, 2)
+	SLEEP_CHECK_DEATH(8)
+	for(var/mob/living/L in viewers(src))
+		shake_camera(L, 3, 2)
+	playsound(src, 'sound/effects/meteorimpact.ogg', 100, TRUE)
+	setMovetype(movement_type | FLYING)
+	enraging = FALSE
+	adjustHealth(-maxHealth)
+
+/mob/living/simple_animal/hostile/megafauna/demonic_frost_miner/death(gibbed, list/force_grant)
+	if(health > 0)
+		return
+	var/turf/T = get_turf(src)
+	var/loot = rand(1, 3)
+	switch(loot)
+		if(1)
+			new /obj/item/resurrection_crystal(T)
+		if(2)
+			new /obj/item/clothing/shoes/winterboots/ice_boots/speedy(T)
+		if(3)
+			new /obj/item/pickaxe/drill/jackhammer/demonic(T)
+	return ..()
+
+/obj/item/resurrection_crystal
+	name = "resurrection crystal"
+	desc = "When used by anything holding it, this crystal gives them a second chance at life if they die."
+	icon = 'icons/obj/objects.dmi'
+	icon_state = "demonic_crystal"
+
+/obj/item/resurrection_crystal/attack_self(mob/living/user)
+	if(!iscarbon(user))
+		to_chat(user, "<span class='notice'>A dark presence stops you from absorbing the crystal.</span>")
+		return
+	forceMove(user)
+	to_chat(user, "<span class='notice'>You feel a bit safer... but a demonic presence lurks in the back of your head...</span>")
+	RegisterSignal(user, COMSIG_MOB_DEATH, .proc/resurrect)
+
+/// Resurrects the target when they die by cloning them into a new duplicate body and transferring their mind to the clone on a safe station turf
+/obj/item/resurrection_crystal/proc/resurrect(mob/living/carbon/user, gibbed)
+	user.visible_message("<span class='notice'>You see [user]'s soul dragged out of their body!</span>", "<span class='notice'>You feel your soul dragged away to a fresh body!</span>")
+	var/typepath = user.type
+	var/turf/T = find_safe_turf()
+	var/mob/living/carbon/clone = new typepath(T)
+	clone.real_name = user.real_name
+	user.dna.transfer_identity(clone)
+	clone.updateappearance(mutcolor_update=1)
+	user.mind.transfer_to(clone) // second life
+	to_chat(clone, "<span class='notice'>You blink and find yourself in [get_area_name(T)].</span>")
+	user.gib()
+	qdel(src)
+
+/obj/item/clothing/shoes/winterboots/ice_boots/speedy
+	name = "cursed ice hiking boots"
+	desc = "A pair of winter boots contractually made by a devil, they cannot be taken off once put on."
+	slowdown = SHOES_SPEED_SLIGHT
+
+/obj/item/clothing/shoes/winterboots/ice_boots/speedy/Initialize()
+	. = ..()
+	ADD_TRAIT(src, TRAIT_NODROP, CURSED_ITEM_TRAIT)
+
+/obj/item/pickaxe/drill/jackhammer/demonic
+	name = "demonic jackhammer"
+	desc = "Cracks rocks at an inhuman speed, as well as being enhanced for combat purposes."
+	toolspeed = 0
+
+/obj/item/pickaxe/drill/jackhammer/demonic/Initialize()
+	. = ..()
+	AddComponent(/datum/component/knockback, 4, FALSE, TRUE)
+	AddComponent(/datum/component/lifesteal, 5)
+
+/obj/item/crusher_trophy/ice_block_talisman
+	name = "ice block talisman"
+	desc = "A glowing trinket that a demonic miner had on him, it seems he couldn't utilize it for whatever reason."
+	icon_state = "ice_trap_talisman"
+	denied_type = /obj/item/crusher_trophy/ice_block_talisman
+
+/obj/item/crusher_trophy/ice_block_talisman/effect_desc()
+	return "mark detonation to freeze a creature in a block of ice for a period, preventing them from moving"
+
+/obj/item/crusher_trophy/ice_block_talisman/on_mark_detonation(mob/living/target, mob/living/user)
+	target.apply_status_effect(/datum/status_effect/ice_block_talisman)
+
+/datum/status_effect/ice_block_talisman
+	id = "ice_block_talisman"
+	duration = 25
+	status_type = STATUS_EFFECT_REFRESH
+	alert_type = /obj/screen/alert/status_effect/ice_block_talisman
+	/// Stored icon overlay for the hit mob, removed when effect is removed
+	var/icon/cube
+
+/obj/screen/alert/status_effect/ice_block_talisman
+	name = "Frozen Solid"
+	desc = "You're frozen inside an ice cube, and cannot move!"
+	icon_state = "frozen"
+
+/datum/status_effect/ice_block_talisman/on_apply()
+	RegisterSignal(owner, COMSIG_MOVABLE_PRE_MOVE, .proc/owner_moved)
+	if(!owner.stat)
+		to_chat(owner, "<span class='userdanger'>You become frozen in a cube!</span>")
+	cube = icon('icons/effects/freeze.dmi', "ice_cube")
+	var/icon/size_check = icon(owner.icon, owner.icon_state)
+	cube.Scale(size_check.Width(), size_check.Height())
+	owner.add_overlay(cube)
+	return ..()
+
+/// Blocks movement from the status effect owner
+/datum/status_effect/ice_block_talisman/proc/owner_moved()
+	return COMPONENT_MOVABLE_BLOCK_PRE_MOVE
+
+/datum/status_effect/ice_block_talisman/on_remove()
+	if(!owner.stat)
+		to_chat(owner, "<span class='notice'>The cube melts!</span>")
+	owner.cut_overlay(cube)
+	UnregisterSignal(owner, COMSIG_MOVABLE_PRE_MOVE)

code/modules/mob/living/simple_animal/hostile/megafauna/megafauna.dm

@@ -27,12 +27,18 @@
 	mob_size = MOB_SIZE_LARGE
 	layer = LARGE_MOB_LAYER //Looks weird with them slipping under mineral walls and cameras and shit otherwise
 	flags_1 = PREVENT_CONTENTS_EXPLOSION_1 | HEAR_1
+	/// Crusher loot dropped when fauna killed with a crusher
 	var/list/crusher_loot
 	var/medal_type
+	/// Score given to players when the fauna is killed
 	var/score_type = BOSS_SCORE
+	/// If the megafauna is actually killed (vs entering another phase)
 	var/elimination = 0
+	/// Modifies attacks when at lower health
 	var/anger_modifier = 0
+	/// Internal tracking GPS inside fauna
 	var/obj/item/gps/internal
+	/// Next time fauna can use a melee attack
 	var/recovery_time = 0
 
 /mob/living/simple_animal/hostile/megafauna/Initialize(mapload)

code/modules/mob/living/simple_animal/hostile/megafauna/wendigo.dm

@@ -0,0 +1,208 @@
+/*
+Difficulty: Hard
+*/
+
+/mob/living/simple_animal/hostile/megafauna/wendigo
+	name = "wendigo"
+	desc = "A mythological man-eating legendary creature, you probably aren't going to survive this."
+	health = 2500
+	maxHealth = 2500
+	icon_state = "wendigo"
+	icon_living = "wendigo"
+	icon_dead = "wendigo_dead"
+	icon = 'icons/mob/icemoon/64x64megafauna.dmi'
+	attack_verb_continuous = "claws"
+	attack_verb_simple = "claw"
+	attack_sound = 'sound/magic/demon_attack1.ogg'
+	weather_immunities = list("snow")
+	speak_emote = list("roars")
+	armour_penetration = 40
+	melee_damage_lower = 40
+	melee_damage_upper = 40
+	vision_range = 9
+	aggro_vision_range = 18 // man-eating for a reason
+	speed = 8
+	move_to_delay = 8
+	rapid_melee = 16 // every 1/8 second
+	melee_queue_distance = 20 // as far as possible really, need this because of charging and teleports
+	ranged = TRUE
+	pixel_x = -16
+	loot = list()
+	butcher_results = list()
+	guaranteed_butcher_results = list(/obj/item/wendigo_blood)
+	crusher_loot = list(/obj/item/wendigo_blood, /obj/item/crusher_trophy/demon_claws)
+	wander = FALSE
+	del_on_death = FALSE
+	blood_volume = BLOOD_VOLUME_NORMAL
+	achievement_type = /datum/award/achievement/boss/wendigo_kill
+	crusher_achievement_type = /datum/award/achievement/boss/wendigo_crusher
+	score_achievement_type = /datum/award/score/wendigo_score
+	deathmessage = "falls, shaking the ground around it"
+	deathsound = 'sound/effects/gravhit.ogg'
+	footstep_type = FOOTSTEP_MOB_HEAVY
+	attack_action_types = list(/datum/action/innate/megafauna_attack/heavy_stomp,
+							   /datum/action/innate/megafauna_attack/teleport,
+							   /datum/action/innate/megafauna_attack/disorienting_scream)
+	/// Saves the turf the megafauna was created at (spawns exit portal here)
+	var/turf/starting
+	/// Range for wendigo stomping when it moves
+	var/stomp_range = 1
+	/// Stores directions the mob is moving, then calls that a move has fully ended when these directions are removed in moved
+	var/stored_move_dirs = 0
+	/// If the wendigo is allowed to move
+	var/can_move = TRUE
+
+/datum/action/innate/megafauna_attack/heavy_stomp
+	name = "Heavy Stomp"
+	icon_icon = 'icons/mob/actions/actions_items.dmi'
+	button_icon_state = "sniper_zoom"
+	chosen_message = "<span class='colossus'>You are now stomping the ground around you.</span>"
+	chosen_attack_num = 1
+
+/datum/action/innate/megafauna_attack/teleport
+	name = "Teleport"
+	icon_icon = 'icons/effects/bubblegum.dmi'
+	button_icon_state = "smack ya one"
+	chosen_message = "<span class='colossus'>You are now teleporting at the target you click on.</span>"
+	chosen_attack_num = 2
+
+/datum/action/innate/megafauna_attack/disorienting_scream
+	name = "Disorienting Scream"
+	icon_icon = 'icons/turf/walls/wall.dmi'
+	button_icon_state = "wall"
+	chosen_message = "<span class='colossus'>You are now screeching, disorienting targets around you.</span>"
+	chosen_attack_num = 3
+
+/mob/living/simple_animal/hostile/megafauna/wendigo/Initialize()
+	. = ..()
+	starting = get_turf(src)
+
+/mob/living/simple_animal/hostile/megafauna/wendigo/OpenFire()
+	SetRecoveryTime(0, 100)
+	if(health <= maxHealth*0.5)
+		stomp_range = 2
+		speed = 6
+		move_to_delay = 6
+	else
+		stomp_range = initial(stomp_range)
+		speed = initial(speed)
+		move_to_delay = initial(move_to_delay)
+
+	if(client)
+		switch(chosen_attack)
+			if(1)
+				heavy_stomp()
+			if(2)
+				teleport()
+			if(3)
+				disorienting_scream()
+		return
+
+	chosen_attack = rand(1, 3)
+	switch(chosen_attack)
+		if(1)
+			heavy_stomp()
+		if(2)
+			teleport()
+		if(3)
+			disorienting_scream()
+
+/mob/living/simple_animal/hostile/megafauna/wendigo/Move(atom/newloc, direct)
+	if(!can_move)
+		return
+	stored_move_dirs |= direct
+	return ..()
+
+/mob/living/simple_animal/hostile/megafauna/wendigo/Moved(atom/oldloc, direct)
+	. = ..()
+	stored_move_dirs &= ~direct
+	if(!stored_move_dirs)
+		INVOKE_ASYNC(src, .proc/ground_slam, stomp_range, 1)
+
+/// Slams the ground around the wendigo throwing back enemies caught nearby
+/mob/living/simple_animal/hostile/megafauna/wendigo/proc/ground_slam(range, delay)
+	var/turf/orgin = get_turf(src)
+	var/list/all_turfs = RANGE_TURFS(range, orgin)
+	for(var/i = 0 to range)
+		for(var/turf/T in all_turfs)
+			if(get_dist(orgin, T) > i)
+				continue
+			playsound(T,'sound/effects/bamf.ogg', 600, TRUE, 10)
+			new /obj/effect/temp_visual/small_smoke/halfsecond(T)
+			for(var/mob/living/L in T)
+				if(L == src || L.throwing)
+					continue
+				to_chat(L, "<span class='userdanger'>[src]'s ground slam shockwave sends you flying!</span>")
+				var/turf/thrownat = get_ranged_target_turf_direct(src, L, 8, rand(-10, 10))
+				L.throw_at(thrownat, 8, 2, src, TRUE, force = MOVE_FORCE_OVERPOWERING, gentle = TRUE)
+				L.apply_damage(20, BRUTE)
+				shake_camera(L, 2, 1)
+			all_turfs -= T
+		sleep(delay)
+
+/// Larger but slower ground stomp
+/mob/living/simple_animal/hostile/megafauna/wendigo/proc/heavy_stomp()
+	can_move = FALSE
+	ground_slam(5, 2)
+	SetRecoveryTime(0, 0)
+	can_move = TRUE
+
+/// Teleports to a location 4 turfs away from the enemy in view
+/mob/living/simple_animal/hostile/megafauna/wendigo/proc/teleport()
+	var/list/possible_ends = list()
+	for(var/turf/T in view(4, target.loc) - view(3, target.loc))
+		if(isclosedturf(T))
+			continue
+		possible_ends |= T
+	var/turf/end = pick(possible_ends)
+	do_teleport(src, end, 0,  channel=TELEPORT_CHANNEL_BLUESPACE, forced = TRUE)
+	SetRecoveryTime(20, 0)
+
+/// Shakes all nearby enemies screens and animates the wendigo shaking up and down
+/mob/living/simple_animal/hostile/megafauna/wendigo/proc/disorienting_scream()
+	can_move = FALSE
+	playsound(src, 'sound/magic/demon_dies.ogg', 600, FALSE, 10)
+	animate(src, pixel_z = rand(5, 15), time = 1, loop = 6)
+	animate(pixel_z = 0, time = 1)
+	for(var/mob/living/L in get_hearers_in_view(7, src) - src)
+		shake_camera(L, 120, 2)
+		to_chat(L, "<span class='danger'>The wendigo screams loudly!</span>")
+	SetRecoveryTime(30, 0)
+	SLEEP_CHECK_DEATH(12)
+	can_move = TRUE
+	return
+
+/mob/living/simple_animal/hostile/megafauna/wendigo/death(gibbed, list/force_grant)
+	if(health > 0)
+		return
+	var/obj/effect/portal/permanent/one_way/exit = new /obj/effect/portal/permanent/one_way(starting)
+	exit.id = "wendigo arena exit"
+	exit.add_atom_colour(COLOR_RED_LIGHT, ADMIN_COLOUR_PRIORITY)
+	exit.set_light(20, 1, LIGHT_COLOR_RED)
+	return ..()
+
+/obj/item/wendigo_blood
+	name = "bottle of wendigo blood"
+	desc = "You're not actually going to drink this, are you?"
+	icon = 'icons/obj/wizard.dmi'
+	icon_state = "vial"
+
+/obj/item/wendigo_blood/attack_self(mob/living/user)
+	if(!ishuman(user))
+		return
+	var/mob/living/carbon/human/H = user
+	if(!H.mind)
+		return
+	to_chat(H, "<span class='danger'>Power courses through you! You can now shift your form at will.</span>")
+	var/obj/effect/proc_holder/spell/targeted/shapeshift/polar_bear/P = new
+	H.mind.AddSpell(P)
+	playsound(H.loc,'sound/items/drink.ogg', rand(10,50), TRUE)
+	qdel(src)
+
+/obj/effect/proc_holder/spell/targeted/shapeshift/polar_bear
+	name = "Polar Bear Form"
+	desc = "Take on the shape of a polar bear."
+	invocation = "RAAAAAAAAWR!"
+	convert_damage = FALSE
+
+	shapeshift_type = /mob/living/simple_animal/hostile/asteroid/polarbear

code/modules/mob/living/simple_animal/hostile/mining_mobs/hivelord.dm

@@ -424,3 +424,26 @@
 			l_pocket = /obj/item/reagent_containers/food/drinks/soda_cans/buzz_fuzz
 			mask = /obj/item/clothing/mask/rat/bee
 	. = ..()
+
+// Snow Legion
+/mob/living/simple_animal/hostile/asteroid/hivelord/legion/snow
+	name = "snow legion"
+	desc = "You can still see what was once a human under the shifting snowy mass, clearly decorated by a clown."
+	icon = 'icons/mob/icemoon/icemoon_monsters.dmi'
+	icon_state = "snowlegion"
+	icon_living = "snowlegion"
+	icon_aggro = "snowlegion_alive"
+	icon_dead = "snowlegion"
+	crusher_loot = /obj/item/crusher_trophy/legion_skull
+	loot = list(/obj/item/organ/regenerative_core/legion)
+	brood_type = /mob/living/simple_animal/hostile/asteroid/hivelordbrood/legion/snow
+
+// Snow Legion skull
+/mob/living/simple_animal/hostile/asteroid/hivelordbrood/legion/snow
+	name = "snow legion"
+	desc = "One of many."
+	icon = 'icons/mob/icemoon/icemoon_monsters.dmi'
+	icon_state = "snowlegion_head"
+	icon_living = "snowlegion_head"
+	icon_aggro = "snowlegion_head"
+	icon_dead = "snowlegion_head"

code/modules/mob/living/simple_animal/hostile/mining_mobs/ice_demon.dm

@@ -0,0 +1,78 @@
+/mob/living/simple_animal/hostile/asteroid/ice_demon
+	name = "demonic watcher"
+	desc = "A creature formed entirely out of ice, bluespace energy emanates from inside of it."
+	icon = 'icons/mob/icemoon/icemoon_monsters.dmi'
+	icon_state = "ice_demon"
+	icon_living = "ice_demon"
+	icon_dead = "ice_demon_dead"
+	icon_gib = "syndicate_gib"
+	mob_biotypes = MOB_ORGANIC|MOB_BEAST
+	mouse_opacity = MOUSE_OPACITY_ICON
+	speak_emote = list("telepathically cries")
+	speed = 2
+	move_to_delay = 2
+	projectiletype = /obj/projectile/temp/basilisk/ice
+	projectilesound = 'sound/weapons/pierce.ogg'
+	ranged = TRUE
+	ranged_message = "manifests ice"
+	ranged_cooldown_time = 30
+	minimum_distance = 3
+	retreat_distance = 3
+	maxHealth = 150
+	health = 150
+	obj_damage = 40
+	melee_damage_lower = 15
+	melee_damage_upper = 15
+	attack_verb_continuous = "slices"
+	attack_verb_simple = "slice"
+	attack_sound = 'sound/weapons/bladeslice.ogg'
+	vision_range = 9
+	aggro_vision_range = 9
+	move_force = MOVE_FORCE_VERY_STRONG
+	move_resist = MOVE_FORCE_VERY_STRONG
+	pull_force = MOVE_FORCE_VERY_STRONG
+	del_on_death = TRUE
+	loot = list(/obj/item/stack/ore/bluespace_crystal = 3)
+	crusher_loot = /obj/item/crusher_trophy/watcher_wing/ice_wing
+	deathmessage = "fades as the energies that tied it to this world dissipate."
+	deathsound = 'sound/magic/demon_dies.ogg'
+	stat_attack = UNCONSCIOUS
+	movement_type = FLYING
+	robust_searching = TRUE
+	footstep_type = FOOTSTEP_MOB_CLAW
+	/// Distance the demon will teleport from the target
+	var/teleport_distance = 3
+
+/obj/projectile/temp/basilisk/ice
+	name = "ice blast"
+	damage = 5
+	nodamage = FALSE
+	temperature = -75
+
+/mob/living/simple_animal/hostile/asteroid/ice_demon/OpenFire()
+	if(teleport_distance <= 0)
+		return ..()
+	var/list/possible_ends = list()
+	for(var/turf/T in view(teleport_distance, target.loc) - view(teleport_distance - 1, target.loc))
+		if(isclosedturf(T))
+			continue
+		possible_ends |= T
+	var/turf/end = pick(possible_ends)
+	do_teleport(src, end, 0,  channel=TELEPORT_CHANNEL_BLUESPACE, forced = TRUE)
+	SLEEP_CHECK_DEATH(8)
+	return ..()
+
+/mob/living/simple_animal/hostile/asteroid/ice_demon/Life()
+	. = ..()
+	if(!. || target)
+		return
+	adjustHealth(-maxHealth*0.025)
+
+/mob/living/simple_animal/hostile/asteroid/ice_demon/death(gibbed)
+	move_force = MOVE_FORCE_DEFAULT
+	move_resist = MOVE_RESIST_DEFAULT
+	pull_force = PULL_FORCE_DEFAULT
+	var/turf/T = get_turf(src)
+	if(T && prob(5))
+		new /obj/item/assembly/signaler/anomaly/bluespace(T)
+	return ..()

code/modules/mob/living/simple_animal/hostile/mining_mobs/ice_whelp.dm

@@ -0,0 +1,57 @@
+/mob/living/simple_animal/hostile/asteroid/ice_whelp
+	name = "ice whelp"
+	desc = "The offspring of an ice drake, weak in comparison but still terrifying."
+	icon = 'icons/mob/icemoon/icemoon_monsters.dmi'
+	icon_state = "ice_whelp"
+	icon_living = "ice_whelp"
+	icon_dead = "ice_whelp_dead"
+	mob_biotypes = MOB_ORGANIC|MOB_BEAST
+	mouse_opacity = MOUSE_OPACITY_ICON
+	friendly_verb_continuous = "stares down"
+	friendly_verb_simple = "stare down"
+	speak_emote = list("roars")
+	speed = 30
+	move_to_delay = 30
+	ranged = TRUE
+	ranged_cooldown_time = 40
+	maxHealth = 350
+	health = 350
+	obj_damage = 40
+	armour_penetration = 20
+	melee_damage_lower = 20
+	melee_damage_upper = 20
+	attack_verb_continuous = "chomps"
+	attack_verb_simple = "chomp"
+	attack_sound = 'sound/magic/demon_attack1.ogg'
+	vision_range = 9
+	aggro_vision_range = 9
+	move_force = MOVE_FORCE_VERY_STRONG
+	move_resist = MOVE_FORCE_VERY_STRONG
+	pull_force = MOVE_FORCE_VERY_STRONG
+	butcher_results = list(/obj/item/stack/ore/diamond = 3, /obj/item/stack/sheet/sinew = 2, /obj/item/stack/sheet/bone = 10, /obj/item/stack/sheet/animalhide/ashdrake = 1)
+	loot = list()
+	crusher_loot = /obj/item/crusher_trophy/tail_spike
+	deathmessage = "collapses on it's side."
+	deathsound = 'sound/magic/demon_dies.ogg'
+	stat_attack = UNCONSCIOUS
+	robust_searching = TRUE
+	footstep_type = FOOTSTEP_MOB_CLAW
+	/// How far the whelps fire can go
+	var/fire_range = 4
+
+/mob/living/simple_animal/hostile/asteroid/ice_whelp/OpenFire()
+	var/turf/T = get_ranged_target_turf_direct(src, target, fire_range)
+	var/list/burn_turfs = getline(src, T) - get_turf(src)
+	dragon_fire_line(src, burn_turfs)
+
+/mob/living/simple_animal/hostile/asteroid/ice_whelp/Life()
+	. = ..()
+	if(!. || target)
+		return
+	adjustHealth(-maxHealth*0.025)
+
+/mob/living/simple_animal/hostile/asteroid/ice_whelp/death(gibbed)
+	move_force = MOVE_FORCE_DEFAULT
+	move_resist = MOVE_RESIST_DEFAULT
+	pull_force = PULL_FORCE_DEFAULT
+	return ..()

code/modules/mob/living/simple_animal/hostile/mining_mobs/mining_mobs.dm

@@ -28,7 +28,7 @@
 
 /mob/living/simple_animal/hostile/asteroid/Aggro()
 	..()
-	if(vision_range != aggro_vision_range)
+	if(vision_range == aggro_vision_range && icon_aggro)
 		icon_state = icon_aggro
 
 /mob/living/simple_animal/hostile/asteroid/LoseAggro()

code/modules/mob/living/simple_animal/hostile/mining_mobs/polarbear.dm

@@ -0,0 +1,59 @@
+/mob/living/simple_animal/hostile/asteroid/polarbear
+	name = "polar bear"
+	desc = "An aggressive animal that defends it's territory with incredible power. These beasts don't run from their enemies."
+	icon = 'icons/mob/icemoon/icemoon_monsters.dmi'
+	icon_state = "polarbear"
+	icon_living = "polarbear"
+	icon_dead = "polarbear_dead"
+	mob_biotypes = MOB_ORGANIC|MOB_BEAST
+	mouse_opacity = MOUSE_OPACITY_ICON
+	friendly_verb_continuous = "growls at"
+	friendly_verb_simple = "growl at"
+	speak_emote = list("growls")
+	speed = 12
+	move_to_delay = 12
+	maxHealth = 300
+	health = 300
+	obj_damage = 40
+	melee_damage_lower = 25
+	melee_damage_upper = 25
+	attack_verb_continuous = "claws"
+	attack_verb_simple = "claw"
+	attack_sound = 'sound/weapons/bladeslice.ogg'
+	vision_range = 2 // don't aggro unless you basically antagonize it, though they will kill you worse than a goliath will
+	aggro_vision_range = 9
+	move_force = MOVE_FORCE_VERY_STRONG
+	move_resist = MOVE_FORCE_VERY_STRONG
+	pull_force = MOVE_FORCE_VERY_STRONG
+	butcher_results = list(/obj/item/reagent_containers/food/snacks/meat/slab/bear = 3, /obj/item/stack/sheet/bone = 2)
+	guaranteed_butcher_results = list(/obj/item/stack/sheet/animalhide/goliath_hide/polar_bear_hide = 1)
+	loot = list()
+	crusher_loot = /obj/item/crusher_trophy/goliath_tentacle
+	stat_attack = UNCONSCIOUS
+	robust_searching = TRUE
+	footstep_type = FOOTSTEP_MOB_CLAW
+	/// Message for when the polar bear starts to attack faster
+	var/aggressive_message_said = FALSE
+
+/mob/living/simple_animal/hostile/asteroid/polarbear/adjustHealth(amount, updating_health = TRUE, forced = FALSE)
+	. = ..()
+	if(health > maxHealth*0.5)
+		rapid_melee = initial(rapid_melee)
+		return
+	if(!aggressive_message_said && target)
+		visible_message("<span class='danger'>The [name] gets an enraged look at [target]!</span>")
+		aggressive_message_said = TRUE
+	rapid_melee = 2
+
+/mob/living/simple_animal/hostile/asteroid/polarbear/Life()
+	. = ..()
+	if(!. || target)
+		return
+	adjustHealth(-maxHealth*0.025)
+	aggressive_message_said = FALSE
+
+/mob/living/simple_animal/hostile/asteroid/polarbear/death(gibbed)
+	move_force = MOVE_FORCE_DEFAULT
+	move_resist = MOVE_RESIST_DEFAULT
+	pull_force = PULL_FORCE_DEFAULT
+	return ..()

code/modules/mob/living/simple_animal/hostile/mining_mobs/wolf.dm

@@ -0,0 +1,60 @@
+/mob/living/simple_animal/hostile/asteroid/wolf
+	name = "white wolf"
+	desc = "A beast that survives by feasting on weaker opponents, they're much stronger with numbers."
+	icon = 'icons/mob/icemoon/icemoon_monsters.dmi'
+	icon_state = "whitewolf"
+	icon_living = "whitewolf"
+	icon_dead = "whitewolf_dead"
+	mob_biotypes = MOB_ORGANIC|MOB_BEAST
+	mouse_opacity = MOUSE_OPACITY_ICON
+	friendly_verb_continuous = "howls at"
+	friendly_verb_simple = "howl at"
+	speak_emote = list("howls")
+	speed = 5
+	move_to_delay = 5
+	maxHealth = 130
+	health = 130
+	obj_damage = 15
+	melee_damage_lower = 7.5
+	melee_damage_upper = 7.5
+	rapid_melee = 2 // every second attack
+	dodging = TRUE
+	dodge_prob = 50
+	attack_verb_continuous = "bites"
+	attack_verb_simple = "bite"
+	attack_sound = 'sound/weapons/bite.ogg'
+	vision_range = 7
+	aggro_vision_range = 7
+	move_force = MOVE_FORCE_WEAK
+	move_resist = MOVE_FORCE_WEAK
+	pull_force = MOVE_FORCE_WEAK
+	butcher_results = list(/obj/item/reagent_containers/food/snacks/meat/slab = 2, /obj/item/stack/sheet/sinew/wolf = 2, /obj/item/stack/sheet/bone = 2)
+	loot = list()
+	crusher_loot = /obj/item/crusher_trophy/watcher_wing
+	stat_attack = UNCONSCIOUS
+	robust_searching = TRUE
+	footstep_type = FOOTSTEP_MOB_CLAW
+	/// Message for when the wolf decides to start running away
+	var/retreat_message_said = FALSE
+
+/mob/living/simple_animal/hostile/asteroid/wolf/Move(atom/newloc)
+	if(newloc && newloc.z == z && (islava(newloc) || ischasm(newloc)))
+		return FALSE
+	return ..()
+
+/mob/living/simple_animal/hostile/asteroid/wolf/adjustHealth(amount, updating_health = TRUE, forced = FALSE)
+	. = ..()
+	if(stat == DEAD || health > maxHealth*0.1)
+		retreat_distance = initial(retreat_distance)
+		return
+	if(!retreat_message_said && target)
+		visible_message("<span class='danger'>The [name] tries to flee from [target]!</span>")
+		retreat_message_said = TRUE
+	retreat_distance = 30
+
+/mob/living/simple_animal/hostile/asteroid/wolf/Life()
+	. = ..()
+	if(!. || target)
+		return
+	adjustHealth(-maxHealth*0.025)
+	retreat_message_said = FALSE

code/modules/ruins/icemoonruin_code/hotsprings.dm

@@ -0,0 +1,55 @@
+GLOBAL_LIST_EMPTY(cursed_minds)
+
+/**
+  * Turns whoever enters into a mob or random person
+  *
+  * If mob is chosen, turns the person into a random animal type
+  * If appearance is chosen, turns the person into a random human with a random species
+  * This changes name, and changes their DNA as well
+  * Random species is same as wizard swap event so people don't get killed ex: plasmamen
+  * Once the spring is used, it cannot be used by the same mind ever again
+  * After usage, teleports the user back to a random safe turf (so mobs are not killed by ice moon atmosphere)
+  *
+  */
+
+/turf/open/water/cursed_spring
+	baseturfs = /turf/open/water/cursed_spring
+	initial_gas_mix = ICEMOON_DEFAULT_ATMOS
+
+/turf/open/water/cursed_spring/Entered(atom/movable/thing, atom/oldLoc)
+	. = ..()
+	if(!isliving(thing))
+		return
+	var/mob/living/L = thing
+	if(!L.client)
+		return
+	if(GLOB.cursed_minds[L.mind])
+		return
+	GLOB.cursed_minds[L.mind] = TRUE
+	RegisterSignal(L.mind, COMSIG_PARENT_QDELETING, .proc/remove_from_cursed)
+	var/random_choice = pick("Mob", "Appearance")
+	switch(random_choice)
+		if("Mob")
+			L = wabbajack(L, "animal")
+		if("Appearance")
+			var/mob/living/carbon/human/H = wabbajack(L, "humanoid")
+			randomize_human(H)
+			var/list/all_species = list()
+			for(var/stype in subtypesof(/datum/species))
+				var/datum/species/S = stype
+				if(initial(S.changesource_flags) & RACE_SWAP)
+					all_species += stype
+			var/random_race = pick(all_species)
+			H.set_species(random_race)
+			H.dna.unique_enzymes = H.dna.generate_unique_enzymes()
+			L = H
+	var/turf/T = find_safe_turf()
+	L.forceMove(T)
+	to_chat(L, "<span class='notice'>You blink and find yourself in [get_area_name(T)].</span>")
+
+/**
+  * Deletes minds from the cursed minds list after their deletion
+  *
+  */
+/turf/open/water/cursed_spring/proc/remove_from_cursed(datum/mind/M)
+	GLOB.cursed_minds -= M

code/modules/ruins/icemoonruin_code/library.dm

@@ -0,0 +1,33 @@
+/obj/machinery/door/keycard/library
+	name = "wooden door"
+	desc = "A dusty, scratched door with a thick lock attached."
+	icon = 'icons/obj/doors/puzzledoor/wood.dmi'
+	puzzle_id = "library"
+	open_message = "The door opens with a loud creak."
+
+/obj/item/keycard/library
+	name = "golden key"
+	desc = "A dull, golden key."
+	icon_state = "golden_key"
+	puzzle_id = "library"
+
+/obj/item/paper/crumpled/bloody/fluff/stations/lavaland/library/warning
+	name = "ancient note"
+	info = "<b>Here lies the vast collection of He Who Knows Ten Thousand Things. May all who pursue this knowledge for power be cursed a thousand times.</b>"
+
+/obj/item/paper/crumpled/fluff/stations/lavaland/library/diary
+	name = "diary entry 13"
+	info = "It has been a week since the library was buried. I am so hungry that I can barely muster the energy to think, let alone write. The owl is gone."
+
+/obj/item/paper/crumpled/fluff/stations/lavaland/library/diary2
+	name = "diary entry 18"
+	info = "I've lost track of time. I lack the strength to even pick up books off the shelves. To think, after all this time spent searching for the library, I will die before I can so much as graze the depth of its knowledge."
+
+/obj/item/feather
+	name = "feather"
+	desc = "A dark, wilting feather. It seems as old as time."
+	icon = 'icons/obj/objects.dmi'
+	icon_state = "feather"
+	force = 0
+	throwforce = 0
+	w_class = WEIGHT_CLASS_TINY

code/modules/shuttle/syndicate.dm

@@ -62,6 +62,7 @@
 	view_range = 13
 	x_offset = -7
 	y_offset = -1
+	whitelist_turfs = list(/turf/open/space, /turf/open/floor/plating, /turf/open/lava, /turf/closed/mineral)
 	see_hidden = TRUE
 
-#undef SYNDICATE_CHALLENGE_TIMER
+#undef SYNDICATE_CHALLENGE_TIMER