PoojawaandGitHub
cf59ac1c3d
* sync (#3) * shuttle auto call * Merge /vore into /master (#39) * progress * Compile errors fixed No idea if it's test worthy tho as conflicts with race overhaul and narky removal. * Update admins.txt * efforts continue Fuck grab code, seriously * grab code is cancer * Execute the Narkism Do not hesitate. Show no mercy. * holy shit grab code is awful * have I bitched about grab code My bitching, let me show you it * código de agarre es una mierda No really it is * yeah I don't even know anymore. * Lolnope. Fuck grab code * I'm not even sure what to fix anymore * Self eating is not an acceptable fate * Taste the void, son. * My code doesn't pass it's own sanity check. Maybe it's a sign of things to come. * uncommented and notes * It Works and I Don't Know Why (#38) * shuttle auto call * it works and I don't know why * Subsystem 12/21 Most Recent TG subsystem folder * globalvars 12/21 Tossed out the flavor_misc and parallax files * Onclick 12/21 as well as .dme updates * _defines 12/21 ommited old _MC.dm * _HELPERS 12/21 Preserved snowflake placement of furry sprites * _defeines/genetics reapplied narkism holdover for snowflake races. * Oops forgot mutant colors * modules porting 12/21 + Sounds/icons Admin, Client and most of mob life files ommitted * enviroment file * Admin optimizations ahelp log system kept * Mob ports 12/21 Flavor text preserved * datums ported 12/21 * Game ported 12/21 * batch of duplicate fixes/dogborg work Dogborgs need to be modernized to refractored borg standards. * moar fixes * Maps and futher compile fixes
123 lines
4.3 KiB
Plaintext
123 lines
4.3 KiB
Plaintext
/mob/living/carbon/alien/humanoid
|
|
name = "alien"
|
|
icon_state = "alien_s"
|
|
pass_flags = PASSTABLE
|
|
butcher_results = list(/obj/item/weapon/reagent_containers/food/snacks/meat/slab/xeno = 5, /obj/item/stack/sheet/animalhide/xeno = 1)
|
|
limb_destroyer = 1
|
|
var/obj/item/r_store = null
|
|
var/obj/item/l_store = null
|
|
var/caste = ""
|
|
var/alt_icon = 'icons/mob/alienleap.dmi' //used to switch between the two alien icon files.
|
|
var/leap_on_click = 0
|
|
var/pounce_cooldown = 0
|
|
var/pounce_cooldown_time = 30
|
|
var/custom_pixel_x_offset = 0 //for admin fuckery.
|
|
var/custom_pixel_y_offset = 0
|
|
var/sneaking = 0 //For sneaky-sneaky mode and appropriate slowdown
|
|
var/drooling = 0 //For Neruotoxic spit overlays
|
|
bodyparts = list(/obj/item/bodypart/chest/alien, /obj/item/bodypart/head/alien, /obj/item/bodypart/l_arm/alien,
|
|
/obj/item/bodypart/r_arm/alien, /obj/item/bodypart/r_leg/alien, /obj/item/bodypart/l_leg/alien)
|
|
|
|
|
|
//This is fine right now, if we're adding organ specific damage this needs to be updated
|
|
/mob/living/carbon/alien/humanoid/New()
|
|
AddAbility(new/obj/effect/proc_holder/alien/regurgitate(null))
|
|
..()
|
|
|
|
/mob/living/carbon/alien/humanoid/movement_delay()
|
|
. = ..()
|
|
. += move_delay_add + config.alien_delay + sneaking //move_delay_add is used to slow aliens with stuns
|
|
|
|
/mob/living/carbon/alien/humanoid/restrained(ignore_grab)
|
|
. = handcuffed
|
|
|
|
|
|
/mob/living/carbon/alien/humanoid/show_inv(mob/user)
|
|
user.set_machine(src)
|
|
var/list/dat = list()
|
|
dat += {"
|
|
<HR>
|
|
<B><FONT size=3>[name]</FONT></B>
|
|
<HR>"}
|
|
for(var/i in 1 to held_items.len)
|
|
var/obj/item/I = get_item_for_held_index(i)
|
|
dat += "<BR><B>[get_held_index_name(i)]:</B><A href='?src=\ref[src];item=[slot_hands];hand_index=[i]'>[(I && !(I.flags & ABSTRACT)) ? I : "<font color=grey>Empty</font>"]</a>"
|
|
dat += "<BR><A href='?src=\ref[src];pouches=1'>Empty Pouches</A>"
|
|
|
|
if(handcuffed)
|
|
dat += "<BR><A href='?src=\ref[src];item=[slot_handcuffed]'>Handcuffed</A>"
|
|
if(legcuffed)
|
|
dat += "<BR><A href='?src=\ref[src];item=[slot_legcuffed]'>Legcuffed</A>"
|
|
|
|
dat += {"
|
|
<BR>
|
|
<BR><A href='?src=\ref[user];mach_close=mob\ref[src]'>Close</A>
|
|
"}
|
|
user << browse(dat.Join(), "window=mob\ref[src];size=325x500")
|
|
onclose(user, "mob\ref[src]")
|
|
|
|
|
|
/mob/living/carbon/alien/humanoid/Topic(href, href_list)
|
|
..()
|
|
//strip panel
|
|
if(usr.canUseTopic(src, BE_CLOSE, NO_DEXTERY))
|
|
if(href_list["pouches"])
|
|
visible_message("<span class='danger'>[usr] tries to empty [src]'s pouches.</span>", \
|
|
"<span class='userdanger'>[usr] tries to empty [src]'s pouches.</span>")
|
|
if(do_mob(usr, src, POCKET_STRIP_DELAY * 0.5))
|
|
unEquip(r_store)
|
|
unEquip(l_store)
|
|
|
|
/mob/living/carbon/alien/humanoid/cuff_resist(obj/item/I)
|
|
playsound(src, 'sound/voice/hiss5.ogg', 40, 1, 1) //Alien roars when starting to break free
|
|
..(I, cuff_break = INSTANT_CUFFBREAK)
|
|
|
|
/mob/living/carbon/alien/humanoid/resist_grab(moving_resist)
|
|
if(pulledby.grab_state)
|
|
visible_message("<span class='danger'>[src] has broken free of [pulledby]'s grip!</span>")
|
|
pulledby.stop_pulling()
|
|
. = 0
|
|
|
|
/mob/living/carbon/alien/humanoid/get_standard_pixel_y_offset(lying = 0)
|
|
if(leaping)
|
|
return -32
|
|
else if(custom_pixel_y_offset)
|
|
return custom_pixel_y_offset
|
|
else
|
|
return initial(pixel_y)
|
|
|
|
/mob/living/carbon/alien/humanoid/get_standard_pixel_x_offset(lying = 0)
|
|
if(leaping)
|
|
return -32
|
|
else if(custom_pixel_x_offset)
|
|
return custom_pixel_x_offset
|
|
else
|
|
return initial(pixel_x)
|
|
|
|
/mob/living/carbon/alien/humanoid/get_permeability_protection()
|
|
return 0.8
|
|
|
|
/mob/living/carbon/alien/humanoid/alien_evolve(mob/living/carbon/alien/humanoid/new_xeno)
|
|
drop_all_held_items()
|
|
for(var/atom/movable/A in stomach_contents)
|
|
stomach_contents.Remove(A)
|
|
new_xeno.stomach_contents.Add(A)
|
|
A.loc = new_xeno
|
|
..()
|
|
|
|
//For alien evolution/promotion/queen finder procs. Checks for an active alien of that type
|
|
/proc/get_alien_type(var/alienpath)
|
|
for(var/mob/living/carbon/alien/humanoid/A in living_mob_list)
|
|
if(!istype(A, alienpath))
|
|
continue
|
|
if(!A.key || A.stat == DEAD) //Only living aliens with a ckey are valid.
|
|
continue
|
|
return A
|
|
return FALSE
|
|
|
|
|
|
/mob/living/carbon/alien/humanoid/check_breath(datum/gas_mixture/breath)
|
|
if(breath && breath.total_moles() > 0 && !sneaking)
|
|
playsound(get_turf(src), pick('sound/voice/lowHiss2.ogg', 'sound/voice/lowHiss3.ogg', 'sound/voice/lowHiss4.ogg'), 50, 0, -5)
|
|
..()
|