cf59ac1c3d
* sync (#3) * shuttle auto call * Merge /vore into /master (#39) * progress * Compile errors fixed No idea if it's test worthy tho as conflicts with race overhaul and narky removal. * Update admins.txt * efforts continue Fuck grab code, seriously * grab code is cancer * Execute the Narkism Do not hesitate. Show no mercy. * holy shit grab code is awful * have I bitched about grab code My bitching, let me show you it * código de agarre es una mierda No really it is * yeah I don't even know anymore. * Lolnope. Fuck grab code * I'm not even sure what to fix anymore * Self eating is not an acceptable fate * Taste the void, son. * My code doesn't pass it's own sanity check. Maybe it's a sign of things to come. * uncommented and notes * It Works and I Don't Know Why (#38) * shuttle auto call * it works and I don't know why * Subsystem 12/21 Most Recent TG subsystem folder * globalvars 12/21 Tossed out the flavor_misc and parallax files * Onclick 12/21 as well as .dme updates * _defines 12/21 ommited old _MC.dm * _HELPERS 12/21 Preserved snowflake placement of furry sprites * _defeines/genetics reapplied narkism holdover for snowflake races. * Oops forgot mutant colors * modules porting 12/21 + Sounds/icons Admin, Client and most of mob life files ommitted * enviroment file * Admin optimizations ahelp log system kept * Mob ports 12/21 Flavor text preserved * datums ported 12/21 * Game ported 12/21 * batch of duplicate fixes/dogborg work Dogborgs need to be modernized to refractored borg standards. * moar fixes * Maps and futher compile fixes
109 lines
3.3 KiB
Plaintext
109 lines
3.3 KiB
Plaintext
/**********************Mint**************************/
|
|
|
|
|
|
/obj/machinery/mineral/mint
|
|
name = "coin press"
|
|
icon = 'icons/obj/economy.dmi'
|
|
icon_state = "coinpress0"
|
|
density = 1
|
|
anchored = 1
|
|
var/datum/material_container/materials
|
|
var/newCoins = 0 //how many coins the machine made in it's last load
|
|
var/processing = 0
|
|
var/chosen = MAT_METAL //which material will be used to make coins
|
|
var/coinsToProduce = 10
|
|
speed_process = 1
|
|
|
|
|
|
/obj/machinery/mineral/mint/New()
|
|
..()
|
|
materials = new /datum/material_container(src,
|
|
list(MAT_METAL, MAT_PLASMA, MAT_SILVER, MAT_GOLD, MAT_URANIUM, MAT_DIAMOND, MAT_BANANIUM),
|
|
max_amt = MINERAL_MATERIAL_AMOUNT*50)
|
|
|
|
/obj/machinery/mineral/mint/Destroy()
|
|
qdel(materials)
|
|
materials = null
|
|
return ..()
|
|
|
|
|
|
/obj/machinery/mineral/mint/process()
|
|
var/turf/T = get_step(src, input_dir)
|
|
if(!T)
|
|
return
|
|
|
|
for(var/obj/item/stack/sheet/O in T)
|
|
materials.insert_stack(O, O.amount)
|
|
|
|
/obj/machinery/mineral/mint/attack_hand(mob/user)
|
|
var/dat = "<b>Coin Press</b><br>"
|
|
|
|
for(var/mat_id in materials.materials)
|
|
var/datum/material/M = materials.materials[mat_id]
|
|
if(!M.amount && chosen != mat_id)
|
|
continue
|
|
dat += "<br><b>[M.name] amount:</b> [M.amount] cm<sup>3</sup> "
|
|
if (chosen == mat_id)
|
|
dat += "<b>Chosen</b>"
|
|
else
|
|
dat += "<A href='?src=\ref[src];choose=[mat_id]'>Choose</A>"
|
|
|
|
var/datum/material/M = materials.materials[chosen]
|
|
|
|
dat += "<br><br>Will produce [coinsToProduce] [lowertext(M.name)] coins if enough materials are available.<br>"
|
|
dat += "<A href='?src=\ref[src];chooseAmt=-10'>-10</A> "
|
|
dat += "<A href='?src=\ref[src];chooseAmt=-5'>-5</A> "
|
|
dat += "<A href='?src=\ref[src];chooseAmt=-1'>-1</A> "
|
|
dat += "<A href='?src=\ref[src];chooseAmt=1'>+1</A> "
|
|
dat += "<A href='?src=\ref[src];chooseAmt=5'>+5</A> "
|
|
dat += "<A href='?src=\ref[src];chooseAmt=10'>+10</A> "
|
|
|
|
dat += "<br><br>In total this machine produced <font color='green'><b>[newCoins]</b></font> coins."
|
|
dat += "<br><A href='?src=\ref[src];makeCoins=[1]'>Make coins</A>"
|
|
user << browse(dat, "window=mint")
|
|
|
|
/obj/machinery/mineral/mint/Topic(href, href_list)
|
|
if(..())
|
|
return
|
|
usr.set_machine(src)
|
|
src.add_fingerprint(usr)
|
|
if(processing==1)
|
|
usr << "<span class='notice'>The machine is processing.</span>"
|
|
return
|
|
if(href_list["choose"])
|
|
if(materials.materials[href_list["choose"]])
|
|
chosen = href_list["choose"]
|
|
if(href_list["chooseAmt"])
|
|
coinsToProduce = Clamp(coinsToProduce + text2num(href_list["chooseAmt"]), 0, 1000)
|
|
if(href_list["makeCoins"])
|
|
var/temp_coins = coinsToProduce
|
|
processing = 1
|
|
icon_state = "coinpress1"
|
|
var/coin_mat = MINERAL_MATERIAL_AMOUNT * 0.2
|
|
var/datum/material/M = materials.materials[chosen]
|
|
if(!M || !M.coin_type)
|
|
updateUsrDialog()
|
|
return
|
|
|
|
while(coinsToProduce > 0 && materials.use_amount_type(coin_mat, chosen))
|
|
create_coins(M.coin_type)
|
|
coinsToProduce--
|
|
newCoins++
|
|
src.updateUsrDialog()
|
|
sleep(5)
|
|
|
|
icon_state = "coinpress0"
|
|
processing = 0
|
|
coinsToProduce = temp_coins
|
|
src.updateUsrDialog()
|
|
return
|
|
|
|
/obj/machinery/mineral/mint/proc/create_coins(P)
|
|
var/turf/T = get_step(src,output_dir)
|
|
if(T)
|
|
var/obj/item/O = new P(src)
|
|
var/obj/item/weapon/storage/bag/money/M = locate(/obj/item/weapon/storage/bag/money, T)
|
|
if(!M)
|
|
M = new /obj/item/weapon/storage/bag/money(src)
|
|
unload_mineral(M)
|
|
O.loc = M |