AI Multicamera mode (#37695)

* Added multicamera mode for AIs

* Minor multicamera fixes

* Cameras near an AI multicamera eye now light up red

* Disabled AI multicamera mode without admin intervention

* Fixed AIs being able to use multicamera mode when they should not

code/modules/lighting/lighting_object.dm

@@ -11,8 +11,6 @@
 	layer            = LIGHTING_LAYER
 	invisibility     = INVISIBILITY_LIGHTING
 
-	blend_mode       = BLEND_ADD
-
 	var/needs_update = FALSE
 	var/turf/myturf
 

code/modules/mob/living/silicon/ai/ai.dm

@@ -74,7 +74,7 @@
 	var/nuking = FALSE
 	var/obj/machinery/doomsday_device/doomsday_device
 
-	var/mob/camera/aiEye/eyeobj = new
+	var/mob/camera/aiEye/eyeobj
 	var/sprint = 10
 	var/cooldown = 0
 	var/acceleration = 1
@@ -85,6 +85,13 @@
 	var/datum/action/innate/deploy_last_shell/redeploy_action = new
 	var/chnotify = 0
 
+	var/multicam_allowed = FALSE
+	var/multicam_on = FALSE
+	var/obj/screen/movable/pic_in_pic/ai/master_multicam
+	var/list/multicam_screens = list()
+	var/list/all_eyes = list()
+	var/max_multicams = 6
+
 /mob/living/silicon/ai/Initialize(mapload, datum/ai_laws/L, mob/target_ai)
 	. = ..()
 	if(!target_ai) //If there is no player/brain inside.
@@ -116,8 +123,7 @@
 
 	job = "AI"
 
-	eyeobj.ai = src
-	eyeobj.forceMove(src.loc)
+	create_eye()
 	rename_self("ai")
 
 	holo_icon = getHologramIcon(icon('icons/mob/ai.dmi',"default"))
@@ -871,9 +877,12 @@
 		current = A
 	if(client)
 		if(ismovableatom(A))
+			if(A != GLOB.ai_camera_room_landmark)
+				end_multicam()
 			client.perspective = EYE_PERSPECTIVE
 			client.eye = A
 		else
+			end_multicam()
 			if(isturf(loc))
 				if(eyeobj)
 					client.eye = eyeobj
@@ -993,3 +1002,11 @@
 	. = ..()
 	if(!target_ai)
 		target_ai = src //cheat! just give... ourselves as the spawned AI, because that's technically correct
+
+/mob/living/silicon/ai/proc/camera_visibility(mob/camera/aiEye/moved_eye)
+	GLOB.cameranet.visibility(moved_eye, client, all_eyes)
+
+/mob/living/silicon/ai/forceMove(atom/destination)
+	. = ..()
+	if(.)
+		end_multicam()

code/modules/mob/living/silicon/ai/freelook/cameranet.dm

@@ -38,29 +38,63 @@ GLOBAL_DATUM_INIT(cameranet, /datum/cameranet, new)
 
 // Updates what the aiEye can see. It is recommended you use this when the aiEye moves or it's location is set.
 
-/datum/cameranet/proc/visibility(mob/camera/aiEye/ai)
-	// 0xf = 15
-	var/x1 = max(0, ai.x - 16) & ~(CHUNK_SIZE - 1)
-	var/y1 = max(0, ai.y - 16) & ~(CHUNK_SIZE - 1)
-	var/x2 = min(world.maxx, ai.x + 16) & ~(CHUNK_SIZE - 1)
-	var/y2 = min(world.maxy, ai.y + 16) & ~(CHUNK_SIZE - 1)
+/datum/cameranet/proc/visibility(list/moved_eyes, client/C, list/other_eyes)
+	if(!islist(moved_eyes))
+		moved_eyes = moved_eyes ? list(moved_eyes) : list()
+	if(islist(other_eyes))
+		other_eyes = (other_eyes - moved_eyes)
+	else
+		other_eyes = list()
 
-	var/list/visibleChunks = list()
+	var/list/chunks_pre_seen = list()
+	var/list/chunks_post_seen = list()
 
-	for(var/x = x1; x <= x2; x += CHUNK_SIZE)
-		for(var/y = y1; y <= y2; y += CHUNK_SIZE)
-			visibleChunks |= getCameraChunk(x, y, ai.z)
+	for(var/V in moved_eyes)
+		var/mob/camera/aiEye/eye = V
+		if(C)
+			chunks_pre_seen |= eye.visibleCameraChunks
+		// 0xf = 15
+		var/static_range = eye.static_visibility_range
+		var/x1 = max(0, eye.x - static_range) & ~(CHUNK_SIZE - 1)
+		var/y1 = max(0, eye.y - static_range) & ~(CHUNK_SIZE - 1)
+		var/x2 = min(world.maxx, eye.x + static_range) & ~(CHUNK_SIZE - 1)
+		var/y2 = min(world.maxy, eye.y + static_range) & ~(CHUNK_SIZE - 1)
 
-	var/list/remove = ai.visibleCameraChunks - visibleChunks
-	var/list/add = visibleChunks - ai.visibleCameraChunks
+		var/list/visibleChunks = list()
 
-	for(var/chunk in remove)
-		var/datum/camerachunk/c = chunk
-		c.remove(ai)
+		for(var/x = x1; x <= x2; x += CHUNK_SIZE)
+			for(var/y = y1; y <= y2; y += CHUNK_SIZE)
+				visibleChunks |= getCameraChunk(x, y, eye.z)
 
-	for(var/chunk in add)
-		var/datum/camerachunk/c = chunk
-		c.add(ai)
+		var/list/remove = eye.visibleCameraChunks - visibleChunks
+		var/list/add = visibleChunks - eye.visibleCameraChunks
+
+		for(var/chunk in remove)
+			var/datum/camerachunk/c = chunk
+			c.remove(eye, FALSE)
+
+		for(var/chunk in add)
+			var/datum/camerachunk/c = chunk
+			c.add(eye, FALSE)
+
+		if(C)
+			chunks_post_seen |= eye.visibleCameraChunks
+
+	if(C)
+		for(var/V in other_eyes)
+			var/mob/camera/aiEye/eye = V
+			chunks_post_seen |= eye.visibleCameraChunks
+
+		var/list/remove = chunks_pre_seen - chunks_post_seen
+		var/list/add = chunks_post_seen - chunks_pre_seen
+
+		for(var/chunk in remove)
+			var/datum/camerachunk/c = chunk
+			C.images -= c.obscured
+
+		for(var/chunk in add)
+			var/datum/camerachunk/c = chunk
+			C.images += c.obscured
 
 // Updates the chunks that the turf is located in. Use this when obstacles are destroyed or	when doors open.
 

code/modules/mob/living/silicon/ai/freelook/chunk.dm

@@ -20,10 +20,11 @@
 
 // Add an AI eye to the chunk, then update if changed.
 
-/datum/camerachunk/proc/add(mob/camera/aiEye/eye)
-	var/client/client = eye.GetViewerClient()
-	if(client)
-		client.images += obscured
+/datum/camerachunk/proc/add(mob/camera/aiEye/eye, add_images = TRUE)
+	if(add_images)
+		var/client/client = eye.GetViewerClient()
+		if(client)
+			client.images += obscured
 	eye.visibleCameraChunks += src
 	visible++
 	seenby += eye
@@ -32,10 +33,11 @@
 
 // Remove an AI eye from the chunk, then update if changed.
 
-/datum/camerachunk/proc/remove(mob/camera/aiEye/eye)
-	var/client/client = eye.GetViewerClient()
-	if(client)
-		client.images -= obscured
+/datum/camerachunk/proc/remove(mob/camera/aiEye/eye, remove_images = TRUE)
+	if(remove_images)
+		var/client/client = eye.GetViewerClient()
+		if(client)
+			client.images -= obscured
 	eye.visibleCameraChunks -= src
 	seenby -= eye
 	if(visible > 0)

code/modules/mob/living/silicon/ai/freelook/eye.dm

@@ -11,6 +11,7 @@
 	var/mob/living/silicon/ai/ai = null
 	var/relay_speech = FALSE
 	var/use_static = TRUE
+	var/static_visibility_range = 16
 
 // Use this when setting the aiEye's location.
 // It will also stream the chunk that the new loc is in.
@@ -25,8 +26,8 @@
 		else
 			moveToNullspace() // ????
 		if(use_static)
-			GLOB.cameranet.visibility(src)
-		if(ai.client)
+			ai.camera_visibility(src)
+		if(ai.client && !ai.multicam_on)
 			ai.client.eye = src
 		update_parallax_contents()
 		//Holopad
@@ -35,6 +36,8 @@
 			H.move_hologram(ai, T)
 		if(ai.camera_light_on)
 			ai.light_cameras()
+		if(ai.master_multicam)
+			ai.master_multicam.refresh_view()
 
 /mob/camera/aiEye/Move()
 	return 0
@@ -45,20 +48,27 @@
 	return null
 
 /mob/camera/aiEye/proc/RemoveImages()
-	if(use_static)
-		for(var/datum/camerachunk/chunk in visibleCameraChunks)
-			chunk.remove(src)
+	var/client/C = GetViewerClient()
+	if(C && use_static)
+		for(var/V in visibleCameraChunks)
+			var/datum/camerachunk/c = V
+			C.images -= c.obscured
 
 /mob/camera/aiEye/Destroy()
-	ai = null
+	if(ai)
+		ai.all_eyes -= src
+		ai = null
+	for(var/V in visibleCameraChunks)
+		var/datum/camerachunk/c = V
+		c.remove(src)
 	return ..()
 
 /atom/proc/move_camera_by_click()
 	if(isAI(usr))
 		var/mob/living/silicon/ai/AI = usr
-		if(AI.eyeobj && AI.client.eye == AI.eyeobj)
+		if(AI.eyeobj && (AI.multicam_on || (AI.client.eye == AI.eyeobj)) && (AI.eyeobj.z == z))
 			AI.cameraFollow = null
-			if (isturf(src.loc) || isturf(src))
+			if (isturf(loc) || isturf(src))
 				AI.eyeobj.setLoc(src)
 
 // This will move the AIEye. It will also cause lights near the eye to light up, if toggled.
@@ -95,12 +105,19 @@
 
 	if(!eyeobj || !eyeobj.loc || QDELETED(eyeobj))
 		to_chat(src, "ERROR: Eyeobj not found. Creating new eye...")
-		eyeobj = new(loc)
-		eyeobj.ai = src
-		eyeobj.name = "[src.name] (AI Eye)" // Give it a name
+		create_eye()
 
 	eyeobj.setLoc(loc)
 
+/mob/living/silicon/ai/proc/create_eye()
+	if(eyeobj)
+		return
+	eyeobj = new /mob/camera/aiEye()
+	all_eyes += eyeobj
+	eyeobj.ai = src
+	eyeobj.setLoc(loc)
+	eyeobj.name = "[name] (AI Eye)"
+
 /mob/living/silicon/ai/verb/toggle_acceleration()
 	set category = "AI Commands"
 	set name = "Toggle Camera Acceleration"

code/modules/mob/living/silicon/ai/life.dm

@@ -96,6 +96,7 @@
 
 /mob/living/silicon/ai/proc/start_RestorePowerRoutine()
 	to_chat(src, "Backup battery online. Scanners, camera, and radio interface offline. Beginning fault-detection.")
+	end_multicam()
 	sleep(50)
 	var/turf/T = get_turf(src)
 	var/area/AIarea = get_area(src)

code/modules/mob/living/silicon/ai/login.dm

@@ -4,4 +4,6 @@
 		for(var/obj/machinery/ai_status_display/O in GLOB.ai_status_displays) //change status
 			O.mode = 1
 			O.emotion = "Neutral"
+	if(multicam_on)
+		end_multicam()
 	view_core()

code/modules/mob/living/silicon/ai/multicam.dm

@@ -0,0 +1,266 @@
+//Picture in picture
+
+/obj/screen/movable/pic_in_pic/ai
+	var/mob/living/silicon/ai/ai
+	var/mutable_appearance/highlighted_background
+	var/highlighted = FALSE
+	var/mob/camera/aiEye/pic_in_pic/aiEye
+
+/obj/screen/movable/pic_in_pic/ai/Initialize()
+	. = ..()
+	aiEye = new /mob/camera/aiEye/pic_in_pic()
+	aiEye.screen = src
+
+/obj/screen/movable/pic_in_pic/ai/Destroy()
+	set_ai(null)
+	QDEL_NULL(aiEye)
+	return ..()
+
+/obj/screen/movable/pic_in_pic/ai/Click()
+	..()
+	if(ai)
+		ai.select_main_multicam_window(src)
+
+/obj/screen/movable/pic_in_pic/ai/make_backgrounds()
+	..()
+	highlighted_background = new /mutable_appearance()
+	highlighted_background.icon = 'icons/misc/pic_in_pic.dmi'
+	highlighted_background.icon_state = "background_highlight"
+	highlighted_background.layer = SPACE_LAYER
+
+/obj/screen/movable/pic_in_pic/ai/add_background()
+	if((width > 0) && (height > 0))
+		var/matrix/M = matrix()
+		M.Scale(width + 0.5, height + 0.5)
+		M.Translate((width-1)/2 * world.icon_size, (height-1)/2 * world.icon_size)
+		highlighted_background.transform = M
+		standard_background.transform = M
+		add_overlay(highlighted ? highlighted_background : standard_background)
+
+/obj/screen/movable/pic_in_pic/ai/set_view_size(width, height, do_refresh = TRUE)
+	aiEye.static_visibility_range =	(round(max(width, height) / 2) + 1)
+	if(ai)
+		ai.camera_visibility(aiEye)
+	..()
+
+/obj/screen/movable/pic_in_pic/ai/set_view_center(atom/target, do_refresh = TRUE)
+	..()
+	aiEye.setLoc(get_turf(target))
+
+/obj/screen/movable/pic_in_pic/ai/refresh_view()
+	..()
+	aiEye.setLoc(get_turf(center))
+
+/obj/screen/movable/pic_in_pic/ai/proc/highlight()
+	if(highlighted)
+		return
+	highlighted = TRUE
+	cut_overlay(standard_background)
+	add_overlay(highlighted_background)
+
+/obj/screen/movable/pic_in_pic/ai/proc/unhighlight()
+	if(!highlighted)
+		return
+	highlighted = FALSE
+	cut_overlay(highlighted_background)
+	add_overlay(standard_background)
+
+/obj/screen/movable/pic_in_pic/ai/proc/set_ai(mob/living/silicon/ai/new_ai)
+	if(ai)
+		ai.multicam_screens -= src
+		ai.all_eyes -= aiEye
+		if(ai.master_multicam == src)
+			ai.master_multicam = null
+		if(ai.multicam_on)
+			unshow_to(ai.client)
+	ai = new_ai
+	if(new_ai)
+		new_ai.multicam_screens += src
+		ai.all_eyes += aiEye
+		if(new_ai.multicam_on)
+			show_to(new_ai.client)
+
+//Turf, area, and landmark for the viewing room
+
+/turf/open/ai_visible
+	name = ""
+	icon = 'icons/misc/pic_in_pic.dmi'
+	icon_state = "room_background"
+	flags_1 = NOJAUNT_1
+
+/turf/open/ai_visible/Initialize()
+	. = ..()
+	obscured = image(null, src, null)
+
+/area/ai_multicam_room
+	name = "ai_multicam_room"
+	icon_state = "ai_camera_room"
+	dynamic_lighting = DYNAMIC_LIGHTING_DISABLED
+	valid_territory = FALSE
+	ambientsounds = list()
+	blob_allowed = FALSE
+	noteleport = TRUE
+	hidden = TRUE
+	safe = TRUE
+
+GLOBAL_DATUM(ai_camera_room_landmark, /obj/effect/landmark/ai_multicam_room)
+
+/obj/effect/landmark/ai_multicam_room
+	name = "ai camera room"
+	icon = 'icons/mob/landmarks.dmi'
+	icon_state = "x"
+
+/obj/effect/landmark/ai_multicam_room/Initialize()
+	. = ..()
+	qdel(GLOB.ai_camera_room_landmark)
+	GLOB.ai_camera_room_landmark = src
+
+/obj/effect/landmark/ai_multicam_room/Destroy()
+	if(GLOB.ai_camera_room_landmark == src)
+		GLOB.ai_camera_room_landmark = null
+	return ..()
+
+//Dummy camera eyes
+
+/mob/camera/aiEye/pic_in_pic
+	name = "Secondary AI Eye"
+	var/obj/screen/movable/pic_in_pic/ai/screen
+	var/list/cameras_telegraphed = list()
+	var/telegraph_cameras = TRUE
+	var/telegraph_range = 7
+
+/mob/camera/aiEye/pic_in_pic/GetViewerClient()
+	if(screen && screen.ai)
+		return screen.ai.client
+
+/mob/camera/aiEye/pic_in_pic/setLoc(turf/T)
+	if (T)
+		forceMove(T)
+	else
+		moveToNullspace()
+	if(screen && screen.ai)
+		screen.ai.camera_visibility(src)
+	else
+		GLOB.cameranet.visibility(src)
+	update_camera_telegraphing()
+
+/mob/camera/aiEye/pic_in_pic/proc/update_camera_telegraphing()
+	if(!telegraph_cameras)
+		return
+	var/list/obj/machinery/camera/add = list()
+	var/list/obj/machinery/camera/remove = list()
+	var/list/obj/machinery/camera/visible = list()
+	for (var/VV in visibleCameraChunks)
+		var/datum/camerachunk/CC = VV
+		for (var/V in CC.cameras)
+			var/obj/machinery/camera/C = V
+			if (!C.can_use() || (get_dist(C, src) > telegraph_range))
+				continue
+			visible |= C
+
+	add = visible - cameras_telegraphed
+	remove = cameras_telegraphed - visible
+
+	for (var/V in remove)
+		var/obj/machinery/camera/C = V
+		if(QDELETED(C))
+			continue
+		cameras_telegraphed -= C
+		C.in_use_lights--
+		C.update_icon()
+	for (var/V in add)
+		var/obj/machinery/camera/C = V
+		if(QDELETED(C))
+			continue
+		cameras_telegraphed |= C
+		C.in_use_lights++
+		C.update_icon()
+
+/mob/camera/aiEye/pic_in_pic/proc/disable_camera_telegraphing()
+	telegraph_cameras = FALSE
+	for (var/V in cameras_telegraphed)
+		var/obj/machinery/camera/C = V
+		if(QDELETED(C))
+			continue
+		C.in_use_lights--
+		C.update_icon()
+	cameras_telegraphed.Cut()
+
+/mob/camera/aiEye/pic_in_pic/Destroy()
+	disable_camera_telegraphing()
+	return ..()
+
+//AI procs
+
+/mob/living/silicon/ai/proc/drop_new_multicam(silent = FALSE)
+	if(!multicam_allowed)
+		if(!silent)
+			to_chat(src, "<span class='warning'>This action is currently disabled. Contact an administrator to enable this feature.</span>")
+		return
+	if(!eyeobj)
+		return
+	if(multicam_screens.len >= max_multicams)
+		if(!silent)
+			to_chat(src, "<span class='warning'>Cannot place more than [max_multicams] multicamera windows.</span>")
+		return
+	var/obj/screen/movable/pic_in_pic/ai/C = new /obj/screen/movable/pic_in_pic/ai()
+	C.set_view_size(3, 3, FALSE)
+	C.set_view_center(get_turf(eyeobj))
+	C.set_ai(src)
+	if(!silent)
+		to_chat(src, "<span class='notice'>Added new multicamera window.</span>")
+	return C
+
+/mob/living/silicon/ai/proc/toggle_multicam()
+	if(!multicam_allowed)
+		to_chat(src, "<span class='warning'>This action is currently disabled. Contact an administrator to enable this feature.</span>")
+		return
+	if(multicam_on)
+		end_multicam()
+	else
+		start_multicam()
+
+/mob/living/silicon/ai/proc/start_multicam()
+	if(multicam_on || aiRestorePowerRoutine || !isturf(loc))
+		return
+	if(!GLOB.ai_camera_room_landmark)
+		to_chat(src, "<span class='warning'>This function is not available at this time.</span>")
+		return
+	multicam_on = TRUE
+	refresh_multicam()
+	to_chat(src, "<span class='notice'>Multiple-camera viewing mode activated.</span>")
+
+/mob/living/silicon/ai/proc/refresh_multicam()
+	reset_perspective(GLOB.ai_camera_room_landmark)
+	if(client)
+		for(var/V in multicam_screens)
+			var/obj/screen/movable/pic_in_pic/P = V
+			P.show_to(client)
+
+/mob/living/silicon/ai/proc/end_multicam()
+	if(!multicam_on)
+		return
+	multicam_on = FALSE
+	select_main_multicam_window(null)
+	if(client)
+		for(var/V in multicam_screens)
+			var/obj/screen/movable/pic_in_pic/P = V
+			P.unshow_to(client)
+	reset_perspective()
+	to_chat(src, "<span class='notice'>Multiple-camera viewing mode deactivated.</span>")
+
+
+/mob/living/silicon/ai/proc/select_main_multicam_window(obj/screen/movable/pic_in_pic/ai/P)
+	if(master_multicam == P)
+		return
+
+	if(master_multicam)
+		master_multicam.set_view_center(get_turf(eyeobj), FALSE)
+		master_multicam.unhighlight()
+		master_multicam = null
+
+	if(P)
+		P.highlight()
+		eyeobj.setLoc(get_turf(P.center))
+		P.set_view_center(eyeobj)
+		master_multicam = P