mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-08-28 15:47:15 +01:00
Refactors the forensics component into a datum (#66809)
About The Pull Request
This was doing things component really shouldn't be doing, and now all
of its behaviour is contained onto a datum, as it should've been the
whole time
Why It's Good For The CODEBASE
some things just really shouldn't be components, this was made back when DCS was first implemented and just thrown in because it was the new hot thing i guess, but datumized forensics makes far more sense, AND doesn't use GetComponent
TODO:
More thorough testing to make sure nothing broke
Changelog
🆑
refactor: Turned the forensics component into a datum.
/🆑
This commit is contained in:
Seth Scherer
@@ -0,0 +1,237 @@
|
||||
/**
|
||||
* Forensics datum
|
||||
*
|
||||
* Placed onto atoms, and contains:
|
||||
* * List of fingerprints on the atom
|
||||
* * List of hidden prints (used for admins)
|
||||
* * List of blood on the atom
|
||||
* * List of clothing fibers on the atom
|
||||
*/
|
||||
/datum/forensics
|
||||
/// Weakref to the parent owning this datum
|
||||
var/datum/weakref/parent
|
||||
/**
|
||||
* List of fingerprints on this atom
|
||||
*
|
||||
* Formatting:
|
||||
* * print = print
|
||||
*/
|
||||
var/list/fingerprints
|
||||
/**
|
||||
* List of hiddenprints on this atom
|
||||
*
|
||||
* Formatting:
|
||||
* * ckey = realname/gloves/ckey
|
||||
*/
|
||||
var/list/hiddenprints
|
||||
/**
|
||||
* List of blood dna on this atom
|
||||
*
|
||||
* Formatting:
|
||||
* * dna = bloodtype
|
||||
*/
|
||||
var/list/blood_DNA
|
||||
/**
|
||||
* List of clothing fibers on this atom
|
||||
*
|
||||
* Formatting:
|
||||
* * fiber = fiber
|
||||
*/
|
||||
var/list/fibers
|
||||
|
||||
/datum/forensics/New(atom/parent, fingerprints, hiddenprints, blood_DNA, fibers)
|
||||
if(!isatom(parent))
|
||||
stack_trace("We tried adding a forensics datum to something that isnt an atom. What the hell are you doing?")
|
||||
qdel(src)
|
||||
return
|
||||
|
||||
RegisterSignal(parent, COMSIG_COMPONENT_CLEAN_ACT, .proc/clean_act)
|
||||
|
||||
src.parent = WEAKREF(parent)
|
||||
src.fingerprints = fingerprints
|
||||
src.hiddenprints = hiddenprints
|
||||
src.blood_DNA = blood_DNA
|
||||
src.fibers = fibers
|
||||
check_blood()
|
||||
|
||||
/// Merges the given lists into the preexisting values
|
||||
/datum/forensics/proc/inherit_new(list/fingerprints, list/hiddenprints, list/blood_DNA, list/fibers) //Use of | and |= being different here is INTENTIONAL.
|
||||
if (fingerprints)
|
||||
src.fingerprints = LAZY_LISTS_OR(src.fingerprints, fingerprints)
|
||||
if (hiddenprints)
|
||||
src.hiddenprints = LAZY_LISTS_OR(src.hiddenprints, hiddenprints)
|
||||
if (blood_DNA)
|
||||
src.blood_DNA = LAZY_LISTS_OR(src.blood_DNA, blood_DNA)
|
||||
if (fibers)
|
||||
src.fibers = LAZY_LISTS_OR(src.fibers, fibers)
|
||||
check_blood()
|
||||
|
||||
/datum/forensics/Destroy(force, ...)
|
||||
var/atom/parent_atom = parent.resolve()
|
||||
if (!isnull(parent_atom))
|
||||
UnregisterSignal(parent_atom, list(COMSIG_COMPONENT_CLEAN_ACT))
|
||||
return ..()
|
||||
|
||||
/// Empties the fingerprints list
|
||||
/datum/forensics/proc/wipe_fingerprints()
|
||||
fingerprints = null
|
||||
return TRUE
|
||||
|
||||
/// Empties the blood_DNA list
|
||||
/datum/forensics/proc/wipe_blood_DNA()
|
||||
blood_DNA = null
|
||||
return TRUE
|
||||
|
||||
/// Empties the fibers list
|
||||
/datum/forensics/proc/wipe_fibers()
|
||||
fibers = null
|
||||
return TRUE
|
||||
|
||||
/// Handles cleaning up the various forensic types
|
||||
/datum/forensics/proc/clean_act(datum/source, clean_types)
|
||||
SIGNAL_HANDLER
|
||||
|
||||
if(clean_types & CLEAN_TYPE_FINGERPRINTS)
|
||||
wipe_fingerprints()
|
||||
if(clean_types & CLEAN_TYPE_BLOOD)
|
||||
wipe_blood_DNA()
|
||||
if(clean_types & CLEAN_TYPE_FIBERS)
|
||||
wipe_fibers()
|
||||
|
||||
/// Adds the given list into fingerprints
|
||||
/datum/forensics/proc/add_fingerprint_list(list/fingerprints)
|
||||
if(!length(fingerprints))
|
||||
return
|
||||
LAZYINITLIST(src.fingerprints)
|
||||
for(var/fingerprint in fingerprints) //We use an associative list, make sure we don't just merge a non-associative list into ours.
|
||||
src.fingerprints[fingerprint] = fingerprint
|
||||
return TRUE
|
||||
|
||||
/// Adds a single fingerprint
|
||||
/datum/forensics/proc/add_fingerprint(mob/living/suspect, ignoregloves = FALSE)
|
||||
if(!isliving(suspect))
|
||||
if(!iscameramob(suspect))
|
||||
return
|
||||
if(isaicamera(suspect))
|
||||
var/mob/camera/ai_eye/ai_camera = suspect
|
||||
if(!ai_camera.ai)
|
||||
return
|
||||
suspect = ai_camera.ai
|
||||
add_hiddenprint(suspect)
|
||||
if(ishuman(suspect))
|
||||
var/mob/living/carbon/human/human_suspect = suspect
|
||||
add_fibers(human_suspect)
|
||||
var/obj/item/gloves = human_suspect.gloves
|
||||
if(gloves) //Check if the gloves (if any) hide fingerprints
|
||||
if(!(gloves.body_parts_covered & HANDS) || HAS_TRAIT(gloves, TRAIT_FINGERPRINT_PASSTHROUGH) || HAS_TRAIT(human_suspect, TRAIT_FINGERPRINT_PASSTHROUGH))
|
||||
ignoregloves = TRUE
|
||||
if(!ignoregloves)
|
||||
human_suspect.gloves.add_fingerprint(human_suspect, ignoregloves = TRUE) //ignoregloves = TRUE to avoid infinite loop.
|
||||
return
|
||||
var/full_print = md5(human_suspect.dna.unique_identity)
|
||||
LAZYSET(fingerprints, full_print, full_print)
|
||||
return TRUE
|
||||
|
||||
/// Adds the given list into fibers
|
||||
/datum/forensics/proc/add_fiber_list(list/fibers)
|
||||
if(!length(fibers))
|
||||
return
|
||||
LAZYINITLIST(src.fibers)
|
||||
for(var/fiber in fibers) //We use an associative list, make sure we don't just merge a non-associative list into ours.
|
||||
src.fibers[fiber] = fiber
|
||||
return TRUE
|
||||
|
||||
#define ITEM_FIBER_MULTIPLIER 1.2
|
||||
#define NON_ITEM_FIBER_MULTIPLIER 1
|
||||
|
||||
/// Adds a single fiber
|
||||
/datum/forensics/proc/add_fibers(mob/living/carbon/human/suspect)
|
||||
var/fibertext
|
||||
var/item_multiplier = isitem(src) ? ITEM_FIBER_MULTIPLIER : NON_ITEM_FIBER_MULTIPLIER
|
||||
if(suspect.wear_suit)
|
||||
fibertext = "Material from \a [suspect.wear_suit]."
|
||||
if(prob(10 * item_multiplier) && !LAZYACCESS(fibers, fibertext))
|
||||
LAZYSET(fibers, fibertext, fibertext)
|
||||
if(!(suspect.wear_suit.body_parts_covered & CHEST))
|
||||
if(suspect.w_uniform)
|
||||
fibertext = "Fibers from \a [suspect.w_uniform]."
|
||||
if(prob(12 * item_multiplier) && !LAZYACCESS(fibers, fibertext)) //Wearing a suit means less of the uniform exposed.
|
||||
LAZYSET(fibers, fibertext, fibertext)
|
||||
if(!(suspect.wear_suit.body_parts_covered & HANDS))
|
||||
if(suspect.gloves)
|
||||
fibertext = "Material from a pair of [suspect.gloves.name]."
|
||||
if(prob(20 * item_multiplier) && !LAZYACCESS(fibers, fibertext))
|
||||
LAZYSET(fibers, fibertext, fibertext)
|
||||
else if(suspect.w_uniform)
|
||||
fibertext = "Fibers from \a [suspect.w_uniform]."
|
||||
if(prob(15 * item_multiplier) && !LAZYACCESS(fibers, fibertext))
|
||||
LAZYSET(fibers, fibertext, fibertext)
|
||||
if(suspect.gloves)
|
||||
fibertext = "Material from a pair of [suspect.gloves.name]."
|
||||
if(prob(20 * item_multiplier) && !LAZYACCESS(fibers, fibertext))
|
||||
LAZYSET(fibers, fibertext, fibertext)
|
||||
else if(suspect.gloves)
|
||||
fibertext = "Material from a pair of [suspect.gloves.name]."
|
||||
if(prob(20 * item_multiplier) && !LAZYACCESS(fibers, fibertext))
|
||||
LAZYSET(fibers, fibertext, fibertext)
|
||||
return TRUE
|
||||
|
||||
#undef ITEM_FIBER_MULTIPLIER
|
||||
#undef NON_ITEM_FIBER_MULTIPLIER
|
||||
|
||||
/// Adds the given list into hiddenprints
|
||||
/datum/forensics/proc/add_hiddenprint_list(list/hiddenprints) //list(ckey = text)
|
||||
if(!length(hiddenprints))
|
||||
return
|
||||
LAZYINITLIST(src.hiddenprints)
|
||||
for(var/hidden_print in hiddenprints) //We use an associative list, make sure we don't just merge a non-associative list into ours.
|
||||
src.hiddenprints[hidden_print] = hiddenprints[hidden_print]
|
||||
return TRUE
|
||||
|
||||
/// Adds a single hiddenprint
|
||||
/datum/forensics/proc/add_hiddenprint(mob/suspect)
|
||||
if(!isliving(suspect))
|
||||
if(!iscameramob(suspect))
|
||||
return
|
||||
if(isaicamera(suspect))
|
||||
var/mob/camera/ai_eye/ai_camera = suspect
|
||||
if(!ai_camera.ai)
|
||||
return
|
||||
suspect = ai_camera.ai
|
||||
if(!suspect.key)
|
||||
return
|
||||
var/has_gloves = ""
|
||||
if(ishuman(suspect))
|
||||
var/mob/living/carbon/human/human_suspect = suspect
|
||||
if(human_suspect.gloves)
|
||||
has_gloves = "(gloves)"
|
||||
var/current_time = time_stamp()
|
||||
if(!LAZYACCESS(hiddenprints, suspect.key))
|
||||
LAZYSET(hiddenprints, suspect.key, "First: \[[current_time]\] \"[suspect.real_name]\"[has_gloves]. Ckey: [suspect.ckey]")
|
||||
else
|
||||
var/last_stamp_pos = findtext(LAZYACCESS(hiddenprints, suspect.key), "\nLast: ")
|
||||
if(last_stamp_pos)
|
||||
LAZYSET(hiddenprints, suspect.key, copytext(hiddenprints[suspect.key], 1, last_stamp_pos))
|
||||
hiddenprints[suspect.key] += "\nLast: \[[current_time]\] \"[suspect.real_name]\"[has_gloves]. Ckey: [suspect.ckey]" //made sure to be existing by if(!LAZYACCESS);else
|
||||
var/atom/parent_atom = parent.resolve()
|
||||
parent_atom.fingerprintslast = suspect.ckey
|
||||
return TRUE
|
||||
|
||||
/// Adds the given list into blood_DNA
|
||||
/datum/forensics/proc/add_blood_DNA(list/blood_DNA)
|
||||
if(!length(blood_DNA))
|
||||
return
|
||||
LAZYINITLIST(src.blood_DNA)
|
||||
for(var/gene in blood_DNA)
|
||||
src.blood_DNA[gene] = blood_DNA[gene]
|
||||
check_blood()
|
||||
return TRUE
|
||||
|
||||
/// Updates the blood displayed on parent
|
||||
/datum/forensics/proc/check_blood()
|
||||
if(!isitem(parent.resolve()))
|
||||
return
|
||||
if(!length(blood_DNA))
|
||||
return
|
||||
var/atom/parent_atom = parent.resolve()
|
||||
parent_atom.AddElement(/datum/element/decal/blood)
|
||||
@@ -0,0 +1,122 @@
|
||||
/// Adds a list of fingerprints to the atom
|
||||
/atom/proc/add_fingerprint_list(list/fingerprints_to_add) //ASSOC LIST FINGERPRINT = FINGERPRINT
|
||||
if (isnull(fingerprints_to_add))
|
||||
return
|
||||
if (forensics)
|
||||
forensics.inherit_new(fingerprints = fingerprints_to_add)
|
||||
else
|
||||
forensics = new(src, fingerprints = fingerprints_to_add)
|
||||
return TRUE
|
||||
|
||||
/// Adds a single fingerprint to the atom
|
||||
/atom/proc/add_fingerprint(mob/suspect, ignoregloves = FALSE) //Set ignoregloves to add prints irrespective of the mob having gloves on.
|
||||
if (QDELING(src))
|
||||
return
|
||||
if (isnull(forensics))
|
||||
forensics = new(src)
|
||||
forensics.add_fingerprint(suspect, ignoregloves)
|
||||
return TRUE
|
||||
|
||||
/// Add a list of fibers to the atom
|
||||
/atom/proc/add_fiber_list(list/fibers_to_add) //ASSOC LIST FIBERTEXT = FIBERTEXT
|
||||
if (isnull(fibers_to_add))
|
||||
return
|
||||
if (forensics)
|
||||
forensics.inherit_new(fibers = fibers_to_add)
|
||||
else
|
||||
forensics = new(src, fibers = fibers_to_add)
|
||||
return TRUE
|
||||
|
||||
/// Adds a single fiber to the atom
|
||||
/atom/proc/add_fibers(mob/living/carbon/human/suspect)
|
||||
var/old = 0
|
||||
if(suspect.gloves && istype(suspect.gloves, /obj/item/clothing))
|
||||
var/obj/item/clothing/gloves/suspect_gloves = suspect.gloves
|
||||
old = length(GET_ATOM_BLOOD_DNA(suspect_gloves))
|
||||
if(suspect_gloves.transfer_blood > 1) //bloodied gloves transfer blood to touched objects
|
||||
if(add_blood_DNA(GET_ATOM_BLOOD_DNA(suspect_gloves)) && GET_ATOM_BLOOD_DNA_LENGTH(suspect_gloves) > old) //only reduces the bloodiness of our gloves if the item wasn't already bloody
|
||||
suspect_gloves.transfer_blood -= 1
|
||||
else if(suspect.blood_in_hands > 1)
|
||||
old = length(GET_ATOM_BLOOD_DNA(suspect))
|
||||
if(add_blood_DNA(GET_ATOM_BLOOD_DNA(suspect)) && GET_ATOM_BLOOD_DNA_LENGTH(suspect) > old)
|
||||
suspect.blood_in_hands -= 1
|
||||
if (isnull(forensics))
|
||||
forensics = new(src)
|
||||
forensics.add_fibers(suspect)
|
||||
return TRUE
|
||||
|
||||
/// Adds a list of hiddenprints to the atom
|
||||
/atom/proc/add_hiddenprint_list(list/hiddenprints_to_add) //NOTE: THIS IS FOR ADMINISTRATION FINGERPRINTS, YOU MUST CUSTOM SET THIS TO INCLUDE CKEY/REAL NAMES! CHECK FORENSICS.DM
|
||||
if (isnull(hiddenprints_to_add))
|
||||
return
|
||||
if (forensics)
|
||||
forensics.inherit_new(hiddenprints = hiddenprints_to_add)
|
||||
else
|
||||
forensics = new(src, hiddenprints = hiddenprints_to_add)
|
||||
return TRUE
|
||||
|
||||
/// Adds a single hiddenprint to the atom
|
||||
/atom/proc/add_hiddenprint(mob/suspect)
|
||||
if (isnull(forensics))
|
||||
forensics = new(src)
|
||||
forensics.add_hiddenprint(suspect)
|
||||
return TRUE
|
||||
|
||||
/// Adds blood dna to the atom
|
||||
/atom/proc/add_blood_DNA(list/blood_DNA_to_add) //ASSOC LIST DNA = BLOODTYPE
|
||||
return FALSE
|
||||
|
||||
/obj/add_blood_DNA(list/blood_DNA_to_add)
|
||||
. = ..()
|
||||
if (isnull(blood_DNA_to_add))
|
||||
return .
|
||||
if (forensics)
|
||||
forensics.inherit_new(blood_DNA = blood_DNA_to_add)
|
||||
else
|
||||
forensics = new(src, blood_DNA = blood_DNA_to_add)
|
||||
return TRUE
|
||||
|
||||
/obj/item/clothing/gloves/add_blood_DNA(list/blood_dna, list/datum/disease/diseases)
|
||||
transfer_blood = rand(2, 4)
|
||||
return ..()
|
||||
|
||||
/turf/add_blood_DNA(list/blood_dna, list/datum/disease/diseases)
|
||||
var/obj/effect/decal/cleanable/blood/splatter/blood_splatter = locate() in src
|
||||
if(!blood_splatter)
|
||||
blood_splatter = new /obj/effect/decal/cleanable/blood/splatter(src, diseases)
|
||||
if(!QDELETED(blood_splatter))
|
||||
blood_splatter.add_blood_DNA(blood_dna) //give blood info to the blood decal.
|
||||
return TRUE //we bloodied the floor
|
||||
return FALSE
|
||||
|
||||
/mob/living/carbon/human/add_blood_DNA(list/blood_DNA_to_add, list/datum/disease/diseases)
|
||||
if(wear_suit)
|
||||
wear_suit.add_blood_DNA(blood_DNA_to_add)
|
||||
update_inv_wear_suit()
|
||||
else if(w_uniform)
|
||||
w_uniform.add_blood_DNA(blood_DNA_to_add)
|
||||
update_inv_w_uniform()
|
||||
if(gloves)
|
||||
var/obj/item/clothing/gloves/mob_gloves = gloves
|
||||
mob_gloves.add_blood_DNA(blood_DNA_to_add)
|
||||
else if(length(blood_DNA_to_add))
|
||||
if (isnull(forensics))
|
||||
forensics = new(src)
|
||||
forensics.inherit_new(blood_DNA = blood_DNA_to_add)
|
||||
blood_in_hands = rand(2, 4)
|
||||
update_inv_gloves()
|
||||
return TRUE
|
||||
|
||||
/*
|
||||
* Transfer all the fingerprints and hidden prints from [src] to [transfer_to].
|
||||
*/
|
||||
/atom/proc/transfer_fingerprints_to(atom/transfer_to)
|
||||
transfer_to.add_fingerprint_list(GET_ATOM_FINGERPRINTS(src))
|
||||
transfer_to.add_hiddenprint_list(GET_ATOM_HIDDENPRINTS(src))
|
||||
transfer_to.fingerprintslast = fingerprintslast
|
||||
|
||||
/*
|
||||
* Transfer all the fibers from [src] to [transfer_to].
|
||||
*/
|
||||
/atom/proc/transfer_fibers_to(atom/transfer_to)
|
||||
transfer_to.add_fiber_list(GET_ATOM_FIBRES(src))
|
||||
Reference in New Issue
Block a user