Porting components updates and fixing phantom thief component.

code/datums/components/_component.dm

@@ -2,6 +2,10 @@
 	var/dupe_mode = COMPONENT_DUPE_HIGHLANDER
 	var/dupe_type
 	var/datum/parent
+	//only set to true if you are able to properly transfer this component
+	//At a minimum RegisterWithParent and UnregisterFromParent should be used
+	//Make sure you also implement PostTransfer for any post transfer handling
+	var/can_transfer = FALSE
 
 /datum/component/New(datum/P, ...)
 	parent = P
@@ -83,7 +87,7 @@
 /datum/component/proc/UnregisterFromParent()
 	return
 
-/datum/proc/RegisterSignal(datum/target, sig_type_or_types, proc_or_callback, override = FALSE)
+/datum/proc/RegisterSignal(datum/target, sig_type_or_types, proctype, override = FALSE)
 	if(QDELETED(src) || QDELETED(target))
 		return
 
@@ -96,15 +100,12 @@
 	if(!lookup)
 		target.comp_lookup = lookup = list()
 
-	if(!istype(proc_or_callback, /datum/callback)) //if it wasnt a callback before, it is now
-		proc_or_callback = CALLBACK(src, proc_or_callback)
-
 	var/list/sig_types = islist(sig_type_or_types) ? sig_type_or_types : list(sig_type_or_types)
 	for(var/sig_type in sig_types)
 		if(!override && procs[target][sig_type])
 			stack_trace("[sig_type] overridden. Use override = TRUE to suppress this warning")
 
-		procs[target][sig_type] = proc_or_callback
+		procs[target][sig_type] = proctype
 
 		if(!lookup[sig_type]) // Nothing has registered here yet
 			lookup[sig_type] = src
@@ -154,7 +155,7 @@
 	return
 
 /datum/component/proc/PostTransfer()
-	return
+	return COMPONENT_INCOMPATIBLE //Do not support transfer by default as you must properly support it
 
 /datum/component/proc/_GetInverseTypeList(our_type = type)
 	//we can do this one simple trick
@@ -171,17 +172,20 @@
 		var/datum/C = target
 		if(!C.signal_enabled)
 			return NONE
-		var/datum/callback/CB = C.signal_procs[src][sigtype]
-		return CB.InvokeAsync(arglist(arguments))
+		var/proctype = C.signal_procs[src][sigtype]
+		return NONE | CallAsync(C, proctype, arguments)
 	. = NONE
 	for(var/I in target)
 		var/datum/C = I
 		if(!C.signal_enabled)
 			continue
-		var/datum/callback/CB = C.signal_procs[src][sigtype]
-		. |= CB.InvokeAsync(arglist(arguments))
+		var/proctype = C.signal_procs[src][sigtype]
+		. |= CallAsync(C, proctype, arguments)
 
-/datum/proc/GetComponent(c_type)
+// The type arg is casted so initial works, you shouldn't be passing a real instance into this
+/datum/proc/GetComponent(datum/component/c_type)
+	if(initial(c_type.dupe_mode) == COMPONENT_DUPE_ALLOWED)
+		stack_trace("GetComponent was called to get a component of which multiple copies could be on an object. This can easily break and should be changed. Type: \[[c_type]\]")
 	var/list/dc = datum_components
 	if(!dc)
 		return null
@@ -220,10 +224,6 @@
 	if(ispath(nt))
 		if(nt == /datum/component)
 			CRASH("[nt] attempted instantiation!")
-		if(!isnum(dm))
-			CRASH("[nt]: Invalid dupe_mode ([dm])!")
-		if(dt && !ispath(dt))
-			CRASH("[nt]: Invalid dupe_type ([dt])!")
 	else
 		new_comp = nt
 		nt = new_comp.type
@@ -285,10 +285,13 @@
 	if(target.parent)
 		target.RemoveComponent()
 	target.parent = src
-	if(target.PostTransfer() == COMPONENT_INCOMPATIBLE)
-		var/c_type = target.type
-		qdel(target)
-		CRASH("Incompatible [c_type] transfer attempt to a [type]!")
+	var/result = target.PostTransfer()
+	switch(result)
+		if(COMPONENT_INCOMPATIBLE)
+			var/c_type = target.type
+			qdel(target)
+			CRASH("Incompatible [c_type] transfer attempt to a [type]!")
+
 	if(target == AddComponent(target))
 		target._JoinParent()
 
@@ -298,10 +301,13 @@
 		return
 	var/comps = dc[/datum/component]
 	if(islist(comps))
-		for(var/I in comps)
-			target.TakeComponent(I)
+		for(var/datum/component/I in comps)
+			if(I.can_transfer)
+				target.TakeComponent(I)
 	else
-		target.TakeComponent(comps)
+		var/datum/component/C = comps
+		if(C.can_transfer)
+			target.TakeComponent(comps)
 
 /datum/component/ui_host()
 	return parent

code/datums/components/decal.dm

@@ -1,6 +1,6 @@
 /datum/component/decal
 	dupe_mode = COMPONENT_DUPE_ALLOWED
-
+	can_transfer = TRUE
 	var/cleanable
 	var/description
 	var/mutable_appearance/pic

code/datums/components/earprotection.dm

@@ -1,11 +1,11 @@
 /datum/component/wearertargeting/earprotection
 	signals = list(COMSIG_CARBON_SOUNDBANG)
 	mobtype = /mob/living/carbon
+	proctype = .proc/reducebang
 
 /datum/component/wearertargeting/earprotection/Initialize(_valid_slots)
 	. = ..()
 	valid_slots = _valid_slots
-	callback = CALLBACK(src, .proc/reducebang)
 
 /datum/component/wearertargeting/earprotection/proc/reducebang(datum/source, list/reflist)
 	reflist[1]--

code/datums/components/forensics.dm

@@ -1,5 +1,6 @@
 /datum/component/forensics
 	dupe_mode = COMPONENT_DUPE_UNIQUE
+	can_transfer = TRUE
 	var/list/fingerprints		//assoc print = print
 	var/list/hiddenprints		//assoc ckey = realname/gloves/ckey
 	var/list/blood_DNA			//assoc dna = bloodtype
@@ -21,8 +22,18 @@
 	blood_DNA = new_blood_DNA
 	fibers = new_fibers
 	check_blood()
+
+/datum/component/forensics/RegisterWithParent()
+	check_blood()
 	RegisterSignal(parent, COMSIG_COMPONENT_CLEAN_ACT, .proc/clean_act)
 
+/datum/component/forensics/UnregisterFromParent()
+    UnregisterSignal(parent, list(COMSIG_COMPONENT_CLEAN_ACT))
+
+/datum/component/forensics/PostTransfer()
+	if(!isatom(parent))
+		return COMPONENT_INCOMPATIBLE
+
 /datum/component/forensics/proc/wipe_fingerprints()
 	fingerprints = null
 	return TRUE

code/datums/components/lockon_aiming.dm

@@ -237,6 +237,3 @@
 		LOCKON_RANGING_BREAK_CHECK
 		cd++
 		CHECK_TICK
-
-/datum/component/lockon_aiming/PostTransfer(datum/new_parent)
-	return COMPONENT_INCOMPATIBLE

code/datums/components/mirage_border.dm

@@ -1,4 +1,5 @@
 /datum/component/mirage_border
+	can_transfer = TRUE
 	var/obj/effect/abstract/mirage_holder/holder
 
 /datum/component/mirage_border/Initialize(turf/target, direction, range=world.view)

code/datums/components/orbiter.dm

@@ -1,8 +1,7 @@
 /datum/component/orbiter
+	can_transfer = TRUE
 	dupe_mode = COMPONENT_DUPE_UNIQUE_PASSARGS
 	var/list/orbiters
-	var/datum/callback/orbiter_spy
-	var/datum/callback/orbited_spy
 
 //radius: range to orbit at, radius of the circle formed by orbiting (in pixels)
 //clockwise: whether you orbit clockwise or anti clockwise
@@ -14,8 +13,6 @@
 		return COMPONENT_INCOMPATIBLE
 
 	orbiters = list()
-	orbiter_spy = CALLBACK(src, .proc/orbiter_move_react)
-	orbited_spy = CALLBACK(src, .proc/move_react)
 
 	var/atom/master = parent
 	master.orbiters = src
@@ -25,7 +22,7 @@
 /datum/component/orbiter/RegisterWithParent()
 	var/atom/target = parent
 	while(ismovableatom(target))
-		RegisterSignal(target, COMSIG_MOVABLE_MOVED, orbited_spy)
+		RegisterSignal(target, COMSIG_MOVABLE_MOVED, .proc/move_react)
 		target = target.loc
 
 /datum/component/orbiter/UnregisterFromParent()
@@ -40,8 +37,6 @@
 	for(var/i in orbiters)
 		end_orbit(i)
 	orbiters = null
-	QDEL_NULL(orbiter_spy)
-	QDEL_NULL(orbited_spy)
 	return ..()
 
 /datum/component/orbiter/InheritComponent(datum/component/orbiter/newcomp, original, list/arguments)
@@ -64,7 +59,7 @@
 			orbiter.orbiting.end_orbit(orbiter)
 	orbiters[orbiter] = TRUE
 	orbiter.orbiting = src
-	RegisterSignal(orbiter, COMSIG_MOVABLE_MOVED, orbiter_spy)
+	RegisterSignal(orbiter, COMSIG_MOVABLE_MOVED, .proc/orbiter_move_react)
 	var/matrix/initial_transform = matrix(orbiter.transform)
 
 	// Head first!
@@ -120,7 +115,7 @@
 	if(orbited?.loc && orbited.loc != newturf) // We want to know when anything holding us moves too
 		var/atom/target = orbited.loc
 		while(ismovableatom(target))
-			RegisterSignal(target, COMSIG_MOVABLE_MOVED, orbited_spy, TRUE)
+			RegisterSignal(target, COMSIG_MOVABLE_MOVED, .proc/move_react, TRUE)
 			target = target.loc
 
 	var/atom/curloc = master.loc

code/datums/components/phantomthief.dm

@@ -0,0 +1,39 @@
+//This component applies a customizable drop_shadow filter to its wearer when they toggle combat mode on or off. This can stack.
+
+/datum/component/wearertargeting/phantomthief
+	dupe_mode = COMPONENT_DUPE_UNIQUE_PASSARGS
+	signals = list(COMSIG_COMBAT_TOGGLED)
+	proctype = .proc/handlefilterstuff
+	var/filter_x
+	var/filter_y
+	var/filter_size
+	var/filter_border
+	var/filter_color
+
+/datum/component/wearertargeting/phantomthief/Initialize(_x = -2, _y = 0, _size = 0, _border = 0, _color = "#E62111", list/_valid_slots = list(SLOT_GLASSES))
+	. = ..()
+	if(. == COMPONENT_INCOMPATIBLE)
+		return
+	filter_x = _x
+	filter_y = _y
+	filter_size = _size
+	filter_border = _border
+	filter_color = _color
+	valid_slots = _valid_slots
+
+/datum/component/wearertargeting/phantomthief/proc/handlefilterstuff(datum/source, mob/user, combatmodestate)
+	if(istype(user))
+		var/thefilter = filter(type = "drop_shadow", x = filter_x, y = filter_y, size = filter_size, border = filter_border, color = filter_color)
+		if(!combatmodestate)
+			user.filters -= thefilter
+		else
+			user.filters += thefilter
+
+/datum/component/wearertargeting/phantomthief/proc/stripdesiredfilter(mob/user)
+	if(istype(user))
+		var/thefilter = filter(type = "drop_shadow", x = filter_x, y = filter_y, size = filter_size, border = filter_border, color = filter_color)
+		user.filters -= thefilter
+
+/datum/component/wearertargeting/phantomthief/on_drop(datum/source, mob/user)
+	. = ..()
+	stripdesiredfilter(user)

code/datums/components/rotation.dm

@@ -44,19 +44,21 @@
 	if(src.rotation_flags & ROTATION_CLOCKWISE)
 		default_rotation_direction = ROTATION_CLOCKWISE
 
-	if(src.rotation_flags & ROTATION_ALTCLICK)
+/datum/component/simple_rotation/proc/add_signals()
+	if(rotation_flags & ROTATION_ALTCLICK)
 		RegisterSignal(parent, COMSIG_CLICK_ALT, .proc/HandRot)
 		RegisterSignal(parent, COMSIG_PARENT_EXAMINE, .proc/ExamineMessage)
-	if(src.rotation_flags & ROTATION_WRENCH)
+	if(rotation_flags & ROTATION_WRENCH)
 		RegisterSignal(parent, COMSIG_PARENT_ATTACKBY, .proc/WrenchRot)
 
-	if(src.rotation_flags & ROTATION_VERBS)
+/datum/component/simple_rotation/proc/add_verbs()
+	if(rotation_flags & ROTATION_VERBS)
 		var/atom/movable/AM = parent
-		if(src.rotation_flags & ROTATION_FLIP)
+		if(rotation_flags & ROTATION_FLIP)
 			AM.verbs += /atom/movable/proc/simple_rotate_flip
-		if(src.rotation_flags & ROTATION_CLOCKWISE)
+		if(rotation_flags & ROTATION_CLOCKWISE)
 			AM.verbs += /atom/movable/proc/simple_rotate_clockwise
-		if(src.rotation_flags & ROTATION_COUNTERCLOCKWISE)
+		if(rotation_flags & ROTATION_COUNTERCLOCKWISE)
 			AM.verbs += /atom/movable/proc/simple_rotate_counterclockwise
 
 /datum/component/simple_rotation/proc/remove_verbs()
@@ -66,11 +68,31 @@
 		AM.verbs -= /atom/movable/proc/simple_rotate_clockwise
 		AM.verbs -= /atom/movable/proc/simple_rotate_counterclockwise
 
-/datum/component/simple_rotation/Destroy()
+
+/datum/component/simple_rotation/proc/remove_signals()
+		UnregisterSignal(parent, list(COMSIG_CLICK_ALT, COMSIG_PARENT_EXAMINE, COMSIG_PARENT_ATTACKBY))
+
+/datum/component/simple_rotation/RegisterWithParent()
+	add_verbs()
+	add_signals()
+	. = ..()
+
+/datum/component/simple_rotation/PostTransfer()
+	//Because of the callbacks which we don't track cleanly we can't transfer this
+	//item cleanly, better to let the new of the new item create a new rotation datum
+	//instead (there's no real state worth transferring)
+	return COMPONENT_NOTRANSFER
+
+/datum/component/simple_rotation/UnregisterFromParent()
 	remove_verbs()
+	remove_signals()
+	. = ..()
+
+/datum/component/simple_rotation/Destroy()
 	QDEL_NULL(can_user_rotate)
 	QDEL_NULL(can_be_rotated)
 	QDEL_NULL(after_rotation)
+	//Signals + verbs removed via UnRegister
 	. = ..()
 
 /datum/component/simple_rotation/RemoveComponent()

code/datums/components/signal_redirect.dm

@@ -1,33 +0,0 @@
-// This should only be used by non components trying to listen to a signal
-// If you use this inside a component I will replace your eyes with lemons ~ninjanomnom
-
-/datum/component/redirect
-	dupe_mode = COMPONENT_DUPE_ALLOWED
-	var/list/signals
-	var/datum/callback/turfchangeCB
-
-/datum/component/redirect/Initialize(list/_signals, flags=NONE)
-	//It's not our job to verify the right signals are registered here, just do it.
-	if(!LAZYLEN(_signals))
-		return COMPONENT_INCOMPATIBLE
-	if(flags & REDIRECT_TRANSFER_WITH_TURF && isturf(parent))
-		// If they also want to listen to the turf change then we need to set it up so both callbacks run
-		if(_signals[COMSIG_TURF_CHANGE])
-			turfchangeCB = _signals[COMSIG_TURF_CHANGE]
-			if(!istype(turfchangeCB))
-				. = COMPONENT_INCOMPATIBLE
-				CRASH("Redirect components must be given instanced callbacks, not proc paths.")
-		_signals[COMSIG_TURF_CHANGE] = CALLBACK(src, .proc/turf_change)
-	
-	signals = _signals
-
-/datum/component/redirect/RegisterWithParent()
-	for(var/signal in signals)
-		RegisterSignal(parent, signal, signals[signal])
-
-/datum/component/redirect/UnregisterFromParent()
-	UnregisterSignal(parent, signals)
-
-/datum/component/redirect/proc/turf_change(datum/source, path, new_baseturfs, flags, list/transfers)
-	transfers += src
-	return turfchangeCB?.InvokeAsync(arglist(args))

code/datums/components/storage/concrete/_concrete.dm

@@ -4,6 +4,7 @@
 // /mob/living/Move() in /modules/mob/living/living.dm - hiding storage boxes on mob movement
 
 /datum/component/storage/concrete
+	can_transfer = TRUE
 	var/drop_all_on_deconstruct = TRUE
 	var/drop_all_on_destroy = FALSE
 	var/drop_all_on_break = FALSE

code/datums/components/virtual_reality.dm

@@ -1,5 +1,5 @@
 /datum/component/virtual_reality
-	dupe_mode = COMPONENT_DUPE_ALLOWED //mindswap memes, shouldn't stack up otherwise.
+	can_transfer = TRUE
 	var/datum/mind/mastermind // where is my mind t. pixies
 	var/datum/mind/current_mind
 	var/obj/machinery/vr_sleeper/vr_sleeper

code/datums/components/wearertargeting.dm

@@ -3,7 +3,7 @@
 /datum/component/wearertargeting
 	var/list/valid_slots = list()
 	var/list/signals = list()
-	var/datum/callback/callback = CALLBACK(GLOBAL_PROC, .proc/pass)
+	var/proctype = .proc/pass
 	var/mobtype = /mob/living
 
 /datum/component/wearertargeting/Initialize()
@@ -14,13 +14,9 @@
 
 /datum/component/wearertargeting/proc/on_equip(datum/source, mob/equipper, slot)
 	if((slot in valid_slots) && istype(equipper, mobtype))
-		RegisterSignal(equipper, signals, callback, TRUE)
+		RegisterSignal(equipper, signals, proctype, TRUE)
 	else
 		UnregisterSignal(equipper, signals)
 
 /datum/component/wearertargeting/proc/on_drop(datum/source, mob/user)
-	UnregisterSignal(user, signals)
-
-/datum/component/wearertargeting/Destroy()
-	QDEL_NULL(callback) //is likely to ourselves.
-	return ..()
+	UnregisterSignal(user, signals)

code/datums/components/wet_floor.dm

@@ -1,5 +1,6 @@
 /datum/component/wet_floor
 	dupe_mode = COMPONENT_DUPE_UNIQUE_PASSARGS
+	can_transfer = TRUE
 	var/highest_strength = TURF_DRY
 	var/lube_flags = NONE			//why do we have this?
 	var/list/time_left_list			//In deciseconds.
@@ -26,14 +27,19 @@
 	if(!isopenturf(parent))
 		return COMPONENT_INCOMPATIBLE
 	add_wet(strength, duration_minimum, duration_add, duration_maximum)
-	RegisterSignal(parent, COMSIG_TURF_IS_WET, .proc/is_wet)
-	RegisterSignal(parent, COMSIG_TURF_MAKE_DRY, .proc/dry)
 	permanent = _permanent
 	if(!permanent)
 		START_PROCESSING(SSwet_floors, src)
 	addtimer(CALLBACK(src, .proc/gc, TRUE), 1)		//GC after initialization.
 	last_process = world.time
 
+/datum/component/wet_floor/RegisterWithParent()
+	RegisterSignal(parent, COMSIG_TURF_IS_WET, .proc/is_wet)
+	RegisterSignal(parent, COMSIG_TURF_MAKE_DRY, .proc/dry)
+
+/datum/component/wet_floor/UnregisterFromParent()
+	UnregisterSignal(parent, list(COMSIG_TURF_IS_WET, COMSIG_TURF_MAKE_DRY))
+
 /datum/component/wet_floor/Destroy()
 	STOP_PROCESSING(SSwet_floors, src)
 	var/turf/T = parent
@@ -138,12 +144,19 @@
 /datum/component/wet_floor/PreTransfer()
 	var/turf/O = parent
 	O.cut_overlay(current_overlay)
+	//That turf is no longer slippery, we're out of here
+	//Slippery components don't transfer due to callbacks
+	qdel(O.GetComponent(/datum/component/slippery))
 
 /datum/component/wet_floor/PostTransfer()
 	if(!isopenturf(parent))
 		return COMPONENT_INCOMPATIBLE
 	var/turf/T = parent
 	T.add_overlay(current_overlay)
+	//Make sure to add/update any slippery component on the new turf (update_flags calls LoadComponent)
+	update_flags()
+
+	//NB it's possible we get deleted after this, due to inherit
 
 /datum/component/wet_floor/proc/add_wet(type, duration_minimum = 0, duration_add = 0, duration_maximum = MAXIMUM_WET_TIME, _permanent = FALSE)
 	var/static/list/allowed_types = list(TURF_WET_WATER, TURF_WET_LUBE, TURF_WET_ICE, TURF_WET_PERMAFROST)

code/datums/status_effects/gas.dm

@@ -5,7 +5,6 @@
 	alert_type = /obj/screen/alert/status_effect/freon
 	var/icon/cube
 	var/can_melt = TRUE
-	var/datum/weakref/redirect_component
 
 /obj/screen/alert/status_effect/freon
 	name = "Frozen Solid"
@@ -13,7 +12,7 @@
 	icon_state = "frozen"
 
 /datum/status_effect/freon/on_apply()
-	redirect_component = WEAKREF(owner.AddComponent(/datum/component/redirect, list(COMSIG_LIVING_RESIST = CALLBACK(src, .proc/owner_resist))))
+	RegisterSignal(owner, COMSIG_LIVING_RESIST, .proc/owner_resist)
 	if(!owner.stat)
 		to_chat(owner, "<span class='userdanger'>You become frozen in a cube!</span>")
 	cube = icon('icons/effects/freeze.dmi', "ice_cube")
@@ -40,8 +39,7 @@
 	owner.cut_overlay(cube)
 	owner.adjust_bodytemperature(100)
 	owner.update_canmove()
-	qdel(redirect_component.resolve())
-	redirect_component = null
+	UnregisterSignal(owner, COMSIG_LIVING_RESIST)
 
 /datum/status_effect/freon/watcher
 	duration = 8