bd37d45334
* ports all the tg junk for icemoon, not yet changed to make it all compile * fixes * fixes * fixes * fixes * fixes * new stuff * whew * fixes * it compiles, now to fix the maps * fixes the maps * fixes solars + removes the space tiles in the toxins burn chamber * nukes the SpawnTerrain proc used for tg geysers * linter fix * fix * fixes the non matching turf atmos (hopefully) * more mapping fixes * dmm2tgm * unfucks changeturf for the more_caves * fixes the volanic subtypes of the other thing * fixes the stupid fucking tile placing list * some map fixes, fixes the station_ruin loader shitting out errors this commit took 2 hours of my fucking life * fixes a bunch of mismatch atmos in ruins * fixes wendigo cave having no air * backwards couch backwards couch * fixes the SM up * wendigos can't runtime when butchering if you can't butcher them 😎 * makes the wendigo fight have the same atmos as the surrounding icemoon * Tweaks atmos mixture from o2=22;n2=82;TEMP=180 to o2=18;n2=63;TEMP=180, making lavaland weapons actually work * makes the wendigo screech shake not completely aids * fixes snowlegion portals dropping proper legions instead of skeles * brings the engioutpost ruin over as well * whoopps * empty commit to reroll bots * Fixes pirates, ops, the mining base, and gives pirates and ops drills * fixes lone ops and ninjas * fixes the snowed plating getting fucked when tiles are placed on it * removes some OP junk from the wabbajack pool (aka removes non-antag headslugs again) * more bug fixes * empty commit to reroll bots * hopefully finally kills the active turfs on the library ruin Co-authored-by: kevinz000 <2003111+kevinz000@users.noreply.github.com>
159 lines
4.6 KiB
Plaintext
159 lines
4.6 KiB
Plaintext
GLOBAL_DATUM_INIT(openspace_backdrop_one_for_all, /atom/movable/openspace_backdrop, new)
|
|
|
|
/atom/movable/openspace_backdrop
|
|
name = "openspace_backdrop"
|
|
|
|
anchored = TRUE
|
|
|
|
icon = 'icons/turf/floors.dmi'
|
|
icon_state = "grey"
|
|
plane = OPENSPACE_BACKDROP_PLANE
|
|
mouse_opacity = MOUSE_OPACITY_TRANSPARENT
|
|
layer = SPLASHSCREEN_LAYER
|
|
|
|
/turf/open/openspace
|
|
name = "open space"
|
|
desc = "Watch your step!"
|
|
icon_state = "transparent"
|
|
baseturfs = /turf/open/openspace
|
|
CanAtmosPassVertical = ATMOS_PASS_YES
|
|
//mouse_opacity = MOUSE_OPACITY_TRANSPARENT
|
|
var/can_cover_up = TRUE
|
|
var/can_build_on = TRUE
|
|
|
|
/turf/open/openspace/debug/update_multiz()
|
|
..()
|
|
return TRUE
|
|
|
|
/turf/open/openspace/Initialize() // handle plane and layer here so that they don't cover other obs/turfs in Dream Maker
|
|
. = ..()
|
|
plane = OPENSPACE_PLANE
|
|
layer = OPENSPACE_LAYER
|
|
vis_contents += GLOB.openspace_backdrop_one_for_all //Special grey square for projecting backdrop darkness filter on it.
|
|
return INITIALIZE_HINT_LATELOAD
|
|
|
|
/turf/open/openspace/LateInitialize()
|
|
update_multiz(TRUE, TRUE)
|
|
|
|
/turf/open/openspace/Destroy()
|
|
vis_contents.len = 0
|
|
return ..()
|
|
|
|
/turf/open/openspace/update_multiz(prune_on_fail = FALSE, init = FALSE)
|
|
. = ..()
|
|
var/turf/T = below()
|
|
if(!T)
|
|
vis_contents.len = 0
|
|
if(prune_on_fail)
|
|
ChangeTurf(/turf/open/floor/plating)
|
|
return FALSE
|
|
if(init)
|
|
vis_contents += T
|
|
return TRUE
|
|
|
|
/turf/open/openspace/multiz_turf_del(turf/T, dir)
|
|
if(dir != DOWN)
|
|
return
|
|
update_multiz()
|
|
|
|
/turf/open/openspace/multiz_turf_new(turf/T, dir)
|
|
if(dir != DOWN)
|
|
return
|
|
update_multiz()
|
|
|
|
/turf/open/openspace/zAirIn()
|
|
return TRUE
|
|
|
|
/turf/open/openspace/zAirOut()
|
|
return TRUE
|
|
|
|
/turf/open/openspace/zPassIn(atom/movable/A, direction, turf/source)
|
|
return TRUE
|
|
|
|
/turf/open/openspace/zPassOut(atom/movable/A, direction, turf/destination)
|
|
if(A.anchored)
|
|
return FALSE
|
|
for(var/obj/O in contents)
|
|
if(O.obj_flags & BLOCK_Z_FALL)
|
|
return FALSE
|
|
return TRUE
|
|
|
|
/turf/open/openspace/proc/CanCoverUp()
|
|
return can_cover_up
|
|
|
|
/turf/open/openspace/proc/CanBuildHere()
|
|
return can_build_on
|
|
|
|
/turf/open/openspace/attackby(obj/item/C, mob/user, params)
|
|
..()
|
|
if(!CanBuildHere())
|
|
return
|
|
if(istype(C, /obj/item/stack/rods))
|
|
var/obj/item/stack/rods/R = C
|
|
var/obj/structure/lattice/L = locate(/obj/structure/lattice, src)
|
|
var/obj/structure/lattice/catwalk/W = locate(/obj/structure/lattice/catwalk, src)
|
|
if(W)
|
|
to_chat(user, "<span class='warning'>There is already a catwalk here!</span>")
|
|
return
|
|
if(L)
|
|
if(R.use(1))
|
|
to_chat(user, "<span class='notice'>You construct a catwalk.</span>")
|
|
playsound(src, 'sound/weapons/genhit.ogg', 50, 1)
|
|
new/obj/structure/lattice/catwalk(src)
|
|
else
|
|
to_chat(user, "<span class='warning'>You need two rods to build a catwalk!</span>")
|
|
return
|
|
if(R.use(1))
|
|
to_chat(user, "<span class='notice'>You construct a lattice.</span>")
|
|
playsound(src, 'sound/weapons/genhit.ogg', 50, 1)
|
|
ReplaceWithLattice()
|
|
else
|
|
to_chat(user, "<span class='warning'>You need one rod to build a lattice.</span>")
|
|
return
|
|
if(istype(C, /obj/item/stack/tile/plasteel))
|
|
if(!CanCoverUp())
|
|
return
|
|
var/obj/structure/lattice/L = locate(/obj/structure/lattice, src)
|
|
if(L)
|
|
var/obj/item/stack/tile/plasteel/S = C
|
|
if(S.use(1))
|
|
qdel(L)
|
|
playsound(src, 'sound/weapons/genhit.ogg', 50, 1)
|
|
to_chat(user, "<span class='notice'>You build a floor.</span>")
|
|
PlaceOnTop(/turf/open/floor/plating, flags = CHANGETURF_INHERIT_AIR)
|
|
else
|
|
to_chat(user, "<span class='warning'>You need one floor tile to build a floor!</span>")
|
|
else
|
|
to_chat(user, "<span class='warning'>The plating is going to need some support! Place metal rods first.</span>")
|
|
|
|
/turf/open/openspace/rcd_vals(mob/user, obj/item/construction/rcd/the_rcd)
|
|
if(!CanBuildHere())
|
|
return FALSE
|
|
|
|
switch(the_rcd.mode)
|
|
if(RCD_FLOORWALL)
|
|
var/obj/structure/lattice/L = locate(/obj/structure/lattice, src)
|
|
if(L)
|
|
return list("mode" = RCD_FLOORWALL, "delay" = 0, "cost" = 1)
|
|
else
|
|
return list("mode" = RCD_FLOORWALL, "delay" = 0, "cost" = 3)
|
|
return FALSE
|
|
|
|
/turf/open/openspace/rcd_act(mob/user, obj/item/construction/rcd/the_rcd, passed_mode)
|
|
switch(passed_mode)
|
|
if(RCD_FLOORWALL)
|
|
to_chat(user, "<span class='notice'>You build a floor.</span>")
|
|
PlaceOnTop(/turf/open/floor/plating, flags = CHANGETURF_INHERIT_AIR)
|
|
return TRUE
|
|
return FALSE
|
|
|
|
/turf/open/openspace/icemoon
|
|
name = "ice chasm"
|
|
baseturfs = /turf/open/openspace/icemoon
|
|
can_cover_up = FALSE
|
|
can_build_on = FALSE
|
|
initial_gas_mix = ICEMOON_DEFAULT_ATMOS
|
|
|
|
/turf/open/openspace/icemoon/can_zFall(atom/movable/A, levels = 1, turf/target)
|
|
return TRUE
|