Ports the VV Refactor by Kevinz.

code/modules/admin/view_variables/admin_delete.dm

@@ -0,0 +1,24 @@
+/client/proc/admin_delete(datum/D)
+	var/atom/A = D
+	var/coords = ""
+	var/jmp_coords = ""
+	if(istype(A))
+		var/turf/T = get_turf(A)
+		if(T)
+			coords = "at [COORD(T)]"
+			jmp_coords = "at [ADMIN_COORDJMP(T)]"
+		else
+			jmp_coords = coords = "in nullspace"
+
+	if (alert(src, "Are you sure you want to delete:\n[D]\n[coords]?", "Confirmation", "Yes", "No") == "Yes")
+		log_admin("[key_name(usr)] deleted [D] [coords]")
+		message_admins("[key_name_admin(usr)] deleted [D] [jmp_coords]")
+		SSblackbox.record_feedback("tally", "admin_verb", 1, "Delete") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+		if(isturf(D))
+			var/turf/T = D
+			T.ScrapeAway()
+		else
+			vv_update_display(D, "deleted", VV_MSG_DELETED)
+			qdel(D)
+			if(!QDELETED(D))
+				vv_update_display(D, "deleted", "")

code/modules/admin/view_variables/debug_variables.dm

@@ -0,0 +1,76 @@
+#define VV_HTML_ENCODE(thing) ( sanitize ? html_encode(thing) : thing )
+/proc/debug_variable(name, value, level, datum/D, sanitize = TRUE)			//if D is a list, name will be index, and value will be assoc value.
+	var/header
+	if(D)
+		if(islist(D))
+			var/index = name
+			if (value)
+				name = D[name] //name is really the index until this line
+			else
+				value = D[name]
+			header = "<li style='backgroundColor:white'>([VV_HREF_TARGET_1V(D, VV_HK_LIST_EDIT, "E", index)]) ([VV_HREF_TARGET_1V(D, VV_HK_LIST_CHANGE, "C", index)]) ([VV_HREF_TARGET_1V(D, VV_HK_LIST_REMOVE, "-", index)]) "
+		else
+			header = "<li style='backgroundColor:white'>([VV_HREF_TARGET_1V(D, VV_HK_BASIC_EDIT, "E", name)]) ([VV_HREF_TARGET_1V(D, VV_HK_BASIC_CHANGE, "C", name)]) ([VV_HREF_TARGET_1V(D, VV_HK_BASIC_MASSEDIT, "M", name)]) "
+	else
+		header = "<li>"
+
+	var/item
+	if (isnull(value))
+		item = "[VV_HTML_ENCODE(name)] = <span class='value'>null</span>"
+
+	else if (istext(value))
+		item = "[VV_HTML_ENCODE(name)] = <span class='value'>\"[VV_HTML_ENCODE(value)]\"</span>"
+
+	else if (isicon(value))
+		#ifdef VARSICON
+		var/icon/I = icon(value)
+		var/rnd = rand(1,10000)
+		var/rname = "tmp[REF(I)][rnd].png"
+		usr << browse_rsc(I, rname)
+		item = "[VV_HTML_ENCODE(name)] = (<span class='value'>[value]</span>) <img class=icon src=\"[rname]\">"
+		#else
+		item = "[VV_HTML_ENCODE(name)] = /icon (<span class='value'>[value]</span>)"
+		#endif
+
+	else if (isfile(value))
+		item = "[VV_HTML_ENCODE(name)] = <span class='value'>'[value]'</span>"
+
+	else if (istype(value, /datum))
+		var/datum/DV = value
+		if ("[DV]" != "[DV.type]") //if the thing as a name var, lets use it.
+			item = "<a href='?_src_=vars;[HrefToken()];Vars=[REF(value)]'>[VV_HTML_ENCODE(name)] [REF(value)]</a> = [DV] [DV.type]"
+		else
+			item = "<a href='?_src_=vars;[HrefToken()];Vars=[REF(value)]'>[VV_HTML_ENCODE(name)] [REF(value)]</a> = [DV.type]"
+
+	else if (islist(value))
+		var/list/L = value
+		var/list/items = list()
+
+		if (L.len > 0 && !(name == "underlays" || name == "overlays" || L.len > (IS_NORMAL_LIST(L) ? VV_NORMAL_LIST_NO_EXPAND_THRESHOLD : VV_SPECIAL_LIST_NO_EXPAND_THRESHOLD)))
+			for (var/i in 1 to L.len)
+				var/key = L[i]
+				var/val
+				if (IS_NORMAL_LIST(L) && !isnum(key))
+					val = L[key]
+				if (isnull(val))	// we still want to display non-null false values, such as 0 or ""
+					val = key
+					key = i
+
+				items += debug_variable(key, val, level + 1, sanitize = sanitize)
+
+			item = "<a href='?_src_=vars;[HrefToken()];Vars=[REF(value)]'>[VV_HTML_ENCODE(name)] = /list ([L.len])</a><ul>[items.Join()]</ul>"
+		else
+			item = "<a href='?_src_=vars;[HrefToken()];Vars=[REF(value)]'>[VV_HTML_ENCODE(name)] = /list ([L.len])</a>"
+
+	else if (name in GLOB.bitfields)
+		var/list/flags = list()
+		for (var/i in GLOB.bitfields[name])
+			if (value & GLOB.bitfields[name][i])
+				flags += i
+			item = "[VV_HTML_ENCODE(name)] = [VV_HTML_ENCODE(jointext(flags, ", "))]"
+	else
+		item = "[VV_HTML_ENCODE(name)] = <span class='value'>[VV_HTML_ENCODE(value)]</span>"
+
+	return "[header][item]</li>"
+
+#undef VV_HTML_ENCODE

code/modules/admin/view_variables/get_variables.dm

@@ -0,0 +1,271 @@
+/client/proc/vv_get_class(var_name, var_value)
+	if(isnull(var_value))
+		. = VV_NULL
+
+	else if(isnum(var_value))
+		if(var_name in GLOB.bitfields)
+			. = VV_BITFIELD
+		else
+			. = VV_NUM
+
+	else if(istext(var_value))
+		if(findtext(var_value, "\n"))
+			. = VV_MESSAGE
+		else
+			. = VV_TEXT
+
+	else if(isicon(var_value))
+		. = VV_ICON
+
+	else if(ismob(var_value))
+		. = VV_MOB_REFERENCE
+
+	else if(isloc(var_value))
+		. = VV_ATOM_REFERENCE
+
+	else if(istype(var_value, /client))
+		. = VV_CLIENT
+
+	else if(istype(var_value, /datum))
+		. = VV_DATUM_REFERENCE
+
+	else if(ispath(var_value))
+		if(ispath(var_value, /atom))
+			. = VV_ATOM_TYPE
+		else if(ispath(var_value, /datum))
+			. = VV_DATUM_TYPE
+		else
+			. = VV_TYPE
+
+	else if(islist(var_value))
+		. = VV_LIST
+
+	else if(isfile(var_value))
+		. = VV_FILE
+	else
+		. = VV_NULL
+
+/client/proc/vv_get_value(class, default_class, current_value, list/restricted_classes, list/extra_classes, list/classes, var_name)
+	. = list("class" = class, "value" = null)
+	if(!class)
+		if(!classes)
+			classes = list (
+				VV_NUM,
+				VV_TEXT,
+				VV_MESSAGE,
+				VV_ICON,
+				VV_ATOM_REFERENCE,
+				VV_DATUM_REFERENCE,
+				VV_MOB_REFERENCE,
+				VV_CLIENT,
+				VV_ATOM_TYPE,
+				VV_DATUM_TYPE,
+				VV_TYPE,
+				VV_FILE,
+				VV_NEW_ATOM,
+				VV_NEW_DATUM,
+				VV_NEW_TYPE,
+				VV_NEW_LIST,
+				VV_NULL,
+				VV_RESTORE_DEFAULT,
+				VV_TEXT_LOCATE,
+				VV_PROCCALL_RETVAL,
+				)
+
+		var/markstring
+		if(!(VV_MARKED_DATUM in restricted_classes))
+			markstring = "[VV_MARKED_DATUM] (CURRENT: [(istype(holder) && istype(holder.marked_datum))? holder.marked_datum.type : "NULL"])"
+			classes += markstring
+
+		if(restricted_classes)
+			classes -= restricted_classes
+
+		if(extra_classes)
+			classes += extra_classes
+
+		.["class"] = input(src, "What kind of data?", "Variable Type", default_class) as null|anything in classes
+		if(holder && holder.marked_datum && .["class"] == markstring)
+			.["class"] = VV_MARKED_DATUM
+
+	switch(.["class"])
+		if(VV_TEXT)
+			.["value"] = input("Enter new text:", "Text", current_value) as null|text
+			if(.["value"] == null)
+				.["class"] = null
+				return
+		if(VV_MESSAGE)
+			.["value"] = input("Enter new text:", "Text", current_value) as null|message
+			if(.["value"] == null)
+				.["class"] = null
+				return
+
+
+		if(VV_NUM)
+			.["value"] = input("Enter new number:", "Num", current_value) as null|num
+			if(.["value"] == null)
+				.["class"] = null
+				return
+
+		if(VV_BITFIELD)
+			.["value"] = input_bitfield(usr, "Editing bitfield: [var_name]", var_name, current_value)
+			if(.["value"] == null)
+				.["class"] = null
+				return
+
+		if(VV_ATOM_TYPE)
+			.["value"] = pick_closest_path(FALSE)
+			if(.["value"] == null)
+				.["class"] = null
+				return
+
+		if(VV_DATUM_TYPE)
+			.["value"] = pick_closest_path(FALSE, get_fancy_list_of_datum_types())
+			if(.["value"] == null)
+				.["class"] = null
+				return
+
+		if(VV_TYPE)
+			var/type = current_value
+			var/error = ""
+			do
+				type = input("Enter type:[error]", "Type", type) as null|text
+				if(!type)
+					break
+				type = text2path(type)
+				error = "\nType not found, Please try again"
+			while(!type)
+			if(!type)
+				.["class"] = null
+				return
+			.["value"] = type
+
+		if(VV_ATOM_REFERENCE)
+			var/type = pick_closest_path(FALSE)
+			var/subtypes = vv_subtype_prompt(type)
+			if(subtypes == null)
+				.["class"] = null
+				return
+			var/list/things = vv_reference_list(type, subtypes)
+			var/value = input("Select reference:", "Reference", current_value) as null|anything in things
+			if(!value)
+				.["class"] = null
+				return
+			.["value"] = things[value]
+
+		if(VV_DATUM_REFERENCE)
+			var/type = pick_closest_path(FALSE, get_fancy_list_of_datum_types())
+			var/subtypes = vv_subtype_prompt(type)
+			if(subtypes == null)
+				.["class"] = null
+				return
+			var/list/things = vv_reference_list(type, subtypes)
+			var/value = input("Select reference:", "Reference", current_value) as null|anything in things
+			if(!value)
+				.["class"] = null
+				return
+			.["value"] = things[value]
+
+		if(VV_MOB_REFERENCE)
+			var/type = pick_closest_path(FALSE, make_types_fancy(typesof(/mob)))
+			var/subtypes = vv_subtype_prompt(type)
+			if(subtypes == null)
+				.["class"] = null
+				return
+			var/list/things = vv_reference_list(type, subtypes)
+			var/value = input("Select reference:", "Reference", current_value) as null|anything in things
+			if(!value)
+				.["class"] = null
+				return
+			.["value"] = things[value]
+
+		if(VV_CLIENT)
+			.["value"] = input("Select reference:", "Reference", current_value) as null|anything in GLOB.clients
+			if(.["value"] == null)
+				.["class"] = null
+				return
+
+		if(VV_FILE)
+			.["value"] = input("Pick file:", "File") as null|file
+			if(.["value"] == null)
+				.["class"] = null
+				return
+
+		if(VV_ICON)
+			.["value"] = input("Pick icon:", "Icon") as null|icon
+			if(.["value"] == null)
+				.["class"] = null
+				return
+
+		if(VV_MARKED_DATUM)
+			.["value"] = holder.marked_datum
+			if(.["value"] == null)
+				.["class"] = null
+				return
+
+		if(VV_PROCCALL_RETVAL)
+			var/list/get_retval = list()
+			callproc_blocking(get_retval)
+			.["value"] = get_retval[1]		//should have been set in proccall!
+			if(.["value"] == null)
+				.["class"] = null
+				return
+
+		if(VV_NEW_ATOM)
+			var/type = pick_closest_path(FALSE)
+			if(!type)
+				.["class"] = null
+				return
+			.["type"] = type
+			var/atom/newguy = new type()
+			newguy.datum_flags |= DF_VAR_EDITED
+			.["value"] = newguy
+
+		if(VV_NEW_DATUM)
+			var/type = pick_closest_path(FALSE, get_fancy_list_of_datum_types())
+			if(!type)
+				.["class"] = null
+				return
+			.["type"] = type
+			var/datum/newguy = new type()
+			newguy.datum_flags |= DF_VAR_EDITED
+			.["value"] = newguy
+
+		if(VV_NEW_TYPE)
+			var/type = current_value
+			var/error = ""
+			do
+				type = input("Enter type:[error]", "Type", type) as null|text
+				if(!type)
+					break
+				type = text2path(type)
+				error = "\nType not found, Please try again"
+			while(!type)
+			if(!type)
+				.["class"] = null
+				return
+			.["type"] = type
+			var/datum/newguy = new type()
+			if(istype(newguy))
+				newguy.datum_flags |= DF_VAR_EDITED
+			.["value"] = newguy
+
+		if(VV_NEW_LIST)
+			.["value"] = list()
+			.["type"] = /list
+
+		if(VV_TEXT_LOCATE)
+			var/datum/D
+			do
+				var/ref = input("Enter reference:", "Reference") as null|text
+				if(!ref)
+					break
+				D = locate(ref)
+				if(!D)
+					alert("Invalid ref!")
+					continue
+				if(!D.can_vv_mark())
+					alert("Datum can not be marked!")
+					continue
+			while(!D)
+			.["type"] = D.type
+			.["value"] = D

code/modules/admin/view_variables/mark_datum.dm

@@ -0,0 +1,12 @@
+/client/proc/mark_datum(datum/D)
+	if(!holder)
+		return
+	if(holder.marked_datum)
+		vv_update_display(holder.marked_datum, "marked", "")
+	holder.marked_datum = D
+	vv_update_display(D, "marked", VV_MSG_MARKED)
+
+/client/proc/mark_datum_mapview(datum/D as mob|obj|turf|area in view(view))
+	set category = "Debug"
+	set name = "Mark Object"
+	mark_datum(D)

code/modules/admin/view_variables/mass_edit_variables.dm

@@ -0,0 +1,271 @@
+/client/proc/cmd_mass_modify_object_variables(atom/A, var_name)
+	set category = "Debug"
+	set name = "Mass Edit Variables"
+	set desc="(target) Edit all instances of a target item's variables"
+
+	var/method = 0	//0 means strict type detection while 1 means this type and all subtypes (IE: /obj/item with this set to 1 will set it to ALL items)
+
+	if(!check_rights(R_VAREDIT))
+		return
+
+	if(A && A.type)
+		method = vv_subtype_prompt(A.type)
+
+	src.massmodify_variables(A, var_name, method)
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Mass Edit Variables") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+/client/proc/massmodify_variables(datum/O, var_name = "", method = 0)
+	if(!check_rights(R_VAREDIT))
+		return
+	if(!istype(O))
+		return
+
+	var/variable = ""
+	if(!var_name)
+		var/list/names = list()
+		for (var/V in O.vars)
+			names += V
+
+		names = sortList(names)
+
+		variable = input("Which var?", "Var") as null|anything in names
+	else
+		variable = var_name
+
+	if(!variable || !O.can_vv_get(variable))
+		return
+	var/default
+	var/var_value = O.vars[variable]
+
+	if(variable in GLOB.VVckey_edit)
+		to_chat(src, "It's forbidden to mass-modify ckeys. It'll crash everyone's client you dummy.")
+		return
+	if(variable in GLOB.VVlocked)
+		if(!check_rights(R_DEBUG))
+			return
+	if(variable in GLOB.VVicon_edit_lock)
+		if(!check_rights(R_FUN|R_DEBUG))
+			return
+	if(variable in GLOB.VVpixelmovement)
+		if(!check_rights(R_DEBUG))
+			return
+		var/prompt = alert(src, "Editing this var may irreparably break tile gliding for the rest of the round. THIS CAN'T BE UNDONE", "DANGER", "ABORT ", "Continue", " ABORT")
+		if (prompt != "Continue")
+			return
+
+	default = vv_get_class(variable, var_value)
+
+	if(isnull(default))
+		to_chat(src, "Unable to determine variable type.")
+	else
+		to_chat(src, "Variable appears to be <b>[uppertext(default)]</b>.")
+
+	to_chat(src, "Variable contains: [var_value]")
+
+	if(default == VV_NUM)
+		var/dir_text = ""
+		if(var_value > 0 && var_value < 16)
+			if(var_value & 1)
+				dir_text += "NORTH"
+			if(var_value & 2)
+				dir_text += "SOUTH"
+			if(var_value & 4)
+				dir_text += "EAST"
+			if(var_value & 8)
+				dir_text += "WEST"
+
+		if(dir_text)
+			to_chat(src, "If a direction, direction is: [dir_text]")
+
+	var/value = vv_get_value(default_class = default)
+	var/new_value = value["value"]
+	var/class = value["class"]
+
+	if(!class || !new_value == null && class != VV_NULL)
+		return
+
+	if (class == VV_MESSAGE)
+		class = VV_TEXT
+
+	if (value["type"])
+		class = VV_NEW_TYPE
+
+	var/original_name = "[O]"
+
+	var/rejected = 0
+	var/accepted = 0
+
+	switch(class)
+		if(VV_RESTORE_DEFAULT)
+			to_chat(src, "Finding items...")
+			var/list/items = get_all_of_type(O.type, method)
+			to_chat(src, "Changing [items.len] items...")
+			for(var/thing in items)
+				if (!thing)
+					continue
+				var/datum/D = thing
+				if (D.vv_edit_var(variable, initial(D.vars[variable])) != FALSE)
+					accepted++
+				else
+					rejected++
+				CHECK_TICK
+
+		if(VV_TEXT)
+			var/list/varsvars = vv_parse_text(O, new_value)
+			var/pre_processing = new_value
+			var/unique
+			if (varsvars && varsvars.len)
+				unique = alert(usr, "Process vars unique to each instance, or same for all?", "Variable Association", "Unique", "Same")
+				if(unique == "Unique")
+					unique = TRUE
+				else
+					unique = FALSE
+					for(var/V in varsvars)
+						new_value = replacetext(new_value,"\[[V]]","[O.vars[V]]")
+
+			to_chat(src, "Finding items...")
+			var/list/items = get_all_of_type(O.type, method)
+			to_chat(src, "Changing [items.len] items...")
+			for(var/thing in items)
+				if (!thing)
+					continue
+				var/datum/D = thing
+				if(unique)
+					new_value = pre_processing
+					for(var/V in varsvars)
+						new_value = replacetext(new_value,"\[[V]]","[D.vars[V]]")
+
+				if (D.vv_edit_var(variable, new_value) != FALSE)
+					accepted++
+				else
+					rejected++
+				CHECK_TICK
+
+		if (VV_NEW_TYPE)
+			var/many = alert(src, "Create only one [value["type"]] and assign each or a new one for each thing", "How Many", "One", "Many", "Cancel")
+			if (many == "Cancel")
+				return
+			if (many == "Many")
+				many = TRUE
+			else
+				many = FALSE
+
+			var/type = value["type"]
+			to_chat(src, "Finding items...")
+			var/list/items = get_all_of_type(O.type, method)
+			to_chat(src, "Changing [items.len] items...")
+			for(var/thing in items)
+				if (!thing)
+					continue
+				var/datum/D = thing
+				if(many && !new_value)
+					new_value = new type()
+
+				if (D.vv_edit_var(variable, new_value) != FALSE)
+					accepted++
+				else
+					rejected++
+				new_value = null
+				CHECK_TICK
+
+		else
+			to_chat(src, "Finding items...")
+			var/list/items = get_all_of_type(O.type, method)
+			to_chat(src, "Changing [items.len] items...")
+			for(var/thing in items)
+				if (!thing)
+					continue
+				var/datum/D = thing
+				if (D.vv_edit_var(variable, new_value) != FALSE)
+					accepted++
+				else
+					rejected++
+				CHECK_TICK
+
+
+	var/count = rejected+accepted
+	if (!count)
+		to_chat(src, "No objects found")
+		return
+	if (!accepted)
+		to_chat(src, "Every object rejected your edit")
+		return
+	if (rejected)
+		to_chat(src, "[rejected] out of [count] objects rejected your edit")
+
+	log_world("### MassVarEdit by [src]: [O.type] (A/R [accepted]/[rejected]) [variable]=[html_encode("[O.vars[variable]]")]([list2params(value)])")
+	log_admin("[key_name(src)] mass modified [original_name]'s [variable] to [O.vars[variable]] ([accepted] objects modified)")
+	message_admins("[key_name_admin(src)] mass modified [original_name]'s [variable] to [O.vars[variable]] ([accepted] objects modified)")
+
+//not using global lists as vv is a debug function and debug functions should rely on as less things as possible.
+/proc/get_all_of_type(var/T, subtypes = TRUE)
+	var/list/typecache = list()
+	typecache[T] = 1
+	if (subtypes)
+		typecache = typecacheof(typecache)
+	. = list()
+	if (ispath(T, /mob))
+		for(var/mob/thing in world)
+			if (typecache[thing.type])
+				. += thing
+			CHECK_TICK
+
+	else if (ispath(T, /obj/machinery/door))
+		for(var/obj/machinery/door/thing in world)
+			if (typecache[thing.type])
+				. += thing
+			CHECK_TICK
+
+	else if (ispath(T, /obj/machinery))
+		for(var/obj/machinery/thing in world)
+			if (typecache[thing.type])
+				. += thing
+			CHECK_TICK
+
+	else if (ispath(T, /obj/item))
+		for(var/obj/item/thing in world)
+			if (typecache[thing.type])
+				. += thing
+			CHECK_TICK
+
+	else if (ispath(T, /obj))
+		for(var/obj/thing in world)
+			if (typecache[thing.type])
+				. += thing
+			CHECK_TICK
+
+	else if (ispath(T, /atom/movable))
+		for(var/atom/movable/thing in world)
+			if (typecache[thing.type])
+				. += thing
+			CHECK_TICK
+
+	else if (ispath(T, /turf))
+		for(var/turf/thing in world)
+			if (typecache[thing.type])
+				. += thing
+			CHECK_TICK
+
+	else if (ispath(T, /atom))
+		for(var/atom/thing in world)
+			if (typecache[thing.type])
+				. += thing
+			CHECK_TICK
+
+	else if (ispath(T, /client))
+		for(var/client/thing in world)
+			if (typecache[thing.type])
+				. += thing
+			CHECK_TICK
+
+	else if (ispath(T, /datum))
+		for(var/datum/thing)
+			if (typecache[thing.type])
+				. += thing
+			CHECK_TICK
+
+	else
+		for(var/datum/thing in world)
+			if (typecache[thing.type])
+				. += thing
+			CHECK_TICK

code/modules/admin/view_variables/modify_variables.dm

@@ -0,0 +1,388 @@
+GLOBAL_LIST_INIT(VVlocked, list("vars", "datum_flags", "client", "mob"))		//Requires DEBUG
+GLOBAL_PROTECT(VVlocked)
+GLOBAL_LIST_INIT(VVicon_edit_lock, list("icon", "icon_state", "overlays", "underlays"))		//Requires DEBUG or FUN
+GLOBAL_PROTECT(VVicon_edit_lock)
+GLOBAL_LIST_INIT(VVckey_edit, list("key", "ckey"))	//Requires DEBUG or SPAWN
+GLOBAL_PROTECT(VVckey_edit)
+GLOBAL_LIST_INIT(VVpixelmovement, list("bound_x", "bound_y", "step_x", "step_y", "step_size", "bound_height", "bound_width", "bounds"))		//No editing ever.
+GLOBAL_PROTECT(VVpixelmovement)
+
+/client/proc/vv_parse_text(O, new_var)
+	if(O && findtext(new_var,"\["))
+		var/process_vars = alert(usr,"\[] detected in string, process as variables?","Process Variables?","Yes","No")
+		if(process_vars == "Yes")
+			. = string2listofvars(new_var, O)
+
+//do they want you to include subtypes?
+//FALSE = no subtypes, strict exact type pathing (or the type doesn't have subtypes)
+//TRUE = Yes subtypes
+//NULL = User cancelled at the prompt or invalid type given
+/client/proc/vv_subtype_prompt(var/type)
+	if (!ispath(type))
+		return
+	var/list/subtypes = subtypesof(type)
+	if (!subtypes || !subtypes.len)
+		return FALSE
+	if (subtypes && subtypes.len)
+		switch(alert("Strict object type detection?", "Type detection", "Strictly this type","This type and subtypes", "Cancel"))
+			if("Strictly this type")
+				return FALSE
+			if("This type and subtypes")
+				return TRUE
+			else
+				return
+
+/client/proc/vv_reference_list(type, subtypes)
+	. = list()
+	var/list/types = list(type)
+	if (subtypes)
+		types = typesof(type)
+
+	var/list/fancytypes = make_types_fancy(types)
+
+	for(var/fancytype in fancytypes) //swap the assoication
+		types[fancytypes[fancytype]] = fancytype
+
+	var/things = get_all_of_type(type, subtypes)
+
+	var/i = 0
+	for(var/thing in things)
+		var/datum/D = thing
+		i++
+		//try one of 3 methods to shorten the type text:
+		//	fancy type,
+		//	fancy type with the base type removed from the begaining,
+		//	the type with the base type removed from the begaining
+		var/fancytype = types[D.type]
+		if (findtext(fancytype, types[type]))
+			fancytype = copytext(fancytype, length(types[type]) + 1)
+		var/shorttype = copytext("[D.type]", length("[type]") + 1)
+		if (length_char(shorttype) > length_char(fancytype))
+			shorttype = fancytype
+		if (!length(shorttype))
+			shorttype = "/"
+
+		.["[D]([shorttype])[REF(D)]#[i]"] = D
+
+/client/proc/mod_list_add_ass(atom/O) //hehe
+
+	var/list/L = vv_get_value(restricted_classes = list(VV_RESTORE_DEFAULT))
+	var/class = L["class"]
+	if (!class)
+		return
+	var/var_value = L["value"]
+
+	if(class == VV_TEXT || class == VV_MESSAGE)
+		var/list/varsvars = vv_parse_text(O, var_value)
+		for(var/V in varsvars)
+			var_value = replacetext(var_value,"\[[V]]","[O.vars[V]]")
+
+	return var_value
+
+
+/client/proc/mod_list_add(list/L, atom/O, original_name, objectvar)
+	var/list/LL = vv_get_value(restricted_classes = list(VV_RESTORE_DEFAULT))
+	var/class = LL["class"]
+	if (!class)
+		return
+	var/var_value = LL["value"]
+
+	if(class == VV_TEXT || class == VV_MESSAGE)
+		var/list/varsvars = vv_parse_text(O, var_value)
+		for(var/V in varsvars)
+			var_value = replacetext(var_value,"\[[V]]","[O.vars[V]]")
+
+	if (O)
+		L = L.Copy()
+
+	L += var_value
+
+	switch(alert("Would you like to associate a value with the list entry?",,"Yes","No"))
+		if("Yes")
+			L[var_value] = mod_list_add_ass(O) //hehe
+	if (O)
+		if (O.vv_edit_var(objectvar, L) == FALSE)
+			to_chat(src, "Your edit was rejected by the object.")
+			return
+	log_world("### ListVarEdit by [src]: [(O ? O.type : "/list")] [objectvar]: ADDED=[var_value]")
+	log_admin("[key_name(src)] modified [original_name]'s [objectvar]: ADDED=[var_value]")
+	message_admins("[key_name_admin(src)] modified [original_name]'s [objectvar]: ADDED=[var_value]")
+
+/client/proc/mod_list(list/L, atom/O, original_name, objectvar, index, autodetect_class = FALSE)
+	if(!check_rights(R_VAREDIT))
+		return
+	if(!istype(L, /list))
+		to_chat(src, "Not a List.")
+		return
+
+	if(L.len > 1000)
+		var/confirm = alert(src, "The list you're trying to edit is very long, continuing may crash the server.", "Warning", "Continue", "Abort")
+		if(confirm != "Continue")
+			return
+
+	var/is_normal_list = IS_NORMAL_LIST(L)
+
+	var/list/names = list()
+	for (var/i in 1 to L.len)
+		var/key = L[i]
+		var/value
+		if (is_normal_list && !isnum(key))
+			value = L[key]
+		if (value == null)
+			value = "null"
+		names["#[i] [key] = [value]"] = i
+	if (!index)
+		var/variable = input("Which var?","Var") as null|anything in names + "(ADD VAR)" + "(CLEAR NULLS)" + "(CLEAR DUPES)" + "(SHUFFLE)"
+
+		if(variable == null)
+			return
+
+		if(variable == "(ADD VAR)")
+			mod_list_add(L, O, original_name, objectvar)
+			return
+
+		if(variable == "(CLEAR NULLS)")
+			L = L.Copy()
+			listclearnulls(L)
+			if (!O.vv_edit_var(objectvar, L))
+				to_chat(src, "Your edit was rejected by the object.")
+				return
+			log_world("### ListVarEdit by [src]: [O.type] [objectvar]: CLEAR NULLS")
+			log_admin("[key_name(src)] modified [original_name]'s [objectvar]: CLEAR NULLS")
+			message_admins("[key_name_admin(src)] modified [original_name]'s list [objectvar]: CLEAR NULLS")
+			return
+
+		if(variable == "(CLEAR DUPES)")
+			L = uniqueList(L)
+			if (!O.vv_edit_var(objectvar, L))
+				to_chat(src, "Your edit was rejected by the object.")
+				return
+			log_world("### ListVarEdit by [src]: [O.type] [objectvar]: CLEAR DUPES")
+			log_admin("[key_name(src)] modified [original_name]'s [objectvar]: CLEAR DUPES")
+			message_admins("[key_name_admin(src)] modified [original_name]'s list [objectvar]: CLEAR DUPES")
+			return
+
+		if(variable == "(SHUFFLE)")
+			L = shuffle(L)
+			if (!O.vv_edit_var(objectvar, L))
+				to_chat(src, "Your edit was rejected by the object.")
+				return
+			log_world("### ListVarEdit by [src]: [O.type] [objectvar]: SHUFFLE")
+			log_admin("[key_name(src)] modified [original_name]'s [objectvar]: SHUFFLE")
+			message_admins("[key_name_admin(src)] modified [original_name]'s list [objectvar]: SHUFFLE")
+			return
+
+		index = names[variable]
+
+
+	var/assoc_key
+	if (index == null)
+		return
+	var/assoc = 0
+	var/prompt = alert(src, "Do you want to edit the key or its assigned value?", "Associated List", "Key", "Assigned Value", "Cancel")
+	if (prompt == "Cancel")
+		return
+	if (prompt == "Assigned Value")
+		assoc = 1
+		assoc_key = L[index]
+	var/default
+	var/variable
+	var/old_assoc_value		//EXPERIMENTAL - Keep old associated value while modifying key, if any
+	if(is_normal_list)
+		if (assoc)
+			variable = L[assoc_key]
+		else
+			variable = L[index]
+			//EXPERIMENTAL - Keep old associated value while modifying key, if any
+			var/found = L[variable]
+			if(!isnull(found))
+				old_assoc_value = found
+			//
+
+	default = vv_get_class(objectvar, variable)
+
+	to_chat(src, "Variable appears to be <b>[uppertext(default)]</b>.")
+
+	to_chat(src, "Variable contains: [variable]")
+
+	if(default == VV_NUM)
+		var/dir_text = ""
+		var/tdir = variable
+		if(tdir > 0 && tdir < 16)
+			if(tdir & 1)
+				dir_text += "NORTH"
+			if(tdir & 2)
+				dir_text += "SOUTH"
+			if(tdir & 4)
+				dir_text += "EAST"
+			if(tdir & 8)
+				dir_text += "WEST"
+
+		if(dir_text)
+			to_chat(usr, "If a direction, direction is: [dir_text]")
+
+	var/original_var = variable
+
+	if (O)
+		L = L.Copy()
+	var/class
+	if(autodetect_class)
+		if (default == VV_TEXT)
+			default = VV_MESSAGE
+		class = default
+	var/list/LL = vv_get_value(default_class = default, current_value = original_var, restricted_classes = list(VV_RESTORE_DEFAULT), extra_classes = list(VV_LIST, "DELETE FROM LIST"))
+	class = LL["class"]
+	if (!class)
+		return
+	var/new_var = LL["value"]
+
+	if(class == VV_MESSAGE)
+		class = VV_TEXT
+
+	switch(class) //Spits a runtime error if you try to modify an entry in the contents list. Dunno how to fix it, yet.
+		if(VV_LIST)
+			mod_list(variable, O, original_name, objectvar)
+
+		if("DELETE FROM LIST")
+			L.Cut(index, index+1)
+			if (O)
+				if (O.vv_edit_var(objectvar, L))
+					to_chat(src, "Your edit was rejected by the object.")
+					return
+			log_world("### ListVarEdit by [src]: [O.type] [objectvar]: REMOVED=[html_encode("[original_var]")]")
+			log_admin("[key_name(src)] modified [original_name]'s [objectvar]: REMOVED=[original_var]")
+			message_admins("[key_name_admin(src)] modified [original_name]'s [objectvar]: REMOVED=[original_var]")
+			return
+
+		if(VV_TEXT)
+			var/list/varsvars = vv_parse_text(O, new_var)
+			for(var/V in varsvars)
+				new_var = replacetext(new_var,"\[[V]]","[O.vars[V]]")
+
+	if(is_normal_list)
+		if(assoc)
+			L[assoc_key] = new_var
+		else
+			L[index] = new_var
+			if(!isnull(old_assoc_value) && IS_VALID_ASSOC_KEY(new_var))
+				L[new_var] = old_assoc_value
+	if (O)
+		if (O.vv_edit_var(objectvar, L) == FALSE)
+			to_chat(src, "Your edit was rejected by the object.")
+			return
+	log_world("### ListVarEdit by [src]: [(O ? O.type : "/list")] [objectvar]: [original_var]=[new_var]")
+	log_admin("[key_name(src)] modified [original_name]'s [objectvar]: [original_var]=[new_var]")
+	message_admins("[key_name_admin(src)] modified [original_name]'s varlist [objectvar]: [original_var]=[new_var]")
+
+/proc/vv_varname_lockcheck(param_var_name)
+	if(param_var_name in GLOB.VVlocked)
+		if(!check_rights(R_DEBUG))
+			return FALSE
+	if(param_var_name in GLOB.VVckey_edit)
+		if(!check_rights(R_SPAWN|R_DEBUG))
+			return FALSE
+	if(param_var_name in GLOB.VVicon_edit_lock)
+		if(!check_rights(R_FUN|R_DEBUG))
+			return FALSE
+	return TRUE
+
+/client/proc/modify_variables(atom/O, param_var_name = null, autodetect_class = 0)
+	if(!check_rights(R_VAREDIT))
+		return
+
+	var/class
+	var/variable
+	var/var_value
+
+	if(param_var_name)
+		if(!(param_var_name in O.vars))
+			to_chat(src, "A variable with this name ([param_var_name]) doesn't exist in this datum ([O])")
+			return
+		variable = param_var_name
+
+	else
+		var/list/names = list()
+		for (var/V in O.vars)
+			names += V
+
+		names = sortList(names)
+
+		variable = input("Which var?","Var") as null|anything in names
+		if(!variable)
+			return
+
+	if(!O.can_vv_get(variable))
+		return
+
+	var_value = O.vars[variable]
+	if(!vv_varname_lockcheck(variable))
+		return
+
+	var/default = vv_get_class(variable, var_value)
+
+	if(isnull(default))
+		to_chat(src, "Unable to determine variable type.")
+	else
+		to_chat(src, "Variable appears to be <b>[uppertext(default)]</b>.")
+
+	to_chat(src, "Variable contains: [var_value]")
+
+	if(default == VV_NUM)
+		var/dir_text = ""
+		if(var_value > 0 && var_value < 16)
+			if(var_value & 1)
+				dir_text += "NORTH"
+			if(var_value & 2)
+				dir_text += "SOUTH"
+			if(var_value & 4)
+				dir_text += "EAST"
+			if(var_value & 8)
+				dir_text += "WEST"
+
+		if(dir_text)
+			to_chat(src, "If a direction, direction is: [dir_text]")
+
+	if(autodetect_class && default != VV_NULL)
+		if (default == VV_TEXT)
+			default = VV_MESSAGE
+		class = default
+
+	var/list/value = vv_get_value(class, default, var_value, extra_classes = list(VV_LIST), var_name = variable)
+	class = value["class"]
+
+	if (!class)
+		return
+	var/var_new = value["value"]
+
+	if(class == VV_MESSAGE)
+		class = VV_TEXT
+
+	var/original_name = "[O]"
+
+	switch(class)
+		if(VV_LIST)
+			if(!islist(var_value))
+				mod_list(list(), O, original_name, variable)
+
+			mod_list(var_value, O, original_name, variable)
+			return
+
+		if(VV_RESTORE_DEFAULT)
+			var_new = initial(O.vars[variable])
+
+		if(VV_TEXT)
+			var/list/varsvars = vv_parse_text(O, var_new)
+			for(var/V in varsvars)
+				var_new = replacetext(var_new,"\[[V]]","[O.vars[V]]")
+
+
+	if (O.vv_edit_var(variable, var_new) == FALSE)
+		to_chat(src, "Your edit was rejected by the object.")
+		return
+	vv_update_display(O, "varedited", VV_MSG_EDITED)
+	log_world("### VarEdit by [key_name(src)]: [O.type] [variable]=[var_value] => [var_new]")
+	log_admin("[key_name(src)] modified [original_name]'s [variable] from [html_encode("[var_value]")] to [html_encode("[var_new]")]")
+	var/msg = "[key_name_admin(src)] modified [original_name]'s [variable] from [var_value] to [var_new]"
+	message_admins(msg)
+	admin_ticket_log(O, msg)
+	return TRUE

code/modules/admin/view_variables/topic.dm

@@ -0,0 +1,128 @@
+//DO NOT ADD MORE TO THIS FILE.
+//Use vv_do_topic() for datums!
+/client/proc/view_var_Topic(href, href_list, hsrc)
+	if( (usr.client != src) || !src.holder || !holder.CheckAdminHref(href, href_list))
+		return
+	var/target = GET_VV_TARGET
+	vv_do_basic(target, href_list, href)
+	if(istype(target, /datum))
+		var/datum/D = target
+		D.vv_do_topic(href_list)
+	else if(islist(target))
+		vv_do_list(target, href_list)
+	if(href_list["Vars"])
+		debug_variables(locate(href_list["Vars"]))
+
+//Stuff below aren't in dropdowns/etc.
+
+	if(check_rights(R_VAREDIT))
+
+	//~CARN: for renaming mobs (updates their name, real_name, mind.name, their ID/PDA and datacore records).
+
+		if(href_list["rename"])
+			if(!check_rights(NONE))
+				return
+
+			var/mob/M = locate(href_list["rename"]) in GLOB.mob_list
+			if(!istype(M))
+				to_chat(usr, "This can only be used on instances of type /mob")
+				return
+
+			var/new_name = stripped_input(usr,"What would you like to name this mob?","Input a name",M.real_name,MAX_NAME_LEN)
+			if( !new_name || !M )
+				return
+
+			message_admins("Admin [key_name_admin(usr)] renamed [key_name_admin(M)] to [new_name].")
+			M.fully_replace_character_name(M.real_name,new_name)
+			vv_update_display(M, "name", new_name)
+			vv_update_display(M, "real_name", M.real_name || "No real name")
+
+		else if(href_list["rotatedatum"])
+			if(!check_rights(NONE))
+				return
+
+			var/atom/A = locate(href_list["rotatedatum"])
+			if(!istype(A))
+				to_chat(usr, "This can only be done to instances of type /atom")
+				return
+
+			switch(href_list["rotatedir"])
+				if("right")
+					A.setDir(turn(A.dir, -45))
+				if("left")
+					A.setDir(turn(A.dir, 45))
+			vv_update_display(A, "dir", dir2text(A.dir))
+
+
+		else if(href_list["makehuman"])
+			if(!check_rights(R_SPAWN))
+				return
+
+			var/mob/living/carbon/monkey/Mo = locate(href_list["makehuman"]) in GLOB.mob_list
+			if(!istype(Mo))
+				to_chat(usr, "This can only be done to instances of type /mob/living/carbon/monkey")
+				return
+
+			if(alert("Confirm mob type change?",,"Transform","Cancel") != "Transform")
+				return
+			if(!Mo)
+				to_chat(usr, "Mob doesn't exist anymore")
+				return
+			holder.Topic(href, list("humanone"=href_list["makehuman"]))
+
+		else if(href_list["adjustDamage"] && href_list["mobToDamage"])
+			if(!check_rights(NONE))
+				return
+
+			var/mob/living/L = locate(href_list["mobToDamage"]) in GLOB.mob_list
+			if(!istype(L))
+				return
+
+			var/Text = href_list["adjustDamage"]
+
+			var/amount =  input("Deal how much damage to mob? (Negative values here heal)","Adjust [Text]loss",0) as num
+
+			if(!L)
+				to_chat(usr, "Mob doesn't exist anymore")
+				return
+
+			var/newamt
+			switch(Text)
+				if("brute")
+					L.adjustBruteLoss(amount)
+					newamt = L.getBruteLoss()
+				if("fire")
+					L.adjustFireLoss(amount)
+					newamt = L.getFireLoss()
+				if("toxin")
+					L.adjustToxLoss(amount)
+					newamt = L.getToxLoss()
+				if("oxygen")
+					L.adjustOxyLoss(amount)
+					newamt = L.getOxyLoss()
+				if("brain")
+					L.adjustOrganLoss(ORGAN_SLOT_BRAIN, amount)
+					newamt = L.getOrganLoss(ORGAN_SLOT_BRAIN)
+				if("clone")
+					L.adjustCloneLoss(amount)
+					newamt = L.getCloneLoss()
+				if("stamina")
+					L.adjustStaminaLoss(amount)
+					newamt = L.getStaminaLoss()
+				else
+					to_chat(usr, "You caused an error. DEBUG: Text:[Text] Mob:[L]")
+					return
+
+			if(amount != 0)
+				var/log_msg = "[key_name(usr)] dealt [amount] amount of [Text] damage to [key_name(L)]"
+				message_admins("[key_name(usr)] dealt [amount] amount of [Text] damage to [ADMIN_LOOKUPFLW(L)]")
+				log_admin(log_msg)
+				admin_ticket_log(L, "<font color='blue'>[log_msg]</font>")
+				vv_update_display(L, Text, "[newamt]")
+
+
+	//Finally, refresh if something modified the list.
+	if(href_list["datumrefresh"])
+		var/datum/DAT = locate(href_list["datumrefresh"])
+		if(istype(DAT, /datum) || istype(DAT, /client))
+			debug_variables(DAT)

code/modules/admin/view_variables/topic_basic.dm

@@ -0,0 +1,51 @@
+//Not using datum.vv_do_topic for very basic/low level debug things, incase the datum's vv_do_topic is runtiming/whatnot.
+/client/proc/vv_do_basic(datum/target, href_list)
+	var/target_var = GET_VV_VAR_TARGET
+	if(check_rights(R_VAREDIT))
+		if(target_var)
+			if(href_list[VV_HK_BASIC_EDIT])
+				if(!modify_variables(target, target_var, 1))
+					return
+				switch(target_var)
+					if("name")
+						vv_update_display(target, "name", "[target]")
+					if("dir")
+						var/atom/A = target
+						if(istype(A))
+							vv_update_display(target, "dir", dir2text(A.dir) || A.dir)
+					if("ckey")
+						var/mob/living/L = target
+						if(istype(L))
+							vv_update_display(target, "ckey", L.ckey || "No ckey")
+					if("real_name")
+						var/mob/living/L = target
+						if(istype(L))
+							vv_update_display(target, "real_name", L.real_name || "No real name")
+			if(href_list[VV_HK_BASIC_CHANGE])
+				modify_variables(target, target_var, 0)
+			if(href_list[VV_HK_BASIC_MASSEDIT])
+				cmd_mass_modify_object_variables(target, target_var)
+	if(check_rights(R_ADMIN, FALSE))
+		if(href_list[VV_HK_EXPOSE])
+			var/value = vv_get_value(VV_CLIENT)
+			if (value["class"] != VV_CLIENT)
+				return
+			var/client/C = value["value"]
+			if (!C)
+				return
+			if(!target)
+				to_chat(usr, "<span class='warning'>The object you tried to expose to [C] no longer exists (nulled or hard-deled)</span>")
+				return
+			message_admins("[key_name_admin(usr)] Showed [key_name_admin(C)] a <a href='?_src_=vars;datumrefresh=[REF(target)]'>VV window</a>")
+			log_admin("Admin [key_name(usr)] Showed [key_name(C)] a VV window of a [target]")
+			to_chat(C, "[holder.fakekey ? "an Administrator" : "[usr.client.key]"] has granted you access to view a View Variables window")
+			C.debug_variables(target)
+	if(check_rights(R_DEBUG))
+		if(href_list[VV_HK_DELETE])
+			usr.client.admin_delete(target)
+			if (isturf(src))	// show the turf that took its place
+				usr.client.debug_variables(src)
+	if(href_list[VV_HK_MARK])
+		usr.client.mark_datum(target)
+	if(href_list[VV_HK_CALLPROC])
+		usr.client.callproc_datum(target)

code/modules/admin/view_variables/topic_list.dm

@@ -0,0 +1,43 @@
+//LISTS - CAN NOT DO VV_DO_TOPIC BECAUSE LISTS AREN'T DATUMS :(
+/client/proc/vv_do_list(list/target, href_list)
+	var/target_index = text2num(GET_VV_VAR_TARGET)
+	if(check_rights(R_VAREDIT))
+		if(target_index)
+			if(href_list[VV_HK_LIST_EDIT])
+				mod_list(target, null, "list", "contents", target_index, autodetect_class = TRUE)
+			if(href_list[VV_HK_LIST_CHANGE])
+				mod_list(target, null, "list", "contents", target_index, autodetect_class = FALSE)
+			if(href_list[VV_HK_LIST_REMOVE])
+				var/variable = target[target_index]
+				var/prompt = alert("Do you want to remove item number [target_index] from list?", "Confirm", "Yes", "No")
+				if (prompt != "Yes")
+					return
+				target.Cut(target_index, target_index+1)
+				log_world("### ListVarEdit by [src]: /list's contents: REMOVED=[html_encode("[variable]")]")
+				log_admin("[key_name(src)] modified list's contents: REMOVED=[variable]")
+				message_admins("[key_name_admin(src)] modified list's contents: REMOVED=[variable]")
+		if(href_list[VV_HK_LIST_ADD])
+			mod_list_add(target, null, "list", "contents")
+		if(href_list[VV_HK_LIST_ERASE_DUPES])
+			uniqueList_inplace(target)
+			log_world("### ListVarEdit by [src]: /list contents: CLEAR DUPES")
+			log_admin("[key_name(src)] modified list's contents: CLEAR DUPES")
+			message_admins("[key_name_admin(src)] modified list's contents: CLEAR DUPES")
+		if(href_list[VV_HK_LIST_ERASE_NULLS])
+			listclearnulls(target)
+			log_world("### ListVarEdit by [src]: /list contents: CLEAR NULLS")
+			log_admin("[key_name(src)] modified list's contents: CLEAR NULLS")
+			message_admins("[key_name_admin(src)] modified list's contents: CLEAR NULLS")
+		if(href_list[VV_HK_LIST_SET_LENGTH])
+			var/value = vv_get_value(VV_NUM)
+			if (value["class"] != VV_NUM || value["value"] > max(50000, target.len))			//safety - would rather someone not put an extra 0 and erase the server's memory lmao.
+				return
+			target.len = value["value"]
+			log_world("### ListVarEdit by [src]: /list len: [target.len]")
+			log_admin("[key_name(src)] modified list's len: [target.len]")
+			message_admins("[key_name_admin(src)] modified list's len: [target.len]")
+		if(href_list[VV_HK_LIST_SHUFFLE])
+			shuffle_inplace(target)
+			log_world("### ListVarEdit by [src]: /list contents: SHUFFLE")
+			log_admin("[key_name(src)] modified list's contents: SHUFFLE")
+			message_admins("[key_name_admin(src)] modified list's contents: SHUFFLE")

code/modules/admin/view_variables/view_variables.dm

@@ -0,0 +1,269 @@
+
+/client/proc/debug_variables(datum/D in world)
+	set category = "Debug"
+	set name = "View Variables"
+	//set src in world
+	var/static/cookieoffset = rand(1, 9999) //to force cookies to reset after the round.
+
+	if(!usr.client || !usr.client.holder)		//This is usr because admins can call the proc on other clients, even if they're not admins, to show them VVs.
+		to_chat(usr, "<span class='danger'>You need to be an administrator to access this.</span>")
+		return
+
+	if(!D)
+		return
+
+	var/islist = islist(D)
+	if(!islist && !istype(D))
+		return
+
+	var/title = ""
+	var/refid = REF(D)
+	var/icon/sprite
+	var/hash
+
+	var/type = islist? /list : D.type
+	var/no_icon = FALSE
+
+	if(istype(D, /atom))
+		sprite = getFlatIcon(D)
+		hash = md5(sprite)
+		if(sprite)
+			hash = md5(sprite)
+			src << browse_rsc(sprite, "vv[hash].png")
+		else
+			no_icon = TRUE
+
+	title = "[D] ([REF(D)]) = [type]"
+	var/formatted_type = replacetext("[type]", "/", "<wbr>/")
+
+	var/sprite_text
+	if(sprite)
+		sprite_text = no_icon? "\[NO ICON\]" : "<img src='vv[hash].png'></td><td>"
+	var/list/header = islist(D)? list("<b>/list</b>") : D.vv_get_header()
+
+	var/marked_line
+	if(holder && holder.marked_datum && holder.marked_datum == D)
+		marked_line = VV_MSG_MARKED
+	var/varedited_line
+	if(!islist && (D.datum_flags & DF_VAR_EDITED))
+		varedited_line = VV_MSG_EDITED
+	var/deleted_line
+	if(!islist && D.gc_destroyed)
+		deleted_line = VV_MSG_DELETED
+
+	var/list/dropdownoptions
+	if (islist)
+		dropdownoptions = list(
+			"---",
+			"Add Item" = VV_HREF_TARGETREF_INTERNAL(refid, VV_HK_LIST_ADD),
+			"Remove Nulls" = VV_HREF_TARGETREF_INTERNAL(refid, VV_HK_LIST_ERASE_NULLS),
+			"Remove Dupes" = VV_HREF_TARGETREF_INTERNAL(refid, VV_HK_LIST_ERASE_DUPES),
+			"Set len" = VV_HREF_TARGETREF_INTERNAL(refid, VV_HK_LIST_SET_LENGTH),
+			"Shuffle" = VV_HREF_TARGETREF_INTERNAL(refid, VV_HK_LIST_SHUFFLE),
+			"Show VV To Player" = VV_HREF_TARGETREF_INTERNAL(refid, VV_HK_EXPOSE),
+			"---"
+			)
+		for(var/i in 1 to length(dropdownoptions))
+			var/name = dropdownoptions[i]
+			var/link = dropdownoptions[name]
+			dropdownoptions[i] = "<option value[link? "='[link]'":""]>[name]</option>"
+	else
+		dropdownoptions = D.vv_get_dropdown()
+
+	var/list/names = list()
+	if(!islist)
+		for(var/V in D.vars)
+			names += V
+	sleep(1)
+
+	var/list/variable_html = list()
+	if(islist)
+		var/list/L = D
+		for(var/i in 1 to L.len)
+			var/key = L[i]
+			var/value
+			if(IS_NORMAL_LIST(L) && IS_VALID_ASSOC_KEY(key))
+				value = L[key]
+			variable_html += debug_variable(i, value, 0, L)
+	else
+		names = sortList(names)
+		for(var/V in names)
+			if(D.can_vv_get(V))
+				variable_html += D.vv_get_var(V)
+
+	var/html = {"
+<html>
+	<head>
+		<meta http-equiv='Content-Type' content='text/html; charset=UTF-8'>
+		<title>[title]</title>
+		<style>
+			body {
+				font-family: Verdana, sans-serif;
+				font-size: 9pt;
+			}
+			.value {
+				font-family: "Courier New", monospace;
+				font-size: 8pt;
+			}
+		</style>
+	</head>
+	<body onload='selectTextField()' onkeydown='return handle_keydown()' onkeyup='handle_keyup()'>
+		<script type="text/javascript">
+			// onload
+			function selectTextField() {
+				var filter_text = document.getElementById('filter');
+				filter_text.focus();
+				filter_text.select();
+				var lastsearch = getCookie("[refid][cookieoffset]search");
+				if (lastsearch) {
+					filter_text.value = lastsearch;
+					updateSearch();
+				}
+			}
+			function getCookie(cname) {
+				var name = cname + "=";
+				var ca = document.cookie.split(';');
+				for(var i=0; i<ca.length; i++) {
+					var c = ca\[i];
+					while (c.charAt(0)==' ') c = c.substring(1,c.length);
+					if (c.indexOf(name)==0) return c.substring(name.length,c.length);
+				}
+				return "";
+			}
+			// main search functionality
+			var last_filter = "";
+			function updateSearch() {
+				var filter = document.getElementById('filter').value.toLowerCase();
+				var vars_ol = document.getElementById("vars");
+				if (filter === last_filter) {
+					// An event triggered an update but nothing has changed.
+					return;
+				} else if (filter.indexOf(last_filter) === 0) {
+					// The new filter starts with the old filter, fast path by removing only.
+					var children = vars_ol.childNodes;
+					for (var i = children.length - 1; i >= 0; --i) {
+						try {
+							var li = children\[i];
+							if (li.innerText.toLowerCase().indexOf(filter) == -1) {
+								vars_ol.removeChild(li);
+							}
+						} catch(err) {}
+					}
+				} else {
+					// Remove everything and put back what matches.
+					while (vars_ol.hasChildNodes()) {
+						vars_ol.removeChild(vars_ol.lastChild);
+					}
+					for (var i = 0; i < complete_list.length; ++i) {
+						try {
+							var li = complete_list\[i];
+							if (!filter || li.innerText.toLowerCase().indexOf(filter) != -1) {
+								vars_ol.appendChild(li);
+							}
+						} catch(err) {}
+					}
+				}
+				last_filter = filter;
+				document.cookie="[refid][cookieoffset]search="+encodeURIComponent(filter);
+			}
+			// onkeydown
+			function handle_keydown() {
+				if(event.keyCode == 116) {  //F5 (to refresh properly)
+					document.getElementById("refresh_link").click();
+					event.preventDefault ? event.preventDefault() : (event.returnValue = false);
+					return false;
+				}
+				return true;
+			}
+			// onkeyup
+			function handle_keyup() {
+				updateSearch();
+			}
+			// onchange
+			function handle_dropdown(list) {
+				var value = list.options\[list.selectedIndex].value;
+				if (value !== "") {
+					location.href = value;
+				}
+				list.selectedIndex = 0;
+				document.getElementById('filter').focus();
+			}
+			// byjax
+			function replace_span(what) {
+				var idx = what.indexOf(':');
+				document.getElementById(what.substr(0, idx)).innerHTML = what.substr(idx + 1);
+			}
+		</script>
+		<div align='center'>
+			<table width='100%'>
+				<tr>
+					<td width='50%'>
+						<table align='center' width='100%'>
+							<tr>
+								<td>
+									[sprite_text]
+									<div align='center'>
+										[header.Join()]
+									</div>
+								</td>
+							</tr>
+						</table>
+						<div align='center'>
+							<b><font size='1'>[formatted_type]</font></b>
+							<span id='marked'>[marked_line]</span>
+							<span id='varedited'>[varedited_line]</span>
+							<span id='deleted'>[deleted_line]</span>
+						</div>
+					</td>
+					<td width='50%'>
+						<div align='center'>
+							<a id='refresh_link' href='?_src_=vars;
+datumrefresh=[refid];[HrefToken()]'>Refresh</a>
+							<form>
+								<select name="file" size="1"
+									onchange="handle_dropdown(this)"
+									onmouseclick="this.focus()">
+									<option value selected>Select option</option>
+									[dropdownoptions.Join()]
+								</select>
+							</form>
+						</div>
+					</td>
+				</tr>
+			</table>
+		</div>
+		<hr>
+		<font size='1'>
+			<b>E</b> - Edit, tries to determine the variable type by itself.<br>
+			<b>C</b> - Change, asks you for the var type first.<br>
+			<b>M</b> - Mass modify: changes this variable for all objects of this type.<br>
+		</font>
+		<hr>
+		<table width='100%'>
+			<tr>
+				<td width='20%'>
+					<div align='center'>
+						<b>Search:</b>
+					</div>
+				</td>
+				<td width='80%'>
+					<input type='text' id='filter' name='filter_text' value='' style='width:100%;'>
+				</td>
+			</tr>
+		</table>
+		<hr>
+		<ol id='vars'>
+			[variable_html.Join()]
+		</ol>
+		<script type='text/javascript'>
+			var complete_list = \[\];
+			var lis = document.getElementById("vars").children;
+			for(var i = lis.length; i--;) complete_list\[i\] = lis\[i\];
+		</script>
+	</body>
+</html>
+"}
+	src << browse(html, "window=variables[refid];size=475x650")
+
+/client/proc/vv_update_display(datum/D, span, content)
+	src << output("[span]:[content]", "variables[REF(D)].browser:replace_span")