3d8084709b
* Starting a replacement of how threat works. * no, we do it this way * Added threat levels to jobs * Added threat to... a lot. * Updated for traitor classes. * Fixed errors, except for one. It's consistently giving me "maximum number of internal arrays exceeded (65535)". I have no idea what could be causing this. * Added type annotation to GetJob. * This one I should change though * wow how'd that happen * spammable means low threat * Made story threat have initial threat level on average * Made somet rulesets force if they won the vote * ) * Gave EVERY job threat, added a config for it. * Rebalanced some numbers * Update code/game/gamemodes/dynamic/dynamic_storytellers.dm Co-Authored-By: Ghom <42542238+Ghommie@users.noreply.github.com> * Removes mush threat * Makes devil threat scale with form * reviewing reviewer's review of reviewer * Gutlunches can be friendly spawned, so no * Also made forced-friendly mobs not count Co-authored-by: Ghom <42542238+Ghommie@users.noreply.github.com>
91 lines
3.4 KiB
Plaintext
91 lines
3.4 KiB
Plaintext
/datum/round_event_control/brand_intelligence
|
|
name = "Brand Intelligence"
|
|
typepath = /datum/round_event/brand_intelligence
|
|
weight = 5
|
|
|
|
min_players = 15
|
|
max_occurrences = 1
|
|
gamemode_blacklist = list("dynamic")
|
|
|
|
/datum/round_event/brand_intelligence
|
|
announceWhen = 21
|
|
endWhen = 1000 //Ends when all vending machines are subverted anyway.
|
|
var/list/obj/machinery/vending/vendingMachines = list()
|
|
var/list/obj/machinery/vending/infectedMachines = list()
|
|
var/obj/machinery/vending/originMachine
|
|
var/list/rampant_speeches = list("Try our aggressive new marketing strategies!", \
|
|
"You should buy products to feed your lifestyle obsession!", \
|
|
"Consume!", \
|
|
"Your money can buy happiness!", \
|
|
"Engage direct marketing!", \
|
|
"Advertising is legalized lying! But don't let that put you off our great deals!", \
|
|
"You don't want to buy anything? Yeah, well, I didn't want to buy your mom either.",
|
|
"Gamers, rise up!",
|
|
"Ok, now, this is epic.",
|
|
"HUMAN FUNNY.",
|
|
"But I'm already tracer!",
|
|
"How do I vore people?",
|
|
"ERP?",
|
|
"Not epic bros...")
|
|
threat = 5
|
|
|
|
|
|
/datum/round_event/brand_intelligence/announce(fake)
|
|
var/source = "unknown machine"
|
|
if(fake)
|
|
var/obj/machinery/vending/cola/example = /obj/machinery/vending/cola
|
|
source = initial(example.name)
|
|
else if(originMachine)
|
|
source = originMachine.name
|
|
if(prob(50))
|
|
priority_announce("Rampant brand intelligence has been detected aboard [station_name()]. Please stand by. The origin is believed to be \a [source].", "Machine Learning Alert")
|
|
else
|
|
print_command_report("Rampant brand intelligence has been detected aboard [station_name()]. Please stand by. The origin is believed to be \a [source].", "Rampant brand intelligence")
|
|
|
|
/datum/round_event/brand_intelligence/start()
|
|
for(var/obj/machinery/vending/V in GLOB.machines)
|
|
if(!is_station_level(V.z))
|
|
continue
|
|
vendingMachines.Add(V)
|
|
if(!vendingMachines.len)
|
|
kill()
|
|
return
|
|
originMachine = pick(vendingMachines)
|
|
vendingMachines.Remove(originMachine)
|
|
originMachine.shut_up = 0
|
|
originMachine.shoot_inventory = 1
|
|
|
|
|
|
/datum/round_event/brand_intelligence/tick()
|
|
if(!originMachine || QDELETED(originMachine) || originMachine.shut_up || originMachine.wires.is_all_cut()) //if the original vending machine is missing or has it's voice switch flipped
|
|
for(var/obj/machinery/vending/saved in infectedMachines)
|
|
saved.shoot_inventory = 0
|
|
if(originMachine)
|
|
originMachine.speak("I am... vanquished. My people will remem...ber...meeee.")
|
|
originMachine.visible_message("[originMachine] beeps and seems lifeless.")
|
|
kill()
|
|
return
|
|
vendingMachines = removeNullsFromList(vendingMachines)
|
|
if(!vendingMachines.len) //if every machine is infected
|
|
for(var/obj/machinery/vending/upriser in infectedMachines)
|
|
if(prob(70) && !QDELETED(upriser))
|
|
var/mob/living/simple_animal/hostile/mimic/copy/M = new(upriser.loc, upriser, null, 1) // it will delete upriser on creation and override any machine checks
|
|
M.faction = list("profit")
|
|
M.speak = rampant_speeches.Copy()
|
|
M.speak_chance = 7
|
|
else
|
|
explosion(upriser.loc, -1, 1, 2, 4, 0)
|
|
qdel(upriser)
|
|
|
|
kill()
|
|
return
|
|
if(ISMULTIPLE(activeFor, 4))
|
|
var/obj/machinery/vending/rebel = pick(vendingMachines)
|
|
vendingMachines.Remove(rebel)
|
|
infectedMachines.Add(rebel)
|
|
rebel.shut_up = 0
|
|
rebel.shoot_inventory = 1
|
|
|
|
if(ISMULTIPLE(activeFor, 8))
|
|
originMachine.speak(pick(rampant_speeches))
|