Merge pull request #9626 from Ghommie/Ghommie-cit278

Unmodularize space kiwis and banana spiders.

code/modules/hydroponics/grown/banana.dm

@@ -11,7 +11,7 @@
 	growing_icon = 'icons/obj/hydroponics/growing_fruits.dmi'
 	icon_dead = "banana-dead"
 	genes = list(/datum/plant_gene/trait/slip, /datum/plant_gene/trait/repeated_harvest)
-	mutatelist = list(/obj/item/seeds/banana/mime, /obj/item/seeds/banana/bluespace)
+	mutatelist = list(/obj/item/seeds/banana/mime, /obj/item/seeds/banana/bluespace, /obj/item/seeds/banana/exotic_banana)
 	reagents_add = list("banana" = 0.1, "potassium" = 0.1, "vitamin" = 0.04, "nutriment" = 0.02)
 
 /obj/item/reagent_containers/food/snacks/grown/banana
@@ -120,6 +120,41 @@
 	desc = "A peel from a bluespace banana."
 	icon_state = "banana_peel_blue"
 
+//Banana Spider.
+/obj/item/seeds/banana/exotic_banana
+	name = "pack of exotic banana seeds"
+	desc = "They're seeds that grow into banana trees. However, those bananas might be alive."
+	icon_state = "seed_exoticbanana"
+	species = "exoticbanana"
+	icon_grow = "banana-grow"
+	plantname = "Exotic Banana Tree"
+	product = /obj/item/reagent_containers/food/snacks/grown/banana/banana_spider_spawnable
+	mutatelist = list()
+	genes = list(/datum/plant_gene/trait/slip)
+
+/obj/item/reagent_containers/food/snacks/grown/banana/banana_spider_spawnable
+	seed = /obj/item/seeds/banana/exotic_banana
+	name = "banana spider"
+	desc = "You do not know what it is, but you can bet the clown would love it."
+	icon_state = "exoticbanana"
+	list_reagents = list("nutriment" = 3, "vitamin" = 2)
+	foodtype = GROSS | MEAT | RAW | FRUIT
+	grind_results = list("blood" = 20, "liquidgibs" = 5)
+	var/awakening = 0
+
+/obj/item/reagent_containers/food/snacks/grown/banana/banana_spider_spawnable/attack_self(mob/user)
+	if(awakening || isspaceturf(user.loc))
+		return
+	to_chat(user, "<span class='notice'>You decide to wake up the banana spider...</span>")
+	awakening = 1
+
+	spawn(30)
+		if(!QDELETED(src))
+			var/mob/living/simple_animal/banana_spider/S = new /mob/living/simple_animal/banana_spider(get_turf(src.loc))
+			S.speed += round(10 / seed.potency)
+			S.visible_message("<span class='notice'>The banana spider chitters as it stretches its legs.</span>")
+			qdel(src)
+
 // Other
 /obj/item/grown/bananapeel/specialpeel     //used by /obj/item/clothing/shoes/clown_shoes/banana_shoes
 	name = "synthesized banana peel"

code/modules/mob/living/simple_animal/friendly/farm_animals.dm

@@ -323,6 +323,132 @@
 	else
 		STOP_PROCESSING(SSobj, src)
 
+// Space kiwis, ergo quite a copypasta of chickens.
+
+/mob/living/simple_animal/kiwi
+	name = "space kiwi"
+	desc = "Exposure to low gravity made them grow larger."
+	gender = FEMALE
+	icon_state = "kiwi"
+	icon_living = "kiwi"
+	icon_dead = "kiwi_dead"
+	speak = list("Chirp!","Cheep cheep chirp!!","Cheep.")
+	speak_emote = list("chirps","trills")
+	emote_hear = list("chirps.")
+	emote_see = list("pecks at the ground.","jumps in place.")
+	density = FALSE
+	speak_chance = 2
+	turns_per_move = 3
+	butcher_results = list(/obj/item/reagent_containers/food/snacks/meat/slab = 3)
+	var/egg_type = /obj/item/reagent_containers/food/snacks/egg/kiwiEgg
+	var/food_type = /obj/item/reagent_containers/food/snacks/grown/wheat
+	response_help  = "pets"
+	response_disarm = "gently pushes aside"
+	response_harm   = "kicks"
+	attacktext = "kicks"
+	health = 25
+	maxHealth = 25
+	ventcrawler = VENTCRAWLER_ALWAYS
+	var/eggsleft = 0
+	var/eggsFertile = TRUE
+	pass_flags = PASSTABLE | PASSMOB
+	mob_size = MOB_SIZE_SMALL
+	var/list/feedMessages = list("It chirps happily.","It chirps happily.")
+	var/list/layMessage = list("lays an egg.","squats down and croons.","begins making a huge racket.","begins chirping raucously.")
+	gold_core_spawnable = FRIENDLY_SPAWN
+	var/static/kiwi_count = 0
+
+/mob/living/simple_animal/kiwi/Destroy()
+	--kiwi_count
+	return ..()
+
+/mob/living/simple_animal/kiwi/Initialize()
+	. = ..()
+	++kiwi_count
+
+/mob/living/simple_animal/kiwi/Life()
+	. =..()
+	if(!.)
+		return
+	if((!stat && prob(3) && eggsleft > 0) && egg_type)
+		visible_message("[src] [pick(layMessage)]")
+		eggsleft--
+		var/obj/item/E = new egg_type(get_turf(src))
+		E.pixel_x = rand(-6,6)
+		E.pixel_y = rand(-6,6)
+		if(eggsFertile)
+			if(kiwi_count < MAX_CHICKENS && prob(25))
+				START_PROCESSING(SSobj, E)
+
+/obj/item/reagent_containers/food/snacks/egg/kiwiEgg/process()
+	if(isturf(loc))
+		amount_grown += rand(1,2)
+		if(amount_grown >= 100)
+			visible_message("[src] hatches with a quiet cracking sound.")
+			new /mob/living/simple_animal/babyKiwi(get_turf(src))
+			STOP_PROCESSING(SSobj, src)
+			qdel(src)
+	else
+		STOP_PROCESSING(SSobj, src)
+
+/mob/living/simple_animal/kiwi/attackby(obj/item/O, mob/user, params)
+	if(istype(O, food_type)) //feedin' dem kiwis
+		if(!stat && eggsleft < 8)
+			var/feedmsg = "[user] feeds [O] to [name]! [pick(feedMessages)]"
+			user.visible_message(feedmsg)
+			qdel(O)
+			eggsleft += rand(1, 4)
+		else
+			to_chat(user, "<span class='warning'>[name] doesn't seem hungry!</span>")
+	else
+		..()
+
+/mob/living/simple_animal/babyKiwi
+	name = "baby space kiwi"
+	desc = "So huggable."
+	icon_state = "babykiwi"
+	icon_living = "babykiwi"
+	icon_dead = "babykiwi_dead"
+	gender = FEMALE
+	speak = list("Cherp.","Cherp?","Chirrup.","Cheep!")
+	speak_emote = list("chirps")
+	emote_hear = list("chirps.")
+	emote_see = list("pecks at the ground.","Happily bounces in place.")
+	density = FALSE
+	speak_chance = 2
+	turns_per_move = 2
+	butcher_results = list(/obj/item/reagent_containers/food/snacks/meat/slab = 2)
+	response_help  = "pets"
+	response_disarm = "gently pushes aside"
+	response_harm   = "kicks"
+	attacktext = "kicks"
+	health = 10
+	maxHealth = 10
+	ventcrawler = VENTCRAWLER_ALWAYS
+	var/amount_grown = 0
+	pass_flags = PASSTABLE | PASSGRILLE | PASSMOB
+	mob_size = MOB_SIZE_TINY
+	gold_core_spawnable = FRIENDLY_SPAWN
+
+/mob/living/simple_animal/babyKiwi/Initialize()
+	. = ..()
+	pixel_x = rand(-6, 6)
+	pixel_y = rand(0, 10)
+
+/mob/living/simple_animal/babyKiwi/Life()
+	. =..()
+	if(!.)
+		return
+	if(!stat && !ckey)
+		amount_grown += rand(1,2)
+		if(amount_grown >= 100)
+			new /mob/living/simple_animal/kiwi(src.loc)
+			qdel(src)
+
+/obj/item/reagent_containers/food/snacks/egg/kiwiEgg
+	name = "kiwi egg"
+	desc = "A slightly bigger egg!"
+	icon_state = "kiwiegg"
 
 /obj/item/udder
 	name = "udder"

code/modules/mob/living/simple_animal/hostile/banana_spider.dm

@@ -0,0 +1,100 @@
+/mob/living/simple_animal/banana_spider
+	name = "banana spider"
+	desc = "What the fuck is this abomination?"
+	icon_state = "bananaspider"
+	icon_dead = "bananaspider_peel"
+	health = 1
+	maxHealth = 1
+	turns_per_move = 5			//this isn't player speed =|
+	speed = 2				//this is player speed
+	loot = list(/obj/item/reagent_containers/food/snacks/deadbanana_spider)
+	atmos_requirements = list("min_oxy" = 0, "max_oxy" = 0, "min_tox" = 0, "max_tox" = 0, "min_co2" = 0, "max_co2" = 0, "min_n2" = 0, "max_n2" = 0)
+	minbodytemp = 270
+	maxbodytemp = INFINITY
+	pass_flags = PASSTABLE | PASSGRILLE | PASSMOB
+	mob_size = MOB_SIZE_TINY
+	response_help  = "pokes"
+	response_disarm = "shoos"
+	response_harm   = "splats"
+	speak_emote = list("chitters")
+	mouse_opacity = 2
+	density = TRUE
+	ventcrawler = VENTCRAWLER_ALWAYS
+	gold_core_spawnable = FRIENDLY_SPAWN
+	verb_say = "chitters"
+	verb_ask = "chitters inquisitively"
+	verb_exclaim = "chitters loudly"
+	verb_yell = "chitters loudly"
+	var/squish_chance = 50
+	var/projectile_density = TRUE		//griffons get shot
+	del_on_death = TRUE
+
+/mob/living/simple_animal/banana_spider/Initialize()
+	. = ..()
+	var/area/A = get_area(src)
+	if(A)
+		notify_ghosts("A banana spider has been created in \the [A.name].", source = src, action=NOTIFY_ATTACK, flashwindow = FALSE)
+
+/mob/living/simple_animal/banana_spider/attack_ghost(mob/user)
+	if(key)			//please stop using src. without a good reason.
+		return
+	if(CONFIG_GET(flag/use_age_restriction_for_jobs))
+		if(!isnum(user.client.player_age))
+			return
+	if(!SSticker.mode)
+		to_chat(user, "Can't become a banana spider before the game has started.")
+		return
+	var/be_spider = alert("Become a banana spider? (Warning, You can no longer be cloned!)",,"Yes","No")
+	if(be_spider == "No" || QDELETED(src) || !isobserver(user))
+		return
+	sentience_act()
+	user.transfer_ckey(src, FALSE)
+	density = TRUE
+
+/mob/living/simple_animal/banana_spider/ComponentInitialize()
+	. = ..()
+	AddComponent(/datum/component/slippery, 40)
+
+/mob/living/simple_animal/banana_spider/Crossed(atom/movable/AM)		//no /var in proc headers
+	. = ..()
+	if(istype(AM, /obj/item/projectile) && projectile_density)		//forced projectile density
+		var/obj/item/projectile/P = AM
+		P.Bump(src)
+	if(ismob(AM))
+		if(isliving(AM))
+			var/mob/living/A = AM
+			if(A.mob_size > MOB_SIZE_SMALL && !(A.movement_type & FLYING))
+				if(prob(squish_chance))
+					A.visible_message("<span class='notice'>[A] squashed [src].</span>", "<span class='notice'>You squashed [src] under your weight as you fell.</span>")
+					adjustBruteLoss(1)
+				else
+					visible_message("<span class='notice'>[src] avoids getting crushed.</span>")
+	else
+		if(isstructure(AM))
+			if(prob(squish_chance))
+				AM.visible_message("<span class='notice'>[src] was crushed under [AM]'s weight as they fell.</span>")
+				adjustBruteLoss(1)
+			else
+				visible_message("<span class='notice'>[src] avoids getting crushed.</span>")
+
+/mob/living/simple_animal/banana_spider/ex_act()
+	return
+
+/mob/living/simple_animal/banana_spider/start_pulling()
+	return FALSE			//No.
+
+/obj/item/reagent_containers/food/snacks/deadbanana_spider
+	name = "dead banana spider"
+	desc = "Thank god it's gone...but it does look slippery."
+	icon_state = "bananaspider"
+	bitesize = 3
+	eatverb = "devours"
+	list_reagents = list("nutriment" = 3, "vitamin" = 2)
+	foodtype = GROSS | MEAT | RAW
+	grind_results = list("blood" = 20, "liquidgibs" = 5)
+	juice_results = list("banana" = 0)
+
+
+/obj/item/reagent_containers/food/snacks/deadbanana_spider/Initialize()
+	. = ..()
+	AddComponent(/datum/component/slippery, 20)