Revert "PLASE"

This reverts commit 8af225e6e3.
2019-11-24 03:06:08 +00:00
parent aeb8606ce0
commit ba4fa1ef67
2145 changed files with 1387321 additions and 5257 deletions
@@ -0,0 +1,384 @@
+/obj/item/melee/transforming/energy
+	hitsound_on = 'sound/weapons/blade1.ogg'
+	heat = 3500
+	max_integrity = 200
+	armor = list("melee" = 0, "bullet" = 0, "laser" = 0, "energy" = 0, "bomb" = 0, "bio" = 0, "rad" = 0, "fire" = 100, "acid" = 30)
+	resistance_flags = FIRE_PROOF
+	var/brightness_on = 3
+	total_mass = 0.4 //Survival flashlights typically weigh around 5 ounces.
+
+
+/obj/item/melee/transforming/energy/Initialize()
+	. = ..()
+	total_mass_on = (total_mass_on ? total_mass_on : (w_class_on * 0.75))
+	if(active)
+		set_light(brightness_on)
+		START_PROCESSING(SSobj, src)
+
+/obj/item/melee/transforming/energy/Destroy()
+	STOP_PROCESSING(SSobj, src)
+	return ..()
+
+/obj/item/melee/transforming/energy/suicide_act(mob/user)
+	if(!active)
+		transform_weapon(user, TRUE)
+	user.visible_message("<span class='suicide'>[user] is [pick("slitting [user.p_their()] stomach open with", "falling on")] [src]! It looks like [user.p_theyre()] trying to commit seppuku!</span>")
+	return (BRUTELOSS|FIRELOSS)
+
+/obj/item/melee/transforming/energy/add_blood_DNA(list/blood_dna)
+	return FALSE
+
+/obj/item/melee/transforming/energy/get_sharpness()
+	return active * sharpness
+
+/obj/item/melee/transforming/energy/process()
+	open_flame()
+
+/obj/item/melee/transforming/energy/transform_weapon(mob/living/user, supress_message_text)
+	. = ..()
+	if(.)
+		if(active)
+			if(item_color)
+				icon_state = "sword[item_color]"
+			START_PROCESSING(SSobj, src)
+			set_light(brightness_on)
+		else
+			STOP_PROCESSING(SSobj, src)
+			set_light(0)
+
+/obj/item/melee/transforming/energy/get_temperature()
+	return active * heat
+
+/obj/item/melee/transforming/energy/ignition_effect(atom/A, mob/user)
+	if(!active)
+		return ""
+
+	var/in_mouth = ""
+	if(iscarbon(user))
+		var/mob/living/carbon/C = user
+		if(C.wear_mask)
+			in_mouth = ", barely missing [C.p_their()] nose"
+	. = "<span class='warning'>[user] swings [user.p_their()] [name][in_mouth]. [user.p_they(TRUE)] light[user.p_s()] [user.p_their()] [A.name] in the process.</span>"
+	playsound(loc, hitsound, get_clamped_volume(), 1, -1)
+	add_fingerprint(user)
+
+/obj/item/melee/transforming/energy/axe
+	name = "energy axe"
+	desc = "An energized battle axe."
+	icon_state = "axe0"
+	lefthand_file = 'icons/mob/inhands/weapons/axes_lefthand.dmi'
+	righthand_file = 'icons/mob/inhands/weapons/axes_righthand.dmi'
+	force = 40
+	force_on = 150
+	throwforce = 25
+	throwforce_on = 30
+	hitsound = 'sound/weapons/bladeslice.ogg'
+	throw_speed = 3
+	throw_range = 5
+	w_class = WEIGHT_CLASS_NORMAL
+	w_class_on = WEIGHT_CLASS_HUGE
+	flags_1 = CONDUCT_1
+	armour_penetration = 100
+	attack_verb_off = list("attacked", "chopped", "cleaved", "torn", "cut")
+	attack_verb_on = list()
+	light_color = "#40ceff"
+	total_mass = null
+
+/obj/item/melee/transforming/energy/axe/suicide_act(mob/user)
+	user.visible_message("<span class='suicide'>[user] swings [src] towards [user.p_their()] head! It looks like [user.p_theyre()] trying to commit suicide!</span>")
+	return (BRUTELOSS|FIRELOSS)
+
+/obj/item/melee/transforming/energy/sword
+	name = "energy sword"
+	desc = "May the force be within you."
+	icon_state = "sword0"
+	lefthand_file = 'icons/mob/inhands/weapons/swords_lefthand.dmi'
+	righthand_file = 'icons/mob/inhands/weapons/swords_righthand.dmi'
+	force = 3
+	throwforce = 5
+	hitsound = "swing_hit" //it starts deactivated
+	attack_verb_off = list("tapped", "poked")
+	throw_speed = 3
+	throw_range = 5
+	sharpness = IS_SHARP
+	embedding = list("embed_chance" = 75, "embedded_impact_pain_multiplier" = 10)
+	armour_penetration = 35
+	block_chance = 50
+
+/obj/item/melee/transforming/energy/sword/transform_weapon(mob/living/user, supress_message_text)
+	. = ..()
+	if(. && active && item_color)
+		icon_state = "sword[item_color]"
+
+/obj/item/melee/transforming/energy/sword/hit_reaction(mob/living/carbon/human/owner, atom/movable/hitby, attack_text = "the attack", final_block_chance = 0, damage = 0, attack_type = MELEE_ATTACK)
+	if(active)
+		return ..()
+	return 0
+
+/obj/item/melee/transforming/energy/sword/cyborg
+	item_color = "red"
+	var/hitcost = 50
+
+/obj/item/melee/transforming/energy/sword/cyborg/attack(mob/M, var/mob/living/silicon/robot/R)
+	if(R.cell)
+		var/obj/item/stock_parts/cell/C = R.cell
+		if(active && !(C.use(hitcost)))
+			attack_self(R)
+			to_chat(R, "<span class='notice'>It's out of charge!</span>")
+			return
+		return ..()
+
+/obj/item/melee/transforming/energy/sword/cyborg/saw //Used by medical Syndicate cyborgs
+	name = "energy saw"
+	desc = "For heavy duty cutting. It has a carbon-fiber blade in addition to a toggleable hard-light edge to dramatically increase sharpness."
+	force_on = 30
+	force = 18 //About as much as a spear
+	hitsound = 'sound/weapons/circsawhit.ogg'
+	icon = 'icons/obj/surgery.dmi'
+	icon_state = "esaw_0"
+	icon_state_on = "esaw_1"
+	item_color = null //stops icon from breaking when turned on.
+	hitcost = 75 //Costs more than a standard cyborg esword
+	w_class = WEIGHT_CLASS_NORMAL
+	sharpness = IS_SHARP
+	light_color = "#40ceff"
+	tool_behaviour = TOOL_SAW
+	toolspeed = 0.7
+
+/obj/item/melee/transforming/energy/sword/cyborg/saw/hit_reaction(mob/living/carbon/human/owner, atom/movable/hitby, attack_text = "the attack", final_block_chance = 0, damage = 0, attack_type = MELEE_ATTACK)
+	return 0
+
+/obj/item/melee/transforming/energy/sword/saber
+	var/list/possible_colors = list("red" = LIGHT_COLOR_RED, "blue" = LIGHT_COLOR_LIGHT_CYAN, "green" = LIGHT_COLOR_GREEN, "purple" = LIGHT_COLOR_LAVENDER)
+	var/hacked = FALSE
+
+/obj/item/melee/transforming/energy/sword/saber/Initialize(mapload)
+	. = ..()
+	if(LAZYLEN(possible_colors))
+		var/set_color = pick(possible_colors)
+		item_color = set_color
+		light_color = possible_colors[set_color]
+
+/obj/item/melee/transforming/energy/sword/saber/process()
+	. = ..()
+	if(hacked)
+		var/set_color = pick(possible_colors)
+		light_color = possible_colors[set_color]
+		update_light()
+
+/obj/item/melee/transforming/energy/sword/saber/red
+	possible_colors = list("red" = LIGHT_COLOR_RED)
+
+/obj/item/melee/transforming/energy/sword/saber/blue
+	possible_colors = list("blue" = LIGHT_COLOR_LIGHT_CYAN)
+
+/obj/item/melee/transforming/energy/sword/saber/green
+	possible_colors = list("green" = LIGHT_COLOR_GREEN)
+
+/obj/item/melee/transforming/energy/sword/saber/purple
+	possible_colors = list("purple" = LIGHT_COLOR_LAVENDER)
+
+/obj/item/melee/transforming/energy/sword/saber/attackby(obj/item/W, mob/living/user, params)
+	if(istype(W, /obj/item/multitool))
+		if(!hacked)
+			hacked = TRUE
+			item_color = "rainbow"
+			to_chat(user, "<span class='warning'>RNBW_ENGAGE</span>")
+
+			if(active)
+				icon_state = "swordrainbow"
+				user.update_inv_hands()
+		else
+			to_chat(user, "<span class='warning'>It's already fabulous!</span>")
+	else
+		return ..()
+
+/obj/item/melee/transforming/energy/sword/pirate
+	name = "energy cutlass"
+	desc = "Arrrr matey."
+	icon_state = "cutlass0"
+	lefthand_file = 'icons/mob/inhands/weapons/swords_lefthand.dmi'
+	righthand_file = 'icons/mob/inhands/weapons/swords_righthand.dmi'
+	icon_state_on = "cutlass1"
+	light_color = "#ff0000"
+
+/obj/item/melee/transforming/energy/blade
+	name = "energy blade"
+	desc = "A concentrated beam of energy in the shape of a blade. Very stylish... and lethal."
+	icon_state = "blade"
+	lefthand_file = 'icons/mob/inhands/weapons/swords_lefthand.dmi'
+	righthand_file = 'icons/mob/inhands/weapons/swords_righthand.dmi'
+	force = 30 //Normal attacks deal esword damage
+	hitsound = 'sound/weapons/blade1.ogg'
+	active = 1
+	throwforce = 1 //Throwing or dropping the item deletes it.
+	throw_speed = 3
+	throw_range = 1
+	w_class = WEIGHT_CLASS_BULKY//So you can't hide it in your pocket or some such.
+	var/datum/effect_system/spark_spread/spark_system
+	sharpness = IS_SHARP
+
+//Most of the other special functions are handled in their own files. aka special snowflake code so kewl
+/obj/item/melee/transforming/energy/blade/Initialize()
+	. = ..()
+	spark_system = new /datum/effect_system/spark_spread()
+	spark_system.set_up(5, 0, src)
+	spark_system.attach(src)
+
+/obj/item/melee/transforming/energy/blade/transform_weapon(mob/living/user, supress_message_text)
+	return
+
+/obj/item/melee/transforming/energy/blade/hardlight
+	name = "hardlight blade"
+	desc = "An extremely sharp blade made out of hard light. Packs quite a punch."
+	icon_state = "lightblade"
+	item_state = "lightblade"
+
+/*/////////////////////////////////////////////////////////////////////////
+/////////////		The TRUE Energy Sword		///////////////////////////
+*//////////////////////////////////////////////////////////////////////////
+
+/obj/item/melee/transforming/energy/sword/cx
+	name = "non-eutactic blade"
+	desc = "The Non-Eutactic Blade utilizes a hardlight blade that is dynamically 'forged' on demand to create a deadly sharp edge that is unbreakable."
+	icon_state = "cxsword_hilt"
+	item_state = "cxsword"
+	force = 3
+	force_on = 21
+	throwforce = 5
+	throwforce_on = 20
+	hitsound = "swing_hit" //it starts deactivated
+	hitsound_on = 'sound/weapons/nebhit.ogg'
+	attack_verb_off = list("tapped", "poked")
+	throw_speed = 3
+	throw_range = 5
+	sharpness = IS_SHARP
+	embedding = list("embedded_pain_multiplier" = 6, "embed_chance" = 20, "embedded_fall_chance" = 60)
+	armour_penetration = 10
+	block_chance = 35
+	light_color = "#37FFF7"
+	actions_types = list()
+
+/obj/item/melee/transforming/energy/sword/cx/pre_altattackby(atom/A, mob/living/user, params)	//checks if it can do right click memes
+	altafterattack(A, user, TRUE, params)
+	return TRUE
+
+/obj/item/melee/transforming/energy/sword/cx/altafterattack(atom/target, mob/living/carbon/user, proximity_flag, click_parameters)	//does right click memes
+	if(istype(user))
+		user.visible_message("<span class='notice'>[user] points the tip of [src] at [target].</span>", "<span class='notice'>You point the tip of [src] at [target].</span>")
+	return TRUE
+
+/obj/item/melee/transforming/energy/sword/cx/transform_weapon(mob/living/user, supress_message_text)
+	active = !active				//I'd use a ..() here but it'd inherit from the regular esword's proc instead, so SPAGHETTI CODE
+	if(active)						//also I'd need to rip out the iconstate changing bits
+		force = force_on
+		throwforce = throwforce_on
+		hitsound = hitsound_on
+		throw_speed = 4
+		if(attack_verb_on.len)
+			attack_verb = attack_verb_on
+		w_class = w_class_on
+		START_PROCESSING(SSobj, src)
+		set_light(brightness_on)
+		update_icon()
+	else
+		force = initial(force)
+		throwforce = initial(throwforce)
+		hitsound = initial(hitsound)
+		throw_speed = initial(throw_speed)
+		if(attack_verb_off.len)
+			attack_verb = attack_verb_off
+		w_class = initial(w_class)
+		STOP_PROCESSING(SSobj, src)
+		set_light(0)
+		update_icon()
+	transform_messages(user, supress_message_text)
+	add_fingerprint(user)
+	return TRUE
+
+/obj/item/melee/transforming/energy/sword/cx/transform_messages(mob/living/user, supress_message_text)
+	playsound(user, active ? 'sound/weapons/nebon.ogg' : 'sound/weapons/neboff.ogg', 65, 1)
+	if(!supress_message_text)
+		to_chat(user, "<span class='notice'>[src] [active ? "is now active":"can now be concealed"].</span>")
+
+/obj/item/melee/transforming/energy/sword/cx/update_icon()
+	var/mutable_appearance/blade_overlay = mutable_appearance(icon, "cxsword_blade")
+	var/mutable_appearance/gem_overlay = mutable_appearance(icon, "cxsword_gem")
+
+	if(light_color)
+		blade_overlay.color = light_color
+		gem_overlay.color = light_color
+
+	cut_overlays()		//So that it doesn't keep stacking overlays non-stop on top of each other
+
+	add_overlay(gem_overlay)
+
+	if(active)
+		add_overlay(blade_overlay)
+	if(ismob(loc))
+		var/mob/M = loc
+		M.update_inv_hands()
+
+/obj/item/melee/transforming/energy/sword/cx/AltClick(mob/living/user)
+	if(!in_range(src, user))	//Basic checks to prevent abuse
+		return
+	if(user.incapacitated() || !istype(user))
+		to_chat(user, "<span class='warning'>You can't do that right now!</span>")
+		return
+
+	if(alert("Are you sure you want to recolor your blade?", "Confirm Repaint", "Yes", "No") == "Yes")
+		var/energy_color_input = input(usr,"","Choose Energy Color",light_color) as color|null
+		if(energy_color_input)
+			light_color = sanitize_hexcolor(energy_color_input, desired_format=6, include_crunch=1)
+		update_icon()
+		update_light()
+
+/obj/item/melee/transforming/energy/sword/cx/examine(mob/user)
+	..()
+	to_chat(user, "<span class='notice'>Alt-click to recolor it.</span>")
+
+/obj/item/melee/transforming/energy/sword/cx/worn_overlays(isinhands, icon_file)
+	. = ..()
+	if(active)
+		if(isinhands)
+			var/mutable_appearance/blade_inhand = mutable_appearance(icon_file, "cxsword_blade")
+			blade_inhand.color = light_color
+			. += blade_inhand
+
+//Broken version. Not a toy, but not as strong.
+/obj/item/melee/transforming/energy/sword/cx/broken
+	name = "misaligned non-eutactic blade"
+	desc = "The Non-Eutactic Blade utilizes a hardlight blade that is dynamically 'forged' on demand to create a deadly sharp edge that is unbreakable. This one seems to have a damaged handle and misaligned components, causing the blade to be unstable at best"
+	force_on = 15 //As strong a survival knife/bone dagger
+
+/obj/item/melee/transforming/energy/sword/cx/attackby(obj/item/W, mob/living/user, params)
+	if(istype(W, /obj/item/melee/transforming/energy/sword/cx))
+		if(HAS_TRAIT(W, TRAIT_NODROP) || HAS_TRAIT(src, TRAIT_NODROP))
+			to_chat(user, "<span class='warning'>\the [HAS_TRAIT(src, TRAIT_NODROP) ? src : W] is stuck to your hand, you can't attach it to \the [HAS_TRAIT(src, TRAIT_NODROP) ? W : src]!</span>")
+			return
+		else
+			to_chat(user, "<span class='notice'>You combine the two light swords, making a single supermassive blade! You're cool.</span>")
+			new /obj/item/twohanded/dualsaber/hypereutactic(user.drop_location())
+			qdel(W)
+			qdel(src)
+	else
+		return ..()
+
+////////		Tatortot NEB		/////////////// (same stats as regular esword)
+/obj/item/melee/transforming/energy/sword/cx/traitor
+	name = "\improper Dragon's Tooth Sword"
+	desc = "The Dragon's Tooth sword is a blackmarket modification of a Non-Eutactic Blade, \
+			which utilizes a hardlight blade that is dynamically 'forged' on demand to create a deadly sharp edge that is unbreakable. \
+			It appears to have a wooden grip and a shaved down guard."
+	icon_state = "cxsword_hilt_traitor"
+	force_on = 30
+	armour_penetration = 50
+	embedding = list("embedded_pain_multiplier" = 10, "embed_chance" = 75, "embedded_fall_chance" = 0, "embedded_impact_pain_multiplier" = 10)
+	block_chance = 50
+	hitsound_on = 'sound/weapons/blade1.ogg'
+	light_color = "#37F0FF"
+
+/obj/item/melee/transforming/energy/sword/cx/traitor/transform_messages(mob/living/user, supress_message_text)
+	playsound(user, active ? 'sound/weapons/saberon.ogg' : 'sound/weapons/saberoff.ogg', 35, 1)
+	if(!supress_message_text)
+		to_chat(user, "<span class='notice'>[src] [active ? "is now active":"can now be concealed"].</span>")
@@ -0,0 +1,507 @@
+/obj/item/melee
+	item_flags = NEEDS_PERMIT
+
+/obj/item/melee/proc/check_martial_counter(mob/living/carbon/human/target, mob/living/carbon/human/user)
+	if(target.check_block())
+		target.visible_message("<span class='danger'>[target.name] blocks [src] and twists [user]'s arm behind [user.p_their()] back!</span>",
+					"<span class='userdanger'>You block the attack!</span>")
+		user.Stun(40)
+		return TRUE
+
+
+/obj/item/melee/chainofcommand
+	name = "chain of command"
+	desc = "A tool used by great men to placate the frothing masses."
+	icon_state = "chain"
+	item_state = "chain"
+	lefthand_file = 'icons/mob/inhands/weapons/melee_lefthand.dmi'
+	righthand_file = 'icons/mob/inhands/weapons/melee_righthand.dmi'
+	flags_1 = CONDUCT_1
+	slot_flags = ITEM_SLOT_BELT
+	force = 14
+	throwforce = 10
+	reach = 2
+	w_class = WEIGHT_CLASS_NORMAL
+	attack_verb = list("flogged", "whipped", "lashed", "disciplined")
+	hitsound = 'sound/weapons/chainhit.ogg'
+	materials = list(MAT_METAL = 1000)
+
+/obj/item/melee/chainofcommand/suicide_act(mob/user)
+	user.visible_message("<span class='suicide'>[user] is strangling [user.p_them()]self with [src]! It looks like [user.p_theyre()] trying to commit suicide!</span>")
+	return (OXYLOSS)
+
+/obj/item/melee/synthetic_arm_blade
+	name = "synthetic arm blade"
+	desc = "A grotesque blade that on closer inspection seems made of synthetic flesh, it still feels like it would hurt very badly as a weapon."
+	icon = 'icons/obj/items_and_weapons.dmi'
+	icon_state = "arm_blade"
+	item_state = "arm_blade"
+	lefthand_file = 'icons/mob/inhands/antag/changeling_lefthand.dmi'
+	righthand_file = 'icons/mob/inhands/antag/changeling_righthand.dmi'
+	w_class = WEIGHT_CLASS_HUGE
+	force = 20
+	throwforce = 10
+	hitsound = 'sound/weapons/bladeslice.ogg'
+	attack_verb = list("attacked", "impaled", "stabbed", "sliced", "torn", "ripped", "diced", "cut")
+	sharpness = IS_SHARP
+	total_mass = TOTAL_MASS_HAND_REPLACEMENT
+
+/obj/item/melee/synthetic_arm_blade/Initialize()
+	. = ..()
+	AddComponent(/datum/component/butchering, 60, 80) //very imprecise
+
+/obj/item/melee/sabre
+	name = "officer's sabre"
+	desc = "An elegant weapon, its monomolecular edge is capable of cutting through flesh and bone with ease."
+	icon_state = "sabre"
+	item_state = "sabre"
+	lefthand_file = 'icons/mob/inhands/weapons/swords_lefthand.dmi'
+	righthand_file = 'icons/mob/inhands/weapons/swords_righthand.dmi'
+	flags_1 = CONDUCT_1
+	obj_flags = UNIQUE_RENAME
+	force = 18
+	throwforce = 15
+	w_class = WEIGHT_CLASS_BULKY
+	block_chance = 50
+	armour_penetration = 75
+	sharpness = IS_SHARP
+	attack_verb = list("slashed", "cut")
+	hitsound = 'sound/weapons/rapierhit.ogg'
+	materials = list(MAT_METAL = 1000)
+	total_mass = 3.4
+
+/obj/item/melee/sabre/Initialize()
+	. = ..()
+	AddComponent(/datum/component/butchering, 30, 95, 5) //fast and effective, but as a sword, it might damage the results.
+
+/obj/item/melee/sabre/hit_reaction(mob/living/carbon/human/owner, atom/movable/hitby, attack_text = "the attack", final_block_chance = 0, damage = 0, attack_type = MELEE_ATTACK)
+	if(attack_type == PROJECTILE_ATTACK)
+		final_block_chance = 0 //Don't bring a sword to a gunfight
+	return ..()
+
+/obj/item/melee/sabre/on_exit_storage(obj/item/storage/S)
+	..()
+	var/obj/item/storage/belt/sabre/B = S
+	if(istype(B))
+		playsound(B, 'sound/items/unsheath.ogg', 25, 1)
+
+/obj/item/melee/sabre/on_enter_storage(obj/item/storage/S)
+	..()
+	var/obj/item/storage/belt/sabre/B = S
+	if(istype(B))
+		playsound(B, 'sound/items/sheath.ogg', 25, 1)
+
+/obj/item/melee/sabre/get_belt_overlay()
+	return mutable_appearance('icons/obj/clothing/belt_overlays.dmi', "sabre")
+
+/obj/item/melee/sabre/get_worn_belt_overlay(icon_file)
+	return mutable_appearance(icon_file, "-sabre")
+
+/obj/item/melee/sabre/suicide_act(mob/living/user)
+	user.visible_message("<span class='suicide'>[user] is trying to cut off all [user.p_their()] limbs with [src]! it looks like [user.p_theyre()] trying to commit suicide!</span>")
+	var/i = 0
+	ADD_TRAIT(src, TRAIT_NODROP, SABRE_SUICIDE_TRAIT)
+	if(iscarbon(user))
+		var/mob/living/carbon/Cuser = user
+		var/obj/item/bodypart/holding_bodypart = Cuser.get_holding_bodypart_of_item(src)
+		var/list/limbs_to_dismember
+		var/list/arms = list()
+		var/list/legs = list()
+		var/obj/item/bodypart/bodypart
+
+		for(bodypart in Cuser.bodyparts)
+			if(bodypart == holding_bodypart)
+				continue
+			if(bodypart.body_part & ARMS)
+				arms += bodypart
+			else if (bodypart.body_part & LEGS)
+				legs += bodypart
+
+		limbs_to_dismember = arms + legs
+		if(holding_bodypart)
+			limbs_to_dismember += holding_bodypart
+
+		var/speedbase = abs((4 SECONDS) / limbs_to_dismember.len)
+		for(bodypart in limbs_to_dismember)
+			i++
+			addtimer(CALLBACK(src, .proc/suicide_dismember, user, bodypart), speedbase * i)
+	addtimer(CALLBACK(src, .proc/manual_suicide, user), (5 SECONDS) * i)
+	return MANUAL_SUICIDE
+
+/obj/item/melee/sabre/proc/suicide_dismember(mob/living/user, obj/item/bodypart/affecting)
+	if(!QDELETED(affecting) && affecting.dismemberable && affecting.owner == user && !QDELETED(user))
+		playsound(user, hitsound, 25, 1)
+		affecting.dismember(BRUTE)
+		user.adjustBruteLoss(20)
+
+/obj/item/melee/sabre/proc/manual_suicide(mob/living/user, originally_nodropped)
+	if(!QDELETED(user))
+		user.adjustBruteLoss(200)
+		user.death(FALSE)
+	REMOVE_TRAIT(src, TRAIT_NODROP, SABRE_SUICIDE_TRAIT)
+
+/obj/item/melee/rapier
+	name = "plastitanium rapier"
+	desc = "A impossibly thin blade made of plastitanium with a tip made of diamond. It looks to be able to cut through any armor."
+	icon = 'icons/obj/items_and_weapons.dmi'
+	icon_state = "rapier"
+	item_state = "rapier"
+	lefthand_file = 'icons/mob/inhands/weapons/swords_lefthand.dmi'
+	righthand_file = 'icons/mob/inhands/weapons/swords_righthand.dmi'
+	force = 25
+	throwforce = 35
+	block_chance = 0
+	armour_penetration = 100
+	flags_1 = CONDUCT_1
+	obj_flags = UNIQUE_RENAME
+	w_class = WEIGHT_CLASS_BULKY
+	sharpness = IS_SHARP_ACCURATE //It cant be sharpend cook -_-
+	attack_verb = list("slashed", "cut", "pierces", "pokes")
+	total_mass = 3.4
+
+/obj/item/melee/rapier/Initialize()
+	. = ..()
+	AddComponent(/datum/component/butchering, 20, 65, 0)
+
+/obj/item/melee/rapier/get_belt_overlay()
+	return mutable_appearance('icons/obj/clothing/belt_overlays.dmi', "rapier")
+
+/obj/item/melee/rapier/get_worn_belt_overlay(icon_file)
+	return mutable_appearance(icon_file, "-rapier")
+
+/obj/item/melee/classic_baton
+	name = "police baton"
+	desc = "A wooden truncheon for beating criminal scum."
+	icon = 'icons/obj/items_and_weapons.dmi'
+	icon_state = "baton"
+	item_state = "classic_baton"
+	lefthand_file = 'icons/mob/inhands/equipment/security_lefthand.dmi'
+	righthand_file = 'icons/mob/inhands/equipment/security_righthand.dmi'
+	slot_flags = ITEM_SLOT_BELT
+	force = 12 //9 hit crit
+	w_class = WEIGHT_CLASS_NORMAL
+	var/cooldown = 13
+	var/on = TRUE
+	var/last_hit = 0
+	var/stun_stam_cost_coeff = 1.25
+	var/hardstun_ds = 1
+	var/softstun_ds = 0
+	var/stam_dmg = 30
+
+/obj/item/melee/classic_baton/attack(mob/living/target, mob/living/user)
+	if(!on)
+		return ..()
+
+	if(user.getStaminaLoss() >= STAMINA_SOFTCRIT)//CIT CHANGE - makes batons unusuable in stamina softcrit
+		to_chat(user, "<span class='warning'>You're too exhausted for that.</span>")//CIT CHANGE - ditto
+		return //CIT CHANGE - ditto
+
+	add_fingerprint(user)
+	if((HAS_TRAIT(user, TRAIT_CLUMSY)) && prob(50))
+		to_chat(user, "<span class ='danger'>You club yourself over the head.</span>")
+		user.Knockdown(60 * force)
+		if(ishuman(user))
+			var/mob/living/carbon/human/H = user
+			H.apply_damage(2*force, BRUTE, BODY_ZONE_HEAD)
+		else
+			user.take_bodypart_damage(2*force)
+		return
+	if(iscyborg(target))
+		..()
+		return
+	if(!isliving(target))
+		return
+	if (user.a_intent == INTENT_HARM)
+		if(!..() || !iscyborg(target))
+			return
+	else
+		if(last_hit < world.time)
+			if(ishuman(target))
+				var/mob/living/carbon/human/H = target
+				if (H.check_shields(src, 0, "[user]'s [name]", MELEE_ATTACK))
+					return
+				if(check_martial_counter(H, user))
+					return
+			playsound(get_turf(src), 'sound/effects/woodhit.ogg', 75, 1, -1)
+			target.Knockdown(softstun_ds, TRUE, FALSE, hardstun_ds, stam_dmg)
+			log_combat(user, target, "stunned", src)
+			src.add_fingerprint(user)
+			target.visible_message("<span class ='danger'>[user] has knocked down [target] with [src]!</span>", \
+				"<span class ='userdanger'>[user] has knocked down [target] with [src]!</span>")
+			if(!iscarbon(user))
+				target.LAssailant = null
+			else
+				target.LAssailant = user
+			last_hit = world.time + cooldown
+			user.adjustStaminaLossBuffered(getweight())//CIT CHANGE - makes swinging batons cost stamina
+
+/obj/item/melee/classic_baton/telescopic
+	name = "telescopic baton"
+	desc = "A compact yet robust personal defense weapon. Can be concealed when folded."
+	icon = 'icons/obj/items_and_weapons.dmi'
+	icon_state = "telebaton_0"
+	lefthand_file = 'icons/mob/inhands/weapons/melee_lefthand.dmi'
+	righthand_file = 'icons/mob/inhands/weapons/melee_righthand.dmi'
+	item_state = null
+	slot_flags = ITEM_SLOT_BELT
+	w_class = WEIGHT_CLASS_SMALL
+	item_flags = NONE
+	force = 0
+	on = FALSE
+	total_mass = TOTAL_MASS_NORMAL_ITEM
+
+/obj/item/melee/classic_baton/telescopic/suicide_act(mob/user)
+	var/mob/living/carbon/human/H = user
+	var/obj/item/organ/brain/B = H.getorgan(/obj/item/organ/brain)
+
+	user.visible_message("<span class='suicide'>[user] stuffs [src] up [user.p_their()] nose and presses the 'extend' button! It looks like [user.p_theyre()] trying to clear [user.p_their()] mind.</span>")
+	if(!on)
+		src.attack_self(user)
+	else
+		playsound(loc, 'sound/weapons/batonextend.ogg', 50, 1)
+		add_fingerprint(user)
+	sleep(3)
+	if (H && !QDELETED(H))
+		if (B && !QDELETED(B))
+			H.internal_organs -= B
+			qdel(B)
+		H.spawn_gibs()
+		return (BRUTELOSS)
+
+/obj/item/melee/classic_baton/telescopic/attack_self(mob/user)
+	on = !on
+	if(on)
+		to_chat(user, "<span class ='warning'>You extend the baton.</span>")
+		icon_state = "telebaton_1"
+		item_state = "nullrod"
+		w_class = WEIGHT_CLASS_BULKY //doesnt fit in backpack when its on for balance
+		force = 10 //stunbaton damage
+		attack_verb = list("smacked", "struck", "cracked", "beaten")
+	else
+		to_chat(user, "<span class ='notice'>You collapse the baton.</span>")
+		icon_state = "telebaton_0"
+		item_state = null //no sprite for concealment even when in hand
+		slot_flags = ITEM_SLOT_BELT
+		w_class = WEIGHT_CLASS_SMALL
+		force = 0 //not so robust now
+		attack_verb = list("hit", "poked")
+
+	playsound(src.loc, 'sound/weapons/batonextend.ogg', 50, 1)
+	add_fingerprint(user)
+
+/obj/item/melee/supermatter_sword
+	name = "supermatter sword"
+	desc = "In a station full of bad ideas, this might just be the worst."
+	icon = 'icons/obj/items_and_weapons.dmi'
+	icon_state = "supermatter_sword"
+	item_state = "supermatter_sword"
+	lefthand_file = 'icons/mob/inhands/weapons/swords_lefthand.dmi'
+	righthand_file = 'icons/mob/inhands/weapons/swords_righthand.dmi'
+	slot_flags = null
+	w_class = WEIGHT_CLASS_BULKY
+	force = 0.001
+	armour_penetration = 1000
+	var/obj/machinery/power/supermatter_crystal/shard
+	var/balanced = 1
+	force_string = "INFINITE"
+
+/obj/item/melee/supermatter_sword/Initialize()
+	. = ..()
+	shard = new /obj/machinery/power/supermatter_crystal(src)
+	qdel(shard.countdown)
+	shard.countdown = null
+	START_PROCESSING(SSobj, src)
+	visible_message("<span class='warning'>[src] appears, balanced ever so perfectly on its hilt. This isn't ominous at all.</span>")
+
+/obj/item/melee/supermatter_sword/process()
+	if(balanced || throwing || ismob(src.loc) || isnull(src.loc))
+		return
+	if(!isturf(src.loc))
+		var/atom/target = src.loc
+		forceMove(target.loc)
+		consume_everything(target)
+	else
+		var/turf/T = get_turf(src)
+		if(!isspaceturf(T))
+			shard.consume_turf(T)
+
+/obj/item/melee/supermatter_sword/afterattack(target, mob/user, proximity_flag)
+	. = ..()
+	if(user && target == user)
+		user.dropItemToGround(src)
+	if(proximity_flag)
+		consume_everything(target)
+
+/obj/item/melee/supermatter_sword/throw_impact(target)
+	..()
+	if(ismob(target))
+		var/mob/M
+		if(src.loc == M)
+			M.dropItemToGround(src)
+	consume_everything(target)
+
+/obj/item/melee/supermatter_sword/pickup(user)
+	..()
+	balanced = 0
+
+/obj/item/melee/supermatter_sword/ex_act(severity, target)
+	visible_message("<span class='danger'>The blast wave smacks into [src] and rapidly flashes to ash.</span>",\
+	"<span class='italics'>You hear a loud crack as you are washed with a wave of heat.</span>")
+	consume_everything()
+
+/obj/item/melee/supermatter_sword/acid_act()
+	visible_message("<span class='danger'>The acid smacks into [src] and rapidly flashes to ash.</span>",\
+	"<span class='italics'>You hear a loud crack as you are washed with a wave of heat.</span>")
+	consume_everything()
+
+/obj/item/melee/supermatter_sword/bullet_act(obj/item/projectile/P)
+	visible_message("<span class='danger'>[P] smacks into [src] and rapidly flashes to ash.</span>",\
+	"<span class='italics'>You hear a loud crack as you are washed with a wave of heat.</span>")
+	consume_everything()
+
+/obj/item/melee/supermatter_sword/suicide_act(mob/user)
+	user.visible_message("<span class='suicide'>[user] touches [src]'s blade. It looks like [user.p_theyre()] tired of waiting for the radiation to kill [user.p_them()]!</span>")
+	user.dropItemToGround(src, TRUE)
+	shard.Bumped(user)
+
+/obj/item/melee/supermatter_sword/proc/consume_everything(target)
+	if(isnull(target))
+		shard.Consume()
+	else if(!isturf(target))
+		shard.Bumped(target)
+	else
+		shard.consume_turf(target)
+
+/obj/item/melee/supermatter_sword/add_blood_DNA(list/blood_dna)
+	return FALSE
+
+/obj/item/melee/curator_whip
+	name = "curator's whip"
+	desc = "Somewhat eccentric and outdated, it still stings like hell to be hit by."
+	icon_state = "whip"
+	item_state = "chain"
+	lefthand_file = 'icons/mob/inhands/weapons/melee_lefthand.dmi'
+	righthand_file = 'icons/mob/inhands/weapons/melee_righthand.dmi'
+	slot_flags = ITEM_SLOT_BELT
+	force = 15
+	w_class = WEIGHT_CLASS_NORMAL
+	attack_verb = list("flogged", "whipped", "lashed", "disciplined")
+	hitsound = 'sound/weapons/whip.ogg'
+
+/obj/item/melee/curator_whip/afterattack(target, mob/user, proximity_flag)
+	. = ..()
+	if(ishuman(target) && proximity_flag)
+		var/mob/living/carbon/human/H = target
+		H.drop_all_held_items()
+		H.visible_message("<span class='danger'>[user] disarms [H]!</span>", "<span class='userdanger'>[user] disarmed you!</span>")
+
+/obj/item/melee/roastingstick
+	name = "advanced roasting stick"
+	desc = "A telescopic roasting stick with a miniature shield generator designed to ensure entry into various high-tech shielded cooking ovens and firepits."
+	icon_state = "roastingstick_0"
+	item_state = "null"
+	slot_flags = ITEM_SLOT_BELT
+	w_class = WEIGHT_CLASS_SMALL
+	item_flags = NONE
+	force = 0
+	attack_verb = list("hit", "poked")
+	var/obj/item/reagent_containers/food/snacks/sausage/held_sausage
+	var/static/list/ovens
+	var/on = FALSE
+	var/datum/beam/beam
+	total_mass = 2.5
+
+/obj/item/melee/roastingstick/Initialize()
+	. = ..()
+	if (!ovens)
+		ovens = typecacheof(list(/obj/singularity, /obj/machinery/power/supermatter_crystal, /obj/structure/bonfire, /obj/structure/destructible/clockwork/massive/ratvar))
+
+/obj/item/melee/roastingstick/attack_self(mob/user)
+	on = !on
+	if(on)
+		extend(user)
+	else
+		if (held_sausage)
+			to_chat(user, "<span class='warning'>You can't retract [src] while [held_sausage] is attached!</span>")
+			return
+		retract(user)
+
+	playsound(src.loc, 'sound/weapons/batonextend.ogg', 50, 1)
+	add_fingerprint(user)
+
+/obj/item/melee/roastingstick/attackby(atom/target, mob/user)
+	..()
+	if (istype(target, /obj/item/reagent_containers/food/snacks/sausage))
+		if (!on)
+			to_chat(user, "<span class='warning'>You must extend [src] to attach anything to it!</span>")
+			return
+		if (held_sausage)
+			to_chat(user, "<span class='warning'>[held_sausage] is already attached to [src]!</span>")
+			return
+		if (user.transferItemToLoc(target, src))
+			held_sausage = target
+		else
+			to_chat(user, "<span class='warning'>[target] doesn't seem to want to get on [src]!</span>")
+	update_icon()
+
+/obj/item/melee/roastingstick/attack_hand(mob/user)
+	..()
+	if (held_sausage)
+		user.put_in_hands(held_sausage)
+		held_sausage = null
+	update_icon()
+
+/obj/item/melee/roastingstick/update_icon()
+	. = ..()
+	cut_overlays()
+	if (held_sausage)
+		var/mutable_appearance/sausage = mutable_appearance(icon, "roastingstick_sausage")
+		add_overlay(sausage)
+
+/obj/item/melee/roastingstick/proc/extend(user)
+	to_chat(user, "<span class ='warning'>You extend [src].</span>")
+	icon_state = "roastingstick_1"
+	item_state = "nullrod"
+	w_class = WEIGHT_CLASS_BULKY
+
+/obj/item/melee/roastingstick/proc/retract(user)
+	to_chat(user, "<span class ='notice'>You collapse [src].</span>")
+	icon_state = "roastingstick_0"
+	item_state = null
+	w_class = WEIGHT_CLASS_SMALL
+
+/obj/item/melee/roastingstick/handle_atom_del(atom/target)
+	if (target == held_sausage)
+		held_sausage = null
+		update_icon()
+
+/obj/item/melee/roastingstick/afterattack(atom/target, mob/user, proximity)
+	. = ..()
+	if (!on)
+		return
+	if (is_type_in_typecache(target, ovens))
+		if (held_sausage && held_sausage.roasted)
+			to_chat("Your [held_sausage] has already been cooked.")
+			return
+		if (istype(target, /obj/singularity) && get_dist(user, target) < 10)
+			to_chat(user, "You send [held_sausage] towards [target].")
+			playsound(src, 'sound/items/rped.ogg', 50, 1)
+			beam = user.Beam(target,icon_state="rped_upgrade",time=100)
+		else if (user.Adjacent(target))
+			to_chat(user, "You extend [src] towards [target].")
+			playsound(src.loc, 'sound/weapons/batonextend.ogg', 50, 1)
+		else
+			return
+		if(do_after(user, 100, target = user))
+			finish_roasting(user, target)
+		else
+			QDEL_NULL(beam)
+			playsound(src, 'sound/weapons/batonextend.ogg', 50, 1)
+
+/obj/item/melee/roastingstick/proc/finish_roasting(user, atom/target)
+	to_chat(user, "You finish roasting [held_sausage]")
+	playsound(src,'sound/items/welder2.ogg',50,1)
+	held_sausage.add_atom_colour(rgb(103,63,24), FIXED_COLOUR_PRIORITY)
+	held_sausage.name = "[target.name]-roasted [held_sausage.name]"
+	held_sausage.desc = "[held_sausage.desc] It has been cooked to perfection on \a [target]."
+	update_icon()
@@ -0,0 +1,90 @@
+/obj/item/melee/transforming
+	sharpness = IS_SHARP
+	var/active = FALSE
+	var/force_on = 30 //force when active
+	var/faction_bonus_force = 0 //Bonus force dealt against certain factions
+	var/throwforce_on = 20
+	var/icon_state_on = "axe1"
+	var/hitsound_on = 'sound/weapons/blade1.ogg'
+	var/list/attack_verb_on = list("attacked", "slashed", "stabbed", "sliced", "torn", "ripped", "diced", "cut")
+	var/list/attack_verb_off = list("attacked", "slashed", "stabbed", "sliced", "torn", "ripped", "diced", "cut")
+	w_class = WEIGHT_CLASS_SMALL
+	var/bonus_active = FALSE //If the faction damage bonus is active
+	var/list/nemesis_factions //Any mob with a faction that exists in this list will take bonus damage/effects
+	var/w_class_on = WEIGHT_CLASS_BULKY
+	var/clumsy_check = TRUE
+	var/total_mass_on //Total mass in ounces when transformed. Primarily for balance purposes. Don't think about it too hard.
+
+/obj/item/melee/transforming/Initialize()
+	. = ..()
+	if(active)
+		if(attack_verb_on.len)
+			attack_verb = attack_verb_on
+	else
+		if(attack_verb_off.len)
+			attack_verb = attack_verb_off
+	if(get_sharpness())
+		AddComponent(/datum/component/butchering, 50, 100, 0, hitsound, !active)
+
+/obj/item/melee/transforming/attack_self(mob/living/carbon/user)
+	if(transform_weapon(user))
+		clumsy_transform_effect(user)
+
+/obj/item/melee/transforming/attack(mob/living/target, mob/living/carbon/human/user)
+	var/nemesis_faction = FALSE
+	if(LAZYLEN(nemesis_factions))
+		for(var/F in target.faction)
+			if(F in nemesis_factions)
+				nemesis_faction = TRUE
+				force += faction_bonus_force
+				nemesis_effects(user, target)
+				break
+	. = ..()
+	if(nemesis_faction)
+		force -= faction_bonus_force
+
+/obj/item/melee/transforming/proc/transform_weapon(mob/living/user, supress_message_text)
+	active = !active
+	if(active)
+		force = force_on
+		total_mass = total_mass_on
+		throwforce = throwforce_on
+		hitsound = hitsound_on
+		throw_speed = 4
+		if(attack_verb_on.len)
+			attack_verb = attack_verb_on
+		icon_state = icon_state_on
+		w_class = w_class_on
+	else
+		force = initial(force)
+		throwforce = initial(throwforce)
+		hitsound = initial(hitsound)
+		throw_speed = initial(throw_speed)
+		if(attack_verb_off.len)
+			attack_verb = attack_verb_off
+		icon_state = initial(icon_state)
+		w_class = initial(w_class)
+		total_mass = initial(total_mass)
+	if(get_sharpness())
+		var/datum/component/butchering/BT = LoadComponent(/datum/component/butchering)
+		BT.butchering_enabled = TRUE
+	else
+		var/datum/component/butchering/BT = GetComponent(/datum/component/butchering)
+		if(BT)
+			BT.butchering_enabled = FALSE
+	transform_messages(user, supress_message_text)
+	add_fingerprint(user)
+	return TRUE
+
+/obj/item/melee/transforming/proc/nemesis_effects(mob/living/user, mob/living/target)
+	return
+
+/obj/item/melee/transforming/proc/transform_messages(mob/living/user, supress_message_text)
+	playsound(user, active ? 'sound/weapons/saberon.ogg' : 'sound/weapons/saberoff.ogg', 35, 1)  //changed it from 50% volume to 35% because deafness
+	if(!supress_message_text)
+		to_chat(user, "<span class='notice'>[src] [active ? "is now active":"can now be concealed"].</span>")
+
+/obj/item/melee/transforming/proc/clumsy_transform_effect(mob/living/user)
+	if(clumsy_check && HAS_TRAIT(user, TRAIT_CLUMSY) && prob(50))
+		to_chat(user, "<span class='warning'>You accidentally cut yourself with [src], like a doofus!</span>")
+		user.take_bodypart_damage(5,5)