Revert "PLASE"

This reverts commit 8af225e6e3.

code/game/objects/effects/decals/cleanable.dm

@@ -0,0 +1,96 @@
+/obj/effect/decal/cleanable
+	gender = PLURAL
+	layer = ABOVE_NORMAL_TURF_LAYER
+	var/list/random_icon_states = null
+	var/blood_state = "" //I'm sorry but cleanable/blood code is ass, and so is blood_DNA
+	var/bloodiness = 0 //0-100, amount of blood in this decal, used for making footprints and affecting the alpha of bloody footprints
+	var/mergeable_decal = TRUE //when two of these are on a same tile or do we need to merge them into just one?
+
+/obj/effect/decal/cleanable/Initialize(mapload, list/datum/disease/diseases)
+	. = ..()
+	LAZYINITLIST(blood_DNA) //Kinda needed
+	if (random_icon_states && (icon_state == initial(icon_state)) && length(random_icon_states) > 0)
+		icon_state = pick(random_icon_states)
+	create_reagents(300)
+	if(loc && isturf(loc))
+		for(var/obj/effect/decal/cleanable/C in loc)
+			if(C != src && C.type == type && !QDELETED(C))
+				if (replace_decal(C))
+					return INITIALIZE_HINT_QDEL
+
+	if(LAZYLEN(diseases))
+		var/list/datum/disease/diseases_to_add = list()
+		for(var/datum/disease/D in diseases)
+			if(D.spread_flags & DISEASE_SPREAD_CONTACT_FLUIDS)
+				diseases_to_add += D
+		if(LAZYLEN(diseases_to_add))
+			AddComponent(/datum/component/infective, diseases_to_add)
+
+/obj/effect/decal/cleanable/proc/replace_decal(obj/effect/decal/cleanable/C) // Returns true if we should give up in favor of the pre-existing decal
+	if(mergeable_decal)
+		qdel(C)
+
+/obj/effect/decal/cleanable/attackby(obj/item/W, mob/user, params)
+	if(istype(W, /obj/item/reagent_containers/glass) || istype(W, /obj/item/reagent_containers/food/drinks))
+		if(src.reagents && W.reagents)
+			. = 1 //so the containers don't splash their content on the src while scooping.
+			if(!src.reagents.total_volume)
+				to_chat(user, "<span class='notice'>[src] isn't thick enough to scoop up!</span>")
+				return
+			if(W.reagents.total_volume >= W.reagents.maximum_volume)
+				to_chat(user, "<span class='notice'>[W] is full!</span>")
+				return
+			to_chat(user, "<span class='notice'>You scoop up [src] into [W]!</span>")
+			reagents.trans_to(W, reagents.total_volume)
+			if(!reagents.total_volume) //scooped up all of it
+				qdel(src)
+				return
+	if(W.get_temperature()) //todo: make heating a reagent holder proc
+		if(istype(W, /obj/item/clothing/mask/cigarette))
+			return
+		else
+			var/hotness = W.get_temperature()
+			reagents.expose_temperature(hotness)
+			to_chat(user, "<span class='notice'>You heat [name] with [W]!</span>")
+	else
+		return ..()
+
+/obj/effect/decal/cleanable/ex_act()
+	if(reagents)
+		for(var/datum/reagent/R in reagents.reagent_list)
+			R.on_ex_act()
+	..()
+
+/obj/effect/decal/cleanable/fire_act(exposed_temperature, exposed_volume)
+	if(reagents)
+		reagents.expose_temperature(exposed_temperature)
+	..()
+
+
+//Add "bloodiness" of this blood's type, to the human's shoes
+//This is on /cleanable because fuck this ancient mess
+/obj/effect/decal/cleanable/Crossed(atom/movable/O)
+	..()
+	if(ishuman(O))
+		var/mob/living/carbon/human/H = O
+		if(H.shoes && blood_state && bloodiness && !HAS_TRAIT(H, TRAIT_LIGHT_STEP))
+			var/obj/item/clothing/shoes/S = H.shoes
+			var/add_blood = 0
+			if(bloodiness >= BLOOD_GAIN_PER_STEP)
+				add_blood = BLOOD_GAIN_PER_STEP
+			else
+				add_blood = bloodiness
+			bloodiness -= add_blood
+			S.bloody_shoes[blood_state] = min(MAX_SHOE_BLOODINESS,S.bloody_shoes[blood_state]+add_blood)
+			if(blood_DNA && blood_DNA.len)
+				S.add_blood_DNA(blood_DNA)
+				S.add_blood_overlay()
+			S.blood_state = blood_state
+			update_icon()
+			H.update_inv_shoes()
+
+/obj/effect/decal/cleanable/proc/can_bloodcrawl_in()
+	if((blood_state != BLOOD_STATE_OIL) && (blood_state != BLOOD_STATE_NOT_BLOODY))
+		return bloodiness
+	else
+		return FALSE

code/game/objects/effects/decals/cleanable/aliens.dm

@@ -0,0 +1,70 @@
+
+/obj/effect/decal/cleanable/blood/xeno
+	name = "xeno blood"
+	desc = "It's green and acidic. It looks like... <i>blood?</i>"
+	color = BLOOD_COLOR_XENO
+
+/obj/effect/decal/cleanable/blood/splatter/xeno
+	color = BLOOD_COLOR_XENO
+
+/obj/effect/decal/cleanable/blood/gibs/xeno
+	color = BLOOD_COLOR_XENO
+	gibs_reagent_id = "liquidxenogibs"
+	gibs_bloodtype = "X*"
+
+/obj/effect/decal/cleanable/blood/gibs/xeno/Initialize(mapload, list/datum/disease/diseases)
+	. = ..()
+	update_icon()
+
+/obj/effect/decal/cleanable/blood/gibs/xeno/update_icon()
+	add_atom_colour(blood_DNA_to_color(), FIXED_COLOUR_PRIORITY)
+	cut_overlays()
+	var/mutable_appearance/flesh = mutable_appearance(icon, "[icon_state]x_flesh")
+	flesh.appearance_flags = RESET_COLOR
+	flesh.color = body_colors
+	add_overlay(flesh)
+
+/obj/effect/decal/cleanable/blood/gibs/xeno/streak(list/directions)
+	set waitfor = FALSE
+	var/list/diseases = list()
+	SEND_SIGNAL(src, COMSIG_GIBS_STREAK, directions, diseases)
+	var/direction = pick(directions)
+	for(var/i in 0 to pick(0, 200; 1, 150; 2, 50))
+		sleep(2)
+		if(i > 0)
+			var/obj/effect/decal/cleanable/blood/splatter/xeno/splat = new /obj/effect/decal/cleanable/blood/splatter/xeno(loc, diseases)
+			splat.transfer_blood_dna(blood_DNA, diseases)
+		if(!step_to(src, get_step(src, direction), 0))
+			break
+
+/obj/effect/decal/cleanable/blood/gibs/xeno/up
+	random_icon_states = list("gib1", "gib2", "gib3", "gib4", "gib5", "gib6","gibup1","gibup1","gibup1")
+
+/obj/effect/decal/cleanable/blood/gibs/xeno/down
+	random_icon_states = list("gib1", "gib2", "gib3", "gib4", "gib5", "gib6","gibdown1","gibdown1","gibdown1")
+
+/obj/effect/decal/cleanable/blood/gibs/xeno/body
+	random_icon_states = list("gibhead", "gibtorso")
+
+/obj/effect/decal/cleanable/blood/gibs/xeno/torso
+	random_icon_states = list("gibtorso")
+
+/obj/effect/decal/cleanable/blood/gibs/xeno/limb
+	random_icon_states = list("gibleg", "gibarm")
+
+/obj/effect/decal/cleanable/blood/gibs/xeno/core
+	random_icon_states = list("gibmid1", "gibmid2", "gibmid3")
+
+/obj/effect/decal/cleanable/blood/gibs/xeno/larva
+	random_icon_states = list("xgiblarva1", "xgiblarva2")
+
+/obj/effect/decal/cleanable/blood/gibs/xeno/larva/body
+	random_icon_states = list("xgiblarvahead", "xgiblarvatorso")
+
+/obj/effect/decal/cleanable/blood/xtracks
+	icon_state = "tracks"
+	random_icon_states = null
+
+/obj/effect/decal/cleanable/blood/xtracks/Initialize()
+	add_blood_DNA(list("UNKNOWN DNA" = "X*"))
+	. = ..()

code/game/objects/effects/decals/cleanable/humans.dm

@@ -0,0 +1,194 @@
+/obj/effect/decal/cleanable/blood
+	name = "blood"
+	desc = "It's gooey. Perhaps it's the chef's cooking?"
+	icon = 'icons/effects/blood.dmi'
+	icon_state = "floor1"
+	random_icon_states = list("floor1", "floor2", "floor3", "floor4", "floor5", "floor6", "floor7")
+	blood_state = BLOOD_STATE_BLOOD
+	bloodiness = MAX_SHOE_BLOODINESS
+	color = BLOOD_COLOR_HUMAN //default so we don't have white splotches everywhere.
+
+/obj/effect/decal/cleanable/blood/replace_decal(obj/effect/decal/cleanable/blood/C)
+	if (C.blood_DNA)
+		blood_DNA |= C.blood_DNA.Copy()
+	update_icon()
+	..()
+
+/obj/effect/decal/cleanable/blood/transfer_blood_dna()
+	..()
+	update_icon()
+
+/obj/effect/decal/cleanable/blood/transfer_mob_blood_dna()
+	. = ..()
+	update_icon()
+
+/obj/effect/decal/cleanable/blood/update_icon()
+	color = blood_DNA_to_color()
+
+/obj/effect/decal/cleanable/blood/old
+	name = "dried blood"
+	desc = "Looks like it's been here a while. Eew."
+	bloodiness = 0
+
+/obj/effect/decal/cleanable/blood/old/Initialize(mapload, list/datum/disease/diseases)
+	..()
+	icon_state += "-old"
+	add_blood_DNA(list("Non-human DNA" = "A+"))
+
+/obj/effect/decal/cleanable/blood/splats
+	random_icon_states = list("gibbl1", "gibbl2", "gibbl3", "gibbl4", "gibbl5")
+
+/obj/effect/decal/cleanable/blood/splatter
+	random_icon_states = list("splatter1", "splatter2", "splatter3", "splatter4", "splatter5")
+
+/obj/effect/decal/cleanable/blood/tracks
+	icon_state = "tracks"
+	desc = "They look like tracks left by wheels."
+	random_icon_states = null
+
+/obj/effect/decal/cleanable/trail_holder //not a child of blood on purpose
+	name = "blood"
+	icon_state = "ltrails_1"
+	desc = "Your instincts say you shouldn't be following these."
+	random_icon_states = null
+	var/list/existing_dirs = list()
+
+/obj/effect/decal/cleanable/trail_holder/update_icon()
+	color = blood_DNA_to_color()
+
+/obj/effect/cleanable/trail_holder/Initialize()
+	. = ..()
+	update_icon()
+
+/obj/effect/decal/cleanable/trail_holder/can_bloodcrawl_in()
+	return TRUE
+
+/obj/effect/decal/cleanable/trail_holder/transfer_blood_dna()
+	..()
+	update_icon()
+
+/obj/effect/decal/cleanable/trail_holder/transfer_mob_blood_dna()
+	. = ..()
+	update_icon()
+
+//BLOODY FOOTPRINTS
+/obj/effect/decal/cleanable/blood/footprints
+	name = "footprints"
+	icon = 'icons/effects/footprints.dmi'
+	icon_state = "nothingwhatsoever"
+	desc = "WHOSE FOOTPRINTS ARE THESE?"
+	random_icon_states = null
+	var/entered_dirs = 0
+	var/exited_dirs = 0
+	blood_state = BLOOD_STATE_BLOOD //the icon state to load images from
+	var/list/shoe_types = list()
+
+/obj/effect/decal/cleanable/blood/footprints/Crossed(atom/movable/O)
+	if(ishuman(O))
+		var/mob/living/carbon/human/H = O
+		var/obj/item/clothing/shoes/S = H.shoes
+		if(S && S.bloody_shoes[blood_state])
+			if(color != bloodtype_to_color(S.last_bloodtype))
+				return
+			S.bloody_shoes[blood_state] = max(S.bloody_shoes[blood_state] - BLOOD_LOSS_PER_STEP, 0)
+			shoe_types |= S.type
+			if (!(entered_dirs & H.dir))
+				entered_dirs |= H.dir
+				update_icon()
+
+/obj/effect/decal/cleanable/blood/footprints/Uncrossed(atom/movable/O)
+	if(ishuman(O))
+		var/mob/living/carbon/human/H = O
+		var/obj/item/clothing/shoes/S = H.shoes
+		if(S && S.bloody_shoes[blood_state])
+			if(color != bloodtype_to_color(S.last_bloodtype))//last entry - we check its color
+				return
+			S.bloody_shoes[blood_state] = max(S.bloody_shoes[blood_state] - BLOOD_LOSS_PER_STEP, 0)
+			shoe_types  |= S.type
+			if (!(exited_dirs & H.dir))
+				exited_dirs |= H.dir
+				update_icon()
+
+/obj/effect/decal/cleanable/blood/footprints/update_icon()
+	..()
+	cut_overlays()
+	for(var/Ddir in GLOB.cardinals)
+		if(entered_dirs & Ddir)
+			var/image/bloodstep_overlay = GLOB.bloody_footprints_cache["entered-[blood_state]-[Ddir]"]
+			if(!bloodstep_overlay)
+				GLOB.bloody_footprints_cache["entered-[blood_state]-[Ddir]"] = bloodstep_overlay = image(icon, "[blood_state]1", dir = Ddir)
+			add_overlay(bloodstep_overlay)
+		if(exited_dirs & Ddir)
+			var/image/bloodstep_overlay = GLOB.bloody_footprints_cache["exited-[blood_state]-[Ddir]"]
+			if(!bloodstep_overlay)
+				GLOB.bloody_footprints_cache["exited-[blood_state]-[Ddir]"] = bloodstep_overlay = image(icon, "[blood_state]2", dir = Ddir)
+			add_overlay(bloodstep_overlay)
+
+	alpha = BLOODY_FOOTPRINT_BASE_ALPHA + bloodiness
+
+
+/obj/effect/decal/cleanable/blood/footprints/examine(mob/user)
+	. = ..()
+	if(shoe_types.len)
+		. += "You recognise the footprints as belonging to:\n"
+		for(var/shoe in shoe_types)
+			var/obj/item/clothing/shoes/S = shoe
+			. += "some <B>[initial(S.name)]</B> [icon2html(initial(S.icon), user)]\n"
+
+	to_chat(user, .)
+
+/obj/effect/decal/cleanable/blood/footprints/replace_decal(obj/effect/decal/cleanable/C)
+	if(blood_state != C.blood_state) //We only replace footprints of the same type as us
+		return
+	if(color != C.color)
+		return
+	..()
+
+/obj/effect/decal/cleanable/blood/footprints/can_bloodcrawl_in()
+	if((blood_state != BLOOD_STATE_OIL) && (blood_state != BLOOD_STATE_NOT_BLOODY))
+		return TRUE
+	return FALSE
+
+/* Eventually TODO: make snowflake trails like baycode's
+/obj/effect/decal/cleanable/blood/footprints/tracks/shoe
+	name = "footprints"
+	desc = "They look like tracks left by footwear."
+	icon_state = FOOTPRINT_SHOE
+	print_state = FOOTPRINT_SHOE
+
+/obj/effect/decal/cleanable/blood/footprints/tracks/foot
+	name = "footprints"
+	desc = "They look like tracks left by a bare foot."
+	icon_state = FOOTPRINT_FOOT
+	print_state = FOOTPRINT_FOOT
+
+/obj/effect/decal/cleanable/blood/footprints/tracks/snake
+	name = "tracks"
+	desc = "They look like tracks left by a giant snake."
+	icon_state = FOOTPRINT_SNAKE
+	print_state = FOOTPRINT_SNAKE
+
+/obj/effect/decal/cleanable/blood/footprints/tracks/paw
+	name = "footprints"
+	desc = "They look like tracks left by paws."
+	icon_state = FOOTPRINT_PAW
+	print_state = FOOTPRINT_PAW
+
+/obj/effect/decal/cleanable/blood/footprints/tracks/claw
+	name = "footprints"
+	desc = "They look like tracks left by claws."
+	icon_state = FOOTPRINT_CLAW
+	print_state = FOOTPRINT_CLAW
+
+/obj/effect/decal/cleanable/blood/footprints/tracks/wheels
+	name = "tracks"
+	desc = "They look like tracks left by wheels."
+	gender = PLURAL
+	icon_state = FOOTPRINT_WHEEL
+	print_state = FOOTPRINT_WHEEL
+
+/obj/effect/decal/cleanable/blood/footprints/tracks/body
+	name = "trails"
+	desc = "A trail left by something being dragged."
+	icon_state = FOOTPRINT_DRAG
+	print_state = FOOTPRINT_DRAG */

code/game/objects/effects/decals/cleanable/robots.dm

@@ -0,0 +1,65 @@
+// Note: BYOND is object oriented. There is no reason for this to be copy/pasted blood code.
+
+/obj/effect/decal/cleanable/robot_debris
+	name = "robot debris"
+	desc = "It's a useless heap of junk... <i>or is it?</i>"
+	icon = 'icons/mob/robots.dmi'
+	icon_state = "gib1"
+	layer = LOW_OBJ_LAYER
+	random_icon_states = list("gib1", "gib2", "gib3", "gib4", "gib5", "gib6", "gib7")
+	blood_state = BLOOD_STATE_OIL
+	bloodiness = BLOOD_AMOUNT_PER_DECAL
+	mergeable_decal = FALSE
+
+/obj/effect/decal/cleanable/robot_debris/Initialize(mapload, list/datum/disease/diseases)
+	. = ..()
+	reagents.add_reagent("liquidoilgibs", 5)
+
+/obj/effect/decal/cleanable/robot_debris/proc/streak(list/directions)
+	set waitfor = 0
+	var/direction = pick(directions)
+	for (var/i = 0, i < pick(1, 200; 2, 150; 3, 50), i++)
+		sleep(2)
+		if (i > 0)
+			if (prob(40))
+				new /obj/effect/decal/cleanable/oil/streak(src.loc)
+			else if (prob(10))
+				var/datum/effect_system/spark_spread/s = new /datum/effect_system/spark_spread
+				s.set_up(3, 1, src)
+				s.start()
+		if (!step_to(src, get_step(src, direction), 0))
+			break
+
+/obj/effect/decal/cleanable/robot_debris/ex_act()
+	return
+
+/obj/effect/decal/cleanable/robot_debris/limb
+	random_icon_states = list("gibarm", "gibleg")
+
+/obj/effect/decal/cleanable/robot_debris/up
+	random_icon_states = list("gib1", "gib2", "gib3", "gib4", "gib5", "gib6", "gib7","gibup1","gibup1")
+
+/obj/effect/decal/cleanable/robot_debris/down
+	random_icon_states = list("gib1", "gib2", "gib3", "gib4", "gib5", "gib6", "gib7","gibdown1","gibdown1")
+
+/obj/effect/decal/cleanable/oil
+	name = "motor oil"
+	desc = "It's black and greasy. Looks like Beepsky made another mess."
+	icon = 'icons/mob/robots.dmi'
+	icon_state = "floor1"
+	random_icon_states = list("floor1", "floor2", "floor3", "floor4", "floor5", "floor6", "floor7")
+	blood_state = BLOOD_STATE_OIL
+	bloodiness = BLOOD_AMOUNT_PER_DECAL
+
+/obj/effect/decal/cleanable/oil/Initialize()
+	. = ..()
+	reagents.add_reagent("oil", 30)
+	reagents.add_reagent("liquidoilgibs", 5)
+
+/obj/effect/decal/cleanable/oil/streak
+	random_icon_states = list("streak1", "streak2", "streak3", "streak4", "streak5")
+
+/obj/effect/decal/cleanable/oil/slippery
+
+/obj/effect/decal/cleanable/oil/slippery/Initialize()
+	AddComponent(/datum/component/slippery, 80, (NO_SLIP_WHEN_WALKING | SLIDE))

code/game/objects/effects/decals/decal.dm

@@ -0,0 +1,48 @@
+/obj/effect/decal
+	name = "decal"
+	plane = FLOOR_PLANE
+	anchored = TRUE
+	resistance_flags = FIRE_PROOF | UNACIDABLE | ACID_PROOF
+	var/turf_loc_check = TRUE
+
+/obj/effect/decal/Initialize()
+	. = ..()
+	if(turf_loc_check && (!isturf(loc) || NeverShouldHaveComeHere(loc)))
+		return INITIALIZE_HINT_QDEL
+
+/obj/effect/decal/blob_act(obj/structure/blob/B)
+	if(B && B.loc == loc)
+		qdel(src)
+
+/obj/effect/decal/proc/NeverShouldHaveComeHere(turf/T)
+	return isclosedturf(T) || isgroundlessturf(T)
+
+/obj/effect/decal/ex_act(severity, target)
+	qdel(src)
+
+/obj/effect/decal/fire_act(exposed_temperature, exposed_volume)
+	if(!(resistance_flags & FIRE_PROOF)) //non fire proof decal or being burned by lava
+		qdel(src)
+
+/obj/effect/decal/HandleTurfChange(turf/T)
+	..()
+	if(T == loc && NeverShouldHaveComeHere(T))
+		qdel(src)
+
+//////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
+
+/obj/effect/turf_decal
+	icon = 'icons/turf/decals.dmi'
+	icon_state = "warningline"
+	layer = TURF_DECAL_LAYER
+
+/obj/effect/turf_decal/Initialize()
+	..()
+	return INITIALIZE_HINT_QDEL
+
+/obj/effect/turf_decal/ComponentInitialize()
+	. = ..()
+	var/turf/T = loc
+	if(!istype(T)) //you know this will happen somehow
+		CRASH("Turf decal initialized in an object/nullspace")
+	T.AddComponent(/datum/component/decal, icon, icon_state, dir, CLEAN_GOD, color, null, null, alpha)

code/game/objects/effects/decals/turfdecal/weather.dm

@@ -0,0 +1,25 @@
+/obj/effect/turf_decal/weather
+	name = "sandy floor"
+	icon_state = "sandyfloor"
+
+/obj/effect/turf_decal/weather/snow
+	name = "snowy floor"
+	icon_state = "snowyfloor"
+
+/obj/effect/turf_decal/weather/snow/corner
+	name = "snow corner piece"
+	icon = 'icons/turf/snow.dmi'
+	icon_state = "snow_corner"
+
+/obj/effect/turf_decal/weather/dirt
+	name = "dirt siding"
+	icon = 'icons/turf/decals.dmi'
+	icon_state = "dirt_side"
+
+/obj/effect/turf_decal/weather/sand
+	name = "sand siding"
+	icon = 'icons/misc/beach.dmi'
+	icon_state = "sand_side"
+
+/obj/effect/turf_decal/weather/sand/light
+	icon_state = "lightsand_side"

code/game/objects/effects/effects.dm

@@ -0,0 +1,67 @@
+
+//objects in /obj/effect should never be things that are attackable, use obj/structure instead.
+//Effects are mostly temporary visual effects like sparks, smoke, as well as decals, etc...
+/obj/effect
+	icon = 'icons/effects/effects.dmi'
+	resistance_flags = INDESTRUCTIBLE | LAVA_PROOF | FIRE_PROOF | UNACIDABLE | ACID_PROOF | FREEZE_PROOF
+	obj_flags = 0
+
+/obj/effect/take_damage(damage_amount, damage_type = BRUTE, damage_flag = 0, sound_effect = 1, attack_dir)
+	return
+
+/obj/effect/fire_act(exposed_temperature, exposed_volume)
+	return
+
+/obj/effect/acid_act()
+	return
+
+/obj/effect/mech_melee_attack(obj/mecha/M)
+	return 0
+
+/obj/effect/blob_act(obj/structure/blob/B)
+	return
+
+/obj/effect/attack_hulk(mob/living/carbon/human/user, does_attack_animation = 0)
+	return 0
+
+/obj/effect/experience_pressure_difference()
+	return
+
+/obj/effect/ex_act(severity, target)
+	if(target == src)
+		qdel(src)
+	else
+		switch(severity)
+			if(1)
+				qdel(src)
+			if(2)
+				if(prob(60))
+					qdel(src)
+			if(3)
+				if(prob(25))
+					qdel(src)
+
+/obj/effect/singularity_act()
+	qdel(src)
+	return 0
+
+/obj/effect/ConveyorMove()
+	return
+
+/obj/effect/abstract/ex_act(severity, target)
+	return
+
+/obj/effect/abstract/singularity_pull()
+	return
+
+/obj/effect/abstract/singularity_act()
+	return
+
+/obj/effect/abstract/has_gravity(turf/T)
+	return FALSE
+
+/obj/effect/dummy/singularity_pull()
+	return
+
+/obj/effect/dummy/singularity_act()
+	return

code/game/objects/effects/mines.dm

@@ -0,0 +1,176 @@
+/obj/effect/mine
+	name = "dummy mine"
+	desc = "Better stay away from that thing."
+	density = FALSE
+	anchored = TRUE
+	icon = 'icons/obj/items_and_weapons.dmi'
+	icon_state = "uglymine"
+	var/triggered = 0
+
+/obj/effect/mine/proc/mineEffect(mob/victim)
+	to_chat(victim, "<span class='danger'>*click*</span>")
+
+/obj/effect/mine/Crossed(AM as mob|obj)
+	if(isturf(loc))
+		if(ismob(AM))
+			var/mob/MM = AM
+			if(!(MM.movement_type & FLYING))
+				triggermine(AM)
+		else
+			triggermine(AM)
+
+/obj/effect/mine/proc/triggermine(mob/victim)
+	if(triggered)
+		return
+	visible_message("<span class='danger'>[victim] sets off [icon2html(src, viewers(src))] [src]!</span>")
+	var/datum/effect_system/spark_spread/s = new /datum/effect_system/spark_spread
+	s.set_up(3, 1, src)
+	s.start()
+	mineEffect(victim)
+	triggered = 1
+	qdel(src)
+
+
+/obj/effect/mine/explosive
+	name = "explosive mine"
+	var/range_devastation = 0
+	var/range_heavy = 1
+	var/range_light = 2
+	var/range_flash = 3
+
+/obj/effect/mine/explosive/mineEffect(mob/victim)
+	explosion(loc, range_devastation, range_heavy, range_light, range_flash)
+
+
+/obj/effect/mine/stun
+	name = "stun mine"
+	var/stun_time = 80
+
+/obj/effect/mine/stun/mineEffect(mob/living/victim)
+	if(isliving(victim))
+		victim.Knockdown(stun_time)
+
+/obj/effect/mine/kickmine
+	name = "kick mine"
+
+/obj/effect/mine/kickmine/mineEffect(mob/victim)
+	if(isliving(victim) && victim.client)
+		to_chat(victim, "<span class='userdanger'>You have been kicked FOR NO REISIN!</span>")
+		qdel(victim.client)
+
+
+/obj/effect/mine/gas
+	name = "oxygen mine"
+	var/gas_amount = 360
+	var/gas_type = "o2"
+
+/obj/effect/mine/gas/mineEffect(mob/victim)
+	atmos_spawn_air("[gas_type]=[gas_amount]")
+
+
+/obj/effect/mine/gas/plasma
+	name = "plasma mine"
+	gas_type = "plasma"
+
+
+/obj/effect/mine/gas/n2o
+	name = "\improper N2O mine"
+	gas_type = "n2o"
+
+
+/obj/effect/mine/sound
+	name = "honkblaster 1000"
+	var/sound = 'sound/items/bikehorn.ogg'
+
+/obj/effect/mine/sound/mineEffect(mob/victim)
+	playsound(loc, sound, 100, 1)
+
+
+/obj/effect/mine/sound/bwoink
+	name = "bwoink mine"
+	sound = 'sound/effects/adminhelp.ogg'
+
+/obj/effect/mine/pickup
+	name = "pickup"
+	desc = "pick me up"
+	icon = 'icons/effects/effects.dmi'
+	icon_state = "electricity2"
+	density = FALSE
+	var/duration = 0
+
+/obj/effect/mine/pickup/Initialize()
+	. = ..()
+	animate(src, pixel_y = 4, time = 20, loop = -1)
+
+/obj/effect/mine/pickup/triggermine(mob/victim)
+	if(triggered)
+		return
+	triggered = 1
+	invisibility = INVISIBILITY_ABSTRACT
+	mineEffect(victim)
+	qdel(src)
+
+
+/obj/effect/mine/pickup/bloodbath
+	name = "Red Orb"
+	desc = "You feel angry just looking at it."
+	duration = 1200 //2min
+	color = "#FF0000"
+
+/obj/effect/mine/pickup/bloodbath/mineEffect(mob/living/carbon/victim)
+	if(!victim.client || !istype(victim))
+		return
+	to_chat(victim, "<span class='reallybig redtext'>RIP AND TEAR</span>")
+	var/old_color = victim.client.color
+	var/static/list/red_splash = list(1,0,0,0.8,0.2,0, 0.8,0,0.2,0.1,0,0)
+	var/static/list/pure_red = list(0,0,0,0,0,0,0,0,0,1,0,0)
+
+	spawn(0)
+		new /datum/hallucination/delusion(victim, TRUE, "demon",duration,0)
+
+	var/obj/item/twohanded/required/chainsaw/doomslayer/chainsaw = new(victim.loc)
+	victim.log_message("entered a blood frenzy", LOG_ATTACK)
+
+	ADD_TRAIT(chainsaw, TRAIT_NODROP, CHAINSAW_FRENZY_TRAIT)
+	victim.drop_all_held_items()
+	victim.put_in_hands(chainsaw, forced = TRUE)
+	chainsaw.attack_self(victim)
+	chainsaw.wield(victim)
+	victim.reagents.add_reagent("adminordrazine",25)
+	to_chat(victim, "<span class='warning'>KILL, KILL, KILL! YOU HAVE NO ALLIES ANYMORE, KILL THEM ALL!</span>")
+
+	victim.client.color = pure_red
+	animate(victim.client,color = red_splash, time = 10, easing = SINE_EASING|EASE_OUT)
+	sleep(10)
+	animate(victim.client,color = old_color, time = duration)//, easing = SINE_EASING|EASE_OUT)
+	sleep(duration)
+	to_chat(victim, "<span class='notice'>Your bloodlust seeps back into the bog of your subconscious and you regain self control.</span>")
+	qdel(chainsaw)
+	victim.log_message("exited a blood frenzy", LOG_ATTACK)
+	qdel(src)
+
+/obj/effect/mine/pickup/healing
+	name = "Blue Orb"
+	desc = "You feel better just looking at it."
+	color = "#0000FF"
+
+/obj/effect/mine/pickup/healing/mineEffect(mob/living/carbon/victim)
+	if(!victim.client || !istype(victim))
+		return
+	to_chat(victim, "<span class='notice'>You feel great!</span>")
+	victim.revive(full_heal = 1, admin_revive = 1)
+
+/obj/effect/mine/pickup/speed
+	name = "Yellow Orb"
+	desc = "You feel faster just looking at it."
+	color = "#FFFF00"
+	duration = 300
+
+/obj/effect/mine/pickup/speed/mineEffect(mob/living/carbon/victim)
+	if(!victim.client || !istype(victim))
+		return
+	to_chat(victim, "<span class='notice'>You feel fast!</span>")
+	victim.add_movespeed_modifier(MOVESPEED_ID_YELLOW_ORB, update=TRUE, priority=100, multiplicative_slowdown=-2, blacklisted_movetypes=(FLYING|FLOATING))
+	sleep(duration)
+	victim.remove_movespeed_modifier(MOVESPEED_ID_YELLOW_ORB)
+	to_chat(victim, "<span class='notice'>You slow down.</span>")

code/game/objects/effects/proximity.dm

@@ -0,0 +1,112 @@
+/datum/proximity_monitor
+	var/atom/host	//the atom we are tracking
+	var/atom/hasprox_receiver //the atom that will receive HasProximity calls.
+	var/atom/last_host_loc
+	var/list/checkers //list of /obj/effect/abstract/proximity_checkers
+	var/current_range
+	var/ignore_if_not_on_turf	//don't check turfs in range if the host's loc isn't a turf
+
+/datum/proximity_monitor/New(atom/_host, range, _ignore_if_not_on_turf = TRUE)
+	checkers = list()
+	last_host_loc = _host.loc
+	ignore_if_not_on_turf = _ignore_if_not_on_turf
+	current_range = range
+	SetHost(_host)
+
+/datum/proximity_monitor/proc/SetHost(atom/H,atom/R)
+	if(H == host)
+		return
+	if(host)
+		UnregisterSignal(host, COMSIG_MOVABLE_MOVED)
+	if(R)
+		hasprox_receiver = R
+	else if(hasprox_receiver == host) //Default case
+		hasprox_receiver = H
+	host = H
+	RegisterSignal(host, COMSIG_MOVABLE_MOVED, .proc/HandleMove)
+	last_host_loc = host.loc
+	SetRange(current_range,TRUE)
+
+/datum/proximity_monitor/Destroy()
+	host = null
+	last_host_loc = null
+	hasprox_receiver = null
+	QDEL_LIST(checkers)
+	return ..()
+
+/datum/proximity_monitor/proc/HandleMove()
+	var/atom/_host = host
+	var/atom/new_host_loc = _host.loc
+	if(last_host_loc != new_host_loc)
+		last_host_loc = new_host_loc	//hopefully this won't cause GC issues with containers
+		var/curr_range = current_range
+		SetRange(curr_range, TRUE)
+		if(curr_range)
+			testing("HasProx: [host] -> [host]")
+			hasprox_receiver.HasProximity(host)	//if we are processing, we're guaranteed to be a movable
+
+/datum/proximity_monitor/proc/SetRange(range, force_rebuild = FALSE)
+	if(!force_rebuild && range == current_range)
+		return FALSE
+	. = TRUE
+
+	current_range = range
+
+	var/list/checkers_local = checkers
+	var/old_checkers_len = checkers_local.len
+
+	var/atom/_host = host
+
+	var/atom/loc_to_use = ignore_if_not_on_turf ? _host.loc : get_turf(_host)
+	if(!isturf(loc_to_use))	//only check the host's loc
+		if(range)
+			var/obj/effect/abstract/proximity_checker/pc
+			if(old_checkers_len)
+				pc = checkers_local[old_checkers_len]
+				--checkers_local.len
+				QDEL_LIST(checkers_local)
+			else
+				pc = new(loc_to_use, src)
+
+			checkers_local += pc	//only check the host's loc
+		return
+
+	var/list/turfs = RANGE_TURFS(range, loc_to_use)
+	var/turfs_len = turfs.len
+	var/old_checkers_used = min(turfs_len, old_checkers_len)
+
+	//reuse what we can
+	for(var/I in 1 to old_checkers_len)
+		if(I <= old_checkers_used)
+			var/obj/effect/abstract/proximity_checker/pc = checkers_local[I]
+			pc.forceMove(turfs[I])
+		else
+			qdel(checkers_local[I])	//delete the leftovers
+
+	if(old_checkers_len < turfs_len)
+		//create what we lack
+		for(var/I in (old_checkers_used + 1) to turfs_len)
+			checkers_local += new /obj/effect/abstract/proximity_checker(turfs[I], src)
+	else
+		checkers_local.Cut(old_checkers_used + 1, old_checkers_len)
+
+/obj/effect/abstract/proximity_checker
+	invisibility = INVISIBILITY_ABSTRACT
+	anchored = TRUE
+	var/datum/proximity_monitor/monitor
+
+/obj/effect/abstract/proximity_checker/Initialize(mapload, datum/proximity_monitor/_monitor)
+	. = ..()
+	if(_monitor)
+		monitor = _monitor
+	else
+		stack_trace("proximity_checker created without host")
+		return INITIALIZE_HINT_QDEL
+
+/obj/effect/abstract/proximity_checker/Destroy()
+	monitor = null
+	return ..()
+
+/obj/effect/abstract/proximity_checker/Crossed(atom/movable/AM)
+	set waitfor = FALSE
+	monitor.hasprox_receiver.HasProximity(AM)

code/game/objects/effects/spawners/gibspawner.dm

@@ -0,0 +1,240 @@
+
+/obj/effect/gibspawner
+	var/sparks = FALSE //whether sparks spread
+	var/virusProb = 20 //the chance for viruses to spread on the gibs
+	var/gib_mob_type  //generate a fake mob to transfer DNA from if we weren't passed a mob.
+	var/gib_mob_species //We'll want to nip-pick their species for blood type stuff
+	var/sound_to_play = 'sound/effects/blobattack.ogg'
+	var/sound_vol = 60
+	var/list/gibtypes = list() //typepaths of the gib decals to spawn
+	var/list/gibamounts = list() //amount to spawn for each gib decal type we'll spawn.
+	var/list/gibdirections = list() //of lists of possible directions to spread each gib decal type towards.
+
+/obj/effect/gibspawner/Initialize(mapload, mob/living/source_mob, list/datum/disease/diseases)
+	. = ..()
+	if(gibtypes.len != gibamounts.len)
+		stack_trace("Gib list amount length mismatch!")
+		return
+	if(gibamounts.len != gibdirections.len)
+		stack_trace("Gib list dir length mismatch!")
+		return
+
+	var/obj/effect/decal/cleanable/blood/gibs/gib = null
+
+	if(sound_to_play && isnum(sound_vol))
+		playsound(src, sound_to_play, sound_vol, TRUE)
+
+	if(sparks)
+		var/datum/effect_system/spark_spread/s = new /datum/effect_system/spark_spread
+		s.set_up(2, 1, loc)
+		s.start()
+
+	var/list/dna_to_add //find the dna to pass to the spawned gibs. do note this can be null if the mob doesn't have blood. add_blood_DNA() has built in null handling.
+	var/body_coloring = ""
+	if(source_mob)
+		if(!issilicon(source_mob))
+			dna_to_add = source_mob.get_blood_dna_list() //ez pz
+		if(ishuman(source_mob))
+			var/mob/living/carbon/human/H = source_mob
+			if(H.dna.species.use_skintones)
+				body_coloring = "#[skintone2hex(H.skin_tone)]"
+			else
+				body_coloring = "#[H.dna.features["mcolor"]]"
+
+	else if(gib_mob_type)
+		var/mob/living/temp_mob = new gib_mob_type(src) //generate a fake mob so that we pull the right type of DNA for the gibs.
+		if(gib_mob_species)
+			if(ishuman(temp_mob))
+				var/mob/living/carbon/human/H = temp_mob
+				H.set_species(gib_mob_species)
+				dna_to_add = temp_mob.get_blood_dna_list()
+				if(H.dna.species.use_skintones)
+					body_coloring = "#[skintone2hex(H.skin_tone)]"
+				else
+					body_coloring = "#[H.dna.features["mcolor"]]"
+			else
+				dna_to_add = temp_mob.get_blood_dna_list()
+		else if(!issilicon(temp_mob))
+			dna_to_add = temp_mob.get_blood_dna_list()
+		qdel(temp_mob)
+	else
+		dna_to_add = list("Non-human DNA" = random_blood_type()) //else, generate a random bloodtype for it.
+
+
+	for(var/i = 1, i<= gibtypes.len, i++)
+		if(gibamounts[i])
+			for(var/j = 1, j<= gibamounts[i], j++)
+				var/gibType = gibtypes[i]
+				gib = new gibType(loc, diseases)
+				if(iscarbon(loc))
+					var/mob/living/carbon/digester = loc
+					digester.stomach_contents += gib
+
+				if(dna_to_add && dna_to_add.len)
+					gib.add_blood_DNA(dna_to_add)
+					gib.body_colors = body_coloring
+					gib.update_icon()
+
+				var/list/directions = gibdirections[i]
+				if(isturf(loc))
+					if(directions.len)
+						gib.streak(directions)
+
+	return INITIALIZE_HINT_QDEL
+
+
+/obj/effect/gibspawner/generic
+	gibtypes = list(/obj/effect/decal/cleanable/blood/gibs, /obj/effect/decal/cleanable/blood/gibs, /obj/effect/decal/cleanable/blood/gibs/core)
+	gibamounts = list(2, 2, 1)
+	sound_vol = 40
+
+/obj/effect/gibspawner/generic/Initialize()
+	if(!gibdirections.len)
+		gibdirections = list(list(WEST, NORTHWEST, SOUTHWEST, NORTH),list(EAST, NORTHEAST, SOUTHEAST, SOUTH), list())
+	return ..()
+
+/obj/effect/gibspawner/generic/animal
+	gib_mob_type = /mob/living/simple_animal/pet
+
+/obj/effect/gibspawner/human
+	gibtypes = list(/obj/effect/decal/cleanable/blood/gibs/human/up, /obj/effect/decal/cleanable/blood/gibs/human/down, /obj/effect/decal/cleanable/blood/gibs/human, /obj/effect/decal/cleanable/blood/gibs/human, /obj/effect/decal/cleanable/blood/gibs/human/body, /obj/effect/decal/cleanable/blood/gibs/human/limb, /obj/effect/decal/cleanable/blood/gibs/human/core)
+	gibamounts = list(1, 1, 1, 1, 1, 1, 1)
+	gib_mob_type = /mob/living/carbon/human
+	gib_mob_species = /datum/species/human
+	sound_vol = 50
+
+/obj/effect/gibspawner/human/Initialize()
+	if(!gibdirections.len)
+		gibdirections = list(list(NORTH, NORTHEAST, NORTHWEST),list(SOUTH, SOUTHEAST, SOUTHWEST),list(WEST, NORTHWEST, SOUTHWEST),list(EAST, NORTHEAST, SOUTHEAST), GLOB.alldirs, GLOB.alldirs, list())
+	return ..()
+
+/obj/effect/gibspawner/human/bodypartless //only the gibs that don't look like actual full bodyparts (except torso).
+	gibtypes = list(/obj/effect/decal/cleanable/blood/gibs/human, /obj/effect/decal/cleanable/blood/gibs/human/core, /obj/effect/decal/cleanable/blood/gibs/human, /obj/effect/decal/cleanable/blood/gibs/human/core, /obj/effect/decal/cleanable/blood/gibs/human, /obj/effect/decal/cleanable/blood/gibs/human/torso)
+	gibamounts = list(1, 1, 1, 1, 1, 1)
+
+/obj/effect/gibspawner/human/bodypartless/Initialize()
+	if(!gibdirections.len)
+		gibdirections = list(list(NORTH, NORTHEAST, NORTHWEST),list(SOUTH, SOUTHEAST, SOUTHWEST),list(WEST, NORTHWEST, SOUTHWEST),list(EAST, NORTHEAST, SOUTHEAST), GLOB.alldirs, list())
+	return ..()
+
+/obj/effect/gibspawner/lizard
+	gibtypes = list(/obj/effect/decal/cleanable/blood/gibs/human/lizard/up, /obj/effect/decal/cleanable/blood/gibs/human/lizard/down, /obj/effect/decal/cleanable/blood/gibs/human/lizard, /obj/effect/decal/cleanable/blood/gibs/human/lizard, /obj/effect/decal/cleanable/blood/gibs/human/lizard/body, /obj/effect/decal/cleanable/blood/gibs/human/lizard/limb, /obj/effect/decal/cleanable/blood/gibs/human/lizard/core)
+	gibamounts = list(1, 1, 1, 1, 1, 1, 1)
+	gib_mob_type = /mob/living/carbon/human/species/lizard
+	gib_mob_species = /datum/species/lizard
+	sound_vol = 50
+
+/obj/effect/gibspawner/lizard/Initialize()
+	if(!gibdirections.len)
+		gibdirections = list(list(NORTH, NORTHEAST, NORTHWEST),list(SOUTH, SOUTHEAST, SOUTHWEST),list(WEST, NORTHWEST, SOUTHWEST),list(EAST, NORTHEAST, SOUTHEAST), GLOB.alldirs, GLOB.alldirs, list())
+	return ..()
+
+/obj/effect/gibspawner/lizard/bodypartless
+	gibtypes = list(/obj/effect/decal/cleanable/blood/gibs/human/lizard, /obj/effect/decal/cleanable/blood/gibs/human/lizard/core, /obj/effect/decal/cleanable/blood/gibs/human/lizard, /obj/effect/decal/cleanable/blood/gibs/human/lizard/core, /obj/effect/decal/cleanable/blood/gibs/human/lizard, /obj/effect/decal/cleanable/blood/gibs/human/lizard/torso)
+	gibamounts = list(1, 1, 1, 1, 1, 1)
+
+/obj/effect/gibspawner/lizard/bodypartless/Initialize()
+	if(!gibdirections.len)
+		gibdirections = list(list(NORTH, NORTHEAST, NORTHWEST),list(SOUTH, SOUTHEAST, SOUTHWEST),list(WEST, NORTHWEST, SOUTHWEST),list(EAST, NORTHEAST, SOUTHEAST), GLOB.alldirs, list())
+	return ..()
+
+/obj/effect/gibspawner/slime
+	gibtypes = list(/obj/effect/decal/cleanable/blood/gibs/slime/up, /obj/effect/decal/cleanable/blood/gibs/slime/down, /obj/effect/decal/cleanable/blood/gibs/slime, /obj/effect/decal/cleanable/blood/gibs/slime, /obj/effect/decal/cleanable/blood/gibs/slime/body, /obj/effect/decal/cleanable/blood/gibs/slime/limb, /obj/effect/decal/cleanable/blood/gibs/slime/core)
+	gibamounts = list(1, 1, 1, 1, 1, 1, 1)
+	gib_mob_type = /mob/living/carbon/human/species/roundstartslime
+	gib_mob_species = /datum/species/jelly/roundstartslime
+	sound_vol = 50
+
+/obj/effect/gibspawner/slime/Initialize()
+	if(!gibdirections.len)
+		gibdirections = list(list(NORTH, NORTHEAST, NORTHWEST),list(SOUTH, SOUTHEAST, SOUTHWEST),list(WEST, NORTHWEST, SOUTHWEST),list(EAST, NORTHEAST, SOUTHEAST), GLOB.alldirs, GLOB.alldirs, list())
+	return ..()
+
+/obj/effect/gibspawner/slime/bodypartless //only the gibs that don't look like actual full bodyparts (except torso).
+	gibtypes = list(/obj/effect/decal/cleanable/blood/gibs/slime, /obj/effect/decal/cleanable/blood/gibs/slime/core, /obj/effect/decal/cleanable/blood/gibs/slime, /obj/effect/decal/cleanable/blood/gibs/slime/core, /obj/effect/decal/cleanable/blood/gibs/slime, /obj/effect/decal/cleanable/blood/gibs/slime/torso)
+	gibamounts = list(1, 1, 1, 1, 1, 1)
+
+/obj/effect/gibspawner/slime/bodypartless/Initialize()
+	if(!gibdirections.len)
+		gibdirections = list(list(NORTH, NORTHEAST, NORTHWEST),list(SOUTH, SOUTHEAST, SOUTHWEST),list(WEST, NORTHWEST, SOUTHWEST),list(EAST, NORTHEAST, SOUTHEAST), GLOB.alldirs, list())
+	return ..()
+
+/obj/effect/gibspawner/ipc
+	gibtypes = list(/obj/effect/decal/cleanable/blood/gibs/ipc/up, /obj/effect/decal/cleanable/blood/gibs/ipc/down, /obj/effect/decal/cleanable/blood/gibs/ipc, /obj/effect/decal/cleanable/blood/gibs/ipc, /obj/effect/decal/cleanable/blood/gibs/ipc/body, /obj/effect/decal/cleanable/blood/gibs/ipc/limb, /obj/effect/decal/cleanable/blood/gibs/ipc/core)
+	gibamounts = list(1, 1, 1, 1, 1, 1, 1)
+	gib_mob_type = /mob/living/carbon/human/species/ipc
+	gib_mob_species = /datum/species/ipc
+	sound_vol = 50
+	sparks = TRUE
+	sound_to_play = 'sound/effects/bang.ogg'
+
+/obj/effect/gibspawner/ipc/Initialize()
+	if(!gibdirections.len)
+		gibdirections = list(list(NORTH, NORTHEAST, NORTHWEST),list(SOUTH, SOUTHEAST, SOUTHWEST),list(WEST, NORTHWEST, SOUTHWEST),list(EAST, NORTHEAST, SOUTHEAST), GLOB.alldirs, GLOB.alldirs, list())
+	return ..()
+
+/obj/effect/gibspawner/ipc/bodypartless //only the gibs that don't look like actual full bodyparts (except torso).
+	gibtypes = list(/obj/effect/decal/cleanable/blood/gibs/ipc, /obj/effect/decal/cleanable/blood/gibs/ipc/core, /obj/effect/decal/cleanable/blood/gibs/ipc, /obj/effect/decal/cleanable/blood/gibs/ipc/core, /obj/effect/decal/cleanable/blood/gibs/ipc, /obj/effect/decal/cleanable/blood/gibs/ipc/torso)
+	gibamounts = list(1, 1, 1, 1, 1, 1)
+
+/obj/effect/gibspawner/ipc/bodypartless/Initialize()
+	if(!gibdirections.len)
+		gibdirections = list(list(NORTH, NORTHEAST, NORTHWEST),list(SOUTH, SOUTHEAST, SOUTHWEST),list(WEST, NORTHWEST, SOUTHWEST),list(EAST, NORTHEAST, SOUTHEAST), GLOB.alldirs, list())
+	return ..()
+
+/obj/effect/gibspawner/xeno
+	gibtypes = list(/obj/effect/decal/cleanable/blood/gibs/xeno/up, /obj/effect/decal/cleanable/blood/gibs/xeno/down, /obj/effect/decal/cleanable/blood/gibs/xeno, /obj/effect/decal/cleanable/blood/gibs/xeno, /obj/effect/decal/cleanable/blood/gibs/xeno/body, /obj/effect/decal/cleanable/blood/gibs/xeno/limb, /obj/effect/decal/cleanable/blood/gibs/xeno/core)
+	gibamounts = list(1, 1, 1, 1, 1, 1, 1)
+	gib_mob_type = /mob/living/carbon/alien
+
+/obj/effect/gibspawner/xeno/Initialize()
+	if(!gibdirections.len)
+		gibdirections = list(list(NORTH, NORTHEAST, NORTHWEST),list(SOUTH, SOUTHEAST, SOUTHWEST),list(WEST, NORTHWEST, SOUTHWEST),list(EAST, NORTHEAST, SOUTHEAST), GLOB.alldirs, GLOB.alldirs, list())
+	return ..()
+
+/obj/effect/gibspawner/xeno/bodypartless //only the gibs that don't look like actual full bodyparts (except torso).
+	gibtypes = list(/obj/effect/decal/cleanable/blood/gibs/xeno, /obj/effect/decal/cleanable/blood/gibs/xeno/core, /obj/effect/decal/cleanable/blood/gibs/xeno, /obj/effect/decal/cleanable/blood/gibs/xeno/core, /obj/effect/decal/cleanable/blood/gibs/xeno, /obj/effect/decal/cleanable/blood/gibs/xeno/torso)
+	gibamounts = list(1, 1, 1, 1, 1, 1)
+
+/obj/effect/gibspawner/xeno/bodypartless/Initialize()
+	if(!gibdirections.len)
+		gibdirections = list(list(NORTH, NORTHEAST, NORTHWEST),list(SOUTH, SOUTHEAST, SOUTHWEST),list(WEST, NORTHWEST, SOUTHWEST),list(EAST, NORTHEAST, SOUTHEAST), GLOB.alldirs, list())
+	return ..()
+
+/obj/effect/gibspawner/xeno/xenoperson
+	gib_mob_type = /mob/living/carbon/human/species/xeno
+	gib_mob_species = /datum/species/xeno
+
+/obj/effect/gibspawner/xeno/xenoperson/bodypartless
+
+/obj/effect/gibspawner/larva
+	gibtypes = list(/obj/effect/decal/cleanable/blood/gibs/xeno/larva, /obj/effect/decal/cleanable/blood/gibs/xeno/larva, /obj/effect/decal/cleanable/blood/gibs/xeno/larva/body, /obj/effect/decal/cleanable/blood/gibs/xeno/larva/body)
+	gibamounts = list(1, 1, 1, 1)
+	gib_mob_type = /mob/living/carbon/alien/larva
+
+/obj/effect/gibspawner/larva/Initialize()
+	if(!gibdirections.len)
+		gibdirections = list(list(NORTH, NORTHEAST, NORTHWEST),list(SOUTH, SOUTHEAST, SOUTHWEST), list(), GLOB.alldirs)
+	return ..()
+
+/obj/effect/gibspawner/larva/bodypartless
+	gibtypes = list(/obj/effect/decal/cleanable/blood/gibs/xeno/larva, /obj/effect/decal/cleanable/blood/gibs/xeno/larva, /obj/effect/decal/cleanable/blood/gibs/xeno/larva)
+	gibamounts = list(1, 1, 1)
+
+/obj/effect/gibspawner/larva/bodypartless/Initialize()
+	if(!gibdirections.len)
+		gibdirections = list(list(NORTH, NORTHEAST, NORTHWEST),list(SOUTH, SOUTHEAST, SOUTHWEST), list())
+	return ..()
+
+/obj/effect/gibspawner/robot
+	sparks = TRUE
+	gibtypes = list(/obj/effect/decal/cleanable/robot_debris/up, /obj/effect/decal/cleanable/robot_debris/down, /obj/effect/decal/cleanable/robot_debris, /obj/effect/decal/cleanable/robot_debris, /obj/effect/decal/cleanable/robot_debris, /obj/effect/decal/cleanable/robot_debris/limb)
+	gibamounts = list(1, 1, 1, 1, 1, 1)
+	gib_mob_type = /mob/living/silicon/robot
+
+/obj/effect/gibspawner/robot/Initialize()
+	if(!gibdirections.len)
+		gibdirections = list(list(NORTH, NORTHEAST, NORTHWEST),list(SOUTH, SOUTHEAST, SOUTHWEST),list(WEST, NORTHWEST, SOUTHWEST),list(EAST, NORTHEAST, SOUTHEAST), GLOB.alldirs, GLOB.alldirs)
+	gibamounts[6] = pick(0, 1, 2)
+	return ..()
+

code/game/objects/effects/spiders.dm

@@ -0,0 +1,237 @@
+//generic procs copied from obj/effect/alien
+/obj/structure/spider
+	name = "web"
+	icon = 'icons/effects/effects.dmi'
+	desc = "It's stringy and sticky."
+	anchored = TRUE
+	density = FALSE
+	max_integrity = 15
+
+
+
+/obj/structure/spider/play_attack_sound(damage_amount, damage_type = BRUTE, damage_flag = 0)
+	if(damage_type == BURN)//the stickiness of the web mutes all attack sounds except fire damage type
+		playsound(loc, 'sound/items/welder.ogg', 100, 1)
+
+
+/obj/structure/spider/run_obj_armor(damage_amount, damage_type, damage_flag = 0, attack_dir)
+	if(damage_flag == "melee")
+		switch(damage_type)
+			if(BURN)
+				damage_amount *= 2
+			if(BRUTE)
+				damage_amount *= 0.25
+	. = ..()
+
+/obj/structure/spider/temperature_expose(datum/gas_mixture/air, exposed_temperature, exposed_volume)
+	if(exposed_temperature > 300)
+		take_damage(5, BURN, 0, 0)
+
+/obj/structure/spider/stickyweb
+	icon_state = "stickyweb1"
+
+/obj/structure/spider/stickyweb/Initialize()
+	if(prob(50))
+		icon_state = "stickyweb2"
+	. = ..()
+
+/obj/structure/spider/stickyweb/CanPass(atom/movable/mover, turf/target)
+	if(istype(mover, /mob/living/simple_animal/hostile/poison/giant_spider))
+		return TRUE
+	else if(isliving(mover))
+		if(istype(mover.pulledby, /mob/living/simple_animal/hostile/poison/giant_spider))
+			return TRUE
+		if(prob(50))
+			to_chat(mover, "<span class='danger'>You get stuck in \the [src] for a moment.</span>")
+			return FALSE
+	else if(istype(mover, /obj/item/projectile))
+		return prob(30)
+	return TRUE
+
+/obj/structure/spider/eggcluster
+	name = "egg cluster"
+	desc = "They seem to pulse slightly with an inner life."
+	icon_state = "eggs"
+	var/amount_grown = 0
+	var/player_spiders = 0
+	var/directive = "" //Message from the mother
+	var/poison_type = "toxin"
+	var/poison_per_bite = 5
+	var/list/faction = list("spiders")
+
+/obj/structure/spider/eggcluster/Initialize()
+	pixel_x = rand(3,-3)
+	pixel_y = rand(3,-3)
+	START_PROCESSING(SSobj, src)
+	. = ..()
+
+/obj/structure/spider/eggcluster/process()
+	amount_grown += rand(0,2)
+	if(amount_grown >= 100)
+		var/num = rand(3,12)
+		for(var/i=0, i<num, i++)
+			var/obj/structure/spider/spiderling/S = new /obj/structure/spider/spiderling(src.loc)
+			S.poison_type = poison_type
+			S.poison_per_bite = poison_per_bite
+			S.faction = faction.Copy()
+			S.directive = directive
+			if(player_spiders)
+				S.player_spiders = 1
+		qdel(src)
+
+/obj/structure/spider/spiderling
+	name = "spiderling"
+	desc = "It never stays still for long."
+	icon_state = "spiderling"
+	anchored = FALSE
+	layer = PROJECTILE_HIT_THRESHHOLD_LAYER
+	max_integrity = 3
+	var/amount_grown = 0
+	var/grow_as = null
+	var/obj/machinery/atmospherics/components/unary/vent_pump/entry_vent
+	var/travelling_in_vent = 0
+	var/player_spiders = 0
+	var/directive = "" //Message from the mother
+	var/poison_type = "toxin"
+	var/poison_per_bite = 5
+	var/list/faction = list("spiders")
+
+/obj/structure/spider/spiderling/Destroy()
+	new/obj/item/reagent_containers/food/snacks/spiderling(get_turf(src))
+	. = ..()
+
+/obj/structure/spider/spiderling/Initialize()
+	. = ..()
+	pixel_x = rand(6,-6)
+	pixel_y = rand(6,-6)
+	START_PROCESSING(SSobj, src)
+	AddComponent(/datum/component/swarming)
+
+/obj/structure/spider/spiderling/hunter
+	grow_as = /mob/living/simple_animal/hostile/poison/giant_spider/hunter
+
+/obj/structure/spider/spiderling/nurse
+	grow_as = /mob/living/simple_animal/hostile/poison/giant_spider/nurse
+
+/obj/structure/spider/spiderling/midwife
+	grow_as = /mob/living/simple_animal/hostile/poison/giant_spider/nurse/midwife
+
+/obj/structure/spider/spiderling/viper
+	grow_as = /mob/living/simple_animal/hostile/poison/giant_spider/hunter/viper
+
+/obj/structure/spider/spiderling/tarantula
+	grow_as = /mob/living/simple_animal/hostile/poison/giant_spider/tarantula
+
+/obj/structure/spider/spiderling/Bump(atom/user)
+	if(istype(user, /obj/structure/table))
+		forceMove(user.loc)
+	else
+		..()
+
+/obj/structure/spider/spiderling/process()
+	if(travelling_in_vent)
+		if(isturf(loc))
+			travelling_in_vent = 0
+			entry_vent = null
+	else if(entry_vent)
+		if(get_dist(src, entry_vent) <= 1)
+			var/list/vents = list()
+			var/datum/pipeline/entry_vent_parent = entry_vent.parents[1]
+			for(var/obj/machinery/atmospherics/components/unary/vent_pump/temp_vent in entry_vent_parent.other_atmosmch)
+				vents.Add(temp_vent)
+			if(!vents.len)
+				entry_vent = null
+				return
+			var/obj/machinery/atmospherics/components/unary/vent_pump/exit_vent = pick(vents)
+			if(prob(50))
+				visible_message("<B>[src] scrambles into the ventilation ducts!</B>", \
+								"<span class='italics'>You hear something scampering through the ventilation ducts.</span>")
+
+			spawn(rand(20,60))
+				forceMove(exit_vent)
+				var/travel_time = round(get_dist(loc, exit_vent.loc) / 2)
+				spawn(travel_time)
+
+					if(!exit_vent || exit_vent.welded)
+						forceMove(entry_vent)
+						entry_vent = null
+						return
+
+					if(prob(50))
+						audible_message("<span class='italics'>You hear something scampering through the ventilation ducts.</span>")
+					sleep(travel_time)
+
+					if(!exit_vent || exit_vent.welded)
+						forceMove(entry_vent)
+						entry_vent = null
+						return
+					forceMove(exit_vent.loc)
+					entry_vent = null
+					var/area/new_area = get_area(loc)
+					if(new_area)
+						new_area.Entered(src)
+	//=================
+
+	else if(prob(33))
+		var/list/nearby = oview(10, src)
+		if(nearby.len)
+			var/target_atom = pick(nearby)
+			walk_to(src, target_atom)
+			if(prob(40))
+				src.visible_message("<span class='notice'>\The [src] skitters[pick(" away"," around","")].</span>")
+	else if(prob(10))
+		//ventcrawl!
+		for(var/obj/machinery/atmospherics/components/unary/vent_pump/v in view(7,src))
+			if(!v.welded)
+				entry_vent = v
+				walk_to(src, entry_vent, 1)
+				break
+	if(isturf(loc))
+		amount_grown += rand(0,2)
+		if(amount_grown >= 100)
+			if(!grow_as)
+				if(prob(3))
+					grow_as = pick(/mob/living/simple_animal/hostile/poison/giant_spider/tarantula, /mob/living/simple_animal/hostile/poison/giant_spider/hunter/viper, /mob/living/simple_animal/hostile/poison/giant_spider/nurse/midwife)
+				else
+					grow_as = pick(/mob/living/simple_animal/hostile/poison/giant_spider, /mob/living/simple_animal/hostile/poison/giant_spider/hunter, /mob/living/simple_animal/hostile/poison/giant_spider/nurse)
+			var/mob/living/simple_animal/hostile/poison/giant_spider/S = new grow_as(src.loc)
+			S.poison_per_bite = poison_per_bite
+			S.poison_type = poison_type
+			S.faction = faction.Copy()
+			S.directive = directive
+			if(player_spiders)
+				S.playable_spider = TRUE
+				notify_ghosts("Spider [S.name] can be controlled", null, enter_link="<a href=?src=[REF(S)];activate=1>(Click to play)</a>", source=S, action=NOTIFY_ATTACK, ignore_key = POLL_IGNORE_SPIDER, ignore_dnr_observers = TRUE)
+			qdel(src)
+
+
+
+/obj/structure/spider/cocoon
+	name = "cocoon"
+	desc = "Something wrapped in silky spider web."
+	icon_state = "cocoon1"
+	max_integrity = 60
+
+/obj/structure/spider/cocoon/Initialize()
+	icon_state = pick("cocoon1","cocoon2","cocoon3")
+	. = ..()
+
+/obj/structure/spider/cocoon/container_resist(mob/living/user)
+	var/breakout_time = 600
+	user.changeNext_move(CLICK_CD_BREAKOUT)
+	user.last_special = world.time + CLICK_CD_BREAKOUT
+	to_chat(user, "<span class='notice'>You struggle against the tight bonds... (This will take about [DisplayTimeText(breakout_time)].)</span>")
+	visible_message("You see something struggling and writhing in \the [src]!")
+	if(do_after(user,(breakout_time), target = src))
+		if(!user || user.stat != CONSCIOUS || user.loc != src)
+			return
+		qdel(src)
+
+
+
+/obj/structure/spider/cocoon/Destroy()
+	var/turf/T = get_turf(src)
+	src.visible_message("<span class='warning'>\The [src] splits open.</span>")
+	for(var/atom/movable/A in contents)
+		A.forceMove(T)
+	return ..()

code/game/objects/effects/temporary_visuals/miscellaneous.dm

@@ -0,0 +1,439 @@
+//unsorted miscellaneous temporary visuals
+/obj/effect/temp_visual/dir_setting/bloodsplatter
+	icon = 'icons/effects/blood.dmi'
+	duration = 5
+	randomdir = FALSE
+	layer = BELOW_MOB_LAYER
+	var/splatter_type = "splatter"
+
+/obj/effect/temp_visual/dir_setting/bloodsplatter/Initialize(mapload, set_dir, new_color)
+	if(new_color)
+		color = new_color
+	if(set_dir in GLOB.diagonals)
+		icon_state = "[splatter_type][pick(1, 2, 6)]"
+	else
+		icon_state = "[splatter_type][pick(3, 4, 5)]"
+	. = ..()
+	var/target_pixel_x = 0
+	var/target_pixel_y = 0
+	switch(set_dir)
+		if(NORTH)
+			target_pixel_y = 16
+		if(SOUTH)
+			target_pixel_y = -16
+			layer = ABOVE_MOB_LAYER
+		if(EAST)
+			target_pixel_x = 16
+		if(WEST)
+			target_pixel_x = -16
+		if(NORTHEAST)
+			target_pixel_x = 16
+			target_pixel_y = 16
+		if(NORTHWEST)
+			target_pixel_x = -16
+			target_pixel_y = 16
+		if(SOUTHEAST)
+			target_pixel_x = 16
+			target_pixel_y = -16
+			layer = ABOVE_MOB_LAYER
+		if(SOUTHWEST)
+			target_pixel_x = -16
+			target_pixel_y = -16
+			layer = ABOVE_MOB_LAYER
+	animate(src, pixel_x = target_pixel_x, pixel_y = target_pixel_y, alpha = 0, time = duration)
+
+/obj/effect/temp_visual/dir_setting/bloodsplatter/xenosplatter
+	color = BLOOD_COLOR_XENO
+
+/obj/effect/temp_visual/dir_setting/speedbike_trail
+	name = "speedbike trails"
+	icon_state = "ion_fade"
+	layer = BELOW_MOB_LAYER
+	duration = 10
+	randomdir = 0
+
+/obj/effect/temp_visual/dir_setting/firing_effect
+	icon = 'icons/effects/effects.dmi'
+	icon_state = "firing_effect"
+	duration = 2
+
+/obj/effect/temp_visual/dir_setting/firing_effect/setDir(newdir)
+	switch(newdir)
+		if(NORTH)
+			layer = BELOW_MOB_LAYER
+			pixel_x = rand(-3,3)
+			pixel_y = rand(4,6)
+		if(SOUTH)
+			pixel_x = rand(-3,3)
+			pixel_y = rand(-1,1)
+		else
+			pixel_x = rand(-1,1)
+			pixel_y = rand(-1,1)
+	..()
+
+/obj/effect/temp_visual/dir_setting/firing_effect/energy
+	icon_state = "firing_effect_energy"
+	duration = 3
+
+/obj/effect/temp_visual/dir_setting/firing_effect/magic
+	icon_state = "shieldsparkles"
+	duration = 3
+
+/obj/effect/temp_visual/dir_setting/ninja
+	name = "ninja shadow"
+	icon = 'icons/mob/mob.dmi'
+	icon_state = "uncloak"
+	duration = 9
+
+/obj/effect/temp_visual/dir_setting/ninja/cloak
+	icon_state = "cloak"
+
+/obj/effect/temp_visual/dir_setting/ninja/shadow
+	icon_state = "shadow"
+
+/obj/effect/temp_visual/dir_setting/ninja/phase
+	name = "ninja energy"
+	icon_state = "phasein"
+
+/obj/effect/temp_visual/dir_setting/ninja/phase/out
+	icon_state = "phaseout"
+
+/obj/effect/temp_visual/dir_setting/wraith
+	name = "blood"
+	icon = 'icons/mob/mob.dmi'
+	icon_state = "phase_shift2"
+	duration = 12
+
+/obj/effect/temp_visual/dir_setting/wraith/out
+	icon_state = "phase_shift"
+
+/obj/effect/temp_visual/dir_setting/tailsweep
+	icon_state = "tailsweep"
+	duration = 4
+
+/obj/effect/temp_visual/dir_setting/curse
+	icon_state = "curse"
+	duration = 32
+	var/fades = TRUE
+
+/obj/effect/temp_visual/dir_setting/curse/Initialize(mapload, set_dir)
+	. = ..()
+	if(fades)
+		animate(src, alpha = 0, time = 32)
+
+/obj/effect/temp_visual/dir_setting/curse/blob
+	icon_state = "curseblob"
+
+/obj/effect/temp_visual/dir_setting/curse/grasp_portal
+	icon = 'icons/effects/64x64.dmi'
+	layer = LARGE_MOB_LAYER
+	pixel_y = -16
+	pixel_x = -16
+	duration = 32
+	fades = FALSE
+
+/obj/effect/temp_visual/dir_setting/curse/grasp_portal/fading
+	duration = 32
+	fades = TRUE
+
+/obj/effect/temp_visual/dir_setting/curse/hand
+	icon_state = "cursehand"
+
+/obj/effect/temp_visual/dir_setting/curse/hand/Initialize(mapload, set_dir, handedness)
+	. = ..()
+	update_icon()
+
+/obj/item/projectile/curse_hand/update_icon()
+	icon_state = "[icon_state][handedness]"
+
+/obj/effect/temp_visual/wizard
+	name = "water"
+	icon = 'icons/mob/mob.dmi'
+	icon_state = "reappear"
+	duration = 5
+
+/obj/effect/temp_visual/wizard/out
+	icon_state = "liquify"
+	duration = 12
+
+/obj/effect/temp_visual/monkeyify
+	icon = 'icons/mob/mob.dmi'
+	icon_state = "h2monkey"
+	duration = 22
+
+/obj/effect/temp_visual/monkeyify/humanify
+	icon_state = "monkey2h"
+
+/obj/effect/temp_visual/borgflash
+	icon = 'icons/mob/mob.dmi'
+	icon_state = "blspell"
+	duration = 5
+
+/obj/effect/temp_visual/guardian
+	randomdir = 0
+
+/obj/effect/temp_visual/guardian/phase
+	duration = 5
+	icon_state = "phasein"
+
+/obj/effect/temp_visual/guardian/phase/out
+	icon_state = "phaseout"
+
+/obj/effect/temp_visual/decoy
+	desc = "It's a decoy!"
+	duration = 15
+
+/obj/effect/temp_visual/decoy/Initialize(mapload, atom/mimiced_atom)
+	. = ..()
+	alpha = initial(alpha)
+	if(mimiced_atom)
+		name = mimiced_atom.name
+		appearance = mimiced_atom.appearance
+		setDir(mimiced_atom.dir)
+		mouse_opacity = MOUSE_OPACITY_TRANSPARENT
+
+/obj/effect/temp_visual/decoy/fading/Initialize(mapload, atom/mimiced_atom)
+	. = ..()
+	animate(src, alpha = 0, time = duration)
+
+/obj/effect/temp_visual/decoy/fading/threesecond
+	duration = 40
+
+/obj/effect/temp_visual/decoy/fading/fivesecond
+	duration = 50
+
+/obj/effect/temp_visual/decoy/fading/halfsecond
+	duration = 5
+
+/obj/effect/temp_visual/small_smoke
+	icon_state = "smoke"
+	duration = 50
+
+/obj/effect/temp_visual/small_smoke/halfsecond
+	duration = 5
+
+/obj/effect/temp_visual/fire
+	icon = 'icons/effects/fire.dmi'
+	icon_state = "3"
+	light_range = LIGHT_RANGE_FIRE
+	light_color = LIGHT_COLOR_FIRE
+	duration = 10
+
+/obj/effect/temp_visual/revenant
+	name = "spooky lights"
+	icon_state = "purplesparkles"
+
+/obj/effect/temp_visual/revenant/cracks
+	name = "glowing cracks"
+	icon_state = "purplecrack"
+	duration = 6
+
+/obj/effect/temp_visual/gravpush
+	name = "gravity wave"
+	icon_state = "shieldsparkles"
+	duration = 5
+
+/obj/effect/temp_visual/telekinesis
+	name = "telekinetic force"
+	icon_state = "empdisable"
+	duration = 5
+
+/obj/effect/temp_visual/emp
+	name = "emp sparks"
+	icon_state = "empdisable"
+
+/obj/effect/temp_visual/emp/pulse
+	name = "emp pulse"
+	icon_state = "emppulse"
+	duration = 8
+	randomdir = 0
+
+/obj/effect/temp_visual/bluespace_fissure
+	name = "bluespace fissure"
+	icon_state = "bluestream_fade"
+	duration = 9
+
+/obj/effect/temp_visual/gib_animation
+	icon = 'icons/mob/mob.dmi'
+	duration = 15
+
+/obj/effect/temp_visual/gib_animation/Initialize(mapload, gib_icon)
+	icon_state = gib_icon // Needs to be before ..() so icon is correct
+	. = ..()
+
+/obj/effect/temp_visual/gib_animation/animal
+	icon = 'icons/mob/animal.dmi'
+
+/obj/effect/temp_visual/dust_animation
+	icon = 'icons/mob/mob.dmi'
+	duration = 15
+
+/obj/effect/temp_visual/dust_animation/Initialize(mapload, dust_icon)
+	icon_state = dust_icon // Before ..() so the correct icon is flick()'d
+	. = ..()
+
+/obj/effect/temp_visual/mummy_animation
+	icon = 'icons/mob/mob.dmi'
+	icon_state = "mummy_revive"
+	duration = 20
+
+/obj/effect/temp_visual/heal //color is white by default, set to whatever is needed
+	name = "healing glow"
+	icon_state = "heal"
+	duration = 15
+
+/obj/effect/temp_visual/heal/Initialize(mapload, set_color)
+	if(set_color)
+		add_atom_colour(set_color, FIXED_COLOUR_PRIORITY)
+	. = ..()
+	pixel_x = rand(-12, 12)
+	pixel_y = rand(-9, 0)
+
+/obj/effect/temp_visual/kinetic_blast
+	name = "kinetic explosion"
+	icon = 'icons/obj/projectiles.dmi'
+	icon_state = "kinetic_blast"
+	layer = ABOVE_ALL_MOB_LAYER
+	duration = 4
+
+/obj/effect/temp_visual/explosion
+	name = "explosion"
+	icon = 'icons/effects/96x96.dmi'
+	icon_state = "explosion"
+	pixel_x = -32
+	pixel_y = -32
+	duration = 8
+
+/obj/effect/temp_visual/explosion/fast
+	icon_state = "explosionfast"
+	duration = 4
+
+/obj/effect/temp_visual/blob
+	name = "blob"
+	icon_state = "blob_attack"
+	alpha = 140
+	randomdir = 0
+	duration = 6
+
+/obj/effect/temp_visual/impact_effect
+	icon_state = "impact_bullet"
+	duration = 5
+
+/obj/effect/temp_visual/impact_effect/Initialize(mapload, x, y)
+	pixel_x = x
+	pixel_y = y
+	return ..()
+
+/obj/effect/temp_visual/impact_effect/red_laser
+	icon_state = "impact_laser"
+	duration = 4
+
+/obj/effect/temp_visual/impact_effect/red_laser/wall
+	icon_state = "impact_laser_wall"
+	duration = 10
+
+/obj/effect/temp_visual/impact_effect/blue_laser
+	icon_state = "impact_laser_blue"
+	duration = 4
+
+/obj/effect/temp_visual/impact_effect/green_laser
+	icon_state = "impact_laser_green"
+	duration = 4
+
+/obj/effect/temp_visual/impact_effect/purple_laser
+	icon_state = "impact_laser_purple"
+	duration = 4
+
+/obj/effect/temp_visual/impact_effect/ion
+	icon_state = "shieldsparkles"
+	duration = 6
+
+/obj/effect/temp_visual/heart
+	name = "heart"
+	icon = 'icons/mob/animal.dmi'
+	icon_state = "heart"
+	duration = 25
+
+/obj/effect/temp_visual/heart/Initialize(mapload)
+	. = ..()
+	pixel_x = rand(-4,4)
+	pixel_y = rand(-4,4)
+	animate(src, pixel_y = pixel_y + 32, alpha = 0, time = 25)
+
+/obj/effect/temp_visual/love_heart
+	name = "love heart"
+	icon = 'icons/effects/effects.dmi'
+	icon_state = "heart"
+	duration = 25
+
+/obj/effect/temp_visual/love_heart/Initialize(mapload)
+	. = ..()
+	pixel_x = rand(-10,10)
+	pixel_y = rand(-10,10)
+	animate(src, pixel_y = pixel_y + 32, alpha = 0, time = duration)
+
+/obj/effect/temp_visual/love_heart/invisible
+	icon_state = null
+
+/obj/effect/temp_visual/love_heart/invisible/Initialize(mapload, mob/seer)
+	. = ..()
+	var/image/I = image(icon = 'icons/effects/effects.dmi', icon_state = "heart", layer = ABOVE_MOB_LAYER, loc = src)
+	add_alt_appearance(/datum/atom_hud/alternate_appearance/basic/onePerson, "heart", I, seer)
+	I.alpha = 255
+	I.appearance_flags = RESET_ALPHA
+	animate(I, alpha = 0, time = duration)
+
+/obj/effect/temp_visual/bleed
+	name = "bleed"
+	icon = 'icons/effects/bleed.dmi'
+	icon_state = "bleed0"
+	duration = 10
+	var/shrink = TRUE
+
+/obj/effect/temp_visual/bleed/Initialize(mapload, atom/size_calc_target)
+	. = ..()
+	var/size_matrix = matrix()
+	if(size_calc_target)
+		layer = size_calc_target.layer + 0.01
+		var/icon/I = icon(size_calc_target.icon, size_calc_target.icon_state, size_calc_target.dir)
+		size_matrix = matrix() * (I.Height()/world.icon_size)
+		transform = size_matrix //scale the bleed overlay's size based on the target's icon size
+	var/matrix/M = transform
+	if(shrink)
+		M = size_matrix*0.1
+	else
+		M = size_matrix*2
+	animate(src, alpha = 20, transform = M, time = duration, flags = ANIMATION_PARALLEL)
+
+/obj/effect/temp_visual/bleed/explode
+	icon_state = "bleed10"
+	duration = 12
+	shrink = FALSE
+
+/obj/effect/temp_visual/warp_cube
+	duration = 5
+	var/outgoing = TRUE
+
+/obj/effect/temp_visual/warp_cube/Initialize(mapload, atom/teleporting_atom, warp_color, new_outgoing)
+	. = ..()
+	if(teleporting_atom)
+		outgoing = new_outgoing
+		appearance = teleporting_atom.appearance
+		setDir(teleporting_atom.dir)
+		if(warp_color)
+			color = list(warp_color, warp_color, warp_color, list(0,0,0))
+			set_light(1.4, 1, warp_color)
+		mouse_opacity = MOUSE_OPACITY_TRANSPARENT
+		var/matrix/skew = transform
+		skew = skew.Turn(180)
+		skew = skew.Interpolate(transform, 0.5)
+		if(!outgoing)
+			transform = skew * 2
+			skew = teleporting_atom.transform
+			alpha = 0
+			animate(src, alpha = teleporting_atom.alpha, transform = skew, time = duration)
+		else
+			skew *= 2
+			animate(src, alpha = 0, transform = skew, time = duration)
+	else
+		return INITIALIZE_HINT_QDEL