Merge branch 'master' into abductor-update

code/datums/action.dm

@@ -245,6 +245,14 @@
 /datum/action/item_action/toggle_helmet_light
 	name = "Toggle Helmet Light"
 
+/datum/action/item_action/toggle_welding_screen
+	name = "Toggle Welding Screen"
+
+/datum/action/item_action/toggle_welding_screen/Trigger()
+	var/obj/item/clothing/head/hardhat/weldhat/H = target
+	if(istype(H))
+		H.toggle_welding_screen(owner)
+
 /datum/action/item_action/toggle_headphones
 	name = "Toggle Headphones"
 	desc = "UNTZ UNTZ UNTZ"

code/datums/components/bane.dm

@@ -0,0 +1,45 @@
+/datum/component/bane
+	dupe_mode = COMPONENT_DUPE_ALLOWED
+
+	var/mobtype
+	var/speciestype
+	var/damage_multiplier
+
+/datum/component/bane/Initialize(mobtype, damage_multiplier=1)
+	if(!isitem(parent))
+		return COMPONENT_INCOMPATIBLE
+
+	if(ispath(mobtype, /mob/living))
+		src.mobtype = mobtype
+	else if(ispath(mobtype, /datum/species))
+		speciestype = mobtype
+	else
+		return COMPONENT_INCOMPATIBLE
+
+	src.damage_multiplier = damage_multiplier
+
+/datum/component/bane/RegisterWithParent()
+	if(speciestype)
+		RegisterSignal(parent, COMSIG_ITEM_AFTERATTACK, .proc/speciesCheck)
+	else
+		RegisterSignal(parent, COMSIG_ITEM_AFTERATTACK, .proc/mobCheck)
+
+/datum/component/bane/UnregisterFromParent()
+	UnregisterSignal(parent, COMSIG_ITEM_AFTERATTACK)
+
+/datum/component/bane/proc/speciesCheck(obj/item/source, atom/target, mob/user, proximity_flag, click_parameters)
+	if(!is_species(target, speciestype))
+		return
+	activate(source, target, user)
+
+/datum/component/bane/proc/mobCheck(obj/item/source, atom/target, mob/user, proximity_flag, click_parameters)
+	if(!istype(target, mobtype))
+		return
+	activate(source, target, user)
+
+/datum/component/bane/proc/activate(obj/item/source, mob/living/target, mob/attacker)
+	if(attacker.a_intent != INTENT_HARM)
+		return
+
+	var/extra_damage = max(0, source.force * damage_multiplier)
+	target.apply_damage(extra_damage, source.damtype, attacker.zone_selected)

code/datums/components/fantasy/_fantasy.dm

@@ -0,0 +1,140 @@
+/datum/component/fantasy
+	dupe_mode = COMPONENT_DUPE_UNIQUE_PASSARGS
+
+	var/quality
+
+	var/canFail
+	var/announce
+
+	var/originalName
+	var/list/affixes
+	var/list/appliedComponents
+
+	var/static/list/affixListing
+
+/datum/component/fantasy/Initialize(quality, list/affixes = list(), canFail=FALSE, announce=FALSE)
+	if(!isitem(parent))
+		return COMPONENT_INCOMPATIBLE
+
+	src.quality = quality || randomQuality()
+	src.canFail = canFail
+	src.announce = announce
+
+	src.affixes = affixes
+	appliedComponents = list()
+	randomAffixes()
+
+/datum/component/fantasy/Destroy()
+	unmodify()
+	affixes = null
+	return ..()
+
+/datum/component/fantasy/RegisterWithParent()
+	var/obj/item/master = parent
+	originalName = master.name
+	modify()
+
+/datum/component/fantasy/UnregisterFromParent()
+	unmodify()
+
+/datum/component/fantasy/InheritComponent(datum/component/fantasy/newComp, original, list/arguments)
+	unmodify()
+	if(newComp)
+		quality += newComp.quality
+		canFail = newComp.canFail
+		announce = newComp.announce
+	else
+		arguments.len = 5 // This is done to replicate what happens when an arglist smaller than the necessary arguments is given
+		quality += arguments[1]
+		canFail = arguments[4] || canFail
+		announce = arguments[5] || announce
+	modify()
+
+/datum/component/fantasy/proc/randomQuality()
+	var/quality = pick(1;15, 2;14, 2;13, 2;12, 3;11, 3;10, 3;9, 4;8, 4;7, 4;6, 5;5, 5;4, 5;3, 6;2, 6;1, 6;0)
+	if(prob(50))
+		quality = -quality
+	return quality
+
+/datum/component/fantasy/proc/randomAffixes(force)
+	if(!affixListing)
+		affixListing = list()
+		for(var/T in subtypesof(/datum/fantasy_affix))
+			var/datum/fantasy_affix/affix = new T
+			affixListing[affix] = affix.weight
+
+	if(length(affixes))
+		if(!force)
+			return
+		affixes = list()
+
+	var/alignment
+	if(quality >= 0)
+		alignment |= AFFIX_GOOD
+	if(quality <= 0)
+		alignment |= AFFIX_EVIL
+
+	var/usedSlots = NONE
+	for(var/i in 1 to max(1, abs(quality))) // We want at least 1 affix applied
+		var/datum/fantasy_affix/affix = pickweight(affixListing)
+		if(affix.placement & usedSlots)
+			continue
+		if(!(affix.alignment & alignment))
+			continue
+		if(!affix.validate(src))
+			continue
+		affixes += affix
+		usedSlots |= affix.placement
+
+/datum/component/fantasy/proc/modify()
+	var/obj/item/master = parent
+
+	master.force = max(0, master.force + quality)
+	master.throwforce = max(0, master.throwforce + quality)
+	master.armor = master.armor?.modifyAllRatings(quality)
+
+	var/newName = originalName
+	for(var/i in affixes)
+		var/datum/fantasy_affix/affix = i
+		newName = affix.apply(src, newName)
+
+	if(quality != 0)
+		newName = "[newName] [quality > 0 ? "+" : ""][quality]"
+
+	if(canFail && prob((quality - 9)*10))
+		var/turf/place = get_turf(parent)
+		place.visible_message("<span class='danger'>[parent] <span class='blue'>violently glows blue</span> for a while, then evaporates.</span>")
+		master.burn()
+		return
+	else if(announce)
+		announce()
+
+	master.name = newName
+
+/datum/component/fantasy/proc/unmodify()
+	var/obj/item/master = parent
+
+	for(var/i in affixes)
+		var/datum/fantasy_affix/affix = i
+		affix.remove(src)
+	for(var/i in appliedComponents)
+		qdel(i)
+
+	master.force = max(0, master.force - quality)
+	master.throwforce = max(0, master.throwforce - quality)
+	master.armor = master.armor?.modifyAllRatings(-quality)
+
+	master.name = originalName
+
+/datum/component/fantasy/proc/announce()
+	var/turf/location = get_turf(parent)
+	var/span
+	var/effect_description
+	if(quality >= 0)
+		span = "<span class='notice'>"
+		effect_description = "<span class='heavy_brass'>shimmering golden glow</span>"
+	else
+		span = "<span class='danger'>"
+		effect_description = "<span class='bold'>mottled black glow</span>"
+
+	location.visible_message("[span][originalName] is covered by a [effect_description] and then transforms into [parent]!</span>")

code/datums/components/fantasy/affix.dm

@@ -0,0 +1,13 @@
+/datum/fantasy_affix
+	var/placement // A bitflag of "slots" this affix takes up, for example pre/suffix
+	var/alignment
+	var/weight = 10
+
+// For those occasional affixes which only make sense in certain circumstances
+/datum/fantasy_affix/proc/validate(datum/component/fantasy/comp)
+	return TRUE
+
+/datum/fantasy_affix/proc/apply(datum/component/fantasy/comp, newName)
+	return newName
+
+/datum/fantasy_affix/proc/remove(datum/component/fantasy/comp)

code/datums/components/fantasy/prefixes.dm

@@ -0,0 +1,68 @@
+/datum/fantasy_affix/cosmetic_prefixes
+	placement = AFFIX_PREFIX
+	alignment = AFFIX_GOOD | AFFIX_EVIL
+
+	var/list/goodPrefixes
+	var/list/badPrefixes
+
+/datum/fantasy_affix/cosmetic_prefixes/New()
+	goodPrefixes = list(
+		"greater",
+		"major",
+		"blessed",
+		"superior",
+		"empowered",
+		"honed",
+		"true",
+		"glorious",
+		"robust",
+		)
+	badPrefixes = list(
+		"lesser",
+		"minor",
+		"blighted",
+		"inferior",
+		"enfeebled",
+		"rusted",
+		"unsteady",
+		"tragic",
+		"gimped",
+		"cursed",
+		)
+
+	weight = (length(goodPrefixes) + length(badPrefixes)) * 10
+
+/datum/fantasy_affix/cosmetic_prefixes/apply(datum/component/fantasy/comp, newName)
+	if(comp.quality > 0 || (comp.quality == 0 && prob(50)))
+		return "[pick(goodPrefixes)] [newName]"
+	else
+		return "[pick(badPrefixes)] [newName]"
+
+/datum/fantasy_affix/tactical
+	placement = AFFIX_PREFIX
+	alignment = AFFIX_GOOD
+	weight = 1 // Very powerful, no one should have such power
+
+/datum/fantasy_affix/tactical/apply(datum/component/fantasy/comp, newName)
+	var/obj/item/master = comp.parent
+	comp.appliedComponents += master.AddComponent(/datum/component/tactical)
+	return "tactical [newName]"
+
+/datum/fantasy_affix/pyromantic
+	placement = AFFIX_PREFIX
+	alignment = AFFIX_GOOD
+
+/datum/fantasy_affix/pyromantic/apply(datum/component/fantasy/comp, newName)
+	var/obj/item/master = comp.parent
+	comp.appliedComponents += master.AddComponent(/datum/component/igniter, CLAMP(comp.quality, 1, 10))
+	return "pyromantic [newName]"
+
+/datum/fantasy_affix/vampiric
+	placement = AFFIX_PREFIX
+	alignment = AFFIX_GOOD
+	weight = 5
+
+/datum/fantasy_affix/vampiric/apply(datum/component/fantasy/comp, newName)
+	var/obj/item/master = comp.parent
+	comp.appliedComponents += master.AddComponent(/datum/component/lifesteal, comp.quality)
+	return "vampiric [newName]"

code/datums/components/fantasy/suffixes.dm

@@ -0,0 +1,170 @@
+/datum/fantasy_affix/cosmetic_suffixes
+	placement = AFFIX_SUFFIX
+	alignment = AFFIX_GOOD | AFFIX_EVIL
+
+	var/list/goodSuffixes
+	var/list/badSuffixes
+
+/datum/fantasy_affix/cosmetic_suffixes/New()
+	goodSuffixes = list(
+		"dexterity",
+		"constitution",
+		"intelligence",
+		"wisdom",
+		"charisma",
+		"the forest",
+		"the hills",
+		"the plains",
+		"the sea",
+		"the sun",
+		"the moon",
+		"the void",
+		"the world",
+		"many secrets",
+		"many tales",
+		"many colors",
+		"rending",
+		"sundering",
+		"the night",
+		"the day",
+		)
+	badSuffixes = list(
+		"draining",
+		"burden",
+		"discomfort",
+		"awkwardness",
+		"poor hygiene",
+		"timidity",
+		)
+
+	weight = (length(goodSuffixes) + length(badSuffixes)) * 10
+
+/datum/fantasy_affix/cosmetic_suffixes/apply(datum/component/fantasy/comp, newName)
+	if(comp.quality > 0 || (comp.quality == 0 && prob(50)))
+		return "[newName] of [pick(goodSuffixes)]"
+	else
+		return "[newName] of [pick(badSuffixes)]"
+
+//////////// Good suffixes
+/datum/fantasy_affix/bane
+	placement = AFFIX_SUFFIX
+	alignment = AFFIX_GOOD
+	weight = 20
+
+/datum/fantasy_affix/bane/apply(datum/component/fantasy/comp, newName)
+	. = ..()
+	// This is set up to be easy to add to these lists as I expect it will need modifications
+	var/static/list/possible_mobtypes
+	if(!possible_mobtypes)
+		// The base list of allowed mob/species types
+		possible_mobtypes = typecacheof(list(
+			/mob/living/simple_animal,
+			/mob/living/carbon,
+			/datum/species,
+			))
+		// Some particular types to disallow if they're too broad/abstract
+		possible_mobtypes -= list(
+			/mob/living/simple_animal/hostile,
+			)
+		// Some types to remove them and their subtypes
+		possible_mobtypes -= typecacheof(list(
+			/mob/living/carbon/human/species,
+			))
+
+	var/mob/picked_mobtype = pick(possible_mobtypes)
+	// This works even with the species picks since we're only accessing the name
+
+	var/obj/item/master = comp.parent
+	comp.appliedComponents += master.AddComponent(/datum/component/bane, picked_mobtype)
+	return "[newName] of [initial(picked_mobtype.name)] slaying"
+
+/datum/fantasy_affix/summoning
+	placement = AFFIX_SUFFIX
+	alignment = AFFIX_GOOD
+	weight = 5
+
+/datum/fantasy_affix/summoning/apply(datum/component/fantasy/comp, newName)
+	. = ..()
+	// This is set up to be easy to add to these lists as I expect it will need modifications
+	var/static/list/possible_mobtypes
+	if(!possible_mobtypes)
+		// The base list of allowed mob/species types
+		possible_mobtypes = typecacheof(list(
+			/mob/living/simple_animal,
+			/mob/living/carbon,
+			/datum/species,
+			))
+		// Some particular types to disallow if they're too broad/abstract
+		possible_mobtypes -= list(
+			/mob/living/simple_animal/hostile,
+			)
+		// Some types to remove them and their subtypes
+		possible_mobtypes -= typecacheof(list(
+			/mob/living/carbon/human/species,
+			/mob/living/simple_animal/hostile/megafauna,
+			))
+
+	var/mob/picked_mobtype = pick(possible_mobtypes)
+	// This works even with the species picks since we're only accessing the name
+
+	var/obj/item/master = comp.parent
+	var/max_mobs = max(CEILING(comp.quality/2, 1), 1)
+	var/spawn_delay = 300 - 30 * comp.quality
+	comp.appliedComponents += master.AddComponent(/datum/component/summoning, list(picked_mobtype), 100, max_mobs, spawn_delay)
+	return "[newName] of [initial(picked_mobtype.name)] summoning"
+
+/datum/fantasy_affix/shrapnel
+	placement = AFFIX_SUFFIX
+	alignment = AFFIX_GOOD
+
+/datum/fantasy_affix/shrapnel/validate(datum/component/fantasy/comp)
+	if(isgun(comp.parent))
+		return TRUE
+	return FALSE
+
+/datum/fantasy_affix/shrapnel/apply(datum/component/fantasy/comp, newName)
+	. = ..()
+	// higher means more likely
+	var/list/weighted_projectile_types = list(/obj/item/projectile/meteor = 1,
+											  /obj/item/projectile/energy/nuclear_particle = 1,
+											  /obj/item/projectile/beam/pulse = 1,
+											  /obj/item/projectile/bullet/honker = 15,
+											  /obj/item/projectile/temp = 15,
+											  /obj/item/projectile/ion = 15,
+											  /obj/item/projectile/magic/door = 15,
+											  /obj/item/projectile/magic/locker = 15,
+//											  /obj/item/projectile/magic/fetch = 15,
+											  /obj/item/projectile/beam/emitter = 15,
+//											  /obj/item/projectile/magic/flying = 15,
+											  /obj/item/projectile/energy/net = 15,
+											  /obj/item/projectile/bullet/incendiary/c9mm = 15,
+											  /obj/item/projectile/temp/hot = 15,
+											  /obj/item/projectile/beam/disabler = 15)
+
+	var/obj/item/projectile/picked_projectiletype = pickweight(weighted_projectile_types)
+
+	var/obj/item/master = comp.parent
+	comp.appliedComponents += master.AddComponent(/datum/component/shrapnel, picked_projectiletype)
+	return "[newName] of [initial(picked_projectiletype.name)] shrapnel"
+
+/datum/fantasy_affix/strength
+	placement = AFFIX_SUFFIX
+	alignment = AFFIX_GOOD
+
+/datum/fantasy_affix/strength/apply(datum/component/fantasy/comp, newName)
+	. = ..()
+	var/obj/item/master = comp.parent
+	comp.appliedComponents += master.AddComponent(/datum/component/knockback, CEILING(comp.quality/2, 1), FLOOR(comp.quality/10, 1))
+	return "[newName] of strength"
+
+//////////// Bad suffixes
+
+/datum/fantasy_affix/fool
+	placement = AFFIX_SUFFIX
+	alignment = AFFIX_EVIL
+
+/datum/fantasy_affix/fool/apply(datum/component/fantasy/comp, newName)
+	. = ..()
+	var/obj/item/master = comp.parent
+	comp.appliedComponents += master.AddComponent(/datum/component/squeak, list('sound/items/bikehorn.ogg'=1), 50)
+	return "[newName] of the fool"

code/datums/components/igniter.dm

@@ -0,0 +1,37 @@
+
+/datum/component/igniter
+	var/fire_stacks
+
+/datum/component/igniter/Initialize(fire_stacks=1)
+	if(!isitem(parent) && !ishostile(parent) && !isgun(parent) && !ismachinery(parent) && !isstructure(parent))
+		return COMPONENT_INCOMPATIBLE
+
+	src.fire_stacks = fire_stacks
+
+/datum/component/igniter/RegisterWithParent()
+	if(ismachinery(parent) || isstructure(parent) || isgun(parent)) // turrets, etc
+		RegisterSignal(parent, COMSIG_PROJECTILE_ON_HIT, .proc/projectile_hit)
+	else if(isitem(parent))
+		RegisterSignal(parent, COMSIG_ITEM_AFTERATTACK, .proc/item_afterattack)
+	else if(ishostile(parent))
+		RegisterSignal(parent, COMSIG_HOSTILE_ATTACKINGTARGET, .proc/hostile_attackingtarget)
+
+/datum/component/igniter/UnregisterFromParent()
+	UnregisterSignal(parent, list(COMSIG_ITEM_AFTERATTACK, COMSIG_HOSTILE_ATTACKINGTARGET, COMSIG_PROJECTILE_ON_HIT))
+
+/datum/component/igniter/proc/item_afterattack(obj/item/source, atom/target, mob/user, proximity_flag, click_parameters)
+	if(!proximity_flag)
+		return
+	do_igniter(target)
+
+/datum/component/igniter/proc/hostile_attackingtarget(mob/living/simple_animal/hostile/attacker, atom/target)
+	do_igniter(target)
+
+/datum/component/igniter/proc/projectile_hit(atom/fired_from, atom/movable/firer, atom/target, Angle)
+	do_igniter(target)
+
+/datum/component/igniter/proc/do_igniter(atom/target)
+	if(isliving(target))
+		var/mob/living/L = target
+		L.adjust_fire_stacks(fire_stacks)
+		L.IgniteMob()

code/datums/components/jousting.dm

@@ -45,7 +45,7 @@
 		var/knockdown_chance = (target_buckled? mounted_knockdown_chance_per_tile : unmounted_knockdown_chance_per_tile) * current
 		var/knockdown_time = (target_buckled? mounted_knockdown_time : unmounted_knockdown_time)
 		var/damage = (target_buckled? mounted_damage_boost_per_tile : unmounted_damage_boost_per_tile) * current
-		var/sharp = I.is_sharp()
+		var/sharp = I.get_sharpness()
 		var/msg
 		if(damage)
 			msg += "[user] [sharp? "impales" : "slams into"] [target] [sharp? "on" : "with"] their [parent]"

code/datums/components/knockback.dm

@@ -0,0 +1,44 @@
+/datum/component/knockback
+	var/throw_distance
+	var/throw_anchored
+
+/datum/component/knockback/Initialize(throw_distance=1)
+	if(!isitem(parent) && !ishostile(parent) && !isgun(parent) && !ismachinery(parent) && !isstructure(parent))
+		return COMPONENT_INCOMPATIBLE
+
+	src.throw_distance = throw_distance
+	src.throw_anchored = throw_anchored
+
+/datum/component/knockback/RegisterWithParent()
+	if(ismachinery(parent) || isstructure(parent) || isgun(parent)) // turrets, etc
+		RegisterSignal(parent, COMSIG_PROJECTILE_ON_HIT, .proc/projectile_hit)
+	else if(isitem(parent))
+		RegisterSignal(parent, COMSIG_ITEM_AFTERATTACK, .proc/item_afterattack)
+	else if(ishostile(parent))
+		RegisterSignal(parent, COMSIG_HOSTILE_ATTACKINGTARGET, .proc/hostile_attackingtarget)
+
+/datum/component/knockback/UnregisterFromParent()
+	UnregisterSignal(parent, list(COMSIG_ITEM_AFTERATTACK, COMSIG_HOSTILE_ATTACKINGTARGET, COMSIG_PROJECTILE_ON_HIT))
+
+/datum/component/knockback/proc/item_afterattack(obj/item/source, atom/target, mob/user, proximity_flag, click_parameters)
+	if(!proximity_flag)
+		return
+	do_knockback(target, user, get_dir(source, target))
+
+/datum/component/knockback/proc/hostile_attackingtarget(mob/living/simple_animal/hostile/attacker, atom/target)
+	do_knockback(target, attacker, get_dir(attacker, target))
+
+/datum/component/knockback/proc/projectile_hit(atom/fired_from, atom/movable/firer, atom/target, Angle)
+	do_knockback(target, null, angle2dir(Angle))
+
+/datum/component/knockback/proc/do_knockback(atom/target, mob/thrower, throw_dir)
+	if(!ismovableatom(target) || throw_dir == null)
+		return
+	var/atom/movable/throwee = target
+	if(throwee.anchored && !throw_anchored)
+		return
+	if(throw_distance < 0)
+		throw_dir = turn(throw_dir, 180)
+		throw_distance *= -1
+	var/atom/throw_target = get_edge_target_turf(throwee, throw_dir)
+	throwee.safe_throw_at(throw_target, throw_distance, 1, thrower)

code/datums/components/lifesteal.dm

@@ -0,0 +1,39 @@
+
+/datum/component/lifesteal
+	var/flat_heal // heals a constant amount every time a hit occurs
+	var/static/list/damage_heal_order = list(BRUTE, BURN, OXY)
+
+/datum/component/lifesteal/Initialize(flat_heal=0)
+	if(!isitem(parent) && !ishostile(parent) && !isgun(parent))
+		return COMPONENT_INCOMPATIBLE
+
+	src.flat_heal = flat_heal
+
+/datum/component/lifesteal/RegisterWithParent()
+	if(isgun(parent))
+		RegisterSignal(parent, COMSIG_PROJECTILE_ON_HIT, .proc/projectile_hit)
+	else if(isitem(parent))
+		RegisterSignal(parent, COMSIG_ITEM_AFTERATTACK, .proc/item_afterattack)
+	else if(ishostile(parent))
+		RegisterSignal(parent, COMSIG_HOSTILE_ATTACKINGTARGET, .proc/hostile_attackingtarget)
+
+/datum/component/lifesteal/UnregisterFromParent()
+	UnregisterSignal(parent, list(COMSIG_ITEM_AFTERATTACK, COMSIG_HOSTILE_ATTACKINGTARGET, COMSIG_PROJECTILE_ON_HIT))
+
+/datum/component/lifesteal/proc/item_afterattack(obj/item/source, atom/target, mob/user, proximity_flag, click_parameters)
+	if(!proximity_flag)
+		return
+	do_lifesteal(user, target)
+
+/datum/component/lifesteal/proc/hostile_attackingtarget(mob/living/simple_animal/hostile/attacker, atom/target)
+	do_lifesteal(attacker, target)
+
+/datum/component/lifesteal/proc/projectile_hit(atom/fired_from, atom/movable/firer, atom/target, Angle)
+	do_lifesteal(firer, target)
+
+/datum/component/lifesteal/proc/do_lifesteal(atom/heal_target, atom/damage_target)
+	if(isliving(heal_target) && isliving(damage_target))
+		var/mob/living/healing = heal_target
+		var/mob/living/damaging = damage_target
+		if(damaging.stat != DEAD)
+			healing.heal_ordered_damage(flat_heal, damage_heal_order)

code/datums/components/phantomthief.dm

@@ -7,33 +7,24 @@
 	var/filter_x
 	var/filter_y
 	var/filter_size
-	var/filter_border
 	var/filter_color
 
-/datum/component/wearertargeting/phantomthief/Initialize(_x = -2, _y = 0, _size = 0, _border = 0, _color = "#E62111", list/_valid_slots = list(SLOT_GLASSES))
+/datum/component/wearertargeting/phantomthief/Initialize(_x = -2, _y = 0, _size = 0, _color = "#E62111", list/_valid_slots = list(SLOT_GLASSES))
 	. = ..()
 	if(. == COMPONENT_INCOMPATIBLE)
 		return
 	filter_x = _x
 	filter_y = _y
 	filter_size = _size
-	filter_border = _border
 	filter_color = _color
 	valid_slots = _valid_slots
 
 /datum/component/wearertargeting/phantomthief/proc/handlefilterstuff(datum/source, mob/user, combatmodestate)
-	if(istype(user))
-		var/thefilter = filter(type = "drop_shadow", x = filter_x, y = filter_y, size = filter_size, border = filter_border, color = filter_color)
-		if(!combatmodestate)
-			user.filters -= thefilter
-		else
-			user.filters += thefilter
-
-/datum/component/wearertargeting/phantomthief/proc/stripdesiredfilter(mob/user)
-	if(istype(user))
-		var/thefilter = filter(type = "drop_shadow", x = filter_x, y = filter_y, size = filter_size, border = filter_border, color = filter_color)
-		user.filters -= thefilter
+	if(!combatmodestate)
+		user.remove_filter("phantomthief")
+	else
+		user.add_filter("phantomthief", 4, list(type = "drop_shadow", x = filter_x, y = filter_y, size = filter_size, color = filter_color))
 
 /datum/component/wearertargeting/phantomthief/on_drop(datum/source, mob/user)
 	. = ..()
-	stripdesiredfilter(user)
+	user.remove_filter("phantomthief")

code/datums/components/riding.dm

@@ -18,6 +18,7 @@
 	var/ride_check_rider_incapacitated = FALSE
 	var/ride_check_rider_restrained = FALSE
 	var/ride_check_ridden_incapacitated = FALSE
+	var/list/offhands = list() // keyed list containing all the current riding offsets associated by mob
 
 /datum/component/riding/Initialize()
 	if(!ismovableatom(parent))
@@ -299,36 +300,34 @@
 	M.throw_at(target, 14, 5, AM)
 	M.Knockdown(60)
 
-/datum/component/riding/proc/equip_buckle_inhands(mob/living/carbon/human/user, amount_required = 1, riding_target_override = null)
-	var/atom/movable/AM = parent
-	var/amount_equipped = 0
+/datum/component/riding/proc/equip_buckle_inhands(mob/living/carbon/human/user, amount_required = 1, mob/living/riding_target_override)
+	var/list/equipped
+	var/mob/living/L = riding_target_override ? riding_target_override : user
 	for(var/amount_needed = amount_required, amount_needed > 0, amount_needed--)
-		var/obj/item/riding_offhand/inhand = new /obj/item/riding_offhand(user)
-		if(!riding_target_override)
-			inhand.rider = user
-		else
-			inhand.rider = riding_target_override
-		inhand.parent = AM
-		if(user.put_in_hands(inhand, TRUE))
-			amount_equipped++
-		else
+		var/obj/item/riding_offhand/inhand = new
+		inhand.rider = L
+		inhand.parent = parent
+		if(!user.put_in_hands(inhand, TRUE))
+			qdel(inhand) // it isn't going to be added to offhands anyway
 			break
+		LAZYADD(equipped, src)
+	var/amount_equipped = LAZYLEN(equipped)
+	if(amount_equipped)
+		LAZYADD(offhands[L], amount_equipped)
 	if(amount_equipped >= amount_required)
 		return TRUE
-	else
-		unequip_buckle_inhands(user)
-		return FALSE
+	unequip_buckle_inhands(L)
+	return FALSE
 
 /datum/component/riding/proc/unequip_buckle_inhands(mob/living/carbon/user)
-	var/atom/movable/AM = parent
-	for(var/obj/item/riding_offhand/O in user.contents)
-		if(O.parent != AM)
-			CRASH("RIDING OFFHAND ON WRONG MOB")
-			continue
-		if(O.selfdeleting)
-			continue
-		else
-			qdel(O)
+	for(var/a in offhands[user])
+		LAZYREMOVE(offhands[user], a)
+		if(a) //edge cases null entries
+			var/obj/item/riding_offhand/O = a
+			if(O.parent != parent)
+				CRASH("RIDING OFFHAND ON WRONG MOB")
+			else if(!O.selfdeleting)
+				qdel(O)
 	return TRUE
 
 /obj/item/riding_offhand

code/datums/components/shrapnel.dm

@@ -0,0 +1,39 @@
+
+/datum/component/shrapnel
+	var/projectile_type
+	var/radius // shoots a projectile for every turf on this radius from the hit target
+	var/override_projectile_range
+
+/datum/component/shrapnel/Initialize(projectile_type, radius=1, override_projectile_range)
+	if(!isgun(parent) && !ismachinery(parent) && !isstructure(parent))
+		return COMPONENT_INCOMPATIBLE
+
+	src.projectile_type = projectile_type
+	src.radius = radius
+	src.override_projectile_range = override_projectile_range
+
+/datum/component/shrapnel/RegisterWithParent()
+	if(ismachinery(parent) || isstructure(parent) || isgun(parent)) // turrets, etc
+		RegisterSignal(parent, COMSIG_PROJECTILE_ON_HIT, .proc/projectile_hit)
+
+/datum/component/shrapnel/UnregisterFromParent()
+	UnregisterSignal(parent, list(COMSIG_PROJECTILE_ON_HIT))
+
+/datum/component/shrapnel/proc/projectile_hit(atom/fired_from, atom/movable/firer, atom/target, Angle)
+	do_shrapnel(firer, target)
+
+/datum/component/shrapnel/proc/do_shrapnel(mob/firer, atom/target)
+	if(radius < 1)
+		return
+	var/turf/target_turf = get_turf(target)
+	for(var/turf/shootat_turf in RANGE_TURFS(radius, target) - RANGE_TURFS(radius-1, target))
+		var/obj/item/projectile/P = new projectile_type(target_turf)
+
+		//Shooting Code:
+		P.range = radius+1
+		if(override_projectile_range)
+			P.range = override_projectile_range
+		P.preparePixelProjectile(shootat_turf, target)
+		P.firer = firer // don't hit ourself that would be really annoying
+		P.permutated += target // don't hit the target we hit already with the flak
+		P.fire()

code/datums/components/summoning.dm

@@ -0,0 +1,69 @@
+
+/datum/component/summoning
+	var/list/mob_types = list()
+	var/spawn_chance // chance for the mob to spawn on hit in percent
+	var/max_mobs
+	var/spawn_delay // delay in spawning between mobs (deciseconds)
+	var/spawn_text
+	var/spawn_sound
+	var/list/faction
+
+	var/last_spawned_time = 0
+	var/list/spawned_mobs = list()
+
+/datum/component/summoning/Initialize(mob_types, spawn_chance=100, max_mobs=3, spawn_delay=100, spawn_text="appears out of nowhere", spawn_sound='sound/magic/summon_magic.ogg', faction)
+	if(!isitem(parent) && !ishostile(parent) && !isgun(parent) && !ismachinery(parent) && !isstructure(parent))
+		return COMPONENT_INCOMPATIBLE
+
+	src.mob_types = mob_types
+	src.spawn_chance = spawn_chance
+	src.max_mobs = max_mobs
+	src.spawn_delay = spawn_delay
+	src.spawn_text = spawn_text
+	src.spawn_sound = spawn_sound
+	src.faction = faction
+
+/datum/component/summoning/RegisterWithParent()
+	if(ismachinery(parent) || isstructure(parent) || isgun(parent)) // turrets, etc
+		RegisterSignal(parent, COMSIG_PROJECTILE_ON_HIT, .proc/projectile_hit)
+	else if(isitem(parent))
+		RegisterSignal(parent, COMSIG_ITEM_AFTERATTACK, .proc/item_afterattack)
+	else if(ishostile(parent))
+		RegisterSignal(parent, COMSIG_HOSTILE_ATTACKINGTARGET, .proc/hostile_attackingtarget)
+
+/datum/component/summoning/UnregisterFromParent()
+	UnregisterSignal(parent, list(COMSIG_ITEM_AFTERATTACK, COMSIG_HOSTILE_ATTACKINGTARGET, COMSIG_PROJECTILE_ON_HIT))
+
+/datum/component/summoning/proc/item_afterattack(obj/item/source, atom/target, mob/user, proximity_flag, click_parameters)
+	if(!proximity_flag)
+		return
+	do_spawn_mob(get_turf(target), user)
+
+/datum/component/summoning/proc/hostile_attackingtarget(mob/living/simple_animal/hostile/attacker, atom/target)
+	do_spawn_mob(get_turf(target), attacker)
+
+/datum/component/summoning/proc/projectile_hit(atom/fired_from, atom/movable/firer, atom/target, Angle)
+	do_spawn_mob(get_turf(target), firer)
+
+/datum/component/summoning/proc/do_spawn_mob(atom/spawn_location, summoner)
+	if(spawned_mobs.len >= max_mobs)
+		return 0
+	if(last_spawned_time > world.time)
+		return 0
+	if(!prob(spawn_chance))
+		return 0
+	last_spawned_time = world.time + spawn_delay
+	var/chosen_mob_type = pick(mob_types)
+	var/mob/living/simple_animal/L = new chosen_mob_type(spawn_location)
+	if(ishostile(L))
+		var/mob/living/simple_animal/hostile/H = L
+		H.friends += summoner // do not attack our summon boy
+	spawned_mobs += L
+	if(faction != null)
+		L.faction = faction
+	RegisterSignal(L, COMSIG_MOB_DEATH, .proc/on_spawned_death) // so we can remove them from the list, etc (for mobs with corpses)
+	playsound(spawn_location,spawn_sound, 50, 1)
+	spawn_location.visible_message("<span class='danger'>[L] [spawn_text].</span>")
+
+/datum/component/summoning/proc/on_spawned_death(mob/killed, gibbed)
+	spawned_mobs -= killed

code/datums/components/tactical.dm

@@ -0,0 +1,42 @@
+
+/datum/component/tactical
+	var/allowed_slot
+
+/datum/component/tactical/Initialize(allowed_slot)
+	if(!isitem(parent))
+		return COMPONENT_INCOMPATIBLE
+
+	src.allowed_slot = allowed_slot
+
+/datum/component/tactical/RegisterWithParent()
+	RegisterSignal(parent, COMSIG_ITEM_EQUIPPED, .proc/modify)
+	RegisterSignal(parent, COMSIG_ITEM_DROPPED, .proc/unmodify)
+
+/datum/component/tactical/UnregisterFromParent()
+	UnregisterSignal(parent, list(COMSIG_ITEM_EQUIPPED, COMSIG_ITEM_DROPPED))
+	unmodify()
+
+/datum/component/fantasy/Destroy()
+	unmodify()
+	return ..()
+
+/datum/component/tactical/proc/modify(obj/item/source, mob/user, slot)
+	if(allowed_slot && slot != allowed_slot)
+		unmodify()
+		return
+
+	var/obj/item/master = parent
+	var/image/I = image(icon = master.icon, icon_state = master.icon_state, loc = user)
+	I.copy_overlays(master)
+	I.override = TRUE
+	source.add_alt_appearance(/datum/atom_hud/alternate_appearance/basic/everyone, "sneaking_mission", I)
+	I.layer = ABOVE_MOB_LAYER
+
+/datum/component/tactical/proc/unmodify(obj/item/source, mob/user)
+	var/obj/item/master = source || parent
+	if(!user)
+		if(!ismob(master.loc))
+			return
+		user = master.loc
+
+	user.remove_alt_appearance("sneaking_mission")

code/datums/components/thermite.dm

@@ -15,7 +15,7 @@
 		/turf/closed/indestructible,
 		/turf/open/indestructible)
 		)
-	
+
 	var/static/list/resistlist = typecacheof(
 		/turf/closed/wall/r_wall
 		)
@@ -77,5 +77,5 @@
 		thermite_melt()
 
 /datum/component/thermite/proc/attackby_react(datum/source, obj/item/thing, mob/user, params)
-	if(thing.is_hot())
+	if(thing.get_temperature())
 		thermite_melt(user)

code/datums/dash_weapon.dm

@@ -34,11 +34,10 @@
 	var/turf/T = get_turf(target)
 	if(target in view(user.client.view, user))
 		var/obj/spot1 = new phaseout(get_turf(user), user.dir)
-		user.forceMove(T)
-		playsound(T, dash_sound, 25, 1)
-		var/obj/spot2 = new phasein(get_turf(user), user.dir)
-		spot1.Beam(spot2,beam_effect,time=20)
-		current_charges--
+		if(do_teleport(user, T, null, TRUE, null, null, dash_sound, dash_sound, TRUE, TELEPORT_CHANNEL_FREE, TRUE))
+			var/obj/spot2 = new phasein(get_turf(user), user.dir)
+			spot1.Beam(spot2,beam_effect,time=20)
+			current_charges--
 		holder.update_action_buttons_icon()
 		addtimer(CALLBACK(src, .proc/charge), charge_rate)
 

code/datums/diseases/advance/symptoms/heal.dm

@@ -79,7 +79,7 @@
 	if(M.getToxLoss() && prob(5))
 		to_chat(M, "<span class='notice'>Your skin tingles as the starlight seems to heal you.</span>")
 
-	M.adjustToxLoss(-(4 * heal_amt)) //most effective on toxins
+	M.adjustToxLoss(-(4 * heal_amt), forced = TRUE) //most effective on toxins
 
 	var/list/parts = M.get_damaged_bodyparts(1,1)
 
@@ -368,7 +368,7 @@
 	level = 8
 	passive_message = "<span class='notice'>You feel an odd attraction to plasma.</span>"
 	var/temp_rate = 1
-	threshold_desc = "<b>Transmission 6:</b> Increases temperature adjustment rate.<br>\
+	threshold_desc = "<b>Transmission 6:</b> Increases temperature adjustment rate and heals toxin lovers.<br>\
 					  <b>Stage Speed 7:</b> Increases healing speed."
 
 /datum/symptom/heal/plasma/Start(datum/disease/advance/A)
@@ -410,7 +410,7 @@
 		if(prob(5))
 			to_chat(M, "<span class='notice'>You feel warmer.</span>")
 
-	M.adjustToxLoss(-heal_amt)
+	M.adjustToxLoss(-heal_amt, forced = (temp_rate == 4))
 
 	var/list/parts = M.get_damaged_bodyparts(1,1)
 	if(!parts.len)
@@ -435,7 +435,7 @@
 	symptom_delay_max = 1
 	passive_message = "<span class='notice'>Your skin glows faintly for a moment.</span>"
 	var/cellular_damage = FALSE
-	threshold_desc = "<b>Transmission 6:</b> Additionally heals cellular damage.<br>\
+	threshold_desc = "<b>Transmission 6:</b> Additionally heals cellular damage and toxin lovers.<br>\
 					  <b>Resistance 7:</b> Increases healing speed."
 
 /datum/symptom/heal/radiation/Start(datum/disease/advance/A)
@@ -468,7 +468,7 @@
 	if(cellular_damage)
 		M.adjustCloneLoss(-heal_amt * 0.5)
 
-	M.adjustToxLoss(-(2 * heal_amt))
+	M.adjustToxLoss(-(2 * heal_amt), forced = cellular_damage)
 
 	var/list/parts = M.get_damaged_bodyparts(1,1)
 

code/datums/helper_datums/teleport.dm

@@ -79,6 +79,7 @@
 		tele_play_specials(teleatom, destturf, effectout, asoundout)
 		if(ismegafauna(teleatom))
 			message_admins("[teleatom] [ADMIN_FLW(teleatom)] has teleported from [ADMIN_VERBOSEJMP(curturf)] to [ADMIN_VERBOSEJMP(destturf)].")
+		SEND_SIGNAL(teleatom, COMSIG_MOVABLE_TELEPORTED, channel, curturf, destturf)
 
 	if(ismob(teleatom))
 		var/mob/M = teleatom

code/datums/mind.dm

@@ -41,8 +41,6 @@
 	var/special_role
 	var/list/restricted_roles = list()
 
-	var/list/datum/objective/objectives = list()
-
 	var/list/spell_list = list() // Wizard mode & "Give Spell" badmin button.
 
 	var/linglink
@@ -360,13 +358,15 @@
 	output += memory
 
 
+	var/list/all_objectives = list()
 	for(var/datum/antagonist/A in antag_datums)
 		output += A.antag_memory
+		all_objectives |= A.objectives
 
-	if(objectives.len)
+	if(all_objectives.len)
 		output += "<B>Objectives:</B>"
 		var/obj_count = 1
-		for(var/datum/objective/objective in objectives)
+		for(var/datum/objective/objective in all_objectives)
 			output += "<br><B>Objective #[obj_count++]</B>: [objective.explanation_text]"
 			var/list/datum/mind/other_owners = objective.get_owners() - src
 			if(other_owners.len)
@@ -377,7 +377,7 @@
 
 	if(window)
 		recipient << browse(output,"window=memory")
-	else if(objectives.len || memory)
+	else if(all_objectives.len || memory)
 		to_chat(recipient, "<i>[output]</i>")
 
 /datum/mind/Topic(href, href_list)
@@ -408,34 +408,24 @@
 		memory = new_memo
 
 	else if (href_list["obj_edit"] || href_list["obj_add"])
-		var/datum/objective/objective
-		var/objective_pos
+		var/objective_pos //Edited objectives need to keep same order in antag objective list
 		var/def_value
-
 		var/datum/antagonist/target_antag
+		var/datum/objective/old_objective //The old objective we're replacing/editing
+		var/datum/objective/new_objective //New objective we're be adding
 
-		if (href_list["obj_edit"])
-			objective = locate(href_list["obj_edit"])
-			if (!objective)
+		if(href_list["obj_edit"])
+			for(var/datum/antagonist/A in antag_datums)
+				old_objective = locate(href_list["obj_edit"]) in A.objectives
+				if(old_objective)
+					target_antag = A
+					objective_pos = A.objectives.Find(old_objective)
+					break
+			if(!old_objective)
+				to_chat(usr,"Invalid objective.")
 				return
 
-			for(var/datum/antagonist/A in antag_datums)
-				if(objective in A.objectives)
-					target_antag = A
-					objective_pos = A.objectives.Find(objective)
-					break
-
-			if(!target_antag) //Shouldn't happen anymore
-				stack_trace("objective without antagonist found")
-				objective_pos = objectives.Find(objective)
-
-			//Text strings are easy to manipulate. Revised for simplicity.
-			var/temp_obj_type = "[objective.type]"//Convert path into a text string.
-			def_value = copytext(temp_obj_type, 19)//Convert last part of path into an objective keyword.
-			if(!def_value)//If it's a custom objective, it will be an empty string.
-				def_value = "custom"
 		else
-			//We're adding this objective
 			if(href_list["target_antag"])
 				var/datum/antagonist/X = locate(href_list["target_antag"]) in antag_datums
 				if(X)
@@ -447,7 +437,7 @@
 					if(1)
 						target_antag = antag_datums[1]
 					else
-						var/datum/antagonist/target = input("Which antagonist gets the objective:", "Antagonist", def_value) as null|anything in antag_datums + "(new custom antag)"
+						var/datum/antagonist/target = input("Which antagonist gets the objective:", "Antagonist", "(new custom antag)") as null|anything in antag_datums + "(new custom antag)"
 						if (QDELETED(target))
 							return
 						else if(target == "(new custom antag)")
@@ -455,149 +445,88 @@
 						else
 							target_antag = target
 
-		var/new_obj_type = input("Select objective type:", "Objective type", def_value) as null|anything in list("assassinate", "maroon", "debrain", "protect", "destroy", "prevent", "hijack", "escape", "survive", "martyr", "steal", "download", "nuclear", "capture", "absorb", "custom")
-		if (!new_obj_type)
+		var/static/list/choices
+		if(!choices)
+			choices = list()
+
+			var/list/allowed_types = list(
+				/datum/objective/assassinate,
+				/datum/objective/maroon,
+				/datum/objective/debrain,
+				/datum/objective/protect,
+				/datum/objective/destroy,
+				/datum/objective/hijack,
+				/datum/objective/escape,
+				/datum/objective/survive,
+				/datum/objective/martyr,
+				/datum/objective/steal,
+				/datum/objective/download,
+				/datum/objective/nuclear,
+				/datum/objective/capture,
+				/datum/objective/absorb,
+				/datum/objective/custom
+			)
+
+			for(var/T in allowed_types)
+				var/datum/objective/X = T
+				choices[initial(X.name)] = T
+
+		if(old_objective)
+			if(old_objective.name in choices)
+				def_value = old_objective.name
+
+		var/selected_type = input("Select objective type:", "Objective type", def_value) as null|anything in choices
+		selected_type = choices[selected_type]
+		if (!selected_type)
 			return
 
-		var/datum/objective/new_objective = null
+		if(!old_objective)
+			//Add new one
+			new_objective = new selected_type
+			new_objective.owner = src
+			new_objective.admin_edit(usr)
+			target_antag.objectives += new_objective
 
-		switch (new_obj_type)
-			if ("assassinate","protect","debrain","maroon")
-				var/list/possible_targets = list("Free objective")
-				for(var/datum/mind/possible_target in SSticker.minds)
-					if ((possible_target != src) && ishuman(possible_target.current))
-						possible_targets += possible_target.current
-
-				var/mob/def_target = null
-				var/list/objective_list = typecacheof(list(/datum/objective/assassinate, /datum/objective/protect, /datum/objective/debrain, /datum/objective/maroon))
-				if (is_type_in_typecache(objective, objective_list) && objective.target)
-					def_target = objective.target.current
-
-				var/mob/new_target = input("Select target:", "Objective target", def_target) as null|anything in possible_targets
-				if (!new_target)
-					return
-
-				var/objective_path = text2path("/datum/objective/[new_obj_type]")
-				if (new_target == "Free objective")
-					new_objective = new objective_path
-					new_objective.owner = src
-					new_objective.target = null
-					new_objective.explanation_text = "Free objective"
-				else
-					new_objective = new objective_path
-					new_objective.owner = src
-					new_objective.target = new_target.mind
-					//Will display as special role if the target is set as MODE. Ninjas/commandos/nuke ops.
-					new_objective.update_explanation_text()
-
-			if ("destroy")
-				var/list/possible_targets = active_ais(1)
-				if(possible_targets.len)
-					var/mob/new_target = input("Select target:", "Objective target") as null|anything in possible_targets
-					new_objective = new /datum/objective/destroy
-					new_objective.target = new_target.mind
-					new_objective.owner = src
-					new_objective.update_explanation_text()
-				else
-					to_chat(usr, "No active AIs with minds")
-
-			if ("prevent")
-				new_objective = new /datum/objective/block
-				new_objective.owner = src
-
-			if ("hijack")
-				new_objective = new /datum/objective/hijack
-				new_objective.owner = src
-
-			if ("escape")
-				new_objective = new /datum/objective/escape
-				new_objective.owner = src
-
-			if ("survive")
-				new_objective = new /datum/objective/survive
-				new_objective.owner = src
-
-			if("martyr")
-				new_objective = new /datum/objective/martyr
-				new_objective.owner = src
-
-			if ("nuclear")
-				new_objective = new /datum/objective/nuclear
-				new_objective.owner = src
-
-			if ("steal")
-				if (!istype(objective, /datum/objective/steal))
-					new_objective = new /datum/objective/steal
-					new_objective.owner = src
-				else
-					new_objective = objective
-				var/datum/objective/steal/steal = new_objective
-				if (!steal.select_target())
-					return
-
-			if("download","capture","absorb")
-				var/def_num
-				if(objective&&objective.type==text2path("/datum/objective/[new_obj_type]"))
-					def_num = objective.target_amount
-
-				var/target_number = input("Input target number:", "Objective", def_num) as num | null
-				if (isnull(target_number))//Ordinarily, you wouldn't need isnull. In this case, the value may already exist.
-					return
-
-				switch(new_obj_type)
-					if("download")
-						new_objective = new /datum/objective/download
-						new_objective.explanation_text = "Download [target_number] research node\s."
-					if("capture")
-						new_objective = new /datum/objective/capture
-						new_objective.explanation_text = "Capture [target_number] lifeforms with an energy net. Live, rare specimens are worth more."
-					if("absorb")
-						new_objective = new /datum/objective/absorb
-						new_objective.explanation_text = "Absorb [target_number] compatible genomes."
-				new_objective.owner = src
-				new_objective.target_amount = target_number
-
-			if ("custom")
-				var/expl = stripped_input(usr, "Custom objective:", "Objective", objective ? objective.explanation_text : "")
-				if (!expl)
-					return
-				new_objective = new /datum/objective
-				new_objective.owner = src
-				new_objective.explanation_text = expl
-
-		if (!new_objective)
-			return
-
-		if (objective)
-			if(target_antag)
-				target_antag.objectives -= objective
-			objectives -= objective
-			target_antag.objectives.Insert(objective_pos, new_objective)
-			message_admins("[key_name_admin(usr)] edited [current]'s objective to [new_objective.explanation_text]")
-			log_admin("[key_name(usr)] edited [current]'s objective to [new_objective.explanation_text]")
-		else
-			if(target_antag)
-				target_antag.objectives += new_objective
-			objectives += new_objective
 			message_admins("[key_name_admin(usr)] added a new objective for [current]: [new_objective.explanation_text]")
 			log_admin("[key_name(usr)] added a new objective for [current]: [new_objective.explanation_text]")
+		else
+			if(old_objective.type == selected_type)
+				//Edit the old
+				old_objective.admin_edit(usr)
+				new_objective = old_objective
+			else
+				//Replace the old
+				new_objective = new selected_type
+				new_objective.owner = src
+				new_objective.admin_edit(usr)
+				target_antag.objectives -= old_objective
+				target_antag.objectives.Insert(objective_pos, new_objective)
+			message_admins("[key_name_admin(usr)] edited [current]'s objective to [new_objective.explanation_text]")
+			log_admin("[key_name(usr)] edited [current]'s objective to [new_objective.explanation_text]")
 
 	else if (href_list["obj_delete"])
-		var/datum/objective/objective = locate(href_list["obj_delete"])
-		if(!istype(objective))
-			return
+		var/datum/objective/objective
 
 		for(var/datum/antagonist/A in antag_datums)
-			if(objective in A.objectives)
-				A.objectives -= objective
+			objective = locate(href_list["obj_delete"]) in A.objectives
+			if(istype(objective))
 				break
-		objectives -= objective
+		if(!objective)
+			to_chat(usr,"Invalid objective.")
+			return
+		//qdel(objective) Needs cleaning objective destroys
 		message_admins("[key_name_admin(usr)] removed an objective for [current]: [objective.explanation_text]")
 		log_admin("[key_name(usr)] removed an objective for [current]: [objective.explanation_text]")
 
 	else if(href_list["obj_completed"])
-		var/datum/objective/objective = locate(href_list["obj_completed"])
-		if(!istype(objective))
+		var/datum/objective/objective
+		for(var/datum/antagonist/A in antag_datums)
+			objective = locate(href_list["obj_completed"]) in A.objectives
+			if(istype(objective))
+				objective = objective
+				break
+		if(!objective)
+			to_chat(usr,"Invalid objective.")
 			return
 		objective.completed = !objective.completed
 		log_admin("[key_name(usr)] toggled the win state for [current]'s objective: [objective.explanation_text]")
@@ -652,10 +581,16 @@
 		usr = current
 	traitor_panel()
 
+/datum/mind/proc/get_all_objectives()
+	var/list/all_objectives = list()
+	for(var/datum/antagonist/A in antag_datums)
+		all_objectives |= A.objectives
+	return all_objectives
+
 /datum/mind/proc/announce_objectives()
 	var/obj_count = 1
 	to_chat(current, "<span class='notice'>Your current objectives:</span>")
-	for(var/objective in objectives)
+	for(var/objective in get_all_objectives())
 		var/datum/objective/O = objective
 		to_chat(current, "<B>Objective #[obj_count]</B>: [O.explanation_text]")
 		obj_count++

code/datums/radiation_wave.dm

@@ -66,6 +66,8 @@
 		place = cmaster_turf
 		for(var/i in 1 to distance)
 			place = get_step(place, dir)
+			if(!place)
+				break
 			atoms += get_rad_contents(place)
 
 	return atoms
@@ -108,7 +110,7 @@
 		if(!can_contaminate || blacklisted[thing.type])
 			continue
 		if(prob(contamination_chance)) // Only stronk rads get to have little baby rads
-			if(SEND_SIGNAL(thing, COMSIG_ATOM_RAD_CONTAMINATING, strength) & COMPONENT_BLOCK_CONTAMINATION)
+			if(CHECK_BITFIELD(thing.rad_flags, RAD_NO_CONTAMINATE) || SEND_SIGNAL(thing, COMSIG_ATOM_RAD_CONTAMINATING, strength) & COMPONENT_BLOCK_CONTAMINATION)
 				continue
 			var/rad_strength = (strength-RAD_MINIMUM_CONTAMINATION) * RAD_CONTAMINATION_STR_COEFFICIENT
 			thing.AddComponent(/datum/component/radioactive, rad_strength, source)

code/datums/traits/neutral.dm

@@ -94,6 +94,50 @@
 	lose_text = "<span class='notice'>You don't feel as prudish as before.</span>"
 	medical_record_text = "Patient exhibits a special gene that makes them immune to Crocin and Hexacrocin."
 
+/datum/quirk/libido
+	name = "Nymphomania"
+	desc = "You're always feeling a bit in heat. Also, you get aroused faster than usual."
+	value = 0
+	mob_trait = TRAIT_NYMPHO
+	gain_text = "<span class='notice'>You are feeling extra wild.</span>"
+	lose_text = "<span class='notice'>You don't feel that burning sensation anymore.</span>"
+
+/datum/quirk/libido/add()
+	quirk_holder.min_arousal = 16
+	quirk_holder.arousal_rate = 3
+
+/datum/quirk/libido/remove()
+	if(quirk_holder)
+		quirk_holder.min_arousal = initial(quirk_holder.min_arousal)
+		quirk_holder.arousal_rate = initial(quirk_holder.arousal_rate)
+
+/datum/quirk/maso
+	name = "Masochism"
+	desc = "You are aroused by pain."
+	value = 0
+	mob_trait = TRAIT_MASO
+	gain_text = "<span class='notice'>You desire to be hurt.</span>"
+	lose_text = "<span class='notice'>Pain has become less exciting for you.</span>"
+
+/datum/quirk/exhibitionism
+	name = "Exhibitionism"
+	desc = "You don't mind showing off your bare body to strangers, in fact you find it quite satistying."
+	value = 0
+	medical_record_text = "Patient has been diagnosed with exhibitionistic disorder."
+	mob_trait = TRAIT_EXHIBITIONIST
+	gain_text = "<span class='notice'>You feel like exposing yourself to the world.</span>"
+	lose_text = "<span class='notice'>Indecent exposure doesn't sound as charming to you anymore.</span>"
+
+/datum/quirk/pharmacokinesis //Prevents unwanted organ additions.
+	name = "Acute hepatic pharmacokinesis"
+	desc = "You've a rare genetic disorder that causes Incubus draft and Sucubus milk to be absorbed by your liver instead."
+	value = 0
+	mob_trait = TRAIT_PHARMA
+	lose_text = "<span class='notice'>Your liver feels different.</span>"
+	var/active = FALSE
+	var/power = 0
+	var/cachedmoveCalc = 1
+
 /datum/quirk/assblastusa
 	name = "Buns of Steel"
 	desc = "You've never skipped ass day. With this trait, you are completely immune to all forms of ass slapping and anyone who tries to slap your rock hard ass usually gets a broken hand."