Ports a rewritten version of BAYSTRUMENTS (#11680)

* bay instruments

* k

* AAA

* remove that

* changes

* Update _instrument_key.dm

* safety nets

* @ghommie fixed

* volume

* Update item.dm

* Update item.dm

Co-authored-by: Ghom <42542238+Ghommie@users.noreply.github.com>

code/controllers/subsystem/processing/chemistry.dm

@@ -1,5 +1,4 @@
 PROCESSING_SUBSYSTEM_DEF(chemistry)
 	wait = 5
 	flags = SS_KEEP_TIMING
-
-
+	name = "Chemistry"

code/controllers/subsystem/processing/instruments.dm

@@ -0,0 +1,43 @@
+PROCESSING_SUBSYSTEM_DEF(instruments)
+	name = "Instruments"
+	wait = 0.5
+	init_order = INIT_ORDER_INSTRUMENTS
+	flags = SS_KEEP_TIMING
+	priority = FIRE_PRIORITY_INSTRUMENTS
+	var/static/list/datum/instrument/instrument_data = list()		//id = datum
+	var/static/list/datum/song/songs = list()
+	var/static/musician_maxlines = 600
+	var/static/musician_maxlinechars = 300
+	var/static/musician_hearcheck_mindelay = 5
+	var/static/max_instrument_channels = MAX_INSTRUMENT_CHANNELS
+	var/static/current_instrument_channels = 0
+
+/datum/controller/subsystem/processing/instruments/Initialize()
+	initialize_instrument_data()
+	return ..()
+
+/datum/controller/subsystem/processing/instruments/proc/on_song_new(datum/song/S)
+	songs += S
+
+/datum/controller/subsystem/processing/instruments/proc/on_song_del(datum/song/S)
+	songs -= S
+
+/datum/controller/subsystem/processing/instruments/proc/initialize_instrument_data()
+	for(var/path in subtypesof(/datum/instrument))
+		var/datum/instrument/I = path
+		if(initial(I.abstract_type) == path)
+			continue
+		I = new path
+		I.Initialize()
+		instrument_data[I.id || "[I.type]"] = I
+		CHECK_TICK
+
+/datum/controller/subsystem/processing/instruments/proc/get_instrument(id_or_path)
+	return instrument_data["[id_or_path]"]
+
+/datum/controller/subsystem/processing/instruments/proc/reserve_instrument_channel(datum/instrument/I)
+	if(current_instrument_channels > max_instrument_channels)
+		return
+	. = SSsounds.reserve_sound_channel(I)
+	if(!isnull(.))
+		current_instrument_channels++

code/controllers/subsystem/processing/status_effects.dm

@@ -1,3 +1,4 @@
 PROCESSING_SUBSYSTEM_DEF(status_effects)
 	wait = 1
 	flags = SS_TICKER
+	name = "Status Effects"

code/controllers/subsystem/sounds.dm

@@ -0,0 +1,91 @@
+#define DATUMLESS "NO_DATUM"
+
+SUBSYSTEM_DEF(sounds)
+	name = "Sounds"
+	flags = SS_NO_FIRE
+	init_order = INIT_ORDER_SOUNDS
+	var/static/using_channels_max = CHANNEL_HIGHEST_AVAILABLE		//BYOND max channels
+
+	// Hey uh these two needs to be initialized fast because the whole "things get deleted before init" thing.
+	/// Assoc list, "[channel]" = either the datum using it or TRUE for an unsafe-reserved (datumless reservation) channel
+	var/list/using_channels = list()
+	/// Assoc list datum = list(channel1, channel2, ...) for what channels something reserved.
+	var/list/using_channels_by_datum = list()
+	/// List of all available channels with associations set to TRUE for fast lookups/allocation.
+	var/list/available_channels
+
+/datum/controller/subsystem/sounds/Initialize()
+	setup_available_channels()
+	return ..()
+
+/datum/controller/subsystem/sounds/proc/setup_available_channels()
+	available_channels = list()
+	for(var/i in 1 to using_channels_max)
+		available_channels[num2text(i)] = TRUE
+
+/// Removes a channel from using list.
+/datum/controller/subsystem/sounds/proc/free_sound_channel(channel)
+	channel = num2text(channel)
+	var/using = using_channels[channel]
+	using_channels -= channel
+	if(using)
+		using_channels_by_datum[using] -= channel
+		if(!length(using_channels_by_datum[using]))
+			using_channels_by_datum -= using
+	available_channels[channel] = TRUE
+
+/// Frees all the channels a datum is using.
+/datum/controller/subsystem/sounds/proc/free_datum_channels(datum/D)
+	var/list/L = using_channels_by_datum[D]
+	if(!L)
+		return
+	for(var/channel in L)
+		using_channels -= channel
+		available_channels[channel] = TRUE
+	using_channels_by_datum -= D
+
+/// Frees all datumless channels
+/datum/controller/subsystem/sounds/proc/free_datumless_channels()
+	free_datum_channels(DATUMLESS)
+
+/// NO AUTOMATIC CLEANUP - If you use this, you better manually free it later! Returns an integer for channel.
+/datum/controller/subsystem/sounds/proc/reserve_sound_channel_datumless()
+	var/channel = random_available_channel_text()
+	if(!channel)		//oh no..
+		return FALSE
+	available_channels -= channel
+	using_channels[channel] = DATUMLESS
+	LAZYINITLIST(using_channels_by_datum[DATUMLESS])
+	using_channels_by_datum[DATUMLESS] += channel
+	return text2num(channel)
+
+/// Reserves a channel for a datum. Automatic cleanup only when the datum is deleted. Returns an integer for channel.
+/datum/controller/subsystem/sounds/proc/reserve_sound_channel(datum/D)
+	if(!D)		//i don't like typechecks but someone will fuck it up
+		CRASH("Attempted to reserve sound channel without datum using the managed proc.")
+	var/channel = random_available_channel_text()
+	if(!channel)
+		return FALSE
+	available_channels -= channel
+	using_channels[channel] = D
+	LAZYINITLIST(using_channels_by_datum[D])
+	using_channels_by_datum[D] += channel
+	return text2num(channel)
+
+/// Random available channel, returns text.
+/datum/controller/subsystem/sounds/proc/random_available_channel_text()
+	return pick(available_channels)
+
+/// Random available channel, returns number
+/datum/controller/subsystem/sounds/proc/random_available_channel()
+	return text2num(pick(available_channels))
+
+/// If a channel is available
+/datum/controller/subsystem/sounds/proc/is_channel_available(channel)
+	return available_channels[num2text(channel)]
+
+/// How many channels we have left.
+/datum/controller/subsystem/sounds/proc/available_channels_left()
+	return length(available_channels)
+
+#undef DATUMLESS