Revert "PLASE"

This reverts commit 8af225e6e3.

code/controllers/configuration/config_entry.dm

@@ -0,0 +1,237 @@
+#define VALUE_MODE_NUM 0
+#define VALUE_MODE_TEXT 1
+#define VALUE_MODE_FLAG 2
+#define VALUE_MODE_NUM_LIST 3
+
+#define KEY_MODE_TEXT 0
+#define KEY_MODE_TYPE 1
+
+/datum/config_entry
+	var/name	//read-only, this is determined by the last portion of the derived entry type
+	var/config_entry_value
+	var/default	//read-only, just set value directly
+
+	var/resident_file	//the file which this was loaded from, if any
+	var/modified = FALSE	//set to TRUE if the default has been overridden by a config entry
+
+	var/deprecated_by	//the /datum/config_entry type that supercedes this one
+
+	var/protection = NONE
+	var/abstract_type = /datum/config_entry	//do not instantiate if type matches this
+
+	var/vv_VAS = TRUE		//Force validate and set on VV. VAS proccall guard will run regardless.
+	var/postload_required = FALSE		//requires running OnPostload()
+
+	var/dupes_allowed = FALSE
+
+/datum/config_entry/New()
+	if(type == abstract_type)
+		CRASH("Abstract config entry [type] instatiated!")
+	name = lowertext(type2top(type))
+	if(islist(config_entry_value))
+		var/list/L = config_entry_value
+		default = L.Copy()
+	else
+		default = config_entry_value
+
+/datum/config_entry/Destroy()
+	config.RemoveEntry(src)
+	return ..()
+
+/datum/config_entry/can_vv_get(var_name)
+	. = ..()
+	if(var_name == NAMEOF(src, config_entry_value) || var_name == NAMEOF(src, default))
+		. &= !(protection & CONFIG_ENTRY_HIDDEN)
+
+/datum/config_entry/vv_edit_var(var_name, var_value)
+	var/static/list/banned_edits = list(NAMEOF(src, name), NAMEOF(src, vv_VAS), NAMEOF(src, default), NAMEOF(src, resident_file), NAMEOF(src, protection), NAMEOF(src, abstract_type), NAMEOF(src, modified), NAMEOF(src, dupes_allowed))
+	if(var_name == NAMEOF(src, config_entry_value))
+		if(protection & CONFIG_ENTRY_LOCKED)
+			return FALSE
+		if(vv_VAS)
+			. = ValidateAndSet("[var_value]")
+			if(.)
+				datum_flags |= DF_VAR_EDITED
+			return
+		else
+			return ..()
+	if(var_name in banned_edits)
+		return FALSE
+	return ..()
+
+/datum/config_entry/proc/VASProcCallGuard(str_val)
+	. = !((protection & CONFIG_ENTRY_LOCKED) && IsAdminAdvancedProcCall() && GLOB.LastAdminCalledProc == "ValidateAndSet" && GLOB.LastAdminCalledTargetRef == "[REF(src)]")
+	if(!.)
+		log_admin_private("Config set of [type] to [str_val] attempted by [key_name(usr)]")
+
+/datum/config_entry/proc/ValidateAndSet(str_val)
+	VASProcCallGuard(str_val)
+	CRASH("Invalid config entry type!")
+
+/datum/config_entry/proc/ValidateListEntry(key_name, key_value)
+	return TRUE
+
+/datum/config_entry/proc/DeprecationUpdate(value)
+	return
+
+/datum/config_entry/proc/OnPostload()
+	return
+
+/datum/config_entry/string
+	config_entry_value = ""
+	abstract_type = /datum/config_entry/string
+	var/auto_trim = TRUE
+
+/datum/config_entry/string/vv_edit_var(var_name, var_value)
+	return var_name != "auto_trim" && ..()
+
+/datum/config_entry/string/ValidateAndSet(str_val, during_load)
+	if(!VASProcCallGuard(str_val))
+		return FALSE
+	config_entry_value = auto_trim ? trim(str_val) : str_val
+	return TRUE
+
+/datum/config_entry/number
+	config_entry_value = 0
+	abstract_type = /datum/config_entry/number
+	var/integer = TRUE
+	var/max_val = INFINITY
+	var/min_val = -INFINITY
+
+/datum/config_entry/number/ValidateAndSet(str_val)
+	if(!VASProcCallGuard(str_val))
+		return FALSE
+	var/temp = text2num(trim(str_val))
+	if(!isnull(temp))
+		config_entry_value = CLAMP(integer ? round(temp) : temp, min_val, max_val)
+		if(config_entry_value != temp && !(datum_flags & DF_VAR_EDITED))
+			log_config("Changing [name] from [temp] to [config_entry_value]!")
+		return TRUE
+	return FALSE
+
+/datum/config_entry/number/vv_edit_var(var_name, var_value)
+	var/static/list/banned_edits = list("max_val", "min_val", "integer")
+	return !(var_name in banned_edits) && ..()
+
+/datum/config_entry/flag
+	config_entry_value = FALSE
+	abstract_type = /datum/config_entry/flag
+
+/datum/config_entry/flag/ValidateAndSet(str_val)
+	if(!VASProcCallGuard(str_val))
+		return FALSE
+	config_entry_value = text2num(trim(str_val)) != 0
+	return TRUE
+
+/datum/config_entry/number_list
+	abstract_type = /datum/config_entry/number_list
+	config_entry_value = list()
+
+/datum/config_entry/number_list/ValidateAndSet(str_val)
+	if(!VASProcCallGuard(str_val))
+		return FALSE
+	str_val = trim(str_val)
+	var/list/new_list = list()
+	var/list/values = splittext(str_val," ")
+	for(var/I in values)
+		var/temp = text2num(I)
+		if(isnull(temp))
+			return FALSE
+		new_list += temp
+	if(!new_list.len)
+		return FALSE
+	config_entry_value = new_list
+	return TRUE
+
+/datum/config_entry/keyed_list
+	abstract_type = /datum/config_entry/keyed_list
+	config_entry_value = list()
+	dupes_allowed = TRUE
+	vv_VAS = FALSE			//VAS will not allow things like deleting from lists, it'll just bug horribly.
+	var/key_mode
+	var/value_mode
+	var/splitter = " "
+
+/datum/config_entry/keyed_list/New()
+	. = ..()
+	if(isnull(key_mode) || isnull(value_mode))
+		CRASH("Keyed list of type [type] created with null key or value mode!")
+
+/datum/config_entry/keyed_list/ValidateAndSet(str_val)
+	if(!VASProcCallGuard(str_val))
+		return FALSE
+
+	str_val = trim(str_val)
+	var/key_pos = findtext(str_val, splitter)
+	var/key_name = null
+	var/key_value = null
+
+	if(key_pos || value_mode == VALUE_MODE_FLAG)
+		key_name = lowertext(copytext(str_val, 1, key_pos))
+		key_value = copytext(str_val, key_pos + 1)
+		var/new_key
+		var/new_value
+		var/continue_check_value
+		var/continue_check_key
+		switch(key_mode)
+			if(KEY_MODE_TEXT)
+				new_key = key_name
+				continue_check_key = new_key
+			if(KEY_MODE_TYPE)
+				new_key = key_name
+				if(!ispath(new_key))
+					new_key = text2path(new_key)
+				continue_check_key = ispath(new_key)
+		switch(value_mode)
+			if(VALUE_MODE_FLAG)
+				new_value = TRUE
+				continue_check_value = TRUE
+			if(VALUE_MODE_NUM)
+				new_value = text2num(key_value)
+				continue_check_value = !isnull(new_value)
+			if(VALUE_MODE_TEXT)
+				new_value = key_value
+				continue_check_value = new_value
+			if(VALUE_MODE_NUM_LIST)
+				// this is all copy+pasted from number list up there, but it's super basic so I don't see it being changed soon
+				var/list/new_list = list()
+				var/list/values = splittext(key_value," ")
+				for(var/I in values)
+					var/temp = text2num(I)
+					if(isnull(temp))
+						log_admin("invalid number list entry in [key_name]: [I]")
+						continue_check_value = FALSE
+					new_list += temp
+				new_value = new_list
+				continue_check_value = new_list.len
+		if(continue_check_value && continue_check_key && ValidateListEntry(new_key, new_value))
+			config_entry_value[new_key] = new_value
+			return TRUE
+	return FALSE
+
+/datum/config_entry/keyed_list/vv_edit_var(var_name, var_value)
+	return var_name != "splitter" && ..()
+
+//snowflake for donator things being on one line smh
+/datum/config_entry/multi_keyed_flag
+	vv_VAS = FALSE
+	abstract_type = /datum/config_entry/multi_keyed_flag
+	config_entry_value = list()
+	var/delimiter = "|"
+
+/datum/config_entry/multi_keyed_flag/vv_edit_var(var_name, var_value)
+	if(var_name == NAMEOF(src, delimiter))
+		return FALSE
+	return ..()
+
+/datum/config_entry/multi_keyed_flag/ValidateAndSet(str_val)
+	if(!VASProcCallGuard(str_val))
+		return FALSE
+	str_val = trim(str_val)
+	var/list/keys = splittext(str_val, delimiter)
+	for(var/i in keys)
+		config_entry_value[process_key(i)] = TRUE
+	return length(keys)? TRUE : FALSE
+
+/datum/config_entry/multi_keyed_flag/proc/process_key(key)
+	return trim(key)

code/controllers/configuration/configuration.dm

@@ -0,0 +1,371 @@
+/datum/controller/configuration
+	name = "Configuration"
+
+	var/directory = "config"
+
+	var/warned_deprecated_configs = FALSE
+	var/hiding_entries_by_type = TRUE	//Set for readability, admins can set this to FALSE if they want to debug it
+	var/list/entries
+	var/list/entries_by_type
+
+	var/list/maplist
+	var/datum/map_config/defaultmap
+
+	var/list/modes			// allowed modes
+	var/list/gamemode_cache
+	var/list/votable_modes		// votable modes
+	var/list/mode_names
+	var/list/mode_reports
+	var/list/mode_false_report_weight
+
+	var/motd
+
+/datum/controller/configuration/proc/admin_reload()
+	if(IsAdminAdvancedProcCall())
+		return
+	log_admin("[key_name_admin(usr)] has forcefully reloaded the configuration from disk.")
+	message_admins("[key_name_admin(usr)] has forcefully reloaded the configuration from disk.")
+	full_wipe()
+	Load(world.params[OVERRIDE_CONFIG_DIRECTORY_PARAMETER])
+
+/datum/controller/configuration/proc/Load(_directory)
+	if(IsAdminAdvancedProcCall())		//If admin proccall is detected down the line it will horribly break everything.
+		return
+	if(_directory)
+		directory = _directory
+	if(entries)
+		CRASH("/datum/controller/configuration/Load() called more than once!")
+	InitEntries()
+	LoadModes()
+	if(fexists("[directory]/config.txt") && LoadEntries("config.txt") <= 1)
+		var/list/legacy_configs = list("game_options.txt", "dbconfig.txt", "comms.txt")
+		for(var/I in legacy_configs)
+			if(fexists("[directory]/[I]"))
+				log_config("No $include directives found in config.txt! Loading legacy [legacy_configs.Join("/")] files...")
+				for(var/J in legacy_configs)
+					LoadEntries(J)
+				break
+	loadmaplist(CONFIG_MAPS_FILE)
+	LoadMOTD()
+
+/datum/controller/configuration/proc/full_wipe()
+	if(IsAdminAdvancedProcCall())
+		return
+	entries_by_type.Cut()
+	QDEL_LIST_ASSOC_VAL(entries)
+	entries = null
+	QDEL_LIST_ASSOC_VAL(maplist)
+	maplist = null
+	QDEL_NULL(defaultmap)
+
+/datum/controller/configuration/Destroy()
+	full_wipe()
+	config = null
+
+	return ..()
+
+/datum/controller/configuration/proc/InitEntries()
+	var/list/_entries = list()
+	entries = _entries
+	var/list/_entries_by_type = list()
+	entries_by_type = _entries_by_type
+
+	for(var/I in typesof(/datum/config_entry))	//typesof is faster in this case
+		var/datum/config_entry/E = I
+		if(initial(E.abstract_type) == I)
+			continue
+		E = new I
+		var/esname = E.name
+		var/datum/config_entry/test = _entries[esname]
+		if(test)
+			log_config("Error: [test.type] has the same name as [E.type]: [esname]! Not initializing [E.type]!")
+			qdel(E)
+			continue
+		_entries[esname] = E
+		_entries_by_type[I] = E
+
+/datum/controller/configuration/proc/RemoveEntry(datum/config_entry/CE)
+	entries -= CE.name
+	entries_by_type -= CE.type
+
+/datum/controller/configuration/proc/LoadEntries(filename, list/stack = list())
+	if(IsAdminAdvancedProcCall())
+		return
+
+	var/filename_to_test = world.system_type == MS_WINDOWS ? lowertext(filename) : filename
+	if(filename_to_test in stack)
+		log_config("Warning: Config recursion detected ([english_list(stack)]), breaking!")
+		return
+	stack = stack + filename_to_test
+
+	log_config("Loading config file [filename]...")
+	var/list/lines = world.file2list("[directory]/[filename]")
+	var/list/_entries = entries
+	var/list/postload_required = list()
+	for(var/L in lines)
+		L = trim(L)
+		if(!L)
+			continue
+
+		var/firstchar = copytext(L, 1, 2)
+		if(firstchar == "#")
+			continue
+
+		var/lockthis = firstchar == "@"
+		if(lockthis)
+			L = copytext(L, 2)
+
+		var/pos = findtext(L, " ")
+		var/entry = null
+		var/value = null
+
+		if(pos)
+			entry = lowertext(copytext(L, 1, pos))
+			value = copytext(L, pos + 1)
+		else
+			entry = lowertext(L)
+
+		if(!entry)
+			continue
+
+		if(entry == "$include")
+			if(!value)
+				log_config("Warning: Invalid $include directive: [value]")
+			else
+				LoadEntries(value, stack)
+				++.
+			continue
+
+		var/datum/config_entry/E = _entries[entry]
+		if(!E)
+			log_config("Unknown setting in configuration: '[entry]'")
+			continue
+
+		if(lockthis)
+			E.protection |= CONFIG_ENTRY_LOCKED
+
+		if(E.deprecated_by)
+			var/datum/config_entry/new_ver = entries_by_type[E.deprecated_by]
+			var/new_value = E.DeprecationUpdate(value)
+			var/good_update = istext(new_value)
+			log_config("Entry [entry] is deprecated and will be removed soon. Migrate to [new_ver.name]![good_update ? " Suggested new value is: [new_value]" : ""]")
+			if(!warned_deprecated_configs)
+				addtimer(CALLBACK(GLOBAL_PROC, /proc/message_admins, "This server is using deprecated configuration settings. Please check the logs and update accordingly."), 0)
+				warned_deprecated_configs = TRUE
+			if(good_update)
+				value = new_value
+				E = new_ver
+			else
+				warning("[new_ver.type] is deprecated but gave no proper return for DeprecationUpdate()")
+
+		var/validated = E.ValidateAndSet(value, TRUE)
+		if(!validated)
+			log_config("Failed to validate setting \"[value]\" for [entry]")
+		else
+			if(E.modified && !E.dupes_allowed)
+				log_config("Duplicate setting for [entry] ([value], [E.resident_file]) detected! Using latest.")
+		if(E.postload_required)
+			postload_required[E] = TRUE
+
+		E.resident_file = filename
+
+		if(validated)
+			E.modified = TRUE
+
+	for(var/i in postload_required)
+		var/datum/config_entry/E = i
+		E.OnPostload()
+
+	++.
+
+/datum/controller/configuration/can_vv_get(var_name)
+	return (var_name != NAMEOF(src, entries_by_type) || !hiding_entries_by_type) && ..()
+
+/datum/controller/configuration/vv_edit_var(var_name, var_value)
+	var/list/banned_edits = list(NAMEOF(src, entries_by_type), NAMEOF(src, entries), NAMEOF(src, directory))
+	return !(var_name in banned_edits) && ..()
+
+/datum/controller/configuration/stat_entry()
+	if(!statclick)
+		statclick = new/obj/effect/statclick/debug(null, "Edit", src)
+	stat("[name]:", statclick)
+
+/datum/controller/configuration/proc/Get(entry_type)
+	var/datum/config_entry/E = entry_type
+	var/entry_is_abstract = initial(E.abstract_type) == entry_type
+	if(entry_is_abstract)
+		CRASH("Tried to retrieve an abstract config_entry: [entry_type]")
+	E = entries_by_type[entry_type]
+	if(!E)
+		CRASH("Missing config entry for [entry_type]!")
+	if((E.protection & CONFIG_ENTRY_HIDDEN) && IsAdminAdvancedProcCall() && GLOB.LastAdminCalledProc == "Get" && GLOB.LastAdminCalledTargetRef == "[REF(src)]")
+		log_admin_private("Config access of [entry_type] attempted by [key_name(usr)]")
+		return
+	return E.config_entry_value
+
+/datum/controller/configuration/proc/Set(entry_type, new_val)
+	var/datum/config_entry/E = entry_type
+	var/entry_is_abstract = initial(E.abstract_type) == entry_type
+	if(entry_is_abstract)
+		CRASH("Tried to set an abstract config_entry: [entry_type]")
+	E = entries_by_type[entry_type]
+	if(!E)
+		CRASH("Missing config entry for [entry_type]!")
+	if((E.protection & CONFIG_ENTRY_LOCKED) && IsAdminAdvancedProcCall() && GLOB.LastAdminCalledProc == "Set" && GLOB.LastAdminCalledTargetRef == "[REF(src)]")
+		log_admin_private("Config rewrite of [entry_type] to [new_val] attempted by [key_name(usr)]")
+		return
+	return E.ValidateAndSet("[new_val]")
+
+/datum/controller/configuration/proc/LoadModes()
+	gamemode_cache = typecacheof(/datum/game_mode, TRUE)
+	modes = list()
+	mode_names = list()
+	mode_reports = list()
+	mode_false_report_weight = list()
+	votable_modes = list()
+	var/list/probabilities = Get(/datum/config_entry/keyed_list/probability)
+	for(var/T in gamemode_cache)
+		// I wish I didn't have to instance the game modes in order to look up
+		// their information, but it is the only way (at least that I know of).
+		var/datum/game_mode/M = new T()
+
+		if(M.config_tag)
+			if(!(M.config_tag in modes))		// ensure each mode is added only once
+				modes += M.config_tag
+				mode_names[M.config_tag] = M.name
+				probabilities[M.config_tag] = M.probability
+				mode_reports[M.config_tag] = M.generate_report()
+				if(probabilities[M.config_tag]>0)
+					mode_false_report_weight[M.config_tag] = M.false_report_weight
+				else
+					mode_false_report_weight[M.config_tag] = 1
+				if(M.votable)
+					votable_modes += M.config_tag
+		qdel(M)
+	votable_modes += "secret"
+
+/datum/controller/configuration/proc/LoadMOTD()
+	motd = file2text("[directory]/motd.txt")
+	var/tm_info = GLOB.revdata.GetTestMergeInfo()
+	if(motd || tm_info)
+		motd = motd ? "[motd]<br>[tm_info]" : tm_info
+
+/datum/controller/configuration/proc/loadmaplist(filename)
+	log_config("Loading config file [filename]...")
+	filename = "[directory]/[filename]"
+	var/list/Lines = world.file2list(filename)
+
+	var/datum/map_config/currentmap = null
+	for(var/t in Lines)
+		if(!t)
+			continue
+
+		t = trim(t)
+		if(length(t) == 0)
+			continue
+		else if(copytext(t, 1, 2) == "#")
+			continue
+
+		var/pos = findtext(t, " ")
+		var/command = null
+		var/data = null
+
+		if(pos)
+			command = lowertext(copytext(t, 1, pos))
+			data = copytext(t, pos + 1)
+		else
+			command = lowertext(t)
+
+		if(!command)
+			continue
+
+		if (!currentmap && command != "map")
+			continue
+
+		switch (command)
+			if ("map")
+				currentmap = load_map_config("_maps/[data].json")
+				if(currentmap.defaulted)
+					log_config("Failed to load map config for [data]!")
+					currentmap = null
+			if ("minplayers","minplayer")
+				currentmap.config_min_users = text2num(data)
+			if ("maxplayers","maxplayer")
+				currentmap.config_max_users = text2num(data)
+			if ("weight","voteweight")
+				currentmap.voteweight = text2num(data)
+			if ("default","defaultmap")
+				defaultmap = currentmap
+			if ("endmap")
+				LAZYINITLIST(maplist)
+				maplist[currentmap.map_name] = currentmap
+				currentmap = null
+			if ("disabled")
+				currentmap = null
+			else
+				log_config("Unknown command in map vote config: '[command]'")
+
+
+/datum/controller/configuration/proc/pick_mode(mode_name)
+	// I wish I didn't have to instance the game modes in order to look up
+	// their information, but it is the only way (at least that I know of).
+	// ^ This guy didn't try hard enough
+	for(var/T in gamemode_cache)
+		var/datum/game_mode/M = T
+		var/ct = initial(M.config_tag)
+		if(ct && ct == mode_name)
+			return new T
+	return new /datum/game_mode/extended()
+
+/datum/controller/configuration/proc/get_runnable_modes()
+	var/list/datum/game_mode/runnable_modes = new
+	var/list/probabilities = Get(/datum/config_entry/keyed_list/probability)
+	var/list/min_pop = Get(/datum/config_entry/keyed_list/min_pop)
+	var/list/max_pop = Get(/datum/config_entry/keyed_list/max_pop)
+	var/list/repeated_mode_adjust = Get(/datum/config_entry/number_list/repeated_mode_adjust)
+	for(var/T in gamemode_cache)
+		var/datum/game_mode/M = new T()
+		if(!(M.config_tag in modes))
+			qdel(M)
+			continue
+		if(probabilities[M.config_tag]<=0)
+			qdel(M)
+			continue
+		if(min_pop[M.config_tag])
+			M.required_players = min_pop[M.config_tag]
+		if(max_pop[M.config_tag])
+			M.maximum_players = max_pop[M.config_tag]
+		if(M.can_start())
+			var/final_weight = probabilities[M.config_tag]
+			if(SSpersistence.saved_modes.len == 3 && repeated_mode_adjust.len == 3)
+				var/recent_round = min(SSpersistence.saved_modes.Find(M.config_tag),3)
+				var/adjustment = 0
+				while(recent_round)
+					adjustment += repeated_mode_adjust[recent_round]
+					recent_round = SSpersistence.saved_modes.Find(M.config_tag,recent_round+1,0)
+				final_weight *= ((100-adjustment)/100)
+			runnable_modes[M] = final_weight
+	return runnable_modes
+
+/datum/controller/configuration/proc/get_runnable_midround_modes(crew)
+	var/list/datum/game_mode/runnable_modes = new
+	var/list/probabilities = Get(/datum/config_entry/keyed_list/probability)
+	var/list/min_pop = Get(/datum/config_entry/keyed_list/min_pop)
+	var/list/max_pop = Get(/datum/config_entry/keyed_list/max_pop)
+	for(var/T in (gamemode_cache - SSticker.mode.type))
+		var/datum/game_mode/M = new T()
+		if(!(M.config_tag in modes))
+			qdel(M)
+			continue
+		if(probabilities[M.config_tag]<=0)
+			qdel(M)
+			continue
+		if(min_pop[M.config_tag])
+			M.required_players = min_pop[M.config_tag]
+		if(max_pop[M.config_tag])
+			M.maximum_players = max_pop[M.config_tag]
+		if(M.required_players <= crew)
+			if(M.maximum_players >= 0 && M.maximum_players < crew)
+				continue
+			runnable_modes[M] = probabilities[M.config_tag]
+	return runnable_modes

code/controllers/configuration/entries/donator.dm

@@ -0,0 +1,23 @@
+/datum/config_entry/multi_keyed_flag/donator_group
+	abstract_type = /datum/config_entry/multi_keyed_flag/donator_group
+
+//If we're in the middle of a config load, only do the regeneration afterwards to prevent this from wasting a massive amount of CPU for list regenerations.
+/datum/config_entry/multi_keyed_flag/donator_group/ValidateAndSet(str_val, during_load)
+	. = ..()
+	if(. && !during_load)
+		regenerate_donator_grouping_list()
+
+/datum/config_entry/multi_keyed_flag/donator_group/process_key(key)
+	return ckey(key)
+
+/datum/config_entry/multi_keyed_flag/donator_group/OnPostload()
+	. = ..()
+	regenerate_donator_grouping_list()
+
+//This is kinda weird in that the config entries are defined here but all the handling/calculations are in __HELPERS/donator_groupings.dm
+
+/datum/config_entry/multi_keyed_flag/donator_group/tier_1_donators
+
+/datum/config_entry/multi_keyed_flag/donator_group/tier_2_donators
+
+/datum/config_entry/multi_keyed_flag/donator_group/tier_3_donators

code/controllers/configuration/entries/game_options.dm

@@ -0,0 +1,381 @@
+/datum/config_entry/number_list/repeated_mode_adjust
+
+/datum/config_entry/keyed_list/probability
+	key_mode = KEY_MODE_TEXT
+	value_mode = VALUE_MODE_NUM
+
+/datum/config_entry/keyed_list/probability/ValidateListEntry(key_name)
+	return key_name in config.modes
+
+/datum/config_entry/keyed_list/max_pop
+	key_mode = KEY_MODE_TEXT
+	value_mode = VALUE_MODE_NUM
+
+/datum/config_entry/keyed_list/max_pop/ValidateListEntry(key_name)
+	return key_name in config.modes
+
+/datum/config_entry/keyed_list/min_pop
+	key_mode = KEY_MODE_TEXT
+	value_mode = VALUE_MODE_NUM
+
+/datum/config_entry/keyed_list/min_pop/ValidateListEntry(key_name, key_value)
+	return key_name in config.modes
+
+/datum/config_entry/keyed_list/continuous	// which roundtypes continue if all antagonists die
+	key_mode = KEY_MODE_TEXT
+	value_mode = VALUE_MODE_FLAG
+
+/datum/config_entry/keyed_list/continuous/ValidateListEntry(key_name, key_value)
+	return key_name in config.modes
+
+/datum/config_entry/keyed_list/midround_antag	// which roundtypes use the midround antagonist system
+	key_mode = KEY_MODE_TEXT
+	value_mode = VALUE_MODE_FLAG
+
+/datum/config_entry/keyed_list/midround_antag/ValidateListEntry(key_name, key_value)
+	return key_name in config.modes
+
+/datum/config_entry/keyed_list/policy
+	key_mode = KEY_MODE_TEXT
+	value_mode = VALUE_MODE_TEXT
+
+/datum/config_entry/number/damage_multiplier
+	config_entry_value = 1
+	integer = FALSE
+
+/datum/config_entry/number/minimal_access_threshold	//If the number of players is larger than this threshold, minimal access will be turned on.
+	min_val = 0
+
+/datum/config_entry/flag/jobs_have_minimal_access	//determines whether jobs use minimal access or expanded access.
+
+/datum/config_entry/flag/assistants_have_maint_access
+
+/datum/config_entry/flag/security_has_maint_access
+
+/datum/config_entry/flag/everyone_has_maint_access
+
+/datum/config_entry/flag/sec_start_brig	//makes sec start in brig instead of dept sec posts
+
+/datum/config_entry/flag/force_random_names
+
+/datum/config_entry/flag/humans_need_surnames
+
+/datum/config_entry/flag/allow_ai	// allow ai job
+
+/datum/config_entry/flag/allow_ai_multicam //whether the AI can use their multicam
+
+/datum/config_entry/flag/disable_human_mood
+
+/datum/config_entry/flag/disable_borg_flash_knockdown //Should borg flashes be capable of knocking humanoid entities down?
+
+/datum/config_entry/flag/weaken_secborg //Brings secborgs and k9s back in-line with the other borg modules
+
+/datum/config_entry/flag/disable_secborg	// disallow secborg module to be chosen.
+
+/datum/config_entry/flag/disable_peaceborg
+
+/datum/config_entry/number/minimum_secborg_alert	//Minimum alert level for secborgs to be chosen.
+	config_entry_value = 3
+
+/datum/config_entry/number/traitor_scaling_coeff	//how much does the amount of players get divided by to determine traitors
+	config_entry_value = 6
+	min_val = 1
+
+/datum/config_entry/number/brother_scaling_coeff	//how many players per brother team
+	config_entry_value = 25
+	min_val = 1
+
+/datum/config_entry/number/changeling_scaling_coeff	//how much does the amount of players get divided by to determine changelings
+	config_entry_value = 6
+	min_val = 1
+
+/datum/config_entry/number/security_scaling_coeff	//how much does the amount of players get divided by to determine open security officer positions
+	config_entry_value = 8
+	min_val = 1
+
+/datum/config_entry/number/abductor_scaling_coeff	//how many players per abductor team
+	config_entry_value = 15
+	min_val = 1
+
+/datum/config_entry/number/traitor_objectives_amount
+	config_entry_value = 2
+	min_val = 0
+
+/datum/config_entry/number/brother_objectives_amount
+	config_entry_value = 2
+	min_val = 0
+
+/datum/config_entry/flag/reactionary_explosions	//If we use reactionary explosions, explosions that react to walls and doors
+
+/datum/config_entry/flag/protect_roles_from_antagonist	//If security and such can be traitor/cult/other
+
+/datum/config_entry/flag/protect_assistant_from_antagonist	//If assistants can be traitor/cult/other
+
+/datum/config_entry/flag/enforce_human_authority	//If non-human species are barred from joining as a head of staff
+
+/datum/config_entry/flag/allow_latejoin_antagonists	// If late-joining players can be traitor/changeling
+
+/datum/config_entry/flag/use_antag_rep // see game_options.txt for details
+
+/datum/config_entry/number/antag_rep_maximum
+	config_entry_value = 200
+	min_val = 0
+
+/datum/config_entry/number/default_antag_tickets
+	config_entry_value = 100
+	min_val = 0
+
+/datum/config_entry/number/max_tickets_per_roll
+	config_entry_value = 100
+	min_val = 0
+
+/datum/config_entry/number/midround_antag_time_check	// How late (in minutes you want the midround antag system to stay on, setting this to 0 will disable the system)
+	config_entry_value = 60
+	min_val = 0
+
+/datum/config_entry/number/midround_antag_life_check	// A ratio of how many people need to be alive in order for the round not to immediately end in midround antagonist
+	config_entry_value = 0.7
+	integer = FALSE
+	min_val = 0
+	max_val = 1
+
+/datum/config_entry/number/suicide_reenter_round_timer
+	config_entry_value = 30
+	min_val = 0
+
+/datum/config_entry/number/roundstart_suicide_time_limit
+	config_entry_value = 30
+	min_val = 0
+
+/datum/config_entry/number/shuttle_refuel_delay
+	config_entry_value = 12000
+	min_val = 0
+
+/datum/config_entry/flag/show_game_type_odds	//if set this allows players to see the odds of each roundtype on the get revision screen
+
+/datum/config_entry/keyed_list/roundstart_races	//races you can play as from the get go.
+	key_mode = KEY_MODE_TEXT
+	value_mode = VALUE_MODE_FLAG
+
+/datum/config_entry/flag/join_with_mutant_humans	//players can pick mutant bodyparts for humans before joining the game
+
+/datum/config_entry/flag/no_summon_guns	//No
+
+/datum/config_entry/flag/no_summon_magic	//Fun
+
+/datum/config_entry/flag/no_summon_events	//Allowed
+
+/datum/config_entry/flag/no_intercept_report	//Whether or not to send a communications intercept report roundstart. This may be overridden by gamemodes.
+
+/datum/config_entry/number/arrivals_shuttle_dock_window	//Time from when a player late joins on the arrivals shuttle to when the shuttle docks on the station
+	config_entry_value = 55
+	min_val = 30
+
+/datum/config_entry/flag/arrivals_shuttle_require_undocked	//Require the arrivals shuttle to be undocked before latejoiners can join
+
+/datum/config_entry/flag/arrivals_shuttle_require_safe_latejoin	//Require the arrivals shuttle to be operational in order for latejoiners to join
+
+/datum/config_entry/string/alert_green
+	config_entry_value = "All threats to the station have passed. Security may not have weapons visible, privacy laws are once again fully enforced."
+
+/datum/config_entry/string/alert_blue_upto
+	config_entry_value = "The station has received reliable information about potential threats to the station. Security staff may have weapons visible, random searches are permitted."
+
+/datum/config_entry/string/alert_blue_downto
+	config_entry_value = "Significant confirmed threats have been neutralized. Security may no longer have weapons drawn at all times, but may continue to have them visible. Random searches are still permitted."
+
+/datum/config_entry/string/alert_amber_upto
+	config_entry_value = "There are significant confirmed threats to the station. Security staff may have weapons unholstered at all times. Random searches are allowed and advised."
+
+/datum/config_entry/string/alert_amber_downto
+	config_entry_value = "The immediate threat has passed. Security is no longer authorized to use lethal force, but may continue to have weapons drawn. Access requirements have been restored."
+
+/datum/config_entry/string/alert_red_upto
+	config_entry_value = "There is an immediate serious threat to the station. Security is now authorized to use lethal force. Additionally, access requirements on some machines have been lifted."
+
+/datum/config_entry/string/alert_red_downto
+	config_entry_value = "The station's destruction has been averted. There is still however an immediate serious threat to the station. Security is still authorized to use lethal force."
+
+/datum/config_entry/string/alert_delta
+	config_entry_value = "Destruction of the station is imminent. All crew are instructed to obey all instructions given by heads of staff. Any violations of these orders can be punished by death. This is not a drill."
+
+/datum/config_entry/flag/revival_pod_plants
+
+/datum/config_entry/flag/revival_cloning
+
+/datum/config_entry/number/revival_brain_life
+	config_entry_value = -1
+	min_val = -1
+
+/datum/config_entry/flag/ooc_during_round
+
+/datum/config_entry/flag/emojis
+
+/datum/config_entry/keyed_list/multiplicative_movespeed
+	key_mode = KEY_MODE_TYPE
+	value_mode = VALUE_MODE_NUM
+	config_entry_value = list(			//DEFAULTS
+	/mob/living/simple_animal = 1,
+	/mob/living/silicon/pai = 1,
+	/mob/living/carbon/alien/humanoid/hunter = -1,
+	/mob/living/carbon/alien/humanoid/royal/praetorian = 1,
+	/mob/living/carbon/alien/humanoid/royal/queen = 3
+	)
+
+/datum/config_entry/keyed_list/multiplicative_movespeed/ValidateAndSet()
+	. = ..()
+	if(.)
+		update_config_movespeed_type_lookup(TRUE)
+
+/datum/config_entry/keyed_list/multiplicative_movespeed/vv_edit_var(var_name, var_value)
+	. = ..()
+	if(. && (var_name == NAMEOF(src, config_entry_value)))
+		update_config_movespeed_type_lookup(TRUE)
+
+/datum/config_entry/number/movedelay	//Used for modifying movement speed for mobs.
+	abstract_type = /datum/config_entry/number/movedelay
+
+/datum/config_entry/number/movedelay/ValidateAndSet()
+	. = ..()
+	if(.)
+		update_mob_config_movespeeds()
+
+/datum/config_entry/number/movedelay/vv_edit_var(var_name, var_value)
+	. = ..()
+	if(. && (var_name == NAMEOF(src, config_entry_value)))
+		update_mob_config_movespeeds()
+
+/datum/config_entry/number/movedelay/run_delay
+
+/datum/config_entry/number/movedelay/walk_delay
+
+/////////////////////////////////////////////////Outdated move delay
+/datum/config_entry/number/outdated_movedelay
+	deprecated_by = /datum/config_entry/keyed_list/multiplicative_movespeed
+	abstract_type = /datum/config_entry/number/outdated_movedelay
+
+	var/movedelay_type
+
+/datum/config_entry/number/outdated_movedelay/DeprecationUpdate(value)
+	return "[movedelay_type] [value]"
+
+/datum/config_entry/number/outdated_movedelay/human_delay
+	movedelay_type = /mob/living/carbon/human
+/datum/config_entry/number/outdated_movedelay/robot_delay
+	movedelay_type = /mob/living/silicon/robot
+/datum/config_entry/number/outdated_movedelay/monkey_delay
+	movedelay_type = /mob/living/carbon/monkey
+/datum/config_entry/number/outdated_movedelay/alien_delay
+	movedelay_type = /mob/living/carbon/alien
+/datum/config_entry/number/outdated_movedelay/slime_delay
+	movedelay_type = /mob/living/simple_animal/slime
+/datum/config_entry/number/outdated_movedelay/animal_delay
+	movedelay_type = /mob/living/simple_animal
+/////////////////////////////////////////////////
+
+/datum/config_entry/flag/roundstart_away	//Will random away mission be loaded.
+
+/datum/config_entry/number/gateway_delay	//How long the gateway takes before it activates. Default is half an hour. Only matters if roundstart_away is enabled.
+	config_entry_value = 18000
+	min_val = 0
+
+/datum/config_entry/flag/ghost_interaction
+
+/datum/config_entry/flag/silent_ai
+/datum/config_entry/flag/silent_borg
+
+/datum/config_entry/flag/sandbox_autoclose	// close the sandbox panel after spawning an item, potentially reducing griff
+
+/datum/config_entry/number/default_laws //Controls what laws the AI spawns with.
+	config_entry_value = 0
+	min_val = 0
+	max_val = 3
+
+/datum/config_entry/number/silicon_max_law_amount
+	config_entry_value = 12
+	min_val = 0
+
+/datum/config_entry/keyed_list/random_laws
+	key_mode = KEY_MODE_TEXT
+	value_mode = VALUE_MODE_FLAG
+
+/datum/config_entry/keyed_list/law_weight
+	key_mode = KEY_MODE_TEXT
+	value_mode = VALUE_MODE_NUM
+	splitter = ","
+
+/datum/config_entry/number/overflow_cap
+	config_entry_value = -1
+	min_val = -1
+
+/datum/config_entry/string/overflow_job
+	config_entry_value = "Assistant"
+
+/datum/config_entry/flag/starlight
+/datum/config_entry/flag/grey_assistants
+
+/datum/config_entry/number/lavaland_budget
+	config_entry_value = 60
+	min_val = 0
+
+/datum/config_entry/number/space_budget
+	config_entry_value = 16
+	min_val = 0
+
+/datum/config_entry/flag/allow_random_events	// Enables random events mid-round when set
+
+/datum/config_entry/number/events_min_time_mul	// Multipliers for random events minimal starting time and minimal players amounts
+	config_entry_value = 1
+	min_val = 0
+	integer = FALSE
+
+/datum/config_entry/number/events_min_players_mul
+	config_entry_value = 1
+	min_val = 0
+	integer = FALSE
+
+/datum/config_entry/number/mice_roundstart
+	config_entry_value = 10
+	min_val = 0
+
+/datum/config_entry/number/bombcap
+	config_entry_value = 14
+	min_val = 4
+
+/datum/config_entry/number/bombcap/ValidateAndSet(str_val)
+	. = ..()
+	if(.)
+		GLOB.MAX_EX_DEVESTATION_RANGE = round(config_entry_value / 4)
+		GLOB.MAX_EX_HEAVY_RANGE = round(config_entry_value / 2)
+		GLOB.MAX_EX_LIGHT_RANGE = config_entry_value
+		GLOB.MAX_EX_FLASH_RANGE = config_entry_value
+		GLOB.MAX_EX_FLAME_RANGE = config_entry_value
+
+/datum/config_entry/number/emergency_shuttle_autocall_threshold
+	min_val = 0
+	max_val = 1
+	integer = FALSE
+
+/datum/config_entry/flag/ic_printing
+
+/datum/config_entry/flag/roundstart_traits
+
+/datum/config_entry/flag/enable_night_shifts
+
+/datum/config_entry/flag/randomize_shift_time
+
+/datum/config_entry/flag/shift_time_realtime
+
+/datum/config_entry/keyed_list/antag_rep
+	key_mode = KEY_MODE_TEXT
+	value_mode = VALUE_MODE_NUM
+
+/datum/config_entry/number/monkeycap
+	config_entry_value = 64
+	min_val = 0
+
+/datum/config_entry/flag/disable_stambuffer
+
+/datum/config_entry/number/auto_transfer_delay
+	config_entry_value = 72000
+	min_val = 0

code/controllers/configuration/entries/general.dm

@@ -0,0 +1,431 @@
+/datum/config_entry/flag/autoadmin  // if autoadmin is enabled
+	protection = CONFIG_ENTRY_LOCKED
+
+/datum/config_entry/string/autoadmin_rank	// the rank for autoadmins
+	config_entry_value = "Game Master"
+	protection = CONFIG_ENTRY_LOCKED
+
+/datum/config_entry/string/servername	// server name (the name of the game window)
+
+/datum/config_entry/string/servertagline
+	config_entry_value = "We forgot to set the server's tagline in config.txt"
+
+/datum/config_entry/string/serversqlname	// short form server name used for the DB
+
+/datum/config_entry/string/stationname	// station name (the name of the station in-game)
+
+/datum/config_entry/number/lobby_countdown	// In between round countdown.
+	config_entry_value = 120
+	min_val = 0
+
+/datum/config_entry/number/round_end_countdown	// Post round murder death kill countdown
+	config_entry_value = 25
+	min_val = 0
+
+/datum/config_entry/flag/hub	// if the game appears on the hub or not
+
+/datum/config_entry/flag/log_ooc	// log OOC channel
+
+/datum/config_entry/flag/log_access	// log login/logout
+
+/datum/config_entry/flag/log_say	// log client say
+
+/datum/config_entry/flag/log_admin	// log admin actions
+	protection = CONFIG_ENTRY_LOCKED
+
+/datum/config_entry/flag/log_prayer	// log prayers
+
+/datum/config_entry/flag/log_law	// log lawchanges
+
+/datum/config_entry/flag/log_game	// log game events
+
+/datum/config_entry/flag/log_virus	// log virology data
+
+/datum/config_entry/flag/log_vote	// log voting
+
+/datum/config_entry/flag/log_whisper	// log client whisper
+
+/datum/config_entry/flag/log_attack	// log attack messages
+
+/datum/config_entry/flag/log_emote	// log emotes
+
+/datum/config_entry/flag/log_adminchat	// log admin chat messages
+	protection = CONFIG_ENTRY_LOCKED
+
+/datum/config_entry/flag/log_pda	// log pda messages
+
+/datum/config_entry/flag/log_telecomms	// log telecomms messages
+
+/datum/config_entry/flag/log_twitter	// log certain expliotable parrots and other such fun things in a JSON file of twitter valid phrases.
+
+/datum/config_entry/flag/log_world_topic	// log all world.Topic() calls
+
+/datum/config_entry/flag/log_manifest	// log crew manifest to seperate file
+
+/datum/config_entry/flag/log_job_debug	// log roundstart divide occupations debug information to a file
+
+/datum/config_entry/flag/allow_admin_ooccolor	// Allows admins with relevant permissions to have their own ooc colour
+
+/datum/config_entry/flag/allow_vote_restart	// allow votes to restart
+
+/datum/config_entry/flag/allow_vote_mode	// allow votes to change mode
+
+/datum/config_entry/number/vote_delay	// minimum time between voting sessions (deciseconds, 10 minute default)
+	config_entry_value = 6000
+	min_val = 0
+
+/datum/config_entry/number/vote_period  // length of voting period (deciseconds, default 1 minute)
+	config_entry_value = 600
+	min_val = 0
+
+/datum/config_entry/flag/default_no_vote	// vote does not default to nochange/norestart
+
+/datum/config_entry/flag/no_dead_vote	// dead people can't vote
+
+/datum/config_entry/flag/allow_metadata	// Metadata is supported.
+
+/datum/config_entry/flag/popup_admin_pm	// adminPMs to non-admins show in a pop-up 'reply' window when set
+
+/datum/config_entry/number/fps
+	config_entry_value = 20
+	min_val = 1
+	max_val = 100   //byond will start crapping out at 50, so this is just ridic
+	var/sync_validate = FALSE
+
+/datum/config_entry/number/fps/ValidateAndSet(str_val)
+	. = ..()
+	if(.)
+		sync_validate = TRUE
+		var/datum/config_entry/number/ticklag/TL = config.entries_by_type[/datum/config_entry/number/ticklag]
+		if(!TL.sync_validate)
+			TL.ValidateAndSet(10 / config_entry_value)
+		sync_validate = FALSE
+
+/datum/config_entry/number/ticklag
+	integer = FALSE
+	var/sync_validate = FALSE
+
+/datum/config_entry/number/ticklag/New()	//ticklag weirdly just mirrors fps
+	var/datum/config_entry/CE = /datum/config_entry/number/fps
+	config_entry_value = 10 / initial(CE.config_entry_value)
+	..()
+
+/datum/config_entry/number/ticklag/ValidateAndSet(str_val)
+	. = text2num(str_val) > 0 && ..()
+	if(.)
+		sync_validate = TRUE
+		var/datum/config_entry/number/fps/FPS = config.entries_by_type[/datum/config_entry/number/fps]
+		if(!FPS.sync_validate)
+			FPS.ValidateAndSet(10 / config_entry_value)
+		sync_validate = FALSE
+
+/datum/config_entry/flag/allow_holidays
+
+/datum/config_entry/number/tick_limit_mc_init	//SSinitialization throttling
+	config_entry_value = TICK_LIMIT_MC_INIT_DEFAULT
+	min_val = 0 //oranges warned us
+	integer = FALSE
+
+/datum/config_entry/flag/admin_legacy_system	//Defines whether the server uses the legacy admin system with admins.txt or the SQL system
+	protection = CONFIG_ENTRY_LOCKED
+
+/datum/config_entry/flag/protect_legacy_admins	//Stops any admins loaded by the legacy system from having their rank edited by the permissions panel
+	protection = CONFIG_ENTRY_LOCKED
+
+/datum/config_entry/flag/protect_legacy_ranks	//Stops any ranks loaded by the legacy system from having their flags edited by the permissions panel
+	protection = CONFIG_ENTRY_LOCKED
+
+/datum/config_entry/flag/enable_localhost_rank	//Gives the !localhost! rank to any client connecting from 127.0.0.1 or ::1
+	protection = CONFIG_ENTRY_LOCKED
+
+/datum/config_entry/flag/load_legacy_ranks_only	//Loads admin ranks only from legacy admin_ranks.txt, while enabled ranks are mirrored to the database
+	protection = CONFIG_ENTRY_LOCKED
+
+/datum/config_entry/flag/mentors_mobname_only
+
+/datum/config_entry/flag/mentor_legacy_system	//Defines whether the server uses the legacy mentor system with mentors.txt or the SQL system
+	protection = CONFIG_ENTRY_LOCKED
+
+/datum/config_entry/string/hostedby
+
+/datum/config_entry/flag/norespawn
+
+/datum/config_entry/flag/guest_jobban
+
+/datum/config_entry/flag/usewhitelist
+
+/datum/config_entry/flag/ban_legacy_system	//Defines whether the server uses the legacy banning system with the files in /data or the SQL system.
+	protection = CONFIG_ENTRY_LOCKED
+
+/datum/config_entry/flag/use_age_restriction_for_jobs	//Do jobs use account age restrictions? --requires database
+
+/datum/config_entry/flag/use_account_age_for_jobs	//Uses the time they made the account for the job restriction stuff. New player joining alerts should be unaffected.
+
+/datum/config_entry/flag/use_exp_tracking
+
+/datum/config_entry/flag/use_exp_restrictions_heads
+
+/datum/config_entry/number/use_exp_restrictions_heads_hours
+	config_entry_value = 0
+	min_val = 0
+
+/datum/config_entry/flag/use_exp_restrictions_heads_department
+
+/datum/config_entry/flag/use_exp_restrictions_other
+
+/datum/config_entry/flag/use_exp_restrictions_admin_bypass
+
+/datum/config_entry/string/server
+
+/datum/config_entry/string/banappeals
+
+/datum/config_entry/string/wikiurl
+	config_entry_value = "https://katlin.dog/citadel-wiki"
+
+/datum/config_entry/string/wikiurltg
+	config_entry_value = "http://www.tgstation13.org/wiki"
+
+/datum/config_entry/string/forumurl
+	config_entry_value = "http://tgstation13.org/phpBB/index.php"
+
+/datum/config_entry/string/rulesurl
+	config_entry_value = "http://www.tgstation13.org/wiki/Rules"
+
+/datum/config_entry/string/githuburl
+	config_entry_value = "https://www.github.com/tgstation/-tg-station"
+
+/datum/config_entry/string/roundstatsurl
+
+/datum/config_entry/string/gamelogurl
+
+/datum/config_entry/number/githubrepoid
+	config_entry_value = null
+	min_val = 0
+
+/datum/config_entry/flag/guest_ban
+
+/datum/config_entry/number/id_console_jobslot_delay
+	config_entry_value = 30
+	min_val = 0
+
+/datum/config_entry/number/inactivity_period	//time in ds until a player is considered inactive
+	config_entry_value = 3000
+	min_val = 0
+
+/datum/config_entry/number/inactivity_period/ValidateAndSet(str_val)
+	. = ..()
+	if(.)
+		config_entry_value *= 10 //documented as seconds in config.txt
+
+/datum/config_entry/number/afk_period	//time in ds until a player is considered inactive
+	config_entry_value = 3000
+	min_val = 0
+
+/datum/config_entry/number/afk_period/ValidateAndSet(str_val)
+	. = ..()
+	if(.)
+		config_entry_value *= 10 //documented as seconds in config.txt
+
+/datum/config_entry/flag/kick_inactive	//force disconnect for inactive players
+
+/datum/config_entry/flag/load_jobs_from_txt
+
+/datum/config_entry/flag/forbid_singulo_possession
+
+/datum/config_entry/flag/automute_on	//enables automuting/spam prevention
+
+/datum/config_entry/string/panic_server_name
+
+/datum/config_entry/string/panic_server_name/ValidateAndSet(str_val)
+	return str_val != "\[Put the name here\]" && ..()
+
+/datum/config_entry/string/panic_server_address	//Reconnect a player this linked server if this server isn't accepting new players
+
+/datum/config_entry/string/panic_server_address/ValidateAndSet(str_val)
+	return str_val != "byond://address:port" && ..()
+
+/datum/config_entry/string/invoke_youtubedl
+	protection = CONFIG_ENTRY_LOCKED | CONFIG_ENTRY_HIDDEN
+
+/datum/config_entry/flag/show_irc_name
+
+/datum/config_entry/flag/see_own_notes	//Can players see their own admin notes
+
+/datum/config_entry/number/note_fresh_days
+	config_entry_value = null
+	min_val = 0
+	integer = FALSE
+
+/datum/config_entry/number/note_stale_days
+	config_entry_value = null
+	min_val = 0
+	integer = FALSE
+
+/datum/config_entry/flag/maprotation
+
+/datum/config_entry/flag/tgstyle_maprotation
+
+/datum/config_entry/number/maprotatechancedelta
+	config_entry_value = 0.75
+	min_val = 0
+	max_val = 1
+	integer = FALSE
+
+/datum/config_entry/number/soft_popcap
+	config_entry_value = null
+	min_val = 0
+
+/datum/config_entry/number/hard_popcap
+	config_entry_value = null
+	min_val = 0
+
+/datum/config_entry/number/extreme_popcap
+	config_entry_value = null
+	min_val = 0
+
+/datum/config_entry/string/soft_popcap_message
+	config_entry_value = "Be warned that the server is currently serving a high number of users, consider using alternative game servers."
+
+/datum/config_entry/string/hard_popcap_message
+	config_entry_value = "The server is currently serving a high number of users, You cannot currently join. You may wait for the number of living crew to decline, observe, or find alternative servers."
+
+/datum/config_entry/string/extreme_popcap_message
+	config_entry_value = "The server is currently serving a high number of users, find alternative servers."
+
+/datum/config_entry/flag/panic_bunker	// prevents people the server hasn't seen before from connecting
+
+/datum/config_entry/number/notify_new_player_age	// how long do we notify admins of a new player
+	min_val = -1
+
+/datum/config_entry/number/notify_new_player_account_age	// how long do we notify admins of a new byond account
+	min_val = 0
+
+/datum/config_entry/flag/irc_first_connection_alert	// do we notify the irc channel when somebody is connecting for the first time?
+
+/datum/config_entry/flag/check_randomizer
+
+/datum/config_entry/string/ipintel_email
+
+/datum/config_entry/string/ipintel_email/ValidateAndSet(str_val)
+	return str_val != "ch@nge.me" && ..()
+
+/datum/config_entry/number/ipintel_rating_bad
+	config_entry_value = 1
+	integer = FALSE
+	min_val = 0
+	max_val = 1
+
+/datum/config_entry/number/ipintel_save_good
+	config_entry_value = 12
+	min_val = 0
+
+/datum/config_entry/number/ipintel_save_bad
+	config_entry_value = 1
+	min_val = 0
+
+/datum/config_entry/string/ipintel_domain
+	config_entry_value = "check.getipintel.net"
+
+/datum/config_entry/flag/aggressive_changelog
+
+/datum/config_entry/flag/autoconvert_notes	//if all connecting player's notes should attempt to be converted to the database
+	protection = CONFIG_ENTRY_LOCKED
+
+/datum/config_entry/flag/allow_webclient
+
+/datum/config_entry/flag/webclient_only_byond_members
+
+/datum/config_entry/flag/announce_admin_logout
+
+/datum/config_entry/flag/announce_admin_login
+
+/datum/config_entry/flag/allow_map_voting
+
+/datum/config_entry/number/client_warn_version
+	config_entry_value = null
+	min_val = 500
+
+/datum/config_entry/string/client_warn_message
+	config_entry_value = "Your version of byond may have issues or be blocked from accessing this server in the future."
+
+/datum/config_entry/flag/client_warn_popup
+
+/datum/config_entry/number/client_error_version
+	config_entry_value = null
+	min_val = 500
+
+/datum/config_entry/string/client_error_message
+	config_entry_value = "Your version of byond is too old, may have issues, and is blocked from accessing this server."
+
+/datum/config_entry/number/minute_topic_limit
+	config_entry_value = null
+	min_val = 0
+
+/datum/config_entry/number/second_topic_limit
+	config_entry_value = null
+	min_val = 0
+
+/datum/config_entry/number/minute_click_limit
+	config_entry_value = 400
+	min_val = 0
+
+/datum/config_entry/number/second_click_limit
+	config_entry_value = 15
+	min_val = 0
+
+/datum/config_entry/number/error_cooldown	// The "cooldown" time for each occurrence of a unique error
+	config_entry_value = 600
+	min_val = 0
+
+/datum/config_entry/number/error_limit	// How many occurrences before the next will silence them
+	config_entry_value = 50
+
+/datum/config_entry/number/error_silence_time	// How long a unique error will be silenced for
+	config_entry_value = 6000
+
+/datum/config_entry/number/error_msg_delay	// How long to wait between messaging admins about occurrences of a unique error
+	config_entry_value = 50
+
+/datum/config_entry/flag/irc_announce_new_game
+
+/datum/config_entry/flag/debug_admin_hrefs
+
+/datum/config_entry/number/mc_tick_rate/base_mc_tick_rate
+	integer = FALSE
+	config_entry_value = 1
+
+/datum/config_entry/number/mc_tick_rate/high_pop_mc_tick_rate
+	integer = FALSE
+	config_entry_value = 1.1
+
+/datum/config_entry/number/mc_tick_rate/high_pop_mc_mode_amount
+	config_entry_value = 65
+
+/datum/config_entry/number/mc_tick_rate/disable_high_pop_mc_mode_amount
+	config_entry_value = 60
+
+/datum/config_entry/number/mc_tick_rate
+	abstract_type = /datum/config_entry/number/mc_tick_rate
+
+/datum/config_entry/number/mc_tick_rate/ValidateAndSet(str_val)
+	. = ..()
+	if (.)
+		Master.UpdateTickRate()
+
+/datum/config_entry/flag/resume_after_initializations
+
+/datum/config_entry/flag/resume_after_initializations/ValidateAndSet(str_val)
+	. = ..()
+	if(. && Master.current_runlevel)
+		world.sleep_offline = !config_entry_value
+
+/datum/config_entry/number/rounds_until_hard_restart
+	config_entry_value = -1
+	min_val = 0
+
+/datum/config_entry/string/default_view
+	config_entry_value = "15x15"
+
+/datum/config_entry/flag/log_pictures
+
+/datum/config_entry/flag/picture_logging_camera