Radio Jammers (#502)

Adds radio jammers for antags and improvised version as well.

baystation12.dme

@@ -587,6 +587,7 @@
 #include "code\game\objects\items\devices\paicard.dm"
 #include "code\game\objects\items\devices\pipe_painter.dm"
 #include "code\game\objects\items\devices\powersink.dm"
+#include "code\game\objects\items\devices\radio_jammer.dm"
 #include "code\game\objects\items\devices\scanners.dm"
 #include "code\game\objects\items\devices\spy_bug.dm"
 #include "code\game\objects\items\devices\suit_cooling.dm"

code/defines/procs/radio.dm

@@ -1,7 +1,7 @@
-#define TELECOMMS_RECEPTION_NONE 0
-#define TELECOMMS_RECEPTION_SENDER 1
-#define TELECOMMS_RECEPTION_RECEIVER 2
-#define TELECOMMS_RECEPTION_BOTH 3
+#define TELECOMMS_RECEPTION_NONE 1
+#define TELECOMMS_RECEPTION_SENDER 2
+#define TELECOMMS_RECEPTION_RECEIVER 4
+#define TELECOMMS_RECEPTION_BOTH 8
 
 /proc/register_radio(source, old_frequency, new_frequency, radio_filter)
 	if(old_frequency)
@@ -44,7 +44,7 @@
 /proc/get_message_server()
 	if(message_servers)
 		for (var/obj/machinery/message_server/MS in message_servers)
-			if(MS.active)
+			if(MS.active && !within_jamming_range(MS))
 				return MS
 	return null
 
@@ -52,10 +52,12 @@
 	return signal && signal.data["done"]
 
 /proc/get_sender_reception(var/atom/sender, var/datum/signal/signal)
-	return check_signal(signal) ? TELECOMMS_RECEPTION_SENDER : TELECOMMS_RECEPTION_NONE
+	if (check_signal(signal) && !within_jamming_range(sender))
+		return TELECOMMS_RECEPTION_SENDER
+	return TELECOMMS_RECEPTION_NONE
 
 /proc/get_receiver_reception(var/receiver, var/datum/signal/signal)
-	if(receiver && check_signal(signal))
+	if(receiver && check_signal(signal) && !within_jamming_range(receiver))
 		var/turf/pos = get_turf(receiver)
 		if(pos && (pos.z in signal.data["level"]))
 			return TELECOMMS_RECEPTION_RECEIVER

code/game/gamemodes/game_mode.dm

@@ -78,6 +78,7 @@ var/global/list/additional_antag_types = list()
 			new/datum/uplink_item(/obj/item/weapon/storage/toolbox/syndicate, 1, "Fully Loaded Toolbox", "ST"),
 			new/datum/uplink_item(/obj/item/weapon/plastique, 2, "C-4 (Destroys walls)", "C4"),
 			new/datum/uplink_item(/obj/item/device/encryptionkey/syndicate, 2, "Encrypted Radio Channel Key", "ER"),
+			new/datum/uplink_item(/obj/item/device/radiojammer, 2, "Small Radio Jammer", "RJ"),
 			new/datum/uplink_item(/obj/item/device/encryptionkey/binary, 3, "Binary Translator Key", "BT"),
 			new/datum/uplink_item(/obj/item/weapon/card/emag, 3, "Cryptographic Sequencer", "EC"),
 			new/datum/uplink_item(/obj/item/weapon/storage/box/syndie_kit/clerical, 3, "Morphic Clerical Kit", "CK"),

code/game/objects/items/devices/PDA/PDA.dm

@@ -973,7 +973,7 @@ var/global/list/obj/item/device/pda/PDAs = list()
 	t = reception.message
 
 	if(reception.message_server && (reception.telecomms_reception & TELECOMMS_RECEPTION_SENDER)) // only send the message if it's stable
-		if(reception.telecomms_reception & TELECOMMS_RECEPTION_RECEIVER == 0) // Does our recipient have a broadcaster on their level?
+		if(!(reception.telecomms_reception & TELECOMMS_RECEPTION_RECEIVER)) // Does our recipient have a broadcaster on their level?
 			U << "ERROR: Cannot reach recipient."
 			return
 		var/send_result = reception.message_server.send_pda_message("[P.owner]","[owner]","[t]")

code/game/objects/items/devices/radio/radio.dm

@@ -292,6 +292,9 @@
   /* ###### Radio headsets can only broadcast through subspace ###### */
 
 	if(subspace_transmission)
+		// Check for jamming.
+		if (within_jamming_range(src))
+			return
 		// First, we want to generate a new radio signal
 		var/datum/signal/signal = new
 		signal.transmission_method = 2 // 2 would be a subspace transmission.
@@ -434,6 +437,8 @@
 		return -1
 	if(!listening)
 		return -1
+	if (within_jamming_range(src))
+		return -1
 	if(!(0 in level))
 		var/turf/position = get_turf(src)
 		if(!position || !(position.z in level))
@@ -652,4 +657,4 @@
 	return
 
 /obj/item/device/radio/off
-	listening = 0
+	listening = 0

code/game/objects/items/devices/radio_jammer.dm

@@ -0,0 +1,130 @@
+//Global list for housing active radiojammers:
+var/list/active_radio_jammers = list()
+
+proc/within_jamming_range(var/atom/test) // tests if an object is near a radio jammer
+	if (active_radio_jammers && active_radio_jammers.len)
+		for (var/obj/item/device/radiojammer/Jammer in active_radio_jammers)
+			if (get_dist(test, Jammer) <= Jammer.radius)
+				return 1
+
+	return 0
+
+/obj/item/device/radiojammer
+	name = "radio jammer"
+	desc = "A small, inconspicious looking item with an 'ON/OFF' toggle."
+	icon = 'icons/obj/device.dmi'
+	icon_state = "shield0"
+	w_class = 2
+
+	var/active = 0
+	var/radius = 7
+	var/icon_state_active = "shield1"
+	var/icon_state_inactive = "shield0"
+
+/obj/item/device/radiojammer/New()
+	..()
+	update()
+
+/obj/item/device/radiojammer/Destroy()
+	if (active)
+		active_radio_jammers -= src
+	..()
+
+
+/obj/item/device/radiojammer/attack_self()
+	toggle()
+
+
+/obj/item/device/radiojammer/emp_act()
+	toggle()
+
+
+/obj/item/device/radiojammer/proc/toggle()
+	if (active)
+		usr << "<span class='notice'>You deactivate \the [src].</span>"
+	else
+		usr << "<span class='notice'>You activate \the [src].</span>"
+	set_active(!active)
+
+
+/obj/item/device/radiojammer/proc/set_active(var/new_value)
+	active = new_value
+	update()
+
+
+/obj/item/device/radiojammer/proc/update()
+	if (active)
+		active_radio_jammers += src
+		icon_state = icon_state_active
+	else
+		active_radio_jammers -= src
+		icon_state = icon_state_inactive
+
+
+/obj/item/device/radiojammer/improvised
+	name = "improvised radio jammer"
+	desc = "An awkward bundle of wires, batteries, and radio transmitters."
+	var/obj/item/weapon/cell/cell
+	var/obj/item/device/assembly_holder/assembly_holder
+	// 10 seconds of operation on a standard cell. 200 (roughly 3 minutes) on a super cap.
+	var/power_drain_per_second = 100
+	var/last_updated = null
+	radius = 5
+	icon = 'icons/obj/assemblies/new_assemblies.dmi'
+	icon_state_active = "improvised_jammer_active"
+	icon_state_inactive = "improvised_jammer_inactive"
+
+
+/obj/item/device/radiojammer/improvised/New(var/obj/item/device/assembly_holder/incoming_holder, var/obj/item/weapon/cell/incoming_cell, var/mob/user)
+	..()
+	cell = incoming_cell
+	assembly_holder = incoming_holder
+
+	// Spawn() required to properly move the assembly. Why? No clue!
+	// This does not make any sense, but sure.
+	spawn(0)
+		incoming_holder.forceMove(src, 1)
+		incoming_cell.forceMove(src, 1)
+
+	user.put_in_active_hand(src)
+
+/obj/item/device/radiojammer/improvised/Destroy()
+	if (active)
+		processing_objects.Remove(src)
+	..()
+
+
+/obj/item/device/radiojammer/improvised/process()
+	var/current = world.time // current tick
+	var/delta = (current - last_updated) / 10.0 // delta in seconds
+	last_updated = current
+	if (!cell.use(delta * power_drain_per_second))
+		set_active(0)
+		cell.charge = 0 // drain the last of the battery
+
+
+/obj/item/device/radiojammer/improvised/attackby(obj/item/weapon/W as obj, mob/user as mob)
+	if (istype(W, /obj/item/weapon/screwdriver))
+		user << "<span class='notice'>You disassemble the improvised signal jammer.</span>"
+		user.put_in_hands(assembly_holder)
+		user.put_in_hands(cell)
+		qdel(src)
+
+/obj/item/device/radiojammer/improvised/set_active(var/new_value)
+	if (new_value == 1)
+		if (!cell || !cell.charge)
+			return
+
+	..()
+
+/obj/item/device/radiojammer/improvised/update()
+	if (active)
+		active_radio_jammers += src
+		icon_state = icon_state_active
+		processing_objects.Add(src)
+
+		last_updated = world.time
+	else
+		active_radio_jammers -= src
+		icon_state = icon_state_inactive
+		processing_objects.Remove(src)

code/modules/assembly/signaler.dm

@@ -100,7 +100,11 @@
 
 
 	proc/signal()
-		if(!radio_connection) return
+		if(!radio_connection)
+			return
+
+		if(within_jamming_range(src))
+			return
 
 		var/datum/signal/signal = new
 		signal.source = src
@@ -129,9 +133,18 @@
 
 
 	receive_signal(datum/signal/signal)
-		if(!signal)	return 0
-		if(signal.encryption != code)	return 0
-		if(!(src.wires & WIRE_RADIO_RECEIVE))	return 0
+		if(!signal)
+			return 0
+
+		if(within_jamming_range(src))
+			return 0
+
+		if(signal.encryption != code)
+			return 0
+
+		if(!(src.wires & WIRE_RADIO_RECEIVE))
+			return 0
+
 		pulse(1)
 
 		if(!holder)

code/modules/mob/language/station.dm

@@ -91,8 +91,13 @@
 		speaker_mask = speaker.name
 	var/msg = "<i><span class='game say'>[name], <span class='name'>[speaker_mask]</span> [format_message(message, get_spoken_verb(message))]</span></i>"
 
+	if (within_jamming_range(speaker))
+		// The user thinks that the message got through.
+		speaker << msg
+		return
+
 	for(var/mob/player in player_list)
-		if(istype(player,/mob/dead) || ((src in player.languages) || check_special_condition(player)))
+		if(istype(player,/mob/dead) || ((src in player.languages && !within_jamming_range(player)) || check_special_condition(player)))
 			player << msg
 
 /datum/language/bug/check_special_condition(var/mob/other)
@@ -102,6 +107,8 @@
 		return 0
 	if(istype(M, /mob/new_player))
 		return 0
+	if(within_jamming_range(other))
+		return 0
 	if(locate(/obj/item/organ/vaurca/neuralsocket) in M.internal_organs)
 		return 1
 

code/modules/power/cell.dm

@@ -103,7 +103,15 @@
 			message_admins("LOG: [user.name] ([user.ckey]) injected a power cell with phoron, rigging it to explode.")
 
 		S.reagents.clear_reagents()
+	else if(istype(W, /obj/item/device/assembly_holder))
+		var/obj/item/device/assembly_holder/assembly = W
+		if (istype(assembly.a_left, /obj/item/device/assembly/signaler) && istype(assembly.a_right, /obj/item/device/assembly/signaler))
+			user.drop_item()
+			user.drop_from_inventory(src)
 
+			new /obj/item/device/radiojammer/improvised(assembly, src, user)
+		else
+			user << "<span class='notice'>You'd need both devices to be signallers for this to work.</span>"
 
 /obj/item/weapon/cell/proc/explode()
 	var/turf/T = get_turf(src.loc)

html/changelogs/skull132-jammers.yml

@@ -0,0 +1,12 @@
+author: Skull132
+
+# Optional: Remove this file after generating master changelog.  Useful for PR changelogs that won't get used again.
+delete-after: True
+
+# Any changes you've made.  See valid prefix list above.
+# INDENT WITH TWO SPACES.  NOT TABS.  SPACES.
+# SCREW THIS UP AND IT WON'T WORK.
+# Also, all entries are changed into a single [] after a master changelog generation. Just remove the brackets when you add new entries.
+# Please surround your changes in  double quotes ("), as certain characters otherwise screws up compiling. The quotes will not show up in the changelog.
+changes:
+    - rscadd: "Radio jammers added (syndicate uplink for 2 TC, or improvised out of a signaller/signaller assembly, with a cell added to it). These will jam headsets, PDAs, messaging servers, and Vaurca hivenet."