mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-07-20 04:26:03 +01:00
Decal Painter refactor + merge with tile sprayer + more decals to paint (#91915)
1. Decal painter has been refactored. Decals to paint are now datums. 2. Tile sprayer has been deleted, and merged with the decal painter. 3. A bunch of map decals previously un-paintable are now paintable. 4. Some preset map colors are now available for selection Including: - All sidings (Colored, Plating, Wood) - Missing tile decals (Full tile, checkered tile) - And the missing tile decal colors (Dark colors) - Missing warning decals (Loading area)  1. Makes it drastically easier to add more decals in the future. 2. The split always felt needless to me. I always printed one, ran to my construction site, opened up the UI - only to realize I printed the wrong one. 3. Allows for much greater potential while building 4. Makes it easier to match mapped in decals (This code is commissioned, but I also wanted it, soooo) 🆑 Melbert refactor: Refactored the decal painter, report any missing decals or ones that come out weird. del: Tile sprayer is dead. Its functionality has been merged with the decal painter. qol: A bunch of decals have been added to the decal painter. Style to your heart's content. /🆑
This commit is contained in:
MrMelbert
@@ -0,0 +1,156 @@
|
||||
/obj/item/airlock_painter
|
||||
name = "airlock painter"
|
||||
desc = "An advanced autopainter preprogrammed with several paintjobs for airlocks. Use it on an airlock during or after construction to change the paintjob."
|
||||
desc_controls = "Alt-Click to remove the ink cartridge."
|
||||
icon = 'icons/obj/devices/tool.dmi'
|
||||
icon_state = "paint_sprayer"
|
||||
inhand_icon_state = "paint_sprayer"
|
||||
worn_icon_state = "painter"
|
||||
w_class = WEIGHT_CLASS_SMALL
|
||||
|
||||
custom_materials = list(/datum/material/iron= SMALL_MATERIAL_AMOUNT * 0.5, /datum/material/glass= SMALL_MATERIAL_AMOUNT * 0.5)
|
||||
|
||||
obj_flags = CONDUCTS_ELECTRICITY
|
||||
item_flags = NOBLUDGEON
|
||||
slot_flags = ITEM_SLOT_BELT
|
||||
usesound = 'sound/effects/spray2.ogg'
|
||||
|
||||
/// The ink cartridge to pull charges from.
|
||||
var/obj/item/toner/ink = null
|
||||
/// The type path to instantiate for the ink cartridge the device initially comes with, eg. /obj/item/toner
|
||||
var/initial_ink_type = /obj/item/toner
|
||||
/// Associate list of all paint jobs the airlock painter can apply. The key is the name of the airlock the user will see. The value is the type path of the airlock
|
||||
var/list/available_paint_jobs = list(
|
||||
"Public" = /obj/machinery/door/airlock/public,
|
||||
"Engineering" = /obj/machinery/door/airlock/engineering,
|
||||
"Atmospherics" = /obj/machinery/door/airlock/atmos,
|
||||
"Security" = /obj/machinery/door/airlock/security,
|
||||
"Command" = /obj/machinery/door/airlock/command,
|
||||
"Medical" = /obj/machinery/door/airlock/medical,
|
||||
"Virology" = /obj/machinery/door/airlock/virology,
|
||||
"Research" = /obj/machinery/door/airlock/research,
|
||||
"Hydroponics" = /obj/machinery/door/airlock/hydroponics,
|
||||
"Freezer" = /obj/machinery/door/airlock/freezer,
|
||||
"Science" = /obj/machinery/door/airlock/science,
|
||||
"Mining" = /obj/machinery/door/airlock/mining,
|
||||
"Maintenance" = /obj/machinery/door/airlock/maintenance,
|
||||
"External" = /obj/machinery/door/airlock/external,
|
||||
"External Maintenance"= /obj/machinery/door/airlock/maintenance/external,
|
||||
"Standard" = /obj/machinery/door/airlock
|
||||
)
|
||||
|
||||
/obj/item/airlock_painter/Initialize(mapload)
|
||||
. = ..()
|
||||
ink = new initial_ink_type(src)
|
||||
|
||||
/obj/item/airlock_painter/Destroy(force)
|
||||
QDEL_NULL(ink)
|
||||
return ..()
|
||||
|
||||
//This proc doesn't just check if the painter can be used, but also uses it.
|
||||
//Only call this if you are certain that the painter will be used right after this check!
|
||||
/obj/item/airlock_painter/proc/use_paint(mob/user)
|
||||
if(can_use(user))
|
||||
ink.charges--
|
||||
playsound(src.loc, 'sound/effects/spray2.ogg', 50, TRUE)
|
||||
return TRUE
|
||||
else
|
||||
return FALSE
|
||||
|
||||
//This proc only checks if the painter can be used.
|
||||
//Call this if you don't want the painter to be used right after this check, for example
|
||||
//because you're expecting user input.
|
||||
/obj/item/airlock_painter/proc/can_use(mob/user)
|
||||
if(!ink)
|
||||
balloon_alert(user, "no cartridge!")
|
||||
return FALSE
|
||||
else if(ink.charges < 1)
|
||||
balloon_alert(user, "out of ink!")
|
||||
return FALSE
|
||||
else
|
||||
return TRUE
|
||||
|
||||
/obj/item/airlock_painter/suicide_act(mob/living/user)
|
||||
var/obj/item/organ/lungs/L = user.get_organ_slot(ORGAN_SLOT_LUNGS)
|
||||
|
||||
if(can_use(user) && L)
|
||||
user.visible_message(span_suicide("[user] is inhaling toner from [src]! It looks like [user.p_theyre()] trying to commit suicide!"))
|
||||
use(user)
|
||||
|
||||
// Once you've inhaled the toner, you throw up your lungs
|
||||
// and then die.
|
||||
|
||||
// Find out if there is an open turf in front of us,
|
||||
// and if not, pick the turf we are standing on.
|
||||
var/turf/T = get_step(get_turf(src), user.dir)
|
||||
if(!isopenturf(T))
|
||||
T = get_turf(src)
|
||||
|
||||
// they managed to lose their lungs between then and
|
||||
// now. Good job.
|
||||
if(!L)
|
||||
return OXYLOSS
|
||||
|
||||
L.Remove(user)
|
||||
|
||||
// make some colorful reagent, and apply it to the lungs
|
||||
L.create_reagents(10)
|
||||
L.reagents.add_reagent(/datum/reagent/colorful_reagent, 10)
|
||||
L.reagents.expose(L, TOUCH, 1)
|
||||
|
||||
// TODO maybe add some colorful vomit?
|
||||
|
||||
user.visible_message(span_suicide("[user] vomits out [user.p_their()] [L]!"))
|
||||
playsound(user.loc, 'sound/effects/splat.ogg', 50, TRUE)
|
||||
|
||||
L.forceMove(T)
|
||||
|
||||
return (TOXLOSS|OXYLOSS)
|
||||
else if(can_use(user) && !L)
|
||||
user.visible_message(span_suicide("[user] is spraying toner on [user.p_them()]self from [src]! It looks like [user.p_theyre()] trying to commit suicide."))
|
||||
user.reagents.add_reagent(/datum/reagent/colorful_reagent, 1)
|
||||
user.reagents.expose(user, TOUCH, 1)
|
||||
return TOXLOSS
|
||||
|
||||
else
|
||||
user.visible_message(span_suicide("[user] is trying to inhale toner from [src]! It might be a suicide attempt if [src] had any toner."))
|
||||
return SHAME
|
||||
|
||||
|
||||
/obj/item/airlock_painter/examine(mob/user)
|
||||
. = ..()
|
||||
if(!ink)
|
||||
. += span_notice("It doesn't have a toner cartridge installed.")
|
||||
return
|
||||
var/ink_level = "high"
|
||||
if(ink.charges < 1)
|
||||
ink_level = "empty"
|
||||
else if((ink.charges/ink.max_charges) <= 0.25) //25%
|
||||
ink_level = "low"
|
||||
else if((ink.charges/ink.max_charges) > 1) //Over 100% (admin var edit)
|
||||
ink_level = "dangerously high"
|
||||
. += span_notice("Its ink levels look [ink_level].")
|
||||
|
||||
/obj/item/airlock_painter/attackby(obj/item/W, mob/user, list/modifiers, list/attack_modifiers)
|
||||
if(istype(W, /obj/item/toner))
|
||||
if(ink)
|
||||
to_chat(user, span_warning("[src] already contains \a [ink]!"))
|
||||
return
|
||||
if(!user.transferItemToLoc(W, src))
|
||||
return
|
||||
to_chat(user, span_notice("You install [W] into [src]."))
|
||||
ink = W
|
||||
playsound(src.loc, 'sound/machines/click.ogg', 50, TRUE)
|
||||
else
|
||||
return ..()
|
||||
|
||||
/obj/item/airlock_painter/click_alt(mob/user)
|
||||
if(!ink)
|
||||
return CLICK_ACTION_BLOCKING
|
||||
|
||||
playsound(src.loc, 'sound/machines/click.ogg', 50, TRUE)
|
||||
ink.forceMove(user.drop_location())
|
||||
user.put_in_hands(ink)
|
||||
to_chat(user, span_notice("You remove [ink] from [src]."))
|
||||
ink = null
|
||||
return CLICK_ACTION_SUCCESS
|
||||
@@ -0,0 +1,143 @@
|
||||
/obj/item/airlock_painter/decal
|
||||
name = "decal painter"
|
||||
desc = "An airlock painter, reprogrammed to use a different style of paint in order to apply decals for floor tiles as well, in addition to repainting doors. Decals break when the floor tiles are removed."
|
||||
desc_controls = "Alt-Click to remove the ink cartridge."
|
||||
icon = 'icons/obj/devices/tool.dmi'
|
||||
icon_state = "decal_sprayer"
|
||||
inhand_icon_state = "decal_sprayer"
|
||||
custom_materials = list(/datum/material/iron = SMALL_MATERIAL_AMOUNT * 0.5, /datum/material/glass = SMALL_MATERIAL_AMOUNT * 0.5)
|
||||
initial_ink_type = /obj/item/toner/large
|
||||
/// The current direction of the decal being printed
|
||||
VAR_PRIVATE/selected_dir = SOUTH
|
||||
/// The current color of the decal being printed.
|
||||
VAR_PRIVATE/selected_color = "yellow"
|
||||
/// The current base icon state of the decal being printed.
|
||||
VAR_PRIVATE/selected_decal_icon_state = "warningline"
|
||||
/// Current custom color
|
||||
VAR_PRIVATE/selected_custom_color
|
||||
|
||||
/// Current active decal category. Reference to a global singleton
|
||||
VAR_PRIVATE/datum/paintable_decal_category/current_category
|
||||
|
||||
/obj/item/airlock_painter/decal/Initialize(mapload)
|
||||
. = ..()
|
||||
set_category(GLOB.paintable_decals[1])
|
||||
|
||||
/obj/item/airlock_painter/decal/interact_with_atom(atom/interacting_with, mob/living/user, list/modifiers)
|
||||
if(isfloorturf(interacting_with) && use_paint(user))
|
||||
paint_floor(interacting_with)
|
||||
return ITEM_INTERACT_SUCCESS
|
||||
return NONE
|
||||
|
||||
/**
|
||||
* Actually add current decal to the floor.
|
||||
*
|
||||
* Responsible for actually adding the element to the turf for maximum flexibility.area
|
||||
* Can be overridden for different decal behaviors.
|
||||
* Arguments:
|
||||
* * target - The turf being painted to
|
||||
*/
|
||||
/obj/item/airlock_painter/decal/proc/paint_floor(turf/open/floor/target)
|
||||
var/list/decal_data = current_category.get_decal_info(
|
||||
state = selected_decal_icon_state,
|
||||
color = selected_color,
|
||||
dir = selected_dir,
|
||||
)
|
||||
|
||||
target.AddElement( \
|
||||
/datum/element/decal, \
|
||||
_icon = 'icons/turf/decals.dmi', \
|
||||
_icon_state = decal_data[DECAL_INFO_ICON_STATE], \
|
||||
_dir = decal_data[DECAL_INFO_DIR], \
|
||||
_alpha = decal_data[DECAL_INFO_ALPHA], \
|
||||
_color = decal_data[DECAL_INFO_COLOR], \
|
||||
_cleanable = FALSE, \
|
||||
)
|
||||
|
||||
/obj/item/airlock_painter/decal/proc/set_category(datum/paintable_decal_category/category)
|
||||
current_category = category
|
||||
selected_color = category.possible_colors?[category.possible_colors[1]]
|
||||
selected_decal_icon_state = category.get_ui_data()["decal_list"][1]["icon_state"]
|
||||
return TRUE
|
||||
|
||||
/obj/item/airlock_painter/decal/ui_interact(mob/user, datum/tgui/ui)
|
||||
ui = SStgui.try_update_ui(user, src, ui)
|
||||
if(!ui)
|
||||
ui = new(user, src, "DecalPainter", name)
|
||||
ui.open()
|
||||
|
||||
/obj/item/airlock_painter/decal/ui_assets(mob/user)
|
||||
. = ..()
|
||||
. += get_asset_datum(/datum/asset/spritesheet_batched/decals)
|
||||
|
||||
/obj/item/airlock_painter/decal/ui_static_data(mob/user)
|
||||
var/list/data = list()
|
||||
|
||||
data["categories"] = list()
|
||||
for(var/datum/paintable_decal_category/category as anything in GLOB.paintable_decals)
|
||||
var/list/category_data = category.get_ui_data()
|
||||
data["categories"] += list(list(
|
||||
"category" = category.category,
|
||||
"decal_list" = category_data["decal_list"],
|
||||
"color_list" = category_data["color_list"],
|
||||
"dir_list" = category_data["dir_list"],
|
||||
))
|
||||
|
||||
var/datum/asset/spritesheet_batched/icon_assets = get_asset_datum(/datum/asset/spritesheet_batched/decals)
|
||||
data["icon_prefix"] = "[icon_assets.name]32x32"
|
||||
|
||||
return data
|
||||
|
||||
/obj/item/airlock_painter/decal/ui_data(mob/user)
|
||||
var/list/data = list()
|
||||
data["current_decal"] = selected_decal_icon_state
|
||||
data["current_color"] = selected_color
|
||||
data["current_dir"] = selected_dir
|
||||
data["current_custom_color"] = selected_custom_color
|
||||
data["active_category"] = current_category.category
|
||||
return data
|
||||
|
||||
/obj/item/airlock_painter/decal/ui_act(action, list/params, datum/tgui/ui, datum/ui_state/state)
|
||||
. = ..()
|
||||
if(.)
|
||||
return
|
||||
|
||||
switch(action)
|
||||
if("select_category")
|
||||
var/new_category = params["category"]
|
||||
for(var/datum/paintable_decal_category/category as anything in GLOB.paintable_decals)
|
||||
if(category.category != new_category)
|
||||
continue
|
||||
|
||||
set_category(category)
|
||||
return TRUE
|
||||
|
||||
if("select_decal")
|
||||
var/new_state = params["decal"]
|
||||
var/new_dir = text2num(params["dir"])
|
||||
if(current_category.is_state_valid(new_state))
|
||||
selected_decal_icon_state = new_state
|
||||
if(current_category.is_dir_valid(new_dir))
|
||||
selected_dir = new_dir
|
||||
return TRUE
|
||||
|
||||
if("select_color")
|
||||
var/new_color = params["color"]
|
||||
if(current_category.is_color_valid(new_color))
|
||||
selected_color = new_color
|
||||
return TRUE
|
||||
|
||||
if("pick_custom_color")
|
||||
if("Custom" in current_category.possible_colors)
|
||||
pick_painting_tool_color(usr, selected_custom_color)
|
||||
return TRUE
|
||||
|
||||
/obj/item/airlock_painter/decal/set_painting_tool_color(chosen_color)
|
||||
. = ..()
|
||||
selected_custom_color = chosen_color
|
||||
selected_color = chosen_color
|
||||
|
||||
/obj/item/airlock_painter/decal/debug
|
||||
name = "extreme decal painter"
|
||||
icon_state = "decal_sprayer_ex"
|
||||
initial_ink_type = /obj/item/toner/extreme
|
||||
@@ -0,0 +1,605 @@
|
||||
/**
|
||||
* ## Paintable Decal Category
|
||||
*
|
||||
* Holds a bunch of information the decal painter uses to determine what it can and can't paint, and how to paint it.
|
||||
*/
|
||||
/datum/paintable_decal_category
|
||||
/// Human readable category name
|
||||
var/category = "Generic"
|
||||
/// The type of paintable decal this category contains - should be a subtype of /datum/paintable_decal
|
||||
var/paintable_decal_type
|
||||
/// Color options for this category - formatted as readable label - color value
|
||||
var/list/possible_colors
|
||||
/// Direction options for this category - formatted as readable label - dir value to return
|
||||
var/list/dir_list = list(
|
||||
"North" = NORTH,
|
||||
"South" = SOUTH,
|
||||
"East" = EAST,
|
||||
"West" = WEST,
|
||||
)
|
||||
/// Alpha for decals painted from this category (assuming no custom color is used)
|
||||
var/default_alpha = 255
|
||||
|
||||
/// Icon used for previews
|
||||
var/preview_floor_icon = 'icons/turf/floors.dmi'
|
||||
/// Icon state used for previews
|
||||
var/preview_floor_state = "floor"
|
||||
|
||||
/// Caches UI data to avoid regenerating it every time. It doesn't change anyways
|
||||
VAR_PRIVATE/list/cached_category_data
|
||||
|
||||
/// Returns a key for the spritesheet icon, used to avoid duplicates
|
||||
/datum/paintable_decal_category/proc/spritesheet_key(dir, state, color)
|
||||
SHOULD_NOT_OVERRIDE(TRUE)
|
||||
PRIVATE_PROC(TRUE)
|
||||
|
||||
return "[state]_[dir]_[replacetext(color, "#", "")]"
|
||||
|
||||
/// Returns a list of preview icons for every single variety of every decal in this category for use in a spritesheet
|
||||
/datum/paintable_decal_category/proc/generate_all_spritesheet_icons()
|
||||
SHOULD_NOT_OVERRIDE(TRUE)
|
||||
|
||||
. = list()
|
||||
for(var/datum/paintable_decal/decal_type as anything in subtypesof(paintable_decal_type))
|
||||
var/state = decal_type::icon_state
|
||||
if(!state)
|
||||
continue
|
||||
if(decal_type::directional)
|
||||
for(var/dirname in dir_list)
|
||||
. += generate_independent_decal_spritesheet_icons(dir_list[dirname], state)
|
||||
else
|
||||
. += generate_independent_decal_spritesheet_icons(SOUTH, state)
|
||||
|
||||
/// Returns a list of preview icon for a specific decal state and direction
|
||||
/datum/paintable_decal_category/proc/generate_independent_decal_spritesheet_icons(dir, state)
|
||||
SHOULD_NOT_OVERRIDE(TRUE)
|
||||
PRIVATE_PROC(TRUE)
|
||||
|
||||
. = list()
|
||||
for(var/colorname in possible_colors)
|
||||
.[spritesheet_key(dir, state, possible_colors[colorname])] = generate_colored_decal_spritesheet_icon(state, dir, possible_colors[colorname])
|
||||
|
||||
/// Actually generates the preview icon for a specific decal state, direction, and color
|
||||
/datum/paintable_decal_category/proc/generate_colored_decal_spritesheet_icon(state, dir, color)
|
||||
PROTECTED_PROC(TRUE)
|
||||
|
||||
var/list/decal_data = get_decal_info(state, color, dir)
|
||||
var/datum/universal_icon/colored_decal = uni_icon('icons/turf/decals.dmi', decal_data[DECAL_INFO_ICON_STATE], dir = decal_data[DECAL_INFO_DIR])
|
||||
colored_decal.change_opacity(decal_data[DECAL_INFO_ALPHA] / 255)
|
||||
if(color == "custom")
|
||||
// Do a fun rainbow pattern to stand out while still being static.
|
||||
colored_decal.blend_icon(uni_icon('icons/effects/random_spawners.dmi', "rainbow"), ICON_MULTIPLY)
|
||||
else if(decal_data[DECAL_INFO_COLOR])
|
||||
colored_decal.blend_color(decal_data[DECAL_INFO_COLOR], ICON_MULTIPLY)
|
||||
|
||||
var/datum/universal_icon/floor = uni_icon(preview_floor_icon, preview_floor_state)
|
||||
floor.blend_icon(colored_decal, ICON_OVERLAY)
|
||||
return floor
|
||||
|
||||
/// Constructs and returns this category's UI data
|
||||
/datum/paintable_decal_category/proc/get_ui_data() as /list
|
||||
SHOULD_NOT_OVERRIDE(TRUE)
|
||||
|
||||
if(cached_category_data)
|
||||
return cached_category_data.Copy()
|
||||
|
||||
cached_category_data = list()
|
||||
|
||||
cached_category_data["decal_list"] = list()
|
||||
cached_category_data["color_list"] = list()
|
||||
cached_category_data["dir_list"] = list()
|
||||
|
||||
for(var/datum/paintable_decal/decal_type as anything in subtypesof(paintable_decal_type))
|
||||
var/name = decal_type::name
|
||||
var/state = decal_type::icon_state
|
||||
if(!name || !state)
|
||||
continue
|
||||
|
||||
cached_category_data["decal_list"] += list(list(
|
||||
"name" = name,
|
||||
"icon_state" = state,
|
||||
"directional" = decal_type::directional,
|
||||
))
|
||||
|
||||
for(var/color in possible_colors)
|
||||
cached_category_data["color_list"] += list(list(
|
||||
"name" = color,
|
||||
"color" = possible_colors[color],
|
||||
))
|
||||
|
||||
for(var/dirname in dir_list)
|
||||
cached_category_data["dir_list"] += list(list(
|
||||
"name" = dirname,
|
||||
"dir" = dir_list[dirname],
|
||||
))
|
||||
|
||||
return cached_category_data.Copy()
|
||||
|
||||
/// Checks if the passed icon state is one of this category's decals
|
||||
/datum/paintable_decal_category/proc/is_state_valid(state)
|
||||
SHOULD_NOT_OVERRIDE(TRUE)
|
||||
// Ui data has all icon states so let's just piggyback off of that
|
||||
for(var/list/decal_data as anything in get_ui_data()["decal_list"])
|
||||
if(decal_data["icon_state"] == state)
|
||||
return TRUE
|
||||
return FALSE
|
||||
|
||||
/// Checks if the passed direction is one of this category's directions
|
||||
/datum/paintable_decal_category/proc/is_dir_valid(dir)
|
||||
SHOULD_NOT_OVERRIDE(TRUE)
|
||||
for(var/dirname in dir_list)
|
||||
if(dir_list[dirname] == dir)
|
||||
return TRUE
|
||||
return FALSE
|
||||
|
||||
/// Checks if the passed color is one of this category's colors
|
||||
/datum/paintable_decal_category/proc/is_color_valid(color)
|
||||
SHOULD_NOT_OVERRIDE(TRUE)
|
||||
for(var/colorname in possible_colors)
|
||||
if(possible_colors[colorname] == color)
|
||||
return TRUE
|
||||
return FALSE
|
||||
|
||||
/**
|
||||
* Used by the decal painter to modify the state of the decal based on the... state.
|
||||
*/
|
||||
/datum/paintable_decal_category/proc/get_decal_info(state, color, dir)
|
||||
// Special case for 8-dir sprites. Rather than add support for both 4-dir and 8-dir,
|
||||
// 8-dir are affixed with "__8" at the end of the icon state. Then we handle it in this proc.
|
||||
if(copytext(state, -3) == "__8")
|
||||
state = splicetext(state, -3, 0, "")
|
||||
dir = turn(dir, 45)
|
||||
|
||||
var/static/regex/rgba_regex = new(@"(#[0-9a-fA-F]{6})([0-9a-fA-F]{2})")
|
||||
var/alpha = default_alpha
|
||||
// Special case for RGBA colors
|
||||
if(rgba_regex.Find(color))
|
||||
color = rgba_regex.group[1]
|
||||
alpha = text2num(rgba_regex.group[2], 16)
|
||||
|
||||
return list(
|
||||
"[DECAL_INFO_ICON_STATE]" = state,
|
||||
"[DECAL_INFO_DIR]" = dir,
|
||||
"[DECAL_INFO_COLOR]" = color,
|
||||
"[DECAL_INFO_ALPHA]" = alpha,
|
||||
)
|
||||
|
||||
// Basic tile decals
|
||||
/datum/paintable_decal_category/tile
|
||||
paintable_decal_type = /datum/paintable_decal/tile
|
||||
category = "Tiles"
|
||||
default_alpha = /obj/effect/turf_decal/tile::alpha
|
||||
possible_colors = list(
|
||||
"Neutral" = /obj/effect/turf_decal/tile/neutral::color,
|
||||
"White" = "#FFFFFF",
|
||||
"Dark" = /obj/effect/turf_decal/tile/dark::color,
|
||||
"Bar Burgundy" = /obj/effect/turf_decal/tile/bar::color,
|
||||
"Cargo Brown" = /obj/effect/turf_decal/tile/brown::color,
|
||||
"Dark Blue" = /obj/effect/turf_decal/tile/dark_blue::color,
|
||||
"Dark Green" = /obj/effect/turf_decal/tile/dark_green::color,
|
||||
"Dark Red" = /obj/effect/turf_decal/tile/dark_red::color,
|
||||
"Engi Yellow" = /obj/effect/turf_decal/tile/yellow::color,
|
||||
"Med Blue" = /obj/effect/turf_decal/tile/blue::color,
|
||||
"R&D Purple" = /obj/effect/turf_decal/tile/purple::color,
|
||||
"Sec Blue" = "#486091", // BUBBER EDIT CHANGE
|
||||
"Sec Red" = /obj/effect/turf_decal/tile/red::color,
|
||||
"Service Green" = /obj/effect/turf_decal/tile/green::color,
|
||||
"Custom" = "custom",
|
||||
)
|
||||
|
||||
// Tile trimlines
|
||||
/datum/paintable_decal_category/tile/trimline
|
||||
category = "Trimlines"
|
||||
paintable_decal_type = /datum/paintable_decal/trimline
|
||||
|
||||
// Generic warning stripes
|
||||
/datum/paintable_decal_category/warning
|
||||
paintable_decal_type = /datum/paintable_decal/warning
|
||||
category = "Warning Stripes"
|
||||
possible_colors = list(
|
||||
"Yellow" = "yellow",
|
||||
"Red" = "red",
|
||||
"White" = "white",
|
||||
)
|
||||
|
||||
/datum/paintable_decal_category/warning/generate_colored_decal_spritesheet_icon(state, dir, color)
|
||||
var/list/decal_data = get_decal_info(state, color, dir)
|
||||
var/datum/universal_icon/floor = uni_icon(preview_floor_icon, preview_floor_state)
|
||||
var/datum/universal_icon/decal = uni_icon('icons/turf/decals.dmi', decal_data[DECAL_INFO_ICON_STATE], dir = decal_data[DECAL_INFO_DIR])
|
||||
floor.blend_icon(decal, ICON_OVERLAY)
|
||||
return floor
|
||||
|
||||
/datum/paintable_decal_category/warning/get_decal_info(state, color, dir)
|
||||
// Special case. Default warning stripes are yellow, so don't append anything if passed yellow
|
||||
if(color == "yellow")
|
||||
color = ""
|
||||
|
||||
return list(
|
||||
"[DECAL_INFO_ICON_STATE]" = "[state][color ? "_" : ""][color]",
|
||||
"[DECAL_INFO_DIR]" = dir,
|
||||
"[DECAL_INFO_COLOR]" = color,
|
||||
"[DECAL_INFO_ALPHA]" = default_alpha,
|
||||
)
|
||||
|
||||
// Plain colored siding
|
||||
/datum/paintable_decal_category/siding
|
||||
paintable_decal_type = /datum/paintable_decal/colored_siding
|
||||
category = "Colored Sidings"
|
||||
possible_colors = list(
|
||||
"Dim White" = /obj/effect/turf_decal/siding/white::color,
|
||||
"White" = "#FFFFFF",
|
||||
"Black" = /obj/effect/turf_decal/siding/dark::color,
|
||||
"Cargo Brown" = /obj/effect/turf_decal/siding/brown::color,
|
||||
"Dark Blue" = /obj/effect/turf_decal/siding/dark_blue::color,
|
||||
"Dark Green" = /obj/effect/turf_decal/siding/dark_green::color,
|
||||
"Dark Red" = /obj/effect/turf_decal/siding/dark_red::color,
|
||||
"Engi Yellow" = /obj/effect/turf_decal/siding/yellow::color,
|
||||
"Med Blue" = /obj/effect/turf_decal/siding/blue::color,
|
||||
"R&D Purple" = /obj/effect/turf_decal/siding/purple::color,
|
||||
"Sec Blue" = "#486091", // BUBBER EDIT CHANGE
|
||||
"Sec Red" = /obj/effect/turf_decal/siding/red::color,
|
||||
"Service Green" = /obj/effect/turf_decal/siding/green::color,
|
||||
"Custom" = "custom",
|
||||
)
|
||||
|
||||
// Sidings which are not colored / have a specific pattern, texture, etc
|
||||
/datum/paintable_decal_category/normal_siding
|
||||
paintable_decal_type = /datum/paintable_decal/siding
|
||||
category = "Normal Sidings"
|
||||
possible_colors = list(
|
||||
"Default" = /obj/effect/turf_decal/siding/wood::color,
|
||||
)
|
||||
|
||||
// Plating sidings and all color variations
|
||||
/datum/paintable_decal_category/plating
|
||||
paintable_decal_type = /datum/paintable_decal/plating
|
||||
category = "Plating Sidings"
|
||||
possible_colors = list(
|
||||
"Default" = "#949494",
|
||||
"White" = "#FFFFFF",
|
||||
"Terracotta" = "#b84221",
|
||||
"Dark" = "#36373a",
|
||||
"Light" = "#e2e2e2",
|
||||
)
|
||||
|
||||
/// Global list of all paintable decal categories singletons
|
||||
GLOBAL_LIST_INIT(paintable_decals, init_subtypes(/datum/paintable_decal_category))
|
||||
|
||||
// Spritesheet used by the decal painter
|
||||
/datum/asset/spritesheet_batched/decals
|
||||
name = "paintable_decals"
|
||||
ignore_dir_errors = TRUE
|
||||
|
||||
/datum/asset/spritesheet_batched/decals/create_spritesheets()
|
||||
for(var/datum/paintable_decal_category/category as anything in GLOB.paintable_decals)
|
||||
var/list/generated_icons = category.generate_all_spritesheet_icons()
|
||||
for(var/sprite_key in generated_icons)
|
||||
insert_icon(sprite_key, generated_icons[sprite_key])
|
||||
|
||||
/**
|
||||
* ## Paintable Decal
|
||||
*
|
||||
* Basically just holds a bunch of info pertaining to each decal for the decal painter to use.
|
||||
*/
|
||||
/datum/paintable_decal
|
||||
/// Human readable name of the decal
|
||||
var/name
|
||||
/// Icon state of the decal in decals.dmi
|
||||
var/icon_state
|
||||
/// If TRUE, the decal's sprite changes depending on its dir
|
||||
var/directional = TRUE
|
||||
|
||||
// Basic tile decals
|
||||
/datum/paintable_decal/tile
|
||||
|
||||
/datum/paintable_decal/tile/four_corners
|
||||
name = "4 Corners"
|
||||
icon_state = "tile_fourcorners"
|
||||
directional = FALSE
|
||||
|
||||
/datum/paintable_decal/tile/full
|
||||
name = "Full Tile"
|
||||
icon_state = "tile_full"
|
||||
directional = FALSE
|
||||
|
||||
/datum/paintable_decal/tile/corner
|
||||
name = "Corner"
|
||||
icon_state = "tile_corner"
|
||||
|
||||
/datum/paintable_decal/tile/half
|
||||
name = "Half"
|
||||
icon_state = "tile_half_contrasted"
|
||||
|
||||
/datum/paintable_decal/tile/half_full
|
||||
name = "Full Half"
|
||||
icon_state = "tile_half"
|
||||
|
||||
/datum/paintable_decal/tile/opposing_corners
|
||||
name = "Opposing Corners"
|
||||
icon_state = "tile_opposing_corners"
|
||||
|
||||
/datum/paintable_decal/tile/anticorner
|
||||
name = "3 Corners"
|
||||
icon_state = "tile_anticorner_contrasted"
|
||||
|
||||
/datum/paintable_decal/tile/tram
|
||||
name = "Tram"
|
||||
icon_state = "tile_tram"
|
||||
|
||||
/datum/paintable_decal/tile/diagonal_centre
|
||||
name = "Diagonal Centre"
|
||||
icon_state = "diagonal_centre"
|
||||
directional = FALSE
|
||||
|
||||
/datum/paintable_decal/tile/diagonal_edge
|
||||
name = "Diagonal Edge"
|
||||
icon_state = "diagonal_edge"
|
||||
directional = FALSE
|
||||
|
||||
// Tile trimlines
|
||||
/datum/paintable_decal/trimline
|
||||
|
||||
/datum/paintable_decal/trimline/filled_box
|
||||
name = "Trimline Filled Box"
|
||||
icon_state = "trimline_box_fill"
|
||||
directional = FALSE
|
||||
|
||||
/datum/paintable_decal/trimline/filled_corner
|
||||
name = "Trimline Filled Corner"
|
||||
icon_state = "trimline_corner_fill"
|
||||
|
||||
/datum/paintable_decal/trimline/filled
|
||||
name = "Trimline Filled"
|
||||
icon_state = "trimline_fill"
|
||||
|
||||
/datum/paintable_decal/trimline/filled_l
|
||||
name = "Trimline Filled L"
|
||||
icon_state = "trimline_fill__8" // 8 dir sprite
|
||||
|
||||
/datum/paintable_decal/trimline/filled_end
|
||||
name = "Trimline Filled End"
|
||||
icon_state = "trimline_end_fill"
|
||||
|
||||
/datum/paintable_decal/trimline/box
|
||||
name = "Trimline Box"
|
||||
icon_state = "trimline_box"
|
||||
directional = FALSE
|
||||
|
||||
/datum/paintable_decal/trimline/corner
|
||||
name = "Trimline Corner"
|
||||
icon_state = "trimline_corner"
|
||||
|
||||
/datum/paintable_decal/trimline/circle
|
||||
name = "Trimline Circle"
|
||||
icon_state = "trimline"
|
||||
|
||||
/datum/paintable_decal/trimline/l
|
||||
name = "Trimline L"
|
||||
icon_state = "trimline__8" // 8 dir sprite
|
||||
|
||||
/datum/paintable_decal/trimline/end
|
||||
name = "Trimline End"
|
||||
icon_state = "trimline_end"
|
||||
|
||||
/datum/paintable_decal/trimline/connector_l
|
||||
name = "Trimline Connector L"
|
||||
icon_state = "trimline_shrink_cw"
|
||||
|
||||
/datum/paintable_decal/trimline/connector_r
|
||||
name = "Trimline Connector R"
|
||||
icon_state = "trimline_shrink_ccw"
|
||||
|
||||
/datum/paintable_decal/trimline/arrow_l_filled
|
||||
name = "Trimline Arrow L Filled"
|
||||
icon_state = "trimline_arrow_cw_fill"
|
||||
|
||||
/datum/paintable_decal/trimline/arrow_r_filled
|
||||
name = "Trimline Arrow R Filled"
|
||||
icon_state = "trimline_arrow_ccw_fill"
|
||||
|
||||
/datum/paintable_decal/trimline/warn_filled
|
||||
name = "Trimline Warn Filled"
|
||||
icon_state = "trimline_warn_fill"
|
||||
|
||||
/datum/paintable_decal/trimline/warn_filled_l
|
||||
name = "Trimline Warn Filled L"
|
||||
icon_state = "trimline_warn_fill__8" // 8 dir sprite
|
||||
|
||||
/datum/paintable_decal/trimline/warn_filled_corner
|
||||
name = "Trimline Warn Filled Corner"
|
||||
icon_state = "trimline_corner_warn_fill"
|
||||
|
||||
/datum/paintable_decal/trimline/warn
|
||||
name = "Trimline Warn"
|
||||
icon_state = "trimline_warn"
|
||||
|
||||
/datum/paintable_decal/trimline/warn_l
|
||||
name = "Trimline Warn L"
|
||||
icon_state = "trimline_warn__8" // 8 dir sprite
|
||||
|
||||
/datum/paintable_decal/trimline/arrow_l
|
||||
name = "Trimline Arrow L"
|
||||
icon_state = "trimline_arrow_cw"
|
||||
|
||||
/datum/paintable_decal/trimline/arrow_r
|
||||
name = "Trimline Arrow R"
|
||||
icon_state = "trimline_arrow_ccw"
|
||||
|
||||
/datum/paintable_decal/trimline/mid_joiner
|
||||
name = "Trimline Mid Joiner"
|
||||
icon_state = "trimline_mid"
|
||||
|
||||
/datum/paintable_decal/trimline/mid_joiner_filled
|
||||
name = "Trimline Mid Joiner Filled"
|
||||
icon_state = "trimline_mid_fill"
|
||||
|
||||
/datum/paintable_decal/trimline/tram
|
||||
name = "Trimline Tram"
|
||||
icon_state = "trimline_tram"
|
||||
|
||||
// Generic warning decals of each color
|
||||
/datum/paintable_decal/warning
|
||||
|
||||
/datum/paintable_decal/warning/line
|
||||
name = "Warning Line"
|
||||
icon_state = "warningline"
|
||||
|
||||
/datum/paintable_decal/warning/line_corner
|
||||
name = "Warning Line Corner"
|
||||
icon_state = "warninglinecorner"
|
||||
|
||||
/datum/paintable_decal/warning/caution
|
||||
name = "Caution Label"
|
||||
icon_state = "caution"
|
||||
|
||||
/datum/paintable_decal/warning/arrows
|
||||
name = "Directional Arrows"
|
||||
icon_state = "arrows"
|
||||
|
||||
/datum/paintable_decal/warning/stand_clear
|
||||
name = "Stand Clear Label"
|
||||
icon_state = "stand_clear"
|
||||
|
||||
/datum/paintable_decal/warning/bot
|
||||
name = "Bot"
|
||||
icon_state = "bot"
|
||||
directional = FALSE
|
||||
|
||||
/datum/paintable_decal/warning/loading
|
||||
name = "Loading Zone"
|
||||
icon_state = "loadingarea"
|
||||
|
||||
/datum/paintable_decal/warning/box
|
||||
name = "Box"
|
||||
icon_state = "box"
|
||||
directional = FALSE
|
||||
|
||||
/datum/paintable_decal/warning/box_corners
|
||||
name = "Box Corner"
|
||||
icon_state = "box_corners"
|
||||
|
||||
/datum/paintable_decal/warning/delivery
|
||||
name = "Delivery Marker"
|
||||
icon_state = "delivery"
|
||||
directional = FALSE
|
||||
|
||||
/datum/paintable_decal/warning/warn_full
|
||||
name = "Warning Box"
|
||||
icon_state = "warn_full"
|
||||
directional = FALSE
|
||||
|
||||
// Plain colored siding
|
||||
/datum/paintable_decal/colored_siding
|
||||
|
||||
/datum/paintable_decal/colored_siding/line
|
||||
name = "Siding"
|
||||
icon_state = "siding_plain"
|
||||
|
||||
/datum/paintable_decal/colored_siding/line_corner
|
||||
name = "Siding Corner"
|
||||
icon_state = "siding_plain_corner"
|
||||
|
||||
/datum/paintable_decal/colored_siding/line_end
|
||||
name = "Siding End"
|
||||
icon_state = "siding_plain_end"
|
||||
|
||||
/datum/paintable_decal/colored_siding/line_inner_corner
|
||||
name = "Siding Inner Corner"
|
||||
icon_state = "siding_plain_corner_inner"
|
||||
|
||||
// Sidings which are not colored / have a specific pattern, texture, etc
|
||||
/datum/paintable_decal/siding
|
||||
|
||||
/datum/paintable_decal/siding/wood
|
||||
|
||||
/datum/paintable_decal/siding/wood/line
|
||||
name = "Wood Siding"
|
||||
icon_state = "siding_wood"
|
||||
|
||||
/datum/paintable_decal/siding/wood/line_corner
|
||||
name = "Wood Siding Corner"
|
||||
icon_state = "siding_wood_corner"
|
||||
|
||||
/datum/paintable_decal/siding/wood/line_end
|
||||
name = "Wood Siding End"
|
||||
icon_state = "siding_wood_end"
|
||||
|
||||
/datum/paintable_decal/siding/wood/line_inner_corner
|
||||
name = "Wood Siding Inner Corner"
|
||||
icon_state = "siding_wood__8" // 8 dir sprite
|
||||
|
||||
// Thin plating sidings and all color variations
|
||||
/datum/paintable_decal/plating/thinplating
|
||||
|
||||
/datum/paintable_decal/plating/thinplating/line
|
||||
name = "Thin Plating Siding"
|
||||
icon_state = "siding_thinplating"
|
||||
|
||||
/datum/paintable_decal/plating/thinplating/line_corner
|
||||
name = "Thin Plating Siding Corner"
|
||||
icon_state = "siding_thinplating_corner"
|
||||
|
||||
/datum/paintable_decal/plating/thinplating/line_end
|
||||
name = "Thin Plating Siding End"
|
||||
icon_state = "siding_thinplating_end"
|
||||
|
||||
/datum/paintable_decal/plating/thinplating/line_inner_corner
|
||||
name = "Thin Plating Siding Inner Corner"
|
||||
icon_state = "siding_thinplating__8" // 8 dir sprite
|
||||
|
||||
// Alt / new thin plating sidings and all color variations
|
||||
/datum/paintable_decal/plating/thinplatingalt
|
||||
|
||||
/datum/paintable_decal/plating/thinplatingalt/line
|
||||
name = "Thin Plating Alt Siding"
|
||||
icon_state = "siding_thinplating_new"
|
||||
|
||||
/datum/paintable_decal/plating/thinplatingalt/line_corner
|
||||
name = "Thin Plating Alt Siding Corner"
|
||||
icon_state = "siding_thinplating_new_corner"
|
||||
|
||||
/datum/paintable_decal/plating/thinplatingalt/line_end
|
||||
name = "Thin Plating Alt Siding End"
|
||||
icon_state = "siding_thinplating_new_end"
|
||||
|
||||
/datum/paintable_decal/plating/thinplatingalt/line_inner_corner
|
||||
name = "Thin Plating Alt Siding Inner Corner"
|
||||
icon_state = "siding_thinplating_new__8" // 8 dir sprite
|
||||
|
||||
// Wide plating sidings and all color variations
|
||||
/datum/paintable_decal/plating/wideplating
|
||||
|
||||
/datum/paintable_decal/plating/wideplating/line
|
||||
name = "Wide Plating Siding"
|
||||
icon_state = "siding_wideplating"
|
||||
|
||||
/datum/paintable_decal/plating/wideplating/line_corner
|
||||
name = "Wide Plating Siding Corner"
|
||||
icon_state = "siding_wideplating_corner"
|
||||
|
||||
/datum/paintable_decal/plating/wideplating/line_end
|
||||
name = "Wide Plating Siding End"
|
||||
icon_state = "siding_wideplating_end"
|
||||
|
||||
/datum/paintable_decal/plating/wideplating/line_inner_corner
|
||||
name = "Wide Plating Siding Inner Corner"
|
||||
icon_state = "siding_wideplating__8" // 8 dir sprite
|
||||
|
||||
// Alt / new wide plating sidings and all color variations
|
||||
/datum/paintable_decal/plating/wideplatingalt
|
||||
|
||||
/datum/paintable_decal/plating/wideplatingalt/line
|
||||
name = "Wide Plating Alt Siding"
|
||||
icon_state = "siding_wideplating_new"
|
||||
|
||||
/datum/paintable_decal/plating/wideplatingalt/line_corner
|
||||
name = "Wide Plating Alt Siding Corner"
|
||||
icon_state = "siding_wideplating_new_corner"
|
||||
|
||||
/datum/paintable_decal/plating/wideplatingalt/line_end
|
||||
name = "Wide Plating Alt Siding End"
|
||||
icon_state = "siding_wideplating_new_end"
|
||||
|
||||
/datum/paintable_decal/plating/wideplatingalt/line_inner_corner
|
||||
name = "Wide Plating Alt Siding Inner Corner"
|
||||
icon_state = "siding_wideplating_new__8" // 8 dir sprite
|
||||
Reference in New Issue
Block a user