Ports elements: Lightweight shared/global components.

code/datums/elements/_element.dm

@@ -0,0 +1,29 @@
+/datum/element
+	var/element_flags = NONE
+
+/datum/element/proc/Attach(datum/target)
+	if(type == /datum/element)
+		return ELEMENT_INCOMPATIBLE
+	if(element_flags & ELEMENT_DETACH)
+		RegisterSignal(target, COMSIG_PARENT_QDELETING, .proc/Detach)
+
+/datum/element/proc/Detach(datum/source, force)
+	UnregisterSignal(source, COMSIG_PARENT_QDELETING)
+
+/datum/element/Destroy(force)
+	if(!force)
+		return QDEL_HINT_LETMELIVE
+	SSdcs.elements_by_type -= type
+	return ..()
+
+//DATUM PROCS
+
+/datum/proc/AddElement(eletype, ...)
+	var/datum/element/ele = SSdcs.GetElement(eletype)
+	args[1] = src
+	if(ele.Attach(arglist(args)) == ELEMENT_INCOMPATIBLE)
+		CRASH("Incompatible [eletype] assigned to a [type]! args: [json_encode(args)]")
+
+/datum/proc/RemoveElement(eletype)
+	var/datum/element/ele = SSdcs.GetElement(eletype)
+	ele.Detach(src)

code/datums/elements/cleaning.dm

@@ -0,0 +1,48 @@
+/datum/element/cleaning/Attach(datum/target)
+	. = ..()
+	if(!ismovableatom(target))
+		return ELEMENT_INCOMPATIBLE
+	RegisterSignal(target, COMSIG_MOVABLE_MOVED, .proc/Clean)
+
+/datum/element/cleaning/Detach(datum/target)
+	. = ..()
+	UnregisterSignal(target, COMSIG_MOVABLE_MOVED)
+
+/datum/element/cleaning/proc/Clean(datum/source)
+	var/atom/movable/AM = source
+	var/turf/T = AM.loc
+	SEND_SIGNAL(T, COMSIG_COMPONENT_CLEAN_ACT, CLEAN_WEAK)
+	for(var/A in T)
+		if(is_cleanable(A))
+			qdel(A)
+		else if(isitem(A))
+			var/obj/item/cleaned_item = A
+			SEND_SIGNAL(cleaned_item, COMSIG_COMPONENT_CLEAN_ACT, CLEAN_WEAK)
+			cleaned_item.clean_blood()
+			if(ismob(cleaned_item.loc))
+				var/mob/M = cleaned_item.loc
+				M.regenerate_icons()
+		else if(ishuman(A))
+			var/mob/living/carbon/human/cleaned_human = A
+			if(cleaned_human.lying)
+				if(cleaned_human.head)
+					SEND_SIGNAL(cleaned_human.head, COMSIG_COMPONENT_CLEAN_ACT, CLEAN_WEAK)
+					cleaned_human.head.clean_blood()
+					cleaned_human.update_inv_head()
+				if(cleaned_human.wear_suit)
+					SEND_SIGNAL(cleaned_human.wear_suit, COMSIG_COMPONENT_CLEAN_ACT, CLEAN_WEAK)
+					cleaned_human.wear_suit.clean_blood()
+					cleaned_human.update_inv_wear_suit()
+				else if(cleaned_human.w_uniform)
+					SEND_SIGNAL(cleaned_human.w_uniform, COMSIG_COMPONENT_CLEAN_ACT, CLEAN_WEAK)
+					cleaned_human.w_uniform.clean_blood()
+					cleaned_human.update_inv_w_uniform()
+				if(cleaned_human.shoes)
+					SEND_SIGNAL(cleaned_human.shoes, COMSIG_COMPONENT_CLEAN_ACT, CLEAN_WEAK)
+					cleaned_human.shoes.clean_blood()
+					cleaned_human.update_inv_shoes()
+				SEND_SIGNAL(cleaned_human, COMSIG_COMPONENT_CLEAN_ACT, CLEAN_WEAK)
+				cleaned_human.clean_blood()
+				cleaned_human.wash_cream()
+				cleaned_human.regenerate_icons()
+				to_chat(cleaned_human, "<span class='danger'>[src] cleans your face!</span>")

code/datums/elements/earhealing.dm

@@ -0,0 +1,37 @@
+
+/datum/element/earhealing
+	element_flags = ELEMENT_DETACH
+	var/list/user_by_item = list()
+
+/datum/element/earhealing/New()
+	START_PROCESSING(SSdcs, src)
+
+/datum/element/earhealing/Attach(datum/target)
+	. = ..()
+	if(!isitem(target))
+		return ELEMENT_INCOMPATIBLE
+
+	RegisterSignal(target, list(COMSIG_ITEM_EQUIPPED, COMSIG_ITEM_DROPPED), .proc/equippedChanged)
+
+/datum/element/earhealing/Detach(datum/target)
+	. = ..()
+	UnregisterSignal(target, list(COMSIG_ITEM_EQUIPPED, COMSIG_ITEM_DROPPED))
+	user_by_item -= target
+
+/datum/element/earhealing/proc/equippedChanged(datum/source, mob/living/carbon/user, slot)
+	if(slot == SLOT_EARS && istype(user))
+		user_by_item[source] = user
+	else
+		user_by_item -= source
+
+/datum/element/earhealing/process()
+	for(var/i in user_by_item)
+		var/mob/living/carbon/user = user_by_item[i]
+		if(HAS_TRAIT(user, TRAIT_DEAF))
+			continue
+		var/obj/item/organ/ears/ears = user.getorganslot(ORGAN_SLOT_EARS)
+		if(!ears)
+			continue
+		ears.deaf = max(ears.deaf - 0.25, (ears.damage < ears.maxHealth ? 0 : 1)) // Do not clear deafness if our ears are too damaged
+		ears.damage = max(ears.damage - 0.025, 0)
+		CHECK_TICK