Add cowboy boots! (#44880)

This PR adds 6 new types of cowboy boots. Brown, black and white
cowboy boots have been added to the clothesmate. Two types of lizard
skin boots can be crafted, these boots can then be exported for money.
An additional pair of fancy boots are currently unobtainable, but will
be part of a future project. Cowboy boots can now act as shelter for
some type of snakelike creatures, fill a pair with snakes as a prank
or harebrained assassination plot.

code/datums/components/crafting/tailoring.dm

@@ -129,3 +129,17 @@
 	tools = list(TOOL_WIRECUTTER)
 	reqs = list(/obj/item/bedsheet = 1)
 	category = CAT_CLOTHING
+
+/datum/crafting_recipe/cowboyboots
+	name = "Cowboy Boots"
+	result = /obj/item/clothing/shoes/cowboy
+	reqs = list(/obj/item/stack/sheet/leather = 2)
+	time = 45
+	category = CAT_CLOTHING
+
+/datum/crafting_recipe/lizardboots
+	name = "Lizard Skin Boots"
+	result = /obj/effect/spawner/lootdrop/lizardboots
+	reqs = list(/obj/item/stack/sheet/animalhide/lizard = 1, /obj/item/stack/sheet/leather = 1)
+	time = 60
+	category = CAT_CLOTHING

code/modules/cargo/exports/gear.dm

@@ -81,3 +81,19 @@
 	cost = 100
 	unit_name = "bomb suit"
 	export_types = list(/obj/item/clothing/suit/bomb_suit)
+
+/datum/export/gear/lizardboots
+	cost = 350
+	unit_name = "lizard skin boots"
+	export_types = list(/obj/item/clothing/shoes/cowboy/lizard)
+	include_subtypes = FALSE
+
+/datum/export/gear/lizardmasterwork
+	cost = 1000
+	unit_name = "Hugs-the-Feet lizard boots"
+	export_types = list(/obj/item/clothing/shoes/cowboy/lizard/masterwork)
+
+/datum/export/gear/bilton
+	cost = 2500
+	unit_name = "bilton wrangler boots"
+	export_types = list(/obj/item/clothing/shoes/cowboy/fancy)

code/modules/clothing/shoes/miscellaneous.dm

@@ -336,3 +336,85 @@
 	icon_state = "rus_shoes"
 	item_state = "rus_shoes"
 	pocket_storage_component_path = /datum/component/storage/concrete/pockets/shoes
+
+/obj/item/clothing/shoes/cowboy
+	name = "cowboy boots"
+	desc = "A small sticker lets you know they've been inspected for snakes, It is unclear how long ago the inspection took place..."
+	icon_state = "cowboy_brown"
+	permeability_coefficient = 0.05 //these are quite tall
+	pocket_storage_component_path = /datum/component/storage/concrete/pockets/shoes
+	custom_price = 35 //poor assistants cant afford 50 credits
+	var/list/occupants = list()
+	var/max_occupants = 4
+
+/obj/item/clothing/shoes/cowboy/Initialize()
+	. = ..()
+	if(prob(2))
+		var/mob/living/simple_animal/hostile/retaliate/poison/snake/bootsnake = new/mob/living/simple_animal/hostile/retaliate/poison/snake(src)
+		occupants += bootsnake
+
+
+/obj/item/clothing/shoes/cowboy/equipped(mob/living/carbon/user, slot)
+	. = ..()
+	if(slot == SLOT_SHOES)
+		for(var/mob/living/occupant in occupants)
+			occupant.forceMove(user.drop_location())
+			user.visible_message("<span class='warning'>[user] recoils as something slithers out of [src].</span>", "<span class='userdanger'> You feel a sudden stabbing pain in your [pick("foot", "toe", "ankle")]!</span>")
+			user.Knockdown(20) //Is one second paralyze better here? I feel you would fall on your ass in some fashion.
+			user.apply_damage(5, BRUTE, pick(BODY_ZONE_R_LEG, BODY_ZONE_L_LEG))
+			if(istype(occupant, /mob/living/simple_animal/hostile/retaliate/poison))
+				user.reagents.add_reagent(/datum/reagent/toxin, 7)
+		occupants.Cut()
+
+/obj/item/clothing/shoes/cowboy/MouseDrop_T(mob/living/target, mob/living/user)
+	. = ..()
+	if(user.stat || !(user.mobility_flags & MOBILITY_USE) || user.restrained() || !Adjacent(user) || !user.Adjacent(target) || target.stat == DEAD)
+		return
+	if(occupants.len >= max_occupants)
+		to_chat(user, "<span class='notice'>[src] are full!</span>")
+		return
+	if(istype(target, /mob/living/simple_animal/hostile/retaliate/poison/snake) || istype(target, /mob/living/simple_animal/hostile/headcrab) || istype(target, /mob/living/carbon/alien/larva))
+		occupants += target
+		target.forceMove(src)
+		to_chat(user, "<span class='notice'>[target] slithers into [src]</span>")
+
+/obj/item/clothing/shoes/cowboy/container_resist(mob/living/user)
+	if(!do_after(user, 10, target = user))
+		return
+	user.forceMove(user.drop_location())
+	occupants -= user
+
+/obj/item/clothing/shoes/cowboy/white
+	name = "white cowboy boots"
+	icon_state = "cowboy_white"
+
+/obj/item/clothing/shoes/cowboy/black
+	name = "black cowboy boots"
+	desc = "You get the feeling someone might have been hanged in these boots."
+	icon_state = "cowboy_black"
+
+/obj/item/clothing/shoes/cowboy/fancy
+	name = "bilton wrangler boots"
+	desc = "A pair of authentic haute couture boots from Japanifornia. You doubt they have ever been close to cattle."
+	icon_state = "cowboy_fancy"
+	permeability_coefficient = 0.08
+
+/obj/item/clothing/shoes/cowboy/lizard
+	name = "lizard skin boots"
+	desc = "You can hear a faint hissing from inside the boots; you hope it is just a mournful ghost."
+	icon_state = "lizardboots_green"
+	armor = list("melee" = 0, "bullet" = 0, "laser" = 0, "energy" = 0, "bomb" = 0, "bio" = 0, "rad" = 0, "fire" = 40, "acid" = 0) //lizards like to stay warm
+
+/obj/item/clothing/shoes/cowboy/lizard/masterwork
+	name = "\improper Hugs-The-Feet lizard skin boots"
+	desc = "A pair of masterfully crafted lizard skin boots. Finally a good application for the station's most bothersome inhabitants."
+	icon_state = "lizardboots_blue"
+
+/obj/effect/spawner/lootdrop/lizardboots
+	name = "random lizard boot quality"
+	desc = "Which ever gets picked, the lizard race loses"
+	icon = 'icons/obj/clothing/shoes.dmi'
+	icon_state = "lizardboots_green"
+	loot = list(
+		/obj/item/clothing/shoes/cowboy/lizard = 7,
+		/obj/item/clothing/shoes/cowboy/lizard/masterwork = 1)

code/modules/vending/clothesmate.dm

@@ -101,6 +101,9 @@
 		            /obj/item/clothing/suit/ianshirt = 1,
 		            /obj/item/clothing/shoes/laceup = 2,
 		            /obj/item/clothing/shoes/sandal = 2,
+		            /obj/item/clothing/shoes/cowboy = 2,
+		            /obj/item/clothing/shoes/cowboy/white = 2,
+		            /obj/item/clothing/shoes/cowboy/black = 2,
 		            /obj/item/clothing/suit/jacket/miljacket = 1,
 		            /obj/item/clothing/suit/apron/purple_bartender = 2,
 		            /obj/item/clothing/under/rank/bartender/purple = 2)