7e9b96a00f
* Maps and things no code/icons * helpers defines globalvars * Onclick world.dm orphaned_procs * subsystems Round vote and shuttle autocall done here too * datums * Game folder * Admin - chatter modules * clothing - mining * modular computers - zambies * client * mob level 1 * mob stage 2 + simple_animal * silicons n brains * mob stage 3 + Alien/Monkey * human mobs * icons updated * some sounds * emitter y u no commit * update tgstation.dme * compile fixes * travis fixes Also removes Fast digest mode, because reasons. * tweaks for travis Mentors are broke again Also fixes Sizeray guns * oxygen loss fix for vore code. * removes unused code * some code updates * bulk fixes * further fixes * outside things * whoops. * Maint bar ported * GLOBs.
99 lines
3.1 KiB
Plaintext
99 lines
3.1 KiB
Plaintext
#define PROXIMITY_NONE ""
|
|
#define PROXIMITY_ON_SCREEN "_red"
|
|
#define PROXIMITY_NEAR "_yellow"
|
|
|
|
/**
|
|
* Multitool -- A multitool is used for hacking electronic devices.
|
|
* TO-DO -- Using it as a power measurement tool for cables etc. Nannek.
|
|
*
|
|
*/
|
|
|
|
/obj/item/device/multitool
|
|
name = "multitool"
|
|
desc = "Used for pulsing wires to test which to cut. Not recommended by doctors."
|
|
icon_state = "multitool"
|
|
force = 5
|
|
w_class = WEIGHT_CLASS_SMALL
|
|
throwforce = 0
|
|
throw_range = 7
|
|
throw_speed = 3
|
|
materials = list(MAT_METAL=50, MAT_GLASS=20)
|
|
origin_tech = "magnets=1;engineering=2"
|
|
var/obj/machinery/buffer // simple machine buffer for device linkage
|
|
hitsound = 'sound/weapons/tap.ogg'
|
|
toolspeed = 1
|
|
|
|
|
|
// Syndicate device disguised as a multitool; it will turn red when an AI camera is nearby.
|
|
|
|
|
|
/obj/item/device/multitool/ai_detect
|
|
var/track_cooldown = 0
|
|
var/track_delay = 10 //How often it checks for proximity
|
|
var/detect_state = PROXIMITY_NONE
|
|
var/rangealert = 8 //Glows red when inside
|
|
var/rangewarning = 20 //Glows yellow when inside
|
|
origin_tech = "magnets=1;engineering=2;syndicate=1"
|
|
|
|
/obj/item/device/multitool/ai_detect/New()
|
|
..()
|
|
START_PROCESSING(SSobj, src)
|
|
|
|
/obj/item/device/multitool/ai_detect/Destroy()
|
|
STOP_PROCESSING(SSobj, src)
|
|
return ..()
|
|
|
|
/obj/item/device/multitool/ai_detect/process()
|
|
if(track_cooldown > world.time)
|
|
return
|
|
detect_state = PROXIMITY_NONE
|
|
multitool_detect()
|
|
icon_state = "[initial(icon_state)][detect_state]"
|
|
track_cooldown = world.time + track_delay
|
|
|
|
/obj/item/device/multitool/ai_detect/proc/multitool_detect()
|
|
var/turf/our_turf = get_turf(src)
|
|
for(var/mob/living/silicon/ai/AI in GLOB.ai_list)
|
|
if(AI.cameraFollow == src)
|
|
detect_state = PROXIMITY_ON_SCREEN
|
|
break
|
|
|
|
if(!detect_state && GLOB.cameranet.chunkGenerated(our_turf.x, our_turf.y, our_turf.z))
|
|
var/datum/camerachunk/chunk = GLOB.cameranet.getCameraChunk(our_turf.x, our_turf.y, our_turf.z)
|
|
if(chunk)
|
|
if(chunk.seenby.len)
|
|
for(var/mob/camera/aiEye/A in chunk.seenby)
|
|
var/turf/detect_turf = get_turf(A)
|
|
if(get_dist(our_turf, detect_turf) < rangealert)
|
|
detect_state = PROXIMITY_ON_SCREEN
|
|
break
|
|
if(get_dist(our_turf, detect_turf) < rangewarning)
|
|
detect_state = PROXIMITY_NEAR
|
|
break
|
|
|
|
/obj/item/device/multitool/ai_detect/admin
|
|
desc = "Used for pulsing wires to test which to cut. Not recommended by doctors. Has a strange tag that says 'Grief in Safety'" //What else should I say for a meme item?
|
|
track_delay = 5
|
|
|
|
/obj/item/device/multitool/ai_detect/admin/multitool_detect()
|
|
var/turf/our_turf = get_turf(src)
|
|
for(var/mob/J in urange(rangewarning,our_turf))
|
|
if(GLOB.admin_datums[J.ckey])
|
|
detect_state = PROXIMITY_NEAR
|
|
var/turf/detect_turf = get_turf(J)
|
|
if(get_dist(our_turf, detect_turf) < rangealert)
|
|
detect_state = PROXIMITY_ON_SCREEN
|
|
break
|
|
|
|
/obj/item/device/multitool/cyborg
|
|
name = "multitool"
|
|
desc = "Optimised and stripped-down version of a regular multitool."
|
|
toolspeed = 0.5
|
|
|
|
/obj/item/device/multitool/abductor
|
|
name = "alien multitool"
|
|
desc = "An omni-technological interface."
|
|
icon = 'icons/obj/abductor.dmi'
|
|
icon_state = "multitool"
|
|
toolspeed = 0.1
|
|
origin_tech = "magnets=5;engineering=5;abductor=3" |