bd37d45334
* ports all the tg junk for icemoon, not yet changed to make it all compile * fixes * fixes * fixes * fixes * fixes * new stuff * whew * fixes * it compiles, now to fix the maps * fixes the maps * fixes solars + removes the space tiles in the toxins burn chamber * nukes the SpawnTerrain proc used for tg geysers * linter fix * fix * fixes the non matching turf atmos (hopefully) * more mapping fixes * dmm2tgm * unfucks changeturf for the more_caves * fixes the volanic subtypes of the other thing * fixes the stupid fucking tile placing list * some map fixes, fixes the station_ruin loader shitting out errors this commit took 2 hours of my fucking life * fixes a bunch of mismatch atmos in ruins * fixes wendigo cave having no air * backwards couch backwards couch * fixes the SM up * wendigos can't runtime when butchering if you can't butcher them 😎 * makes the wendigo fight have the same atmos as the surrounding icemoon * Tweaks atmos mixture from o2=22;n2=82;TEMP=180 to o2=18;n2=63;TEMP=180, making lavaland weapons actually work * makes the wendigo screech shake not completely aids * fixes snowlegion portals dropping proper legions instead of skeles * brings the engioutpost ruin over as well * whoopps * empty commit to reroll bots * Fixes pirates, ops, the mining base, and gives pirates and ops drills * fixes lone ops and ninjas * fixes the snowed plating getting fucked when tiles are placed on it * removes some OP junk from the wabbajack pool (aka removes non-antag headslugs again) * more bug fixes * empty commit to reroll bots * hopefully finally kills the active turfs on the library ruin Co-authored-by: kevinz000 <2003111+kevinz000@users.noreply.github.com>
101 lines
3.5 KiB
Plaintext
101 lines
3.5 KiB
Plaintext
/mob/living/carbon/human/get_movespeed_modifiers()
|
|
var/list/considering = ..()
|
|
if(HAS_TRAIT(src, TRAIT_IGNORESLOWDOWN))
|
|
. = list()
|
|
for(var/id in considering)
|
|
var/datum/movespeed_modifier/M = considering[id]
|
|
if(M.flags & IGNORE_NOSLOW || M.multiplicative_slowdown < 0)
|
|
.[id] = M
|
|
return
|
|
return considering
|
|
|
|
/mob/living/carbon/human/movement_delay()
|
|
. = ..()
|
|
if(CHECK_MOBILITY(src, MOBILITY_STAND) && m_intent == MOVE_INTENT_RUN && (combat_flags & COMBAT_FLAG_SPRINT_ACTIVE))
|
|
var/static/datum/config_entry/number/movedelay/sprint_speed_increase/SSI
|
|
if(!SSI)
|
|
SSI = CONFIG_GET_ENTRY(number/movedelay/sprint_speed_increase)
|
|
. -= SSI.config_entry_value
|
|
if(wrongdirmovedelay)
|
|
. += 1
|
|
if (m_intent == MOVE_INTENT_WALK && HAS_TRAIT(src, TRAIT_SPEEDY_STEP))
|
|
. -= 1.5
|
|
|
|
/mob/living/carbon/human/slip(knockdown_amount, obj/O, lube)
|
|
if(HAS_TRAIT(src, TRAIT_NOSLIPALL))
|
|
return 0
|
|
if (!(lube & GALOSHES_DONT_HELP))
|
|
if(HAS_TRAIT(src, TRAIT_NOSLIPWATER))
|
|
return 0
|
|
if(shoes && istype(shoes, /obj/item/clothing))
|
|
var/obj/item/clothing/CS = shoes
|
|
if (CS.clothing_flags & NOSLIP)
|
|
return 0
|
|
if (lube & SLIDE_ICE)
|
|
if(shoes && istype(shoes, /obj/item/clothing))
|
|
var/obj/item/clothing/CS = shoes
|
|
if (CS.clothing_flags & NOSLIP_ICE)
|
|
return FALSE
|
|
return ..()
|
|
|
|
/mob/living/carbon/human/experience_pressure_difference()
|
|
playsound(src, 'sound/effects/space_wind.ogg', 50, 1)
|
|
if(shoes && istype(shoes, /obj/item/clothing))
|
|
var/obj/item/clothing/S = shoes
|
|
if (S.clothing_flags & NOSLIP)
|
|
return 0
|
|
return ..()
|
|
|
|
/mob/living/carbon/human/mob_has_gravity()
|
|
. = ..()
|
|
if(!.)
|
|
if(mob_negates_gravity())
|
|
. = 1
|
|
|
|
/mob/living/carbon/human/mob_negates_gravity()
|
|
return ((shoes && shoes.negates_gravity()) || (dna.species.negates_gravity(src)))
|
|
|
|
/mob/living/carbon/human/Move(NewLoc, direct)
|
|
var/oldpseudoheight = pseudo_z_axis
|
|
. = ..()
|
|
for(var/datum/mutation/human/HM in dna.mutations)
|
|
HM.on_move(NewLoc)
|
|
if(. && (combat_flags & COMBAT_FLAG_SPRINT_ACTIVE) && !(movement_type & FLYING) && CHECK_ALL_MOBILITY(src, MOBILITY_MOVE|MOBILITY_STAND) && m_intent == MOVE_INTENT_RUN && has_gravity(loc) && !pulledby)
|
|
if(!HAS_TRAIT(src, TRAIT_FREESPRINT))
|
|
doSprintLossTiles(1)
|
|
if((oldpseudoheight - pseudo_z_axis) >= 8)
|
|
to_chat(src, "<span class='warning'>You trip off of the elevated surface!</span>")
|
|
for(var/obj/item/I in held_items)
|
|
accident(I)
|
|
DefaultCombatKnockdown(80)
|
|
if(shoes)
|
|
if(!lying && !buckled)
|
|
if(loc == NewLoc)
|
|
if(!has_gravity(loc))
|
|
return
|
|
var/obj/item/clothing/shoes/S = shoes
|
|
|
|
//Bloody footprints
|
|
var/turf/T = get_turf(src)
|
|
if(S.bloody_shoes && S.bloody_shoes[S.blood_state])
|
|
var/obj/effect/decal/cleanable/blood/footprints/oldFP = locate(/obj/effect/decal/cleanable/blood/footprints) in T
|
|
if(oldFP && (oldFP.blood_state == S.blood_state && oldFP.color == bloodtype_to_color(S.last_bloodtype)))
|
|
return
|
|
S.bloody_shoes[S.blood_state] = max(0, S.bloody_shoes[S.blood_state] - BLOOD_LOSS_PER_STEP)
|
|
var/obj/effect/decal/cleanable/blood/footprints/FP = new /obj/effect/decal/cleanable/blood/footprints(T)
|
|
FP.blood_state = S.blood_state
|
|
FP.entered_dirs |= dir
|
|
FP.bloodiness = S.bloody_shoes[S.blood_state]
|
|
if(S.last_bloodtype)
|
|
FP.blood_DNA += list(S.last_blood_DNA = S.last_bloodtype)
|
|
FP.update_icon()
|
|
update_inv_shoes()
|
|
//End bloody footprints
|
|
|
|
S.step_action()
|
|
|
|
/mob/living/carbon/human/Process_Spacemove(movement_dir = 0) //Temporary laziness thing. Will change to handles by species reee.
|
|
if(dna.species.space_move(src))
|
|
return TRUE
|
|
return ..()
|