Merge branch 'Ghommie-cit265' of https://github.com/Ghommie/Citadel-Station-13 into Ghommie-cit435

2019-12-06 19:05:50 +01:00
parent 91e628c73d 6484eea339
commit 72c093d14e
122 changed files with 553 additions and 437 deletions
@@ -0,0 +1,49 @@
+/datum/component/spawner
+	var/mob_types = list(/mob/living/simple_animal/hostile/carp)
+	var/spawn_time = 300 //30 seconds default
+	var/list/spawned_mobs = list()
+	var/spawn_delay = 0
+	var/max_mobs = 5
+	var/spawn_text = "emerges from"
+	var/list/faction = list("mining")
+
+/datum/component/spawner/Initialize(_mob_types, _spawn_time, _faction, _spawn_text, _max_mobs)
+	if(_spawn_time)
+		spawn_time=_spawn_time
+	if(_mob_types)
+		mob_types=_mob_types
+	if(_faction)
+		faction=_faction
+	if(_spawn_text)
+		spawn_text=_spawn_text
+	if(_max_mobs)
+		max_mobs=_max_mobs
+
+	RegisterSignal(parent, list(COMSIG_PARENT_QDELETED), .proc/stop_spawning)
+	START_PROCESSING(SSprocessing, src)
+
+/datum/component/spawner/process()
+	try_spawn_mob()
+
+
+/datum/component/spawner/proc/stop_spawning(force, hint)
+	STOP_PROCESSING(SSprocessing, src)
+	for(var/mob/living/simple_animal/L in spawned_mobs)
+		if(L.nest == src)
+			L.nest = null
+	spawned_mobs = null
+
+/datum/component/spawner/proc/try_spawn_mob()
+	var/atom/P = parent
+	if(spawned_mobs.len >= max_mobs)
+		return 0
+	if(spawn_delay > world.time)
+		return 0
+	spawn_delay = world.time + spawn_time
+	var/chosen_mob_type = pick(mob_types)
+	var/mob/living/simple_animal/L = new chosen_mob_type(P.loc)
+	L.flags_1 |= (P.flags_1 & ADMIN_SPAWNED_1)
+	spawned_mobs += L
+	L.nest = src
+	L.faction = src.faction
+	P.visible_message("<span class='danger'>[L] [spawn_text] [P].</span>")